lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10 use Carp ();
  11
  12 sub dbh_new {
  13         my ($self, $rw) = @_;
  14         my $f = $self->{filename};
  15         my $creat = $rw && !-s $f;
  16         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  17                 AutoCommit => 1,
  18                 RaiseError => 1,
  19                 PrintError => 0,
  20                 ReadOnly => !$rw,
  21                 sqlite_use_immediate_transaction => 1,
  22         });
  23         # no sqlite_unicode, here, all strings are binary
  24         create_tables($dbh) if $rw;
  25         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  26         $dbh->do('PRAGMA case_sensitive_like = ON');
  27         $dbh;
  28 }
  29
  30 sub new {
  31         my ($cls, $f) = @_;
  32         bless { filename => $f, fmap => {} }, $cls;
  33 }
  34
  35 sub lms_write_prepare { ($_[0]->{dbh} //= dbh_new($_[0], 1)) };
  36
  37 sub create_tables {
  38         my ($dbh) = @_;
  39
  40         $dbh->do(<<'');
  41 CREATE TABLE IF NOT EXISTS folders (
  42         fid INTEGER PRIMARY KEY,
  43         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  44         UNIQUE (loc)
  45 )
  46
  47         $dbh->do(<<'');
  48 CREATE TABLE IF NOT EXISTS blob2num (
  49         oidbin VARBINARY NOT NULL,
  50         fid INTEGER NOT NULL, /* folder ID */
  51         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  52         UNIQUE (oidbin, fid, uid)
  53 )
  54
  55         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  56         $dbh->do(<<'');
  57 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  58
  59         $dbh->do(<<'');
  60 CREATE TABLE IF NOT EXISTS blob2name (
  61         oidbin VARBINARY NOT NULL,
  62         fid INTEGER NOT NULL, /* folder ID */
  63         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  64         UNIQUE (oidbin, fid, name)
  65 )
  66
  67         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  68         $dbh->do(<<'');
  69 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  70
  71 }
  72
  73 sub fid_for {
  74         my ($self, $folder, $rw) = @_;
  75         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  76         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  77         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  78         return $fid if defined $fid;
  79
  80         # caller had trailing slash (LeiToMail)
  81         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  82                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  83                 if (defined $fid) {
  84                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  85 UPDATE folders SET loc = ? WHERE fid = ?
  86 EOM
  87                         return $fid;
  88                 }
  89         # sometimes we stored trailing slash..
  90         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
  91                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
  92                 if (defined $fid) {
  93                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  94 UPDATE folders SET loc = ? WHERE fid = ?
  95 EOM
  96                         return $fid;
  97                 }
  98         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
  99                 require PublicInbox::URIimap;
 100                 PublicInbox::URIimap->new($folder)->uidvalidity //
 101                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 102         }
 103         return unless $rw;
 104
 105         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 106
 107         $fid += 1;
 108         # in case we're reusing, clobber existing stale refs:
 109         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 110         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 111
 112         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 113         $sth->execute($fid, $folder);
 114
 115         $fid;
 116 }
 117
 118 sub set_src {
 119         my ($self, $oidbin, $folder, $id) = @_;
 120         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 121         my $sth;
 122         if (ref($id)) { # scalar name
 123                 $id = $$id;
 124                 $sth = $self->{dbh}->prepare_cached(<<'');
 125 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 126
 127         } else { # numeric ID (IMAP UID, MH number)
 128                 $sth = $self->{dbh}->prepare_cached(<<'');
 129 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 130
 131         }
 132         $sth->execute($oidbin, $fid, $id);
 133 }
 134
 135 sub clear_src {
 136         my ($self, $folder, $id) = @_;
 137         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 138         my $sth;
 139         if (ref($id)) { # scalar name
 140                 $id = $$id;
 141                 $sth = $self->{dbh}->prepare_cached(<<'');
 142 DELETE FROM blob2name WHERE fid = ? AND name = ?
 143
 144         } else {
 145                 $sth = $self->{dbh}->prepare_cached(<<'');
 146 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 147
 148         }
 149         $sth->execute($fid, $id);
 150 }
 151
 152 # Maildir-only
 153 sub mv_src {
 154         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 155         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 156         my $sth = $self->{dbh}->prepare_cached(<<'');
 157 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 158
 159         my $nr = $sth->execute($newbn, $fid, $oidbin, $$id);
 160         if ($nr == 0) { # may race with a clear_src, ensure new value exists
 161                 $sth = $self->{dbh}->prepare_cached(<<'');
 162 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 163
 164                 $sth->execute($oidbin, $fid, $newbn);
 165         }
 166 }
 167
 168 # read-only, iterates every oidbin + UID or name for a given folder
 169 sub each_src {
 170         my ($self, $folder, $cb, @args) = @_;
 171         my $dbh = $self->{dbh} //= dbh_new($self);
 172         my $fid;
 173         if (ref($folder) eq 'HASH') {
 174                 $fid = $folder->{fid} // die "BUG: no `fid'";
 175         } else {
 176                 $fid = $self->{fmap}->{$folder} //=
 177                         fid_for($self, $folder) // return;
 178         }
 179
 180         # minimize implicit txn time to avoid blocking writers by
 181         # batching SELECTs.  This looks wonky but is necessary since
 182         # $cb-> may access the DB on its own.
 183         my $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 184 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ?
 185 ORDER BY _rowid_ ASC LIMIT 1000
 186
 187         my $min = @$ary ? $ary->[-1]->[0] : undef;
 188         while (defined $min) {
 189                 for my $row (@$ary) { $cb->($row->[1], $row->[2], @args) }
 190
 191                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 192 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ? AND _rowid_ > ?
 193 ORDER BY _rowid_ ASC LIMIT 1000
 194
 195                 $min = @$ary ? $ary->[-1]->[0] : undef;
 196         }
 197
 198         $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 199 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ?
 200 ORDER BY _rowid_ ASC LIMIT 1000
 201
 202         $min = @$ary ? $ary->[-1]->[0] : undef;
 203         while (defined $min) {
 204                 for my $row (@$ary) { $cb->($row->[1], \($row->[2]), @args) }
 205
 206                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 207 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ? AND _rowid_ > ?
 208 ORDER BY _rowid_ ASC LIMIT 1000
 209
 210                 $min = @$ary ? $ary->[-1]->[0] : undef;
 211         }
 212 }
 213
 214 sub location_stats {
 215         my ($self, $folder) = @_;
 216         my $dbh = $self->{dbh} //= dbh_new($self);
 217         my $fid;
 218         my $ret = {};
 219         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 220         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 221 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 222
 223         $ret->{'name.count'} = $row if $row;
 224         for my $op (qw(count min max)) {
 225                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 226 SELECT $op(uid) FROM blob2num WHERE fid = ?
 227
 228                 $row or last;
 229                 $ret->{"uid.$op"} = $row;
 230         }
 231         $ret;
 232 }
 233
 234 # returns a { location => [ list-of-ids-or-names ] } mapping
 235 sub locations_for {
 236         my ($self, $oidbin) = @_;
 237         my ($fid, $sth, $id, %fid2id);
 238         my $dbh = $self->{dbh} //= dbh_new($self);
 239         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 240         $sth->execute($oidbin);
 241         while (my ($fid, $uid) = $sth->fetchrow_array) {
 242                 push @{$fid2id{$fid}}, $uid;
 243         }
 244         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 245         $sth->execute($oidbin);
 246         while (my ($fid, $name) = $sth->fetchrow_array) {
 247                 push @{$fid2id{$fid}}, $name;
 248         }
 249         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 250         my $ret = {};
 251         while (my ($fid, $ids) = each %fid2id) {
 252                 $sth->execute($fid);
 253                 my ($loc) = $sth->fetchrow_array;
 254                 unless (defined $loc) {
 255                         my $oidhex = unpack('H*', $oidbin);
 256                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 257                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 258                                 } @$ids;
 259                         next;
 260                 }
 261                 $ret->{$loc} = $ids;
 262         }
 263         scalar(keys %$ret) ? $ret : undef;
 264 }
 265
 266 # returns a list of folders used for completion
 267 sub folders {
 268         my ($self, $pfx) = @_;
 269         my $dbh = $self->{dbh} //= dbh_new($self);
 270         my $sql = 'SELECT loc FROM folders';
 271         my @pfx;
 272         if (defined $pfx) {
 273                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 274                 @pfx = ($pfx, '\\');
 275                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 276                 $pfx[0] .= '%';
 277         }
 278         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 279 }
 280
 281 sub local_blob {
 282         my ($self, $oidhex, $vrfy) = @_;
 283         my $dbh = $self->{dbh} //= dbh_new($self);
 284         my $b2n = $dbh->prepare(<<'');
 285 SELECT f.loc,b.name FROM blob2name b
 286 LEFT JOIN folders f ON b.fid = f.fid
 287 WHERE b.oidbin = ?
 288
 289         $b2n->execute(pack('H*', $oidhex));
 290         while (my ($d, $n) = $b2n->fetchrow_array) {
 291                 substr($d, 0, length('maildir:')) = '';
 292                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 293                 # in "new/", despite (from what I understand of reading
 294                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 295                 # applies to files in "cur/".
 296                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 297                 for my $x (@try) {
 298                         my $f = "$d/$x/$n";
 299                         open my $fh, '<', $f or next;
 300                         # some (buggy) Maildir writers are non-atomic:
 301                         next unless -s $fh;
 302                         local $/;
 303                         my $raw = <$fh>;
 304                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 305                                 warn "$f changed $oidhex\n";
 306                                 next;
 307                         }
 308                         return \$raw;
 309                 }
 310         }
 311         undef;
 312 }
 313
 314 sub match_imap_url {
 315         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 316         $all //= [ $self->folders ];
 317         require PublicInbox::URIimap;
 318         my $want = PublicInbox::URIimap->new($url)->canonical;
 319         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 320         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 321                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 322         my @match;
 323         for my $x (@uri) {
 324                 next if $x->mailbox ne $want->mailbox;
 325                 next if $x->host ne $want->host;
 326                 next if $x->port != $want->port;
 327                 my $x_uidval = $x->uidvalidity;
 328                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 329
 330                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 331                 if (defined($x->auth) && !defined($want->auth) &&
 332                                 !defined($want->user)) {
 333                         push @match, $x;
 334                 # or maybe user was forgotten on CLI:
 335                 } elsif (defined($x->user) && !defined($want->user)) {
 336                         push @match, $x;
 337                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 338                         push @match, $x;
 339                 }
 340         }
 341         return @match if wantarray;
 342         scalar(@match) <= 1 ? $match[0] :
 343                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 344 }
 345
 346 # returns undef on failure, number on success
 347 sub group2folders {
 348         my ($self, $lei, $all, $folders) = @_;
 349         return $lei->fail(<<EOM) if @$folders;
 350 --all= not compatible with @$folders on command-line
 351 EOM
 352         my %x = map { $_ => $_ } split(/,/, $all);
 353         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 354         push(@ok, '') if $all eq '';
 355         my @no = keys %x;
 356         if (@no) {
 357                 @no = (join(',', @no));
 358                 return $lei->fail(<<EOM);
 359 --all=@no not accepted (must be `local' and/or `remote')
 360 EOM
 361         }
 362         my (%seen, @inc);
 363         my @all = $self->folders;
 364         for my $ok (@ok) {
 365                 if ($ok eq 'local') {
 366                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 367                 } elsif ($ok eq 'remote') {
 368                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 369                 } elsif ($ok ne '') {
 370                         return $lei->fail("--all=$all not understood");
 371                 } else {
 372                         @inc = @all;
 373                 }
 374                 push(@$folders, (grep { !$seen{$_}++ } @inc));
 375         }
 376         scalar(@$folders) || $lei->fail(<<EOM);
 377 no --mail-sync folders known to lei
 378 EOM
 379 }
 380
 381 # map CLI args to folder table entries, returns undef on failure
 382 sub arg2folder {
 383         my ($self, $lei, $folders) = @_;
 384         my @all = $self->folders;
 385         my %all = map { $_ => 1 } @all;
 386         my ($err, @no);
 387         for (@$folders) {
 388                 next if $all{$_}; # ok
 389                 if (m!\A(maildir|mh):(.+)!i) {
 390                         my $type = lc $1;
 391                         my $d = "$type:".$lei->abs_path($2);
 392                         push(@no, $_) unless $all{$d};
 393                         $_ = $d;
 394                 } elsif (-d "$_/new" && -d "$_/cur") {
 395                         my $d = 'maildir:'.$lei->abs_path($_);
 396                         push(@no, $_) unless $all{$d};
 397                         $_ = $d;
 398                 } elsif (m!\Aimaps?://!i) {
 399                         my $orig = $_;
 400                         my $res = match_imap_url($self, $orig, \@all);
 401                         if (ref $res) {
 402                                 $_ = $$res;
 403                                 push(@{$err->{qerr}}, <<EOM);
 404 # using `$res' instead of `$orig'
 405 EOM
 406                         } else {
 407                                 $lei->err($res) if defined $res;
 408                                 push @no, $orig;
 409                         }
 410                 } else {
 411                         push @no, $_;
 412                 }
 413         }
 414         if (@no) {
 415                 my $no = join("\n\t", @no);
 416                 $err->{fail} = <<EOF;
 417 No sync information for: $no
 418 Run `lei ls-mail-sync' to display valid choices
 419 EOF
 420         }
 421         $err;
 422 }
 423
 424 sub forget_folder {
 425         my ($self, $folder) = @_;
 426         my $fid = delete($self->{fmap}->{$folder}) //
 427                 fid_for($self, $folder) // return;
 428         for my $t (qw(blob2name blob2num folders)) {
 429                 $self->{dbh}->do("DELETE FROM $t WHERE fid = ?", undef, $fid);
 430         }
 431 }
 432
 433 # only used for changing canonicalization errors
 434 sub rename_folder {
 435         my ($self, $old, $new) = @_;
 436         my $ofid = delete($self->{fmap}->{$old}) //
 437                 fid_for($self, $old) // return;
 438         eval {
 439                 $self->{dbh}->do(<<EOM, undef, $new, $ofid);
 440 UPDATE folders SET loc = ? WHERE fid = ?
 441 EOM
 442         };
 443         if ($@ =~ /\bunique\b/i) {
 444                 my $nfid = $self->{fmap}->{$new} // fid_for($self, $new);
 445                 for my $t (qw(blob2name blob2num)) {
 446                         $self->{dbh}->do(<<EOM, undef, $nfid, $ofid);
 447 UPDATE OR REPLACE $t SET fid = ? WHERE fid = ?
 448 EOM
 449                 }
 450                 $self->{dbh}->do(<<EOM, undef, $ofid);
 451 DELETE FROM folders WHERE fid = ?
 452 EOM
 453         }
 454 }
 455
 456 sub imap_oidbin ($$$) {
 457         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY
 458         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return;
 459         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 460 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ?
 461 EOM
 462         $sth->execute($fid, $uid);
 463         $sth->fetchrow_array;
 464 }
 465
 466 sub name_oidbin ($$$) {
 467         my ($self, $mdir, $nm) = @_;
 468         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 469         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 470 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 471 EOM
 472         $sth->execute($fid, $nm);
 473         $sth->fetchrow_array;
 474 }
 475
 476 sub imap_oid {
 477         my ($self, $lei, $uid_uri) = @_;
 478         my $mailbox_uri = $uid_uri->clone;
 479         $mailbox_uri->uid(undef);
 480         my $folders = [ $$mailbox_uri ];
 481         if (my $err = $self->arg2folder($lei, $folders)) {
 482                 if ($err->{fail}) {
 483                         $lei->qerr("# no sync information for $mailbox_uri");
 484                         return;
 485                 }
 486                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
 487         }
 488         my $oidbin = imap_oidbin($self, $folders->[0], $uid_uri->uid);
 489         $oidbin ? unpack('H*', $oidbin) : undef;
 490 }
 491
 492 1;