lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::Lock);
   9 use DBI;
  10 use PublicInbox::ContentHash qw(git_sha);
  11 use Carp ();
  12
  13 sub dbh_new {
  14         my ($self, $rw) = @_;
  15         my $f = $self->{filename};
  16         my $creat = $rw && !-s $f;
  17         if ($creat) {
  18                 require PublicInbox::Spawn;
  19                 open my $fh, '+>>', $f or Carp::croak "open($f): $!";
  20                 PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  21         }
  22         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  23                 AutoCommit => 1,
  24                 RaiseError => 1,
  25                 PrintError => 0,
  26                 ReadOnly => !$rw,
  27                 sqlite_use_immediate_transaction => 1,
  28         });
  29         # no sqlite_unicode, here, all strings are binary
  30         create_tables($self, $dbh) if $rw;
  31         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  32         $dbh->do('PRAGMA case_sensitive_like = ON');
  33         $dbh;
  34 }
  35
  36 sub new {
  37         my ($cls, $f) = @_;
  38         bless {
  39                 filename => $f,
  40                 fmap => {},
  41                 lock_path => "$f.flock",
  42         }, $cls;
  43 }
  44
  45 sub lms_write_prepare { ($_[0]->{dbh} //= dbh_new($_[0], 1)); $_[0] }
  46
  47 sub lms_pause {
  48         my ($self) = @_;
  49         $self->{fmap} = {};
  50         delete $self->{dbh};
  51 }
  52
  53 sub create_tables {
  54         my ($self, $dbh) = @_;
  55         my $lk = $self->lock_for_scope;
  56
  57         $dbh->do(<<'');
  58 CREATE TABLE IF NOT EXISTS folders (
  59         fid INTEGER PRIMARY KEY,
  60         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  61         UNIQUE (loc)
  62 )
  63
  64         $dbh->do(<<'');
  65 CREATE TABLE IF NOT EXISTS blob2num (
  66         oidbin VARBINARY NOT NULL,
  67         fid INTEGER NOT NULL, /* folder ID */
  68         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  69         UNIQUE (oidbin, fid, uid)
  70 )
  71
  72         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  73         $dbh->do(<<'');
  74 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  75
  76         $dbh->do(<<'');
  77 CREATE TABLE IF NOT EXISTS blob2name (
  78         oidbin VARBINARY NOT NULL,
  79         fid INTEGER NOT NULL, /* folder ID */
  80         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  81         UNIQUE (oidbin, fid, name)
  82 )
  83
  84         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  85         $dbh->do(<<'');
  86 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  87
  88 }
  89
  90 sub fid_for {
  91         my ($self, $folder, $rw) = @_;
  92         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  93         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  94         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  95         return $fid if defined $fid;
  96
  97         # caller had trailing slash (LeiToMail)
  98         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  99                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
 100                 if (defined $fid) {
 101                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 102 UPDATE folders SET loc = ? WHERE fid = ?
 103 EOM
 104                         return $fid;
 105                 }
 106         # sometimes we stored trailing slash..
 107         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
 108                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
 109                 if (defined $fid) {
 110                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 111 UPDATE folders SET loc = ? WHERE fid = ?
 112 EOM
 113                         return $fid;
 114                 }
 115         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
 116                 require PublicInbox::URIimap;
 117                 PublicInbox::URIimap->new($folder)->uidvalidity //
 118                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 119         }
 120         return unless $rw;
 121
 122         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 123
 124         $fid += 1;
 125         # in case we're reusing, clobber existing stale refs:
 126         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 127         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 128
 129         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 130         $sth->execute($fid, $folder);
 131
 132         $fid;
 133 }
 134
 135 sub add_folders {
 136         my ($self, @folders) = @_;
 137         my $lk = $self->lock_for_scope;
 138         for my $f (@folders) { $self->{fmap}->{$f} //= fid_for($self, $f, 1) }
 139 }
 140
 141 sub set_src {
 142         my ($self, $oidbin, $folder, $id) = @_;
 143         my $lk = $self->lock_for_scope;
 144         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 145         my $sth;
 146         if (ref($id)) { # scalar name
 147                 $id = $$id;
 148                 $sth = $self->{dbh}->prepare_cached(<<'');
 149 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 150
 151         } else { # numeric ID (IMAP UID, MH number)
 152                 $sth = $self->{dbh}->prepare_cached(<<'');
 153 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 154
 155         }
 156         $sth->execute($oidbin, $fid, $id);
 157 }
 158
 159 sub clear_src {
 160         my ($self, $folder, $id) = @_;
 161         my $lk = $self->lock_for_scope;
 162         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 163         my $sth;
 164         if (ref($id)) { # scalar name
 165                 $id = $$id;
 166                 $sth = $self->{dbh}->prepare_cached(<<'');
 167 DELETE FROM blob2name WHERE fid = ? AND name = ?
 168
 169         } else {
 170                 $sth = $self->{dbh}->prepare_cached(<<'');
 171 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 172
 173         }
 174         $sth->execute($fid, $id);
 175 }
 176
 177 # Maildir-only
 178 sub mv_src {
 179         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 180         my $lk = $self->lock_for_scope;
 181         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 182         my $sth = $self->{dbh}->prepare_cached(<<'');
 183 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 184
 185         my $nr = $sth->execute($newbn, $fid, $oidbin, $$id);
 186         if ($nr == 0) { # may race with a clear_src, ensure new value exists
 187                 $sth = $self->{dbh}->prepare_cached(<<'');
 188 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 189
 190                 $sth->execute($oidbin, $fid, $newbn);
 191         }
 192 }
 193
 194 # read-only, iterates every oidbin + UID or name for a given folder
 195 sub each_src {
 196         my ($self, $folder, $cb, @args) = @_;
 197         my $dbh = $self->{dbh} //= dbh_new($self);
 198         my $fid;
 199         if (ref($folder) eq 'HASH') {
 200                 $fid = $folder->{fid} // die "BUG: no `fid'";
 201         } else {
 202                 $fid = $self->{fmap}->{$folder} //=
 203                         fid_for($self, $folder) // return;
 204         }
 205
 206         # minimize implicit txn time to avoid blocking writers by
 207         # batching SELECTs.  This looks wonky but is necessary since
 208         # $cb-> may access the DB on its own.
 209         my $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 210 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ?
 211 ORDER BY _rowid_ ASC LIMIT 1000
 212
 213         my $min = @$ary ? $ary->[-1]->[0] : undef;
 214         while (defined $min) {
 215                 for my $row (@$ary) { $cb->($row->[1], $row->[2], @args) }
 216
 217                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 218 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ? AND _rowid_ > ?
 219 ORDER BY _rowid_ ASC LIMIT 1000
 220
 221                 $min = @$ary ? $ary->[-1]->[0] : undef;
 222         }
 223
 224         $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 225 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ?
 226 ORDER BY _rowid_ ASC LIMIT 1000
 227
 228         $min = @$ary ? $ary->[-1]->[0] : undef;
 229         while (defined $min) {
 230                 for my $row (@$ary) { $cb->($row->[1], \($row->[2]), @args) }
 231
 232                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 233 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ? AND _rowid_ > ?
 234 ORDER BY _rowid_ ASC LIMIT 1000
 235
 236                 $min = @$ary ? $ary->[-1]->[0] : undef;
 237         }
 238 }
 239
 240 sub location_stats {
 241         my ($self, $folder) = @_;
 242         my $dbh = $self->{dbh} //= dbh_new($self);
 243         my $fid;
 244         my $ret = {};
 245         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 246         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 247 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 248
 249         $ret->{'name.count'} = $row if $row;
 250         my $ntype = ($folder =~ m!\A(?:nntps?|s?news)://!i) ? 'article' :
 251                 (($folder =~ m!\Aimaps?://!i) ? 'uid' : "TODO<$folder>");
 252         for my $op (qw(count min max)) {
 253                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 254 SELECT $op(uid) FROM blob2num WHERE fid = ?
 255
 256                 $row or last;
 257                 $ret->{"$ntype.$op"} = $row;
 258         }
 259         $ret;
 260 }
 261
 262 # returns a { location => [ list-of-ids-or-names ] } mapping
 263 sub locations_for {
 264         my ($self, $oidbin) = @_;
 265         my ($fid, $sth, $id, %fid2id);
 266         my $dbh = $self->{dbh} //= dbh_new($self);
 267         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 268         $sth->execute($oidbin);
 269         while (my ($fid, $uid) = $sth->fetchrow_array) {
 270                 push @{$fid2id{$fid}}, $uid;
 271         }
 272         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 273         $sth->execute($oidbin);
 274         while (my ($fid, $name) = $sth->fetchrow_array) {
 275                 push @{$fid2id{$fid}}, $name;
 276         }
 277         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 278         my $ret = {};
 279         while (my ($fid, $ids) = each %fid2id) {
 280                 $sth->execute($fid);
 281                 my ($loc) = $sth->fetchrow_array;
 282                 unless (defined $loc) {
 283                         my $oidhex = unpack('H*', $oidbin);
 284                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 285                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 286                                 } @$ids;
 287                         next;
 288                 }
 289                 $ret->{$loc} = $ids;
 290         }
 291         scalar(keys %$ret) ? $ret : undef;
 292 }
 293
 294 # returns a list of folders used for completion
 295 sub folders {
 296         my ($self, $pfx) = @_;
 297         my $dbh = $self->{dbh} //= dbh_new($self);
 298         my $sql = 'SELECT loc FROM folders';
 299         my @pfx;
 300         if (defined $pfx) {
 301                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 302                 @pfx = ($pfx, '\\');
 303                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 304                 $pfx[0] .= '%';
 305         }
 306         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 307 }
 308
 309 sub local_blob {
 310         my ($self, $oidhex, $vrfy) = @_;
 311         my $dbh = $self->{dbh} //= dbh_new($self);
 312         my $b2n = $dbh->prepare(<<'');
 313 SELECT f.loc,b.name FROM blob2name b
 314 LEFT JOIN folders f ON b.fid = f.fid
 315 WHERE b.oidbin = ?
 316
 317         $b2n->execute(pack('H*', $oidhex));
 318         while (my ($d, $n) = $b2n->fetchrow_array) {
 319                 substr($d, 0, length('maildir:')) = '';
 320                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 321                 # in "new/", despite (from what I understand of reading
 322                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 323                 # applies to files in "cur/".
 324                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 325                 for my $x (@try) {
 326                         my $f = "$d/$x/$n";
 327                         open my $fh, '<', $f or next;
 328                         # some (buggy) Maildir writers are non-atomic:
 329                         next unless -s $fh;
 330                         local $/;
 331                         my $raw = <$fh>;
 332                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 333                                 warn "$f changed $oidhex\n";
 334                                 next;
 335                         }
 336                         return \$raw;
 337                 }
 338         }
 339         undef;
 340 }
 341
 342 sub match_imap_url {
 343         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 344         $all //= [ $self->folders ];
 345         require PublicInbox::URIimap;
 346         my $want = PublicInbox::URIimap->new($url)->canonical;
 347         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 348         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 349                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 350         my @match;
 351         for my $x (@uri) {
 352                 next if $x->mailbox ne $want->mailbox;
 353                 next if $x->host ne $want->host;
 354                 next if $x->port != $want->port;
 355                 my $x_uidval = $x->uidvalidity;
 356                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 357
 358                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 359                 if (defined($x->auth) && !defined($want->auth) &&
 360                                 !defined($want->user)) {
 361                         push @match, $x;
 362                 # or maybe user was forgotten on CLI:
 363                 } elsif (defined($x->user) && !defined($want->user)) {
 364                         push @match, $x;
 365                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 366                         push @match, $x;
 367                 }
 368         }
 369         return @match if wantarray;
 370         scalar(@match) <= 1 ? $match[0] :
 371                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 372 }
 373
 374 sub match_nntp_url ($$$) {
 375         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 376         $all //= [ $self->folders ];
 377         require PublicInbox::URInntps;
 378         my $want = PublicInbox::URInntps->new($url)->canonical;
 379         my ($s, $h, $p) = ($want->scheme, $want->host, $want->port);
 380         my $ng = $want->group; # force scalar (no article ranges)
 381         my @uri = map { PublicInbox::URInntps->new($_)->canonical }
 382                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$ng\E\b!, @$all);
 383         my @match;
 384         for my $x (@uri) {
 385                 next if $x->group ne $ng || $x->host ne $h || $x->port != $p;
 386                 # maybe user was forgotten on CLI:
 387                 if (defined($x->userinfo) && !defined($want->userinfo)) {
 388                         push @match, $x;
 389                 } elsif (($x->userinfo//"\0") eq ($want->userinfo//"\0")) {
 390                         push @match, $x;
 391                 }
 392         }
 393         return @match if wantarray;
 394         scalar(@match) <= 1 ? $match[0] :
 395                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 396 }
 397
 398 # returns undef on failure, number on success
 399 sub group2folders {
 400         my ($self, $lei, $all, $folders) = @_;
 401         return $lei->fail(<<EOM) if @$folders;
 402 --all= not compatible with @$folders on command-line
 403 EOM
 404         my %x = map { $_ => $_ } split(/,/, $all);
 405         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 406         push(@ok, '') if $all eq '';
 407         my @no = keys %x;
 408         if (@no) {
 409                 @no = (join(',', @no));
 410                 return $lei->fail(<<EOM);
 411 --all=@no not accepted (must be `local' and/or `remote')
 412 EOM
 413         }
 414         my (%seen, @inc);
 415         my @all = $self->folders;
 416         for my $ok (@ok) {
 417                 if ($ok eq 'local') {
 418                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 419                 } elsif ($ok eq 'remote') {
 420                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 421                 } elsif ($ok ne '') {
 422                         return $lei->fail("--all=$all not understood");
 423                 } else {
 424                         @inc = @all;
 425                 }
 426                 push(@$folders, (grep { !$seen{$_}++ } @inc));
 427         }
 428         scalar(@$folders) || $lei->fail(<<EOM);
 429 no --mail-sync folders known to lei
 430 EOM
 431 }
 432
 433 # map CLI args to folder table entries, returns undef on failure
 434 sub arg2folder {
 435         my ($self, $lei, $folders) = @_;
 436         my @all = $self->folders;
 437         my %all = map { $_ => 1 } @all;
 438         my ($err, @no);
 439         for (@$folders) {
 440                 next if $all{$_}; # ok
 441                 if (m!\A(maildir|mh):(.+)!i) {
 442                         my $type = lc $1;
 443                         my $d = "$type:".$lei->abs_path($2);
 444                         push(@no, $_) unless $all{$d};
 445                         $_ = $d;
 446                 } elsif (-d "$_/new" && -d "$_/cur") {
 447                         my $d = 'maildir:'.$lei->abs_path($_);
 448                         push(@no, $_) unless $all{$d};
 449                         $_ = $d;
 450                 } elsif (m!\Aimaps?://!i) {
 451                         my $orig = $_;
 452                         my $res = match_imap_url($self, $orig, \@all);
 453                         if (ref $res) {
 454                                 $_ = $$res;
 455                                 push(@{$err->{qerr}}, <<EOM);
 456 # using `$res' instead of `$orig'
 457 EOM
 458                         } else {
 459                                 $lei->err($res) if defined $res;
 460                                 push @no, $orig;
 461                         }
 462                 } elsif (m!\A(?:nntps?|s?news)://!i) {
 463                         my $orig = $_;
 464                         my $res = match_nntp_url($self, $orig, \@all);
 465                         if (ref $res) {
 466                                 $_ = $$res;
 467                                 push(@{$err->{qerr}}, <<EOM);
 468 # using `$res' instead of `$orig'
 469 EOM
 470                         } else {
 471                                 $lei->err($res) if defined $res;
 472                                 push @no, $orig;
 473                         }
 474                 } else {
 475                         push @no, $_;
 476                 }
 477         }
 478         if (@no) {
 479                 my $no = join("\n\t", @no);
 480                 $err->{fail} = <<EOF;
 481 No sync information for: $no
 482 Run `lei ls-mail-sync' to display valid choices
 483 EOF
 484         }
 485         $err;
 486 }
 487
 488 sub forget_folders {
 489         my ($self, @folders) = @_;
 490         my $lk = $self->lock_for_scope;
 491         for my $folder (@folders) {
 492                 my $fid = delete($self->{fmap}->{$folder}) //
 493                         fid_for($self, $folder) // next;
 494                 for my $t (qw(blob2name blob2num folders)) {
 495                         $self->{dbh}->do("DELETE FROM $t WHERE fid = ?",
 496                                         undef, $fid);
 497                 }
 498         }
 499 }
 500
 501 # only used for changing canonicalization errors
 502 sub rename_folder {
 503         my ($self, $old, $new) = @_;
 504         my $lk = $self->lock_for_scope;
 505         my $ofid = delete($self->{fmap}->{$old}) //
 506                 fid_for($self, $old) // return;
 507         eval {
 508                 $self->{dbh}->do(<<EOM, undef, $new, $ofid);
 509 UPDATE folders SET loc = ? WHERE fid = ?
 510 EOM
 511         };
 512         if ($@ =~ /\bunique\b/i) {
 513                 my $nfid = $self->{fmap}->{$new} // fid_for($self, $new);
 514                 for my $t (qw(blob2name blob2num)) {
 515                         $self->{dbh}->do(<<EOM, undef, $nfid, $ofid);
 516 UPDATE OR REPLACE $t SET fid = ? WHERE fid = ?
 517 EOM
 518                 }
 519                 $self->{dbh}->do(<<EOM, undef, $ofid);
 520 DELETE FROM folders WHERE fid = ?
 521 EOM
 522         }
 523 }
 524
 525 sub imap_oidbin ($$$) {
 526         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY
 527         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return;
 528         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 529 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ?
 530 EOM
 531         $sth->execute($fid, $uid);
 532         $sth->fetchrow_array;
 533 }
 534
 535 sub name_oidbin ($$$) {
 536         my ($self, $mdir, $nm) = @_;
 537         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 538         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 539 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 540 EOM
 541         $sth->execute($fid, $nm);
 542         $sth->fetchrow_array;
 543 }
 544
 545 sub imap_oid {
 546         my ($self, $lei, $uid_uri) = @_;
 547         my $mailbox_uri = $uid_uri->clone;
 548         $mailbox_uri->uid(undef);
 549         my $folders = [ $$mailbox_uri ];
 550         if (my $err = $self->arg2folder($lei, $folders)) {
 551                 if ($err->{fail}) {
 552                         $lei->qerr("# no sync information for $mailbox_uri");
 553                         return;
 554                 }
 555                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
 556         }
 557         my $oidbin = imap_oidbin($self, $folders->[0], $uid_uri->uid);
 558         $oidbin ? unpack('H*', $oidbin) : undef;
 559 }
 560
 561 1;