lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10 use Carp ();
  11
  12 sub dbh_new {
  13         my ($self, $rw) = @_;
  14         my $f = $self->{filename};
  15         my $creat = $rw && !-s $f;
  16         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  17                 AutoCommit => 1,
  18                 RaiseError => 1,
  19                 PrintError => 0,
  20                 ReadOnly => !$rw,
  21                 sqlite_use_immediate_transaction => 1,
  22         });
  23         # no sqlite_unicode, here, all strings are binary
  24         create_tables($dbh) if $rw;
  25         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  26         $dbh->do('PRAGMA case_sensitive_like = ON');
  27         $dbh;
  28 }
  29
  30 sub new {
  31         my ($cls, $f) = @_;
  32         bless { filename => $f, fmap => {} }, $cls;
  33 }
  34
  35 sub lms_commit { delete($_[0]->{dbh})->commit }
  36
  37 sub lms_begin { ($_[0]->{dbh} //= dbh_new($_[0], 1))->begin_work };
  38
  39 sub create_tables {
  40         my ($dbh) = @_;
  41
  42         $dbh->do(<<'');
  43 CREATE TABLE IF NOT EXISTS folders (
  44         fid INTEGER PRIMARY KEY,
  45         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  46         UNIQUE (loc)
  47 )
  48
  49         $dbh->do(<<'');
  50 CREATE TABLE IF NOT EXISTS blob2num (
  51         oidbin VARBINARY NOT NULL,
  52         fid INTEGER NOT NULL, /* folder ID */
  53         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  54         UNIQUE (oidbin, fid, uid)
  55 )
  56
  57         $dbh->do(<<'');
  58 CREATE TABLE IF NOT EXISTS blob2name (
  59         oidbin VARBINARY NOT NULL,
  60         fid INTEGER NOT NULL, /* folder ID */
  61         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  62         UNIQUE (oidbin, fid, name)
  63 )
  64
  65 }
  66
  67 sub _fid_for {
  68         my ($self, $folder, $rw) = @_;
  69         my $dbh = $self->{dbh};
  70         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  71         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  72         return $fid if defined $fid;
  73
  74         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  75                 warn "folder: $folder/ had trailing slash in arg\n";
  76                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  77                 if (defined $fid) {
  78                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  79 UPDATE folders SET loc = ? WHERE fid = ?
  80 EOM
  81                         return $fid;
  82                 }
  83         # sometimes we stored trailing slash..
  84         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
  85                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
  86                 if (defined $fid) {
  87                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  88 UPDATE folders SET loc = ? WHERE fid = ?
  89 EOM
  90                         return $fid;
  91                 }
  92         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
  93                 require PublicInbox::URIimap;
  94                 PublicInbox::URIimap->new($folder)->uidvalidity //
  95                         Carp::croak("BUG: $folder has no UIDVALIDITY");
  96         }
  97         return unless $rw;
  98
  99         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 100
 101         $fid += 1;
 102         # in case we're reusing, clobber existing stale refs:
 103         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 104         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 105
 106         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 107         $sth->execute($fid, $folder);
 108
 109         $fid;
 110 }
 111
 112 sub set_src {
 113         my ($self, $oidhex, $folder, $id) = @_;
 114         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 115         my $sth;
 116         if (ref($id)) { # scalar name
 117                 $id = $$id;
 118                 $sth = $self->{dbh}->prepare_cached(<<'');
 119 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 120
 121         } else { # numeric ID (IMAP UID, MH number)
 122                 $sth = $self->{dbh}->prepare_cached(<<'');
 123 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 124
 125         }
 126         $sth->execute(pack('H*', $oidhex), $fid, $id);
 127 }
 128
 129 sub clear_src {
 130         my ($self, $folder, $id) = @_;
 131         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 132         my $sth;
 133         if (ref($id)) { # scalar name
 134                 $id = $$id;
 135                 $sth = $self->{dbh}->prepare_cached(<<'');
 136 DELETE FROM blob2name WHERE fid = ? AND name = ?
 137
 138         } else {
 139                 $sth = $self->{dbh}->prepare_cached(<<'');
 140 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 141
 142         }
 143         $sth->execute($fid, $id);
 144 }
 145
 146 # Maildir-only
 147 sub mv_src {
 148         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 149         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 150         my $sth = $self->{dbh}->prepare_cached(<<'');
 151 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 152
 153         $sth->execute($newbn, $fid, $oidbin, $$id);
 154 }
 155
 156 # read-only, iterates every oidbin + UID or name for a given folder
 157 sub each_src {
 158         my ($self, $folder, $cb, @args) = @_;
 159         my $dbh = $self->{dbh} //= dbh_new($self);
 160         my ($fid, $sth);
 161         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 162         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 163         $sth->execute($fid);
 164         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 165                 $cb->($oidbin, $id, @args);
 166         }
 167         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 168         $sth->execute($fid);
 169         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 170                 $cb->($oidbin, \$id, @args);
 171         }
 172 }
 173
 174 sub location_stats {
 175         my ($self, $folder) = @_;
 176         my $dbh = $self->{dbh} //= dbh_new($self);
 177         my $fid;
 178         my $ret = {};
 179         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 180         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 181 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 182
 183         $ret->{'name.count'} = $row if $row;
 184         for my $op (qw(count min max)) {
 185                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 186 SELECT $op(uid) FROM blob2num WHERE fid = ?
 187
 188                 $row or last;
 189                 $ret->{"uid.$op"} = $row;
 190         }
 191         $ret;
 192 }
 193
 194 # returns a { location => [ list-of-ids-or-names ] } mapping
 195 sub locations_for {
 196         my ($self, $oidhex) = @_;
 197         my ($fid, $sth, $id, %fid2id);
 198         my $dbh = $self->{dbh} //= dbh_new($self);
 199         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 200         $sth->execute(pack('H*', $oidhex));
 201         while (my ($fid, $uid) = $sth->fetchrow_array) {
 202                 push @{$fid2id{$fid}}, $uid;
 203         }
 204         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 205         $sth->execute(pack('H*', $oidhex));
 206         while (my ($fid, $name) = $sth->fetchrow_array) {
 207                 push @{$fid2id{$fid}}, $name;
 208         }
 209         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 210         my $ret = {};
 211         while (my ($fid, $ids) = each %fid2id) {
 212                 $sth->execute($fid);
 213                 my ($loc) = $sth->fetchrow_array;
 214                 unless (defined $loc) {
 215                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 216                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 217                                 } @$ids;
 218                         next;
 219                 }
 220                 $ret->{$loc} = $ids;
 221         }
 222         scalar(keys %$ret) ? $ret : undef;
 223 }
 224
 225 # returns a list of folders used for completion
 226 sub folders {
 227         my ($self, $pfx) = @_;
 228         my $dbh = $self->{dbh} //= dbh_new($self);
 229         my $sql = 'SELECT loc FROM folders';
 230         my @pfx;
 231         if (defined $pfx) {
 232                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 233                 @pfx = ($pfx, '\\');
 234                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 235                 $pfx[0] .= '%';
 236         }
 237         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 238 }
 239
 240 sub local_blob {
 241         my ($self, $oidhex, $vrfy) = @_;
 242         my $dbh = $self->{dbh} //= dbh_new($self);
 243         my $b2n = $dbh->prepare(<<'');
 244 SELECT f.loc,b.name FROM blob2name b
 245 LEFT JOIN folders f ON b.fid = f.fid
 246 WHERE b.oidbin = ?
 247
 248         $b2n->execute(pack('H*', $oidhex));
 249         while (my ($d, $n) = $b2n->fetchrow_array) {
 250                 substr($d, 0, length('maildir:')) = '';
 251                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 252                 # in "new/", despite (from what I understand of reading
 253                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 254                 # applies to files in "cur/".
 255                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 256                 for my $x (@try) {
 257                         my $f = "$d/$x/$n";
 258                         open my $fh, '<', $f or next;
 259                         # some (buggy) Maildir writers are non-atomic:
 260                         next unless -s $fh;
 261                         local $/;
 262                         my $raw = <$fh>;
 263                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 264                                 warn "$f changed $oidhex\n";
 265                                 next;
 266                         }
 267                         return \$raw;
 268                 }
 269         }
 270         undef;
 271 }
 272
 273 sub match_imap_url {
 274         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 275         $all //= [ $self->folders ];
 276         require PublicInbox::URIimap;
 277         my $want = PublicInbox::URIimap->new($url)->canonical;
 278         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 279         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 280                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 281         my @match;
 282         for my $x (@uri) {
 283                 next if $x->mailbox ne $want->mailbox;
 284                 next if $x->host ne $want->host;
 285                 next if $x->port != $want->port;
 286                 my $x_uidval = $x->uidvalidity;
 287                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 288
 289                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 290                 if (defined($x->auth) && !defined($want->auth) &&
 291                                 !defined($want->user)) {
 292                         push @match, $x;
 293                 # or maybe user was forgotten on CLI:
 294                 } elsif (defined($x->user) && !defined($want->user)) {
 295                         push @match, $x;
 296                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 297                         push @match, $x;
 298                 }
 299         }
 300         return @match if wantarray;
 301         scalar(@match) <= 1 ? $match[0] :
 302                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 303 }
 304
 305 # map CLI args to folder table entries, returns undef on failure
 306 sub arg2folder {
 307         my ($self, $lei, $folders) = @_;
 308         my @all = $self->folders;
 309         my %all = map { $_ => 1 } @all;
 310         my ($err, @no);
 311         for (@$folders) {
 312                 next if $all{$_}; # ok
 313                 if (m!\A(maildir|mh):(.+)!i) {
 314                         my $type = lc $1;
 315                         my $d = "$type:".$lei->abs_path($2);
 316                         push(@no, $_) unless $all{$d};
 317                         $_ = $d;
 318                 } elsif (-d "$_/new" && -d "$_/cur") {
 319                         my $d = 'maildir:'.$lei->abs_path($_);
 320                         push(@no, $_) unless $all{$d};
 321                         $_ = $d;
 322                 } elsif (m!\Aimaps?://!i) {
 323                         my $orig = $_;
 324                         my $res = match_imap_url($self, $orig, \@all);
 325                         if (ref $res) {
 326                                 $_ = $$res;
 327                                 push(@{$err->{qerr}}, <<EOM);
 328 # using `$res' instead of `$orig'
 329 EOM
 330                         } else {
 331                                 $lei->err($res) if defined $res;
 332                                 push @no, $orig;
 333                         }
 334                 } else {
 335                         push @no, $_;
 336                 }
 337         }
 338         if (@no) {
 339                 my $no = join("\n\t", @no);
 340                 $err->{fail} = <<EOF;
 341 No sync information for: $no
 342 Run `lei ls-mail-sync' to display valid choices
 343 EOF
 344         }
 345         $err;
 346 }
 347
 348 1;