lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10
  11 sub dbh_new {
  12         my ($self, $rw) = @_;
  13         my $f = $self->{filename};
  14         my $creat;
  15         if (!-f $f && $rw) {
  16                 require PublicInbox::Spawn;
  17                 open my $fh, '+>>', $f or die "failed to open $f: $!";
  18                 PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  19                 $creat = 1;
  20         }
  21         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  22                 AutoCommit => 1,
  23                 RaiseError => 1,
  24                 PrintError => 0,
  25                 ReadOnly => !$rw,
  26                 sqlite_use_immediate_transaction => 1,
  27         });
  28         # no sqlite_unicode, here, all strings are binary
  29         create_tables($dbh) if $rw;
  30         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  31         $dbh->do('PRAGMA case_sensitive_like = ON');
  32         $dbh;
  33 }
  34
  35 sub new {
  36         my ($cls, $f) = @_;
  37         bless { filename => $f, fmap => {} }, $cls;
  38 }
  39
  40 sub lms_commit { delete($_[0]->{dbh})->commit }
  41
  42 sub lms_begin { ($_[0]->{dbh} //= dbh_new($_[0], 1))->begin_work };
  43
  44 sub create_tables {
  45         my ($dbh) = @_;
  46
  47         $dbh->do(<<'');
  48 CREATE TABLE IF NOT EXISTS folders (
  49         fid INTEGER PRIMARY KEY,
  50         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  51         UNIQUE (loc)
  52 )
  53
  54         $dbh->do(<<'');
  55 CREATE TABLE IF NOT EXISTS blob2num (
  56         oidbin VARBINARY NOT NULL,
  57         fid INTEGER NOT NULL, /* folder ID */
  58         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  59         UNIQUE (oidbin, fid, uid)
  60 )
  61
  62         $dbh->do(<<'');
  63 CREATE TABLE IF NOT EXISTS blob2name (
  64         oidbin VARBINARY NOT NULL,
  65         fid INTEGER NOT NULL, /* folder ID */
  66         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  67         UNIQUE (oidbin, fid, name)
  68 )
  69
  70 }
  71
  72 sub _fid_for {
  73         my ($self, $folder, $rw) = @_;
  74         my $dbh = $self->{dbh};
  75         my ($row) = $dbh->selectrow_array(<<'', undef, $folder);
  76 SELECT fid FROM folders WHERE loc = ? LIMIT 1
  77
  78         return $row if defined $row;
  79         return unless $rw;
  80
  81         ($row) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
  82
  83         my $fid = ($row // 0) + 1;
  84         # in case we're reusing, clobber existing stale refs:
  85         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
  86         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
  87
  88         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
  89         $sth->execute($fid, $folder);
  90
  91         $fid;
  92 }
  93
  94 sub set_src {
  95         my ($self, $oidhex, $folder, $id) = @_;
  96         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
  97         my $sth;
  98         if (ref($id)) { # scalar name
  99                 $id = $$id;
 100                 $sth = $self->{dbh}->prepare_cached(<<'');
 101 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 102
 103         } else { # numeric ID (IMAP UID, MH number)
 104                 $sth = $self->{dbh}->prepare_cached(<<'');
 105 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 106
 107         }
 108         $sth->execute(pack('H*', $oidhex), $fid, $id);
 109 }
 110
 111 sub clear_src {
 112         my ($self, $folder, $id) = @_;
 113         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 114         my $sth;
 115         if (ref($id)) { # scalar name
 116                 $id = $$id;
 117                 $sth = $self->{dbh}->prepare_cached(<<'');
 118 DELETE FROM blob2name WHERE fid = ? AND name = ?
 119
 120         } else {
 121                 $sth = $self->{dbh}->prepare_cached(<<'');
 122 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 123
 124         }
 125         $sth->execute($fid, $id);
 126 }
 127
 128 # read-only, iterates every oidbin + UID or name for a given folder
 129 sub each_src {
 130         my ($self, $folder, $cb, @args) = @_;
 131         my $dbh = $self->{dbh} //= dbh_new($self);
 132         my ($fid, $sth);
 133         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 134         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 135         $sth->execute($fid);
 136         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 137                 $cb->($oidbin, $id, @args);
 138         }
 139         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 140         $sth->execute($fid);
 141         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 142                 $cb->($oidbin, \$id, @args);
 143         }
 144 }
 145
 146 sub location_stats {
 147         my ($self, $folder) = @_;
 148         my $dbh = $self->{dbh} //= dbh_new($self);
 149         my $fid;
 150         my $ret = {};
 151         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 152         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 153 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 154
 155         $ret->{'name.count'} = $row if $row;
 156         for my $op (qw(count min max)) {
 157                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 158 SELECT $op(uid) FROM blob2num WHERE fid = ?
 159
 160                 $row or last;
 161                 $ret->{"uid.$op"} = $row;
 162         }
 163         $ret;
 164 }
 165
 166 # returns a { location => [ list-of-ids-or-names ] } mapping
 167 sub locations_for {
 168         my ($self, $oidhex) = @_;
 169         my ($fid, $sth, $id, %fid2id);
 170         my $dbh = $self->{dbh} //= dbh_new($self);
 171         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 172         $sth->execute(pack('H*', $oidhex));
 173         while (my ($fid, $uid) = $sth->fetchrow_array) {
 174                 push @{$fid2id{$fid}}, $uid;
 175         }
 176         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 177         $sth->execute(pack('H*', $oidhex));
 178         while (my ($fid, $name) = $sth->fetchrow_array) {
 179                 push @{$fid2id{$fid}}, $name;
 180         }
 181         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 182         my $ret = {};
 183         while (my ($fid, $ids) = each %fid2id) {
 184                 $sth->execute($fid);
 185                 my ($loc) = $sth->fetchrow_array;
 186                 unless (defined $loc) {
 187                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 188                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 189                                 } @$ids;
 190                         next;
 191                 }
 192                 $ret->{$loc} = $ids;
 193         }
 194         scalar(keys %$ret) ? $ret : undef;
 195 }
 196
 197 # returns a list of folders used for completion
 198 sub folders {
 199         my ($self, $pfx) = @_;
 200         my $dbh = $self->{dbh} //= dbh_new($self);
 201         my $sql = 'SELECT loc FROM folders';
 202         my @pfx;
 203         if (defined $pfx) {
 204                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 205                 @pfx = ($pfx, '\\');
 206                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 207                 $pfx[0] .= '%';
 208         }
 209         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 210 }
 211
 212 sub local_blob {
 213         my ($self, $oidhex, $vrfy) = @_;
 214         my $dbh = $self->{dbh} //= dbh_new($self);
 215         my $b2n = $dbh->prepare(<<'');
 216 SELECT f.loc,b.name FROM blob2name b
 217 LEFT JOIN folders f ON b.fid = f.fid
 218 WHERE b.oidbin = ?
 219
 220         $b2n->execute(pack('H*', $oidhex));
 221         while (my ($d, $n) = $b2n->fetchrow_array) {
 222                 substr($d, 0, length('maildir:')) = '';
 223                 my $f = "$d/" . ($n =~ /:2,[a-zA-Z]*\z/ ? "cur/$n" : "new/$n");
 224                 open my $fh, '<', $f or next;
 225                 if (-s $fh) {
 226                         local $/;
 227                         my $raw = <$fh>;
 228                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 229                                 warn "$f changed $oidhex\n";
 230                                 next;
 231                         }
 232                         return \$raw;
 233                 }
 234         }
 235         undef;
 236 }
 237
 238 1;