lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::Lock);
   9 use DBI;
  10 use PublicInbox::ContentHash qw(git_sha);
  11 use Carp ();
  12
  13 sub dbh_new {
  14         my ($self, $rw) = @_;
  15         my $f = $self->{filename};
  16         my $creat = $rw && !-s $f;
  17         if ($creat) {
  18                 require PublicInbox::Spawn;
  19                 open my $fh, '+>>', $f or Carp::croak "open($f): $!";
  20                 PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  21         }
  22         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  23                 AutoCommit => 1,
  24                 RaiseError => 1,
  25                 PrintError => 0,
  26                 ReadOnly => !$rw,
  27                 sqlite_use_immediate_transaction => 1,
  28         });
  29         # no sqlite_unicode, here, all strings are binary
  30         create_tables($self, $dbh) if $rw;
  31         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  32         $dbh->do('PRAGMA case_sensitive_like = ON');
  33         $dbh;
  34 }
  35
  36 sub new {
  37         my ($cls, $f) = @_;
  38         bless {
  39                 filename => $f,
  40                 fmap => {},
  41                 lock_path => "$f.flock",
  42         }, $cls;
  43 }
  44
  45 sub lms_write_prepare { ($_[0]->{dbh} //= dbh_new($_[0], 1)); $_[0] }
  46
  47 sub lms_pause {
  48         my ($self) = @_;
  49         $self->{fmap} = {};
  50         delete $self->{dbh};
  51 }
  52
  53 sub create_tables {
  54         my ($self, $dbh) = @_;
  55         my $lk = $self->lock_for_scope;
  56
  57         $dbh->do(<<'');
  58 CREATE TABLE IF NOT EXISTS folders (
  59         fid INTEGER PRIMARY KEY,
  60         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  61         UNIQUE (loc)
  62 )
  63
  64         $dbh->do(<<'');
  65 CREATE TABLE IF NOT EXISTS blob2num (
  66         oidbin VARBINARY NOT NULL,
  67         fid INTEGER NOT NULL, /* folder ID */
  68         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  69         UNIQUE (oidbin, fid, uid)
  70 )
  71
  72         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  73         $dbh->do(<<'');
  74 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  75
  76         $dbh->do(<<'');
  77 CREATE TABLE IF NOT EXISTS blob2name (
  78         oidbin VARBINARY NOT NULL,
  79         fid INTEGER NOT NULL, /* folder ID */
  80         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  81         UNIQUE (oidbin, fid, name)
  82 )
  83
  84         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  85         $dbh->do(<<'');
  86 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  87
  88 }
  89
  90 sub fid_for {
  91         my ($self, $folder, $rw) = @_;
  92         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  93         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  94         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  95         return $fid if defined $fid;
  96
  97         # caller had trailing slash (LeiToMail)
  98         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  99                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
 100                 if (defined $fid) {
 101                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 102 UPDATE folders SET loc = ? WHERE fid = ?
 103 EOM
 104                         return $fid;
 105                 }
 106         # sometimes we stored trailing slash..
 107         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
 108                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
 109                 if (defined $fid) {
 110                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 111 UPDATE folders SET loc = ? WHERE fid = ?
 112 EOM
 113                         return $fid;
 114                 }
 115         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
 116                 require PublicInbox::URIimap;
 117                 PublicInbox::URIimap->new($folder)->uidvalidity //
 118                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 119         }
 120         return unless $rw;
 121
 122         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 123
 124         $fid += 1;
 125         # in case we're reusing, clobber existing stale refs:
 126         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 127         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 128
 129         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 130         $sth->execute($fid, $folder);
 131
 132         $fid;
 133 }
 134
 135 sub add_folders {
 136         my ($self, @folders) = @_;
 137         my $lk = $self->lock_for_scope;
 138         for my $f (@folders) { $self->{fmap}->{$f} //= fid_for($self, $f, 1) }
 139 }
 140
 141 sub set_src {
 142         my ($self, $oidbin, $folder, $id) = @_;
 143         my $lk = $self->lock_for_scope;
 144         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 145         my $sth;
 146         if (ref($id)) { # scalar name
 147                 $id = $$id;
 148                 $sth = $self->{dbh}->prepare_cached(<<'');
 149 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 150
 151         } else { # numeric ID (IMAP UID, MH number)
 152                 $sth = $self->{dbh}->prepare_cached(<<'');
 153 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 154
 155         }
 156         $sth->execute($oidbin, $fid, $id);
 157 }
 158
 159 sub clear_src {
 160         my ($self, $folder, $id) = @_;
 161         my $lk = $self->lock_for_scope;
 162         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 163         my $sth;
 164         if (ref($id)) { # scalar name
 165                 $id = $$id;
 166                 $sth = $self->{dbh}->prepare_cached(<<'');
 167 DELETE FROM blob2name WHERE fid = ? AND name = ?
 168
 169         } else {
 170                 $sth = $self->{dbh}->prepare_cached(<<'');
 171 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 172
 173         }
 174         $sth->execute($fid, $id);
 175 }
 176
 177 # Maildir-only
 178 sub mv_src {
 179         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 180         my $lk = $self->lock_for_scope;
 181         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 182         my $sth = $self->{dbh}->prepare_cached(<<'');
 183 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 184
 185         my $nr = $sth->execute($newbn, $fid, $oidbin, $$id);
 186         if ($nr == 0) { # may race with a clear_src, ensure new value exists
 187                 $sth = $self->{dbh}->prepare_cached(<<'');
 188 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 189
 190                 $sth->execute($oidbin, $fid, $newbn);
 191         }
 192 }
 193
 194 # read-only, iterates every oidbin + UID or name for a given folder
 195 sub each_src {
 196         my ($self, $folder, $cb, @args) = @_;
 197         my $dbh = $self->{dbh} //= dbh_new($self);
 198         my $fid;
 199         if (ref($folder) eq 'HASH') {
 200                 $fid = $folder->{fid} // die "BUG: no `fid'";
 201         } else {
 202                 $fid = $self->{fmap}->{$folder} //=
 203                         fid_for($self, $folder) // return;
 204         }
 205
 206         # minimize implicit txn time to avoid blocking writers by
 207         # batching SELECTs.  This looks wonky but is necessary since
 208         # $cb-> may access the DB on its own.
 209         my $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 210 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ?
 211 ORDER BY _rowid_ ASC LIMIT 1000
 212
 213         my $min = @$ary ? $ary->[-1]->[0] : undef;
 214         while (defined $min) {
 215                 for my $row (@$ary) { $cb->($row->[1], $row->[2], @args) }
 216
 217                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 218 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ? AND _rowid_ > ?
 219 ORDER BY _rowid_ ASC LIMIT 1000
 220
 221                 $min = @$ary ? $ary->[-1]->[0] : undef;
 222         }
 223
 224         $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 225 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ?
 226 ORDER BY _rowid_ ASC LIMIT 1000
 227
 228         $min = @$ary ? $ary->[-1]->[0] : undef;
 229         while (defined $min) {
 230                 for my $row (@$ary) { $cb->($row->[1], \($row->[2]), @args) }
 231
 232                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 233 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ? AND _rowid_ > ?
 234 ORDER BY _rowid_ ASC LIMIT 1000
 235
 236                 $min = @$ary ? $ary->[-1]->[0] : undef;
 237         }
 238 }
 239
 240 sub location_stats {
 241         my ($self, $folder) = @_;
 242         my $dbh = $self->{dbh} //= dbh_new($self);
 243         my $fid;
 244         my $ret = {};
 245         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 246         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 247 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 248
 249         $ret->{'name.count'} = $row if $row;
 250         for my $op (qw(count min max)) {
 251                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 252 SELECT $op(uid) FROM blob2num WHERE fid = ?
 253
 254                 $row or last;
 255                 $ret->{"uid.$op"} = $row;
 256         }
 257         $ret;
 258 }
 259
 260 # returns a { location => [ list-of-ids-or-names ] } mapping
 261 sub locations_for {
 262         my ($self, $oidbin) = @_;
 263         my ($fid, $sth, $id, %fid2id);
 264         my $dbh = $self->{dbh} //= dbh_new($self);
 265         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 266         $sth->execute($oidbin);
 267         while (my ($fid, $uid) = $sth->fetchrow_array) {
 268                 push @{$fid2id{$fid}}, $uid;
 269         }
 270         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 271         $sth->execute($oidbin);
 272         while (my ($fid, $name) = $sth->fetchrow_array) {
 273                 push @{$fid2id{$fid}}, $name;
 274         }
 275         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 276         my $ret = {};
 277         while (my ($fid, $ids) = each %fid2id) {
 278                 $sth->execute($fid);
 279                 my ($loc) = $sth->fetchrow_array;
 280                 unless (defined $loc) {
 281                         my $oidhex = unpack('H*', $oidbin);
 282                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 283                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 284                                 } @$ids;
 285                         next;
 286                 }
 287                 $ret->{$loc} = $ids;
 288         }
 289         scalar(keys %$ret) ? $ret : undef;
 290 }
 291
 292 # returns a list of folders used for completion
 293 sub folders {
 294         my ($self, $pfx) = @_;
 295         my $dbh = $self->{dbh} //= dbh_new($self);
 296         my $sql = 'SELECT loc FROM folders';
 297         my @pfx;
 298         if (defined $pfx) {
 299                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 300                 @pfx = ($pfx, '\\');
 301                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 302                 $pfx[0] .= '%';
 303         }
 304         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 305 }
 306
 307 sub local_blob {
 308         my ($self, $oidhex, $vrfy) = @_;
 309         my $dbh = $self->{dbh} //= dbh_new($self);
 310         my $b2n = $dbh->prepare(<<'');
 311 SELECT f.loc,b.name FROM blob2name b
 312 LEFT JOIN folders f ON b.fid = f.fid
 313 WHERE b.oidbin = ?
 314
 315         $b2n->execute(pack('H*', $oidhex));
 316         while (my ($d, $n) = $b2n->fetchrow_array) {
 317                 substr($d, 0, length('maildir:')) = '';
 318                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 319                 # in "new/", despite (from what I understand of reading
 320                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 321                 # applies to files in "cur/".
 322                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 323                 for my $x (@try) {
 324                         my $f = "$d/$x/$n";
 325                         open my $fh, '<', $f or next;
 326                         # some (buggy) Maildir writers are non-atomic:
 327                         next unless -s $fh;
 328                         local $/;
 329                         my $raw = <$fh>;
 330                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 331                                 warn "$f changed $oidhex\n";
 332                                 next;
 333                         }
 334                         return \$raw;
 335                 }
 336         }
 337         undef;
 338 }
 339
 340 sub match_imap_url {
 341         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 342         $all //= [ $self->folders ];
 343         require PublicInbox::URIimap;
 344         my $want = PublicInbox::URIimap->new($url)->canonical;
 345         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 346         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 347                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 348         my @match;
 349         for my $x (@uri) {
 350                 next if $x->mailbox ne $want->mailbox;
 351                 next if $x->host ne $want->host;
 352                 next if $x->port != $want->port;
 353                 my $x_uidval = $x->uidvalidity;
 354                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 355
 356                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 357                 if (defined($x->auth) && !defined($want->auth) &&
 358                                 !defined($want->user)) {
 359                         push @match, $x;
 360                 # or maybe user was forgotten on CLI:
 361                 } elsif (defined($x->user) && !defined($want->user)) {
 362                         push @match, $x;
 363                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 364                         push @match, $x;
 365                 }
 366         }
 367         return @match if wantarray;
 368         scalar(@match) <= 1 ? $match[0] :
 369                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 370 }
 371
 372 # returns undef on failure, number on success
 373 sub group2folders {
 374         my ($self, $lei, $all, $folders) = @_;
 375         return $lei->fail(<<EOM) if @$folders;
 376 --all= not compatible with @$folders on command-line
 377 EOM
 378         my %x = map { $_ => $_ } split(/,/, $all);
 379         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 380         push(@ok, '') if $all eq '';
 381         my @no = keys %x;
 382         if (@no) {
 383                 @no = (join(',', @no));
 384                 return $lei->fail(<<EOM);
 385 --all=@no not accepted (must be `local' and/or `remote')
 386 EOM
 387         }
 388         my (%seen, @inc);
 389         my @all = $self->folders;
 390         for my $ok (@ok) {
 391                 if ($ok eq 'local') {
 392                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 393                 } elsif ($ok eq 'remote') {
 394                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 395                 } elsif ($ok ne '') {
 396                         return $lei->fail("--all=$all not understood");
 397                 } else {
 398                         @inc = @all;
 399                 }
 400                 push(@$folders, (grep { !$seen{$_}++ } @inc));
 401         }
 402         scalar(@$folders) || $lei->fail(<<EOM);
 403 no --mail-sync folders known to lei
 404 EOM
 405 }
 406
 407 # map CLI args to folder table entries, returns undef on failure
 408 sub arg2folder {
 409         my ($self, $lei, $folders) = @_;
 410         my @all = $self->folders;
 411         my %all = map { $_ => 1 } @all;
 412         my ($err, @no);
 413         for (@$folders) {
 414                 next if $all{$_}; # ok
 415                 if (m!\A(maildir|mh):(.+)!i) {
 416                         my $type = lc $1;
 417                         my $d = "$type:".$lei->abs_path($2);
 418                         push(@no, $_) unless $all{$d};
 419                         $_ = $d;
 420                 } elsif (-d "$_/new" && -d "$_/cur") {
 421                         my $d = 'maildir:'.$lei->abs_path($_);
 422                         push(@no, $_) unless $all{$d};
 423                         $_ = $d;
 424                 } elsif (m!\Aimaps?://!i) {
 425                         my $orig = $_;
 426                         my $res = match_imap_url($self, $orig, \@all);
 427                         if (ref $res) {
 428                                 $_ = $$res;
 429                                 push(@{$err->{qerr}}, <<EOM);
 430 # using `$res' instead of `$orig'
 431 EOM
 432                         } else {
 433                                 $lei->err($res) if defined $res;
 434                                 push @no, $orig;
 435                         }
 436                 } else {
 437                         push @no, $_;
 438                 }
 439         }
 440         if (@no) {
 441                 my $no = join("\n\t", @no);
 442                 $err->{fail} = <<EOF;
 443 No sync information for: $no
 444 Run `lei ls-mail-sync' to display valid choices
 445 EOF
 446         }
 447         $err;
 448 }
 449
 450 sub forget_folders {
 451         my ($self, @folders) = @_;
 452         my $lk = $self->lock_for_scope;
 453         for my $folder (@folders) {
 454                 my $fid = delete($self->{fmap}->{$folder}) //
 455                         fid_for($self, $folder) // next;
 456                 for my $t (qw(blob2name blob2num folders)) {
 457                         $self->{dbh}->do("DELETE FROM $t WHERE fid = ?",
 458                                         undef, $fid);
 459                 }
 460         }
 461 }
 462
 463 # only used for changing canonicalization errors
 464 sub rename_folder {
 465         my ($self, $old, $new) = @_;
 466         my $lk = $self->lock_for_scope;
 467         my $ofid = delete($self->{fmap}->{$old}) //
 468                 fid_for($self, $old) // return;
 469         eval {
 470                 $self->{dbh}->do(<<EOM, undef, $new, $ofid);
 471 UPDATE folders SET loc = ? WHERE fid = ?
 472 EOM
 473         };
 474         if ($@ =~ /\bunique\b/i) {
 475                 my $nfid = $self->{fmap}->{$new} // fid_for($self, $new);
 476                 for my $t (qw(blob2name blob2num)) {
 477                         $self->{dbh}->do(<<EOM, undef, $nfid, $ofid);
 478 UPDATE OR REPLACE $t SET fid = ? WHERE fid = ?
 479 EOM
 480                 }
 481                 $self->{dbh}->do(<<EOM, undef, $ofid);
 482 DELETE FROM folders WHERE fid = ?
 483 EOM
 484         }
 485 }
 486
 487 sub imap_oidbin ($$$) {
 488         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY
 489         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return;
 490         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 491 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ?
 492 EOM
 493         $sth->execute($fid, $uid);
 494         $sth->fetchrow_array;
 495 }
 496
 497 sub name_oidbin ($$$) {
 498         my ($self, $mdir, $nm) = @_;
 499         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 500         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 501 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 502 EOM
 503         $sth->execute($fid, $nm);
 504         $sth->fetchrow_array;
 505 }
 506
 507 sub imap_oid {
 508         my ($self, $lei, $uid_uri) = @_;
 509         my $mailbox_uri = $uid_uri->clone;
 510         $mailbox_uri->uid(undef);
 511         my $folders = [ $$mailbox_uri ];
 512         if (my $err = $self->arg2folder($lei, $folders)) {
 513                 if ($err->{fail}) {
 514                         $lei->qerr("# no sync information for $mailbox_uri");
 515                         return;
 516                 }
 517                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
 518         }
 519         my $oidbin = imap_oidbin($self, $folders->[0], $uid_uri->uid);
 520         $oidbin ? unpack('H*', $oidbin) : undef;
 521 }
 522
 523 1;