lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::Lock);
   9 use DBI;
  10 use PublicInbox::ContentHash qw(git_sha);
  11 use Carp ();
  12
  13 sub dbh_new {
  14         my ($self, $rw) = @_;
  15         my $f = $self->{filename};
  16         my $creat = $rw && !-s $f;
  17         if ($creat) {
  18                 require PublicInbox::Spawn;
  19                 open my $fh, '+>>', $f or Carp::croak "open($f): $!";
  20                 PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  21         }
  22         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  23                 AutoCommit => 1,
  24                 RaiseError => 1,
  25                 PrintError => 0,
  26                 ReadOnly => !$rw,
  27                 sqlite_use_immediate_transaction => 1,
  28         });
  29         # no sqlite_unicode, here, all strings are binary
  30         create_tables($self, $dbh) if $rw;
  31         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  32         $dbh->do('PRAGMA case_sensitive_like = ON');
  33         $dbh;
  34 }
  35
  36 sub new {
  37         my ($cls, $f) = @_;
  38         bless {
  39                 filename => $f,
  40                 fmap => {},
  41                 lock_path => "$f.flock",
  42         }, $cls;
  43 }
  44
  45 sub lms_write_prepare { ($_[0]->{dbh} //= dbh_new($_[0], 1)); $_[0] }
  46
  47 sub lms_pause {
  48         my ($self) = @_;
  49         $self->{fmap} = {};
  50         delete $self->{dbh};
  51 }
  52
  53 sub create_tables {
  54         my ($self, $dbh) = @_;
  55         my $lk = $self->lock_for_scope;
  56
  57         $dbh->do(<<'');
  58 CREATE TABLE IF NOT EXISTS folders (
  59         fid INTEGER PRIMARY KEY,
  60         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  61         UNIQUE (loc)
  62 )
  63
  64         $dbh->do(<<'');
  65 CREATE TABLE IF NOT EXISTS blob2num (
  66         oidbin VARBINARY NOT NULL,
  67         fid INTEGER NOT NULL, /* folder ID */
  68         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  69         /* not UNIQUE(fid, uid), since we may have broken servers */
  70         UNIQUE (oidbin, fid, uid)
  71 )
  72
  73         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  74         $dbh->do(<<'');
  75 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  76
  77         $dbh->do(<<'');
  78 CREATE TABLE IF NOT EXISTS blob2name (
  79         oidbin VARBINARY NOT NULL,
  80         fid INTEGER NOT NULL, /* folder ID */
  81         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  82         /* not UNIQUE(fid, name), since we may have broken software */
  83         UNIQUE (oidbin, fid, name)
  84 )
  85
  86         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  87         $dbh->do(<<'');
  88 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  89
  90 }
  91
  92 sub fid_for {
  93         my ($self, $folder, $rw) = @_;
  94         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  95         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  96         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  97         return $fid if defined $fid;
  98
  99         # caller had trailing slash (LeiToMail)
 100         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
 101                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
 102                 if (defined $fid) {
 103                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 104 UPDATE folders SET loc = ? WHERE fid = ?
 105 EOM
 106                         return $fid;
 107                 }
 108         # sometimes we stored trailing slash..
 109         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
 110                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
 111                 if (defined $fid) {
 112                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 113 UPDATE folders SET loc = ? WHERE fid = ?
 114 EOM
 115                         return $fid;
 116                 }
 117         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
 118                 require PublicInbox::URIimap;
 119                 PublicInbox::URIimap->new($folder)->uidvalidity //
 120                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 121         }
 122         return unless $rw;
 123
 124         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 125
 126         $fid += 1;
 127         # in case we're reusing, clobber existing stale refs:
 128         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 129         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 130
 131         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 132         $sth->execute($fid, $folder);
 133
 134         $fid;
 135 }
 136
 137 sub add_folders {
 138         my ($self, @folders) = @_;
 139         my $lk = $self->lock_for_scope;
 140         for my $f (@folders) { $self->{fmap}->{$f} //= fid_for($self, $f, 1) }
 141 }
 142
 143 sub set_src {
 144         my ($self, $oidbin, $folder, $id) = @_;
 145         my $lk = $self->lock_for_scope;
 146         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 147         my $sth;
 148         if (ref($id)) { # scalar name
 149                 $id = $$id;
 150                 $sth = $self->{dbh}->prepare_cached(<<'');
 151 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 152
 153         } else { # numeric ID (IMAP UID, MH number)
 154                 $sth = $self->{dbh}->prepare_cached(<<'');
 155 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 156
 157         }
 158         $sth->execute($oidbin, $fid, $id);
 159 }
 160
 161 sub clear_src {
 162         my ($self, $folder, $id) = @_;
 163         my $lk = $self->lock_for_scope;
 164         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 165         my $sth;
 166         if (ref($id)) { # scalar name
 167                 $id = $$id;
 168                 $sth = $self->{dbh}->prepare_cached(<<'');
 169 DELETE FROM blob2name WHERE fid = ? AND name = ?
 170
 171         } else {
 172                 $sth = $self->{dbh}->prepare_cached(<<'');
 173 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 174
 175         }
 176         $sth->execute($fid, $id);
 177 }
 178
 179 # Maildir-only
 180 sub mv_src {
 181         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 182         my $lk = $self->lock_for_scope;
 183         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 184         my $sth = $self->{dbh}->prepare_cached(<<'');
 185 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 186
 187         my $nr = $sth->execute($newbn, $fid, $oidbin, $$id);
 188         if ($nr == 0) { # may race with a clear_src, ensure new value exists
 189                 $sth = $self->{dbh}->prepare_cached(<<'');
 190 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 191
 192                 $sth->execute($oidbin, $fid, $newbn);
 193         }
 194 }
 195
 196 # read-only, iterates every oidbin + UID or name for a given folder
 197 sub each_src {
 198         my ($self, $folder, $cb, @args) = @_;
 199         my $dbh = $self->{dbh} //= dbh_new($self);
 200         my ($fid, @rng);
 201         my $and_ge_le = '';
 202         if (ref($folder) eq 'HASH') {
 203                 $fid = $folder->{fid} // die "BUG: no `fid'";
 204                 @rng = grep(defined, @$folder{qw(min max)});
 205                 $and_ge_le = 'AND uid >= ? AND uid <= ?' if @rng;
 206         } else {
 207                 $fid = $self->{fmap}->{$folder} //=
 208                         fid_for($self, $folder) // return;
 209         }
 210
 211         # minimize implicit txn time to avoid blocking writers by
 212         # batching SELECTs.  This looks wonky but is necessary since
 213         # $cb-> may access the DB on its own.
 214         my $ary = $dbh->selectall_arrayref(<<"", undef, $fid, @rng);
 215 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ? $and_ge_le
 216 ORDER BY _rowid_ ASC LIMIT 1000
 217
 218         my $min = @$ary ? $ary->[-1]->[0] : undef;
 219         while (defined $min) {
 220                 for my $row (@$ary) { $cb->($row->[1], $row->[2], @args) }
 221
 222                 $ary = $dbh->selectall_arrayref(<<"", undef, $fid, @rng, $min);
 223 SELECT _rowid_,oidbin,uid FROM blob2num
 224 WHERE fid = ? $and_ge_le AND _rowid_ > ?
 225 ORDER BY _rowid_ ASC LIMIT 1000
 226
 227                 $min = @$ary ? $ary->[-1]->[0] : undef;
 228         }
 229
 230         $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 231 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ?
 232 ORDER BY _rowid_ ASC LIMIT 1000
 233
 234         $min = @$ary ? $ary->[-1]->[0] : undef;
 235         while (defined $min) {
 236                 for my $row (@$ary) { $cb->($row->[1], \($row->[2]), @args) }
 237
 238                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 239 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ? AND _rowid_ > ?
 240 ORDER BY _rowid_ ASC LIMIT 1000
 241
 242                 $min = @$ary ? $ary->[-1]->[0] : undef;
 243         }
 244 }
 245
 246 sub location_stats {
 247         my ($self, $folder) = @_;
 248         my $dbh = $self->{dbh} //= dbh_new($self);
 249         my $fid;
 250         my $ret = {};
 251         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 252         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 253 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 254
 255         $ret->{'name.count'} = $row if $row;
 256         my $ntype = ($folder =~ m!\A(?:nntps?|s?news)://!i) ? 'article' :
 257                 (($folder =~ m!\Aimaps?://!i) ? 'uid' : "TODO<$folder>");
 258         for my $op (qw(count min max)) {
 259                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 260 SELECT $op(uid) FROM blob2num WHERE fid = ?
 261
 262                 $row or last;
 263                 $ret->{"$ntype.$op"} = $row;
 264         }
 265         $ret;
 266 }
 267
 268 # returns a { location => [ list-of-ids-or-names ] } mapping
 269 sub locations_for {
 270         my ($self, $oidbin) = @_;
 271         my ($fid, $sth, $id, %fid2id);
 272         my $dbh = $self->{dbh} //= dbh_new($self);
 273         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 274         $sth->execute($oidbin);
 275         while (my ($fid, $uid) = $sth->fetchrow_array) {
 276                 push @{$fid2id{$fid}}, $uid;
 277         }
 278         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 279         $sth->execute($oidbin);
 280         while (my ($fid, $name) = $sth->fetchrow_array) {
 281                 push @{$fid2id{$fid}}, $name;
 282         }
 283         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 284         my $ret = {};
 285         while (my ($fid, $ids) = each %fid2id) {
 286                 $sth->execute($fid);
 287                 my ($loc) = $sth->fetchrow_array;
 288                 unless (defined $loc) {
 289                         my $oidhex = unpack('H*', $oidbin);
 290                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 291                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 292                                 } @$ids;
 293                         next;
 294                 }
 295                 $ret->{$loc} = $ids;
 296         }
 297         scalar(keys %$ret) ? $ret : undef;
 298 }
 299
 300 # returns a list of folders used for completion
 301 sub folders {
 302         my ($self, $pfx) = @_;
 303         my $dbh = $self->{dbh} //= dbh_new($self);
 304         my $sql = 'SELECT loc FROM folders';
 305         my @pfx;
 306         if (defined $pfx) {
 307                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 308                 @pfx = ($pfx, '\\');
 309                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 310                 $pfx[0] .= '%';
 311         }
 312         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 313 }
 314
 315 sub local_blob {
 316         my ($self, $oidhex, $vrfy) = @_;
 317         my $dbh = $self->{dbh} //= dbh_new($self);
 318         my $b2n = $dbh->prepare(<<'');
 319 SELECT f.loc,b.name FROM blob2name b
 320 LEFT JOIN folders f ON b.fid = f.fid
 321 WHERE b.oidbin = ?
 322
 323         $b2n->execute(pack('H*', $oidhex));
 324         while (my ($d, $n) = $b2n->fetchrow_array) {
 325                 substr($d, 0, length('maildir:')) = '';
 326                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 327                 # in "new/", despite (from what I understand of reading
 328                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 329                 # applies to files in "cur/".
 330                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 331                 for my $x (@try) {
 332                         my $f = "$d/$x/$n";
 333                         open my $fh, '<', $f or next;
 334                         # some (buggy) Maildir writers are non-atomic:
 335                         next unless -s $fh;
 336                         local $/;
 337                         my $raw = <$fh>;
 338                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 339                                 warn "$f changed $oidhex\n";
 340                                 next;
 341                         }
 342                         return \$raw;
 343                 }
 344         }
 345         undef;
 346 }
 347
 348 sub match_imap_url {
 349         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 350         $all //= [ $self->folders ];
 351         require PublicInbox::URIimap;
 352         my $want = PublicInbox::URIimap->new($url)->canonical;
 353         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 354         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 355                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 356         my @match;
 357         for my $x (@uri) {
 358                 next if $x->mailbox ne $want->mailbox;
 359                 next if $x->host ne $want->host;
 360                 next if $x->port != $want->port;
 361                 my $x_uidval = $x->uidvalidity;
 362                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 363
 364                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 365                 if (defined($x->auth) && !defined($want->auth) &&
 366                                 !defined($want->user)) {
 367                         push @match, $x;
 368                 # or maybe user was forgotten on CLI:
 369                 } elsif (defined($x->user) && !defined($want->user)) {
 370                         push @match, $x;
 371                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 372                         push @match, $x;
 373                 }
 374         }
 375         return @match if wantarray;
 376         scalar(@match) <= 1 ? $match[0] :
 377                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 378 }
 379
 380 sub match_nntp_url ($$$) {
 381         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 382         $all //= [ $self->folders ];
 383         require PublicInbox::URInntps;
 384         my $want = PublicInbox::URInntps->new($url)->canonical;
 385         my ($s, $h, $p) = ($want->scheme, $want->host, $want->port);
 386         my $ng = $want->group; # force scalar (no article ranges)
 387         my @uri = map { PublicInbox::URInntps->new($_)->canonical }
 388                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$ng\E\b!, @$all);
 389         my @match;
 390         for my $x (@uri) {
 391                 next if $x->group ne $ng || $x->host ne $h || $x->port != $p;
 392                 # maybe user was forgotten on CLI:
 393                 if (defined($x->userinfo) && !defined($want->userinfo)) {
 394                         push @match, $x;
 395                 } elsif (($x->userinfo//"\0") eq ($want->userinfo//"\0")) {
 396                         push @match, $x;
 397                 }
 398         }
 399         return @match if wantarray;
 400         scalar(@match) <= 1 ? $match[0] :
 401                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 402 }
 403
 404 # returns undef on failure, number on success
 405 sub group2folders {
 406         my ($self, $lei, $all, $folders) = @_;
 407         return $lei->fail(<<EOM) if @$folders;
 408 --all= not compatible with @$folders on command-line
 409 EOM
 410         my %x = map { $_ => $_ } split(/,/, $all);
 411         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 412         push(@ok, '') if $all eq '';
 413         my @no = keys %x;
 414         if (@no) {
 415                 @no = (join(',', @no));
 416                 return $lei->fail(<<EOM);
 417 --all=@no not accepted (must be `local' and/or `remote')
 418 EOM
 419         }
 420         my (%seen, @inc);
 421         my @all = $self->folders;
 422         for my $ok (@ok) {
 423                 if ($ok eq 'local') {
 424                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 425                 } elsif ($ok eq 'remote') {
 426                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 427                 } elsif ($ok ne '') {
 428                         return $lei->fail("--all=$all not understood");
 429                 } else {
 430                         @inc = @all;
 431                 }
 432                 push(@$folders, (grep { !$seen{$_}++ } @inc));
 433         }
 434         scalar(@$folders) || $lei->fail(<<EOM);
 435 no --mail-sync folders known to lei
 436 EOM
 437 }
 438
 439 # map CLI args to folder table entries, returns undef on failure
 440 sub arg2folder {
 441         my ($self, $lei, $folders) = @_;
 442         my @all = $self->folders;
 443         my %all = map { $_ => 1 } @all;
 444         my @no;
 445         for (@$folders) {
 446                 next if $all{$_}; # ok
 447                 if (m!\A(maildir|mh):(.+)!i) {
 448                         my $type = lc $1;
 449                         my $d = "$type:".$lei->abs_path($2);
 450                         push(@no, $_) unless $all{$d};
 451                         $_ = $d;
 452                 } elsif (-d "$_/new" && -d "$_/cur") {
 453                         my $d = 'maildir:'.$lei->abs_path($_);
 454                         push(@no, $_) unless $all{$d};
 455                         $_ = $d;
 456                 } elsif (m!\Aimaps?://!i) {
 457                         my $orig = $_;
 458                         my $res = match_imap_url($self, $orig, \@all);
 459                         if (ref $res) {
 460                                 $_ = $$res;
 461                                 $lei->qerr(<<EOM);
 462 # using `$res' instead of `$orig'
 463 EOM
 464                         } else {
 465                                 $lei->err($res) if defined $res;
 466                                 push @no, $orig;
 467                         }
 468                 } elsif (m!\A(?:nntps?|s?news)://!i) {
 469                         my $orig = $_;
 470                         my $res = match_nntp_url($self, $orig, \@all);
 471                         if (ref $res) {
 472                                 $_ = $$res;
 473                                 $lei->qerr(<<EOM);
 474 # using `$res' instead of `$orig'
 475 EOM
 476                         } else {
 477                                 $lei->err($res) if defined $res;
 478                                 push @no, $orig;
 479                         }
 480                 } else {
 481                         push @no, $_;
 482                 }
 483         }
 484         if (@no) {
 485                 my $no = join("\n\t", @no);
 486                 die <<EOF;
 487 No sync information for: $no
 488 Run `lei ls-mail-sync' to display valid choices
 489 EOF
 490         }
 491 }
 492
 493 sub forget_folders {
 494         my ($self, @folders) = @_;
 495         my $lk = $self->lock_for_scope;
 496         for my $folder (@folders) {
 497                 my $fid = delete($self->{fmap}->{$folder}) //
 498                         fid_for($self, $folder) // next;
 499                 for my $t (qw(blob2name blob2num folders)) {
 500                         $self->{dbh}->do("DELETE FROM $t WHERE fid = ?",
 501                                         undef, $fid);
 502                 }
 503         }
 504 }
 505
 506 # only used for changing canonicalization errors
 507 sub rename_folder {
 508         my ($self, $old, $new) = @_;
 509         my $lk = $self->lock_for_scope;
 510         my $ofid = delete($self->{fmap}->{$old}) //
 511                 fid_for($self, $old) // return;
 512         eval {
 513                 $self->{dbh}->do(<<EOM, undef, $new, $ofid);
 514 UPDATE folders SET loc = ? WHERE fid = ?
 515 EOM
 516         };
 517         if ($@ =~ /\bunique\b/i) {
 518                 my $nfid = $self->{fmap}->{$new} // fid_for($self, $new);
 519                 for my $t (qw(blob2name blob2num)) {
 520                         $self->{dbh}->do(<<EOM, undef, $nfid, $ofid);
 521 UPDATE OR REPLACE $t SET fid = ? WHERE fid = ?
 522 EOM
 523                 }
 524                 $self->{dbh}->do(<<EOM, undef, $ofid);
 525 DELETE FROM folders WHERE fid = ?
 526 EOM
 527         }
 528 }
 529
 530 sub num_oidbin ($$$) {
 531         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY if IMAP
 532         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return ();
 533         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 534 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ? ORDER BY _rowid_
 535 EOM
 536         $sth->execute($fid, $uid);
 537         map { $_->[0] } @{$sth->fetchall_arrayref};
 538 }
 539
 540 sub name_oidbin ($$$) {
 541         my ($self, $mdir, $nm) = @_;
 542         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 543         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 544 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 545 EOM
 546         $sth->execute($fid, $nm);
 547         map { $_->[0] } @{$sth->fetchall_arrayref};
 548 }
 549
 550 sub imap_oidhex {
 551         my ($self, $lei, $uid_uri) = @_;
 552         my $mailbox_uri = $uid_uri->clone;
 553         $mailbox_uri->uid(undef);
 554         my $folders = [ $$mailbox_uri ];
 555         eval { $self->arg2folder($lei, $folders) };
 556         $lei->qerr("# no sync information for $mailbox_uri") if $@;
 557         map { unpack('H*',$_) } num_oidbin($self, $folders->[0], $uid_uri->uid)
 558 }
 559
 560 1;