lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::Lock);
   9 use DBI;
  10 use PublicInbox::ContentHash qw(git_sha);
  11 use Carp ();
  12
  13 sub dbh_new {
  14         my ($self, $rw) = @_;
  15         my $f = $self->{filename};
  16         my $creat = $rw && !-s $f;
  17         if ($creat) {
  18                 require PublicInbox::Spawn;
  19                 open my $fh, '+>>', $f or Carp::croak "open($f): $!";
  20                 PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  21         }
  22         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  23                 AutoCommit => 1,
  24                 RaiseError => 1,
  25                 PrintError => 0,
  26                 ReadOnly => !$rw,
  27                 sqlite_use_immediate_transaction => 1,
  28         });
  29         # no sqlite_unicode, here, all strings are binary
  30         create_tables($self, $dbh) if $rw;
  31         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  32         $dbh->do('PRAGMA case_sensitive_like = ON');
  33         $dbh;
  34 }
  35
  36 sub new {
  37         my ($cls, $f) = @_;
  38         bless {
  39                 filename => $f,
  40                 fmap => {},
  41                 lock_path => "$f.flock",
  42         }, $cls;
  43 }
  44
  45 sub lms_write_prepare { ($_[0]->{dbh} //= dbh_new($_[0], 1)); $_[0] }
  46
  47 sub lms_pause {
  48         my ($self) = @_;
  49         $self->{fmap} = {};
  50         my $dbh = delete $self->{dbh};
  51         eval { $dbh->do('PRAGMA optimize') } if $dbh;
  52 }
  53
  54 sub create_tables {
  55         my ($self, $dbh) = @_;
  56         my $lk = $self->lock_for_scope;
  57
  58         $dbh->do(<<'');
  59 CREATE TABLE IF NOT EXISTS folders (
  60         fid INTEGER PRIMARY KEY,
  61         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  62         UNIQUE (loc)
  63 )
  64
  65         $dbh->do(<<'');
  66 CREATE TABLE IF NOT EXISTS blob2num (
  67         oidbin VARBINARY NOT NULL,
  68         fid INTEGER NOT NULL, /* folder ID */
  69         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  70         /* not UNIQUE(fid, uid), since we may have broken servers */
  71         UNIQUE (oidbin, fid, uid)
  72 )
  73
  74         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  75         $dbh->do(<<'');
  76 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  77
  78         $dbh->do(<<'');
  79 CREATE TABLE IF NOT EXISTS blob2name (
  80         oidbin VARBINARY NOT NULL,
  81         fid INTEGER NOT NULL, /* folder ID */
  82         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  83         /* not UNIQUE(fid, name), since we may have broken software */
  84         UNIQUE (oidbin, fid, name)
  85 )
  86
  87         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  88         $dbh->do(<<'');
  89 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  90
  91 }
  92
  93 sub fid_for {
  94         my ($self, $folder, $rw) = @_;
  95         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  96         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  97         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  98         return $fid if defined $fid;
  99
 100         # caller had trailing slash (LeiToMail)
 101         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
 102                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
 103                 if (defined $fid) {
 104                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 105 UPDATE folders SET loc = ? WHERE fid = ?
 106 EOM
 107                         return $fid;
 108                 }
 109         # sometimes we stored trailing slash..
 110         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
 111                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
 112                 if (defined $fid) {
 113                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 114 UPDATE folders SET loc = ? WHERE fid = ?
 115 EOM
 116                         return $fid;
 117                 }
 118         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
 119                 require PublicInbox::URIimap;
 120                 PublicInbox::URIimap->new($folder)->uidvalidity //
 121                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 122         }
 123         return unless $rw;
 124
 125         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 126
 127         $fid += 1;
 128         # in case we're reusing, clobber existing stale refs:
 129         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 130         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 131
 132         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 133         $sth->execute($fid, $folder);
 134
 135         $fid;
 136 }
 137
 138 sub add_folders {
 139         my ($self, @folders) = @_;
 140         my $lk = $self->lock_for_scope;
 141         for my $f (@folders) { $self->{fmap}->{$f} //= fid_for($self, $f, 1) }
 142 }
 143
 144 sub set_src {
 145         my ($self, $oidbin, $folder, $id) = @_;
 146         my $lk = $self->lock_for_scope;
 147         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 148         my $sth;
 149         if (ref($id)) { # scalar name
 150                 $id = $$id;
 151                 $sth = $self->{dbh}->prepare_cached(<<'');
 152 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 153
 154         } else { # numeric ID (IMAP UID, MH number)
 155                 $sth = $self->{dbh}->prepare_cached(<<'');
 156 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 157
 158         }
 159         $sth->execute($oidbin, $fid, $id);
 160 }
 161
 162 sub clear_src {
 163         my ($self, $folder, $id) = @_;
 164         my $lk = $self->lock_for_scope;
 165         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 166         my $sth;
 167         if (ref($id)) { # scalar name
 168                 $id = $$id;
 169                 $sth = $self->{dbh}->prepare_cached(<<'');
 170 DELETE FROM blob2name WHERE fid = ? AND name = ?
 171
 172         } else {
 173                 $sth = $self->{dbh}->prepare_cached(<<'');
 174 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 175
 176         }
 177         $sth->execute($fid, $id);
 178 }
 179
 180 # Maildir-only
 181 sub mv_src {
 182         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 183         my $lk = $self->lock_for_scope;
 184         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 185         my $sth = $self->{dbh}->prepare_cached(<<'');
 186 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 187
 188         my $nr = $sth->execute($newbn, $fid, $oidbin, $$id);
 189         if ($nr == 0) { # may race with a clear_src, ensure new value exists
 190                 $sth = $self->{dbh}->prepare_cached(<<'');
 191 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 192
 193                 $sth->execute($oidbin, $fid, $newbn);
 194         }
 195 }
 196
 197 # read-only, iterates every oidbin + UID or name for a given folder
 198 sub each_src {
 199         my ($self, $folder, $cb, @args) = @_;
 200         my $dbh = $self->{dbh} //= dbh_new($self);
 201         my ($fid, @rng);
 202         my $and_ge_le = '';
 203         if (ref($folder) eq 'HASH') {
 204                 $fid = $folder->{fid} // die "BUG: no `fid'";
 205                 @rng = grep(defined, @$folder{qw(min max)});
 206                 $and_ge_le = 'AND uid >= ? AND uid <= ?' if @rng;
 207         } else {
 208                 $fid = $self->{fmap}->{$folder} //=
 209                         fid_for($self, $folder) // return;
 210         }
 211
 212         # minimize implicit txn time to avoid blocking writers by
 213         # batching SELECTs.  This looks wonky but is necessary since
 214         # $cb-> may access the DB on its own.
 215         my $ary = $dbh->selectall_arrayref(<<"", undef, $fid, @rng);
 216 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ? $and_ge_le
 217 ORDER BY _rowid_ ASC LIMIT 1000
 218
 219         my $min = @$ary ? $ary->[-1]->[0] : undef;
 220         while (defined $min) {
 221                 for my $row (@$ary) { $cb->($row->[1], $row->[2], @args) }
 222
 223                 $ary = $dbh->selectall_arrayref(<<"", undef, $fid, @rng, $min);
 224 SELECT _rowid_,oidbin,uid FROM blob2num
 225 WHERE fid = ? $and_ge_le AND _rowid_ > ?
 226 ORDER BY _rowid_ ASC LIMIT 1000
 227
 228                 $min = @$ary ? $ary->[-1]->[0] : undef;
 229         }
 230
 231         $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 232 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ?
 233 ORDER BY _rowid_ ASC LIMIT 1000
 234
 235         $min = @$ary ? $ary->[-1]->[0] : undef;
 236         while (defined $min) {
 237                 for my $row (@$ary) { $cb->($row->[1], \($row->[2]), @args) }
 238
 239                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 240 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ? AND _rowid_ > ?
 241 ORDER BY _rowid_ ASC LIMIT 1000
 242
 243                 $min = @$ary ? $ary->[-1]->[0] : undef;
 244         }
 245 }
 246
 247 sub location_stats {
 248         my ($self, $folder) = @_;
 249         my $dbh = $self->{dbh} //= dbh_new($self);
 250         my $fid;
 251         my $ret = {};
 252         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 253         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 254 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 255
 256         $ret->{'name.count'} = $row if $row;
 257         my $ntype = ($folder =~ m!\A(?:nntps?|s?news)://!i) ? 'article' :
 258                 (($folder =~ m!\Aimaps?://!i) ? 'uid' : "TODO<$folder>");
 259         for my $op (qw(count min max)) {
 260                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 261 SELECT $op(uid) FROM blob2num WHERE fid = ?
 262
 263                 $row or last;
 264                 $ret->{"$ntype.$op"} = $row;
 265         }
 266         $ret;
 267 }
 268
 269 # returns a { location => [ list-of-ids-or-names ] } mapping
 270 sub locations_for {
 271         my ($self, $oidbin) = @_;
 272         my ($fid, $sth, $id, %fid2id);
 273         my $dbh = $self->{dbh} //= dbh_new($self);
 274         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 275         $sth->execute($oidbin);
 276         while (my ($fid, $uid) = $sth->fetchrow_array) {
 277                 push @{$fid2id{$fid}}, $uid;
 278         }
 279         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 280         $sth->execute($oidbin);
 281         while (my ($fid, $name) = $sth->fetchrow_array) {
 282                 push @{$fid2id{$fid}}, $name;
 283         }
 284         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 285         my $ret = {};
 286         while (my ($fid, $ids) = each %fid2id) {
 287                 $sth->execute($fid);
 288                 my ($loc) = $sth->fetchrow_array;
 289                 unless (defined $loc) {
 290                         my $oidhex = unpack('H*', $oidbin);
 291                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 292                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 293                                 } @$ids;
 294                         next;
 295                 }
 296                 $ret->{$loc} = $ids;
 297         }
 298         scalar(keys %$ret) ? $ret : undef;
 299 }
 300
 301 # returns a list of folders used for completion
 302 sub folders {
 303         my ($self, @pfx) = @_;
 304         my $sql = 'SELECT loc FROM folders';
 305         if (defined($pfx[0])) {
 306                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 307                 my $anywhere = !!$pfx[1];
 308                 $pfx[1] = '\\';
 309                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 310                 $pfx[0] .= '%';
 311                 substr($pfx[0], 0, 0, '%') if $anywhere;
 312         } else {
 313                 @pfx = (); # [0] may've been undef
 314         }
 315         my $dbh = $self->{dbh} //= dbh_new($self);
 316         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 317 }
 318
 319 sub local_blob {
 320         my ($self, $oidhex, $vrfy) = @_;
 321         my $dbh = $self->{dbh} //= dbh_new($self);
 322         my $b2n = $dbh->prepare(<<'');
 323 SELECT f.loc,b.name FROM blob2name b
 324 LEFT JOIN folders f ON b.fid = f.fid
 325 WHERE b.oidbin = ?
 326
 327         $b2n->execute(pack('H*', $oidhex));
 328         while (my ($d, $n) = $b2n->fetchrow_array) {
 329                 substr($d, 0, length('maildir:')) = '';
 330                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 331                 # in "new/", despite (from what I understand of reading
 332                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 333                 # applies to files in "cur/".
 334                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 335                 for my $x (@try) {
 336                         my $f = "$d/$x/$n";
 337                         open my $fh, '<', $f or next;
 338                         # some (buggy) Maildir writers are non-atomic:
 339                         next unless -s $fh;
 340                         local $/;
 341                         my $raw = <$fh>;
 342                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 343                                 warn "$f changed $oidhex\n";
 344                                 next;
 345                         }
 346                         return \$raw;
 347                 }
 348         }
 349         undef;
 350 }
 351
 352 sub match_imap_url {
 353         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 354         $all //= [ $self->folders ];
 355         require PublicInbox::URIimap;
 356         my $want = PublicInbox::URIimap->new($url)->canonical;
 357         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 358         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 359                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 360         my @match;
 361         for my $x (@uri) {
 362                 next if $x->mailbox ne $want->mailbox;
 363                 next if $x->host ne $want->host;
 364                 next if $x->port != $want->port;
 365                 my $x_uidval = $x->uidvalidity;
 366                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 367
 368                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 369                 if (defined($x->auth) && !defined($want->auth) &&
 370                                 !defined($want->user)) {
 371                         push @match, $x;
 372                 # or maybe user was forgotten on CLI:
 373                 } elsif (defined($x->user) && !defined($want->user)) {
 374                         push @match, $x;
 375                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 376                         push @match, $x;
 377                 }
 378         }
 379         return @match if wantarray;
 380         scalar(@match) <= 1 ? $match[0] :
 381                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 382 }
 383
 384 sub match_nntp_url ($$$) {
 385         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 386         $all //= [ $self->folders ];
 387         require PublicInbox::URInntps;
 388         my $want = PublicInbox::URInntps->new($url)->canonical;
 389         my ($s, $h, $p) = ($want->scheme, $want->host, $want->port);
 390         my $ng = $want->group; # force scalar (no article ranges)
 391         my @uri = map { PublicInbox::URInntps->new($_)->canonical }
 392                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$ng\E\b!, @$all);
 393         my @match;
 394         for my $x (@uri) {
 395                 next if $x->group ne $ng || $x->host ne $h || $x->port != $p;
 396                 # maybe user was forgotten on CLI:
 397                 if (defined($x->userinfo) && !defined($want->userinfo)) {
 398                         push @match, $x;
 399                 } elsif (($x->userinfo//"\0") eq ($want->userinfo//"\0")) {
 400                         push @match, $x;
 401                 }
 402         }
 403         return @match if wantarray;
 404         scalar(@match) <= 1 ? $match[0] :
 405                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 406 }
 407
 408 # returns undef on failure, number on success
 409 sub group2folders {
 410         my ($self, $lei, $all, $folders) = @_;
 411         return $lei->fail(<<EOM) if @$folders;
 412 --all= not compatible with @$folders on command-line
 413 EOM
 414         my %x = map { $_ => $_ } split(/,/, $all);
 415         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 416         push(@ok, '') if $all eq '';
 417         my @no = keys %x;
 418         if (@no) {
 419                 @no = (join(',', @no));
 420                 return $lei->fail(<<EOM);
 421 --all=@no not accepted (must be `local' and/or `remote')
 422 EOM
 423         }
 424         my (%seen, @inc);
 425         my @all = $self->folders;
 426         for my $ok (@ok) {
 427                 if ($ok eq 'local') {
 428                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 429                 } elsif ($ok eq 'remote') {
 430                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 431                 } elsif ($ok ne '') {
 432                         return $lei->fail("--all=$all not understood");
 433                 } else {
 434                         @inc = @all;
 435                 }
 436                 push(@$folders, (grep { !$seen{$_}++ } @inc));
 437         }
 438         scalar(@$folders) || $lei->fail(<<EOM);
 439 no --mail-sync folders known to lei
 440 EOM
 441 }
 442
 443 # map CLI args to folder table entries, returns undef on failure
 444 sub arg2folder {
 445         my ($self, $lei, $folders) = @_;
 446         my @all = $self->folders;
 447         my %all = map { $_ => 1 } @all;
 448         my @no;
 449         for (@$folders) {
 450                 next if $all{$_}; # ok
 451                 if (m!\A(maildir|mh):(.+)!i) {
 452                         my $type = lc $1;
 453                         my $d = "$type:".$lei->abs_path($2);
 454                         push(@no, $_) unless $all{$d};
 455                         $_ = $d;
 456                 } elsif (-d "$_/new" && -d "$_/cur") {
 457                         my $d = 'maildir:'.$lei->abs_path($_);
 458                         push(@no, $_) unless $all{$d};
 459                         $_ = $d;
 460                 } elsif (m!\Aimaps?://!i) {
 461                         my $orig = $_;
 462                         my $res = match_imap_url($self, $orig, \@all);
 463                         if (ref $res) {
 464                                 $_ = $$res;
 465                                 $lei->qerr(<<EOM);
 466 # using `$res' instead of `$orig'
 467 EOM
 468                         } else {
 469                                 warn($res, "\n") if defined $res;
 470                                 push @no, $orig;
 471                         }
 472                 } elsif (m!\A(?:nntps?|s?news)://!i) {
 473                         my $orig = $_;
 474                         my $res = match_nntp_url($self, $orig, \@all);
 475                         if (ref $res) {
 476                                 $_ = $$res;
 477                                 $lei->qerr(<<EOM);
 478 # using `$res' instead of `$orig'
 479 EOM
 480                         } else {
 481                                 warn($res, "\n") if defined $res;
 482                                 push @no, $orig;
 483                         }
 484                 } else {
 485                         push @no, $_;
 486                 }
 487         }
 488         if (@no) {
 489                 my $no = join("\n\t", @no);
 490                 die <<EOF;
 491 No sync information for: $no
 492 Run `lei ls-mail-sync' to display valid choices
 493 EOF
 494         }
 495 }
 496
 497 sub forget_folders {
 498         my ($self, @folders) = @_;
 499         my $lk = $self->lock_for_scope;
 500         for my $folder (@folders) {
 501                 my $fid = delete($self->{fmap}->{$folder}) //
 502                         fid_for($self, $folder) // next;
 503                 for my $t (qw(blob2name blob2num folders)) {
 504                         $self->{dbh}->do("DELETE FROM $t WHERE fid = ?",
 505                                         undef, $fid);
 506                 }
 507         }
 508 }
 509
 510 # only used for changing canonicalization errors
 511 sub rename_folder {
 512         my ($self, $old, $new) = @_;
 513         my $lk = $self->lock_for_scope;
 514         my $ofid = delete($self->{fmap}->{$old}) //
 515                 fid_for($self, $old) // return;
 516         eval {
 517                 $self->{dbh}->do(<<EOM, undef, $new, $ofid);
 518 UPDATE folders SET loc = ? WHERE fid = ?
 519 EOM
 520         };
 521         if ($@ =~ /\bunique\b/i) {
 522                 my $nfid = $self->{fmap}->{$new} // fid_for($self, $new);
 523                 for my $t (qw(blob2name blob2num)) {
 524                         $self->{dbh}->do(<<EOM, undef, $nfid, $ofid);
 525 UPDATE OR REPLACE $t SET fid = ? WHERE fid = ?
 526 EOM
 527                 }
 528                 $self->{dbh}->do(<<EOM, undef, $ofid);
 529 DELETE FROM folders WHERE fid = ?
 530 EOM
 531         }
 532 }
 533
 534 sub num_oidbin ($$$) {
 535         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY if IMAP
 536         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return ();
 537         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 538 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ? ORDER BY _rowid_
 539 EOM
 540         $sth->execute($fid, $uid);
 541         map { $_->[0] } @{$sth->fetchall_arrayref};
 542 }
 543
 544 sub name_oidbin ($$$) {
 545         my ($self, $mdir, $nm) = @_;
 546         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 547         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 548 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 549 EOM
 550         $sth->execute($fid, $nm);
 551         map { $_->[0] } @{$sth->fetchall_arrayref};
 552 }
 553
 554 sub imap_oidhex {
 555         my ($self, $lei, $uid_uri) = @_;
 556         my $mailbox_uri = $uid_uri->clone;
 557         $mailbox_uri->uid(undef);
 558         my $folders = [ $$mailbox_uri ];
 559         eval { $self->arg2folder($lei, $folders) };
 560         $lei->qerr("# no sync information for $mailbox_uri") if $@;
 561         map { unpack('H*',$_) } num_oidbin($self, $folders->[0], $uid_uri->uid)
 562 }
 563
 564 1;