lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10
  11 sub dbh_new {
  12         my ($self, $rw) = @_;
  13         my $f = $self->{filename};
  14         my $creat = $rw && !-s $f;
  15         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  16                 AutoCommit => 1,
  17                 RaiseError => 1,
  18                 PrintError => 0,
  19                 ReadOnly => !$rw,
  20                 sqlite_use_immediate_transaction => 1,
  21         });
  22         # no sqlite_unicode, here, all strings are binary
  23         create_tables($dbh) if $rw;
  24         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  25         $dbh->do('PRAGMA case_sensitive_like = ON');
  26         $dbh;
  27 }
  28
  29 sub new {
  30         my ($cls, $f) = @_;
  31         bless { filename => $f, fmap => {} }, $cls;
  32 }
  33
  34 sub lms_commit { delete($_[0]->{dbh})->commit }
  35
  36 sub lms_begin { ($_[0]->{dbh} //= dbh_new($_[0], 1))->begin_work };
  37
  38 sub create_tables {
  39         my ($dbh) = @_;
  40
  41         $dbh->do(<<'');
  42 CREATE TABLE IF NOT EXISTS folders (
  43         fid INTEGER PRIMARY KEY,
  44         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  45         UNIQUE (loc)
  46 )
  47
  48         $dbh->do(<<'');
  49 CREATE TABLE IF NOT EXISTS blob2num (
  50         oidbin VARBINARY NOT NULL,
  51         fid INTEGER NOT NULL, /* folder ID */
  52         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  53         UNIQUE (oidbin, fid, uid)
  54 )
  55
  56         $dbh->do(<<'');
  57 CREATE TABLE IF NOT EXISTS blob2name (
  58         oidbin VARBINARY NOT NULL,
  59         fid INTEGER NOT NULL, /* folder ID */
  60         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  61         UNIQUE (oidbin, fid, name)
  62 )
  63
  64 }
  65
  66 sub _fid_for {
  67         my ($self, $folder, $rw) = @_;
  68         my $dbh = $self->{dbh};
  69         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  70         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  71         return $fid if defined $fid;
  72
  73         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  74                 warn "folder: $folder/ had trailing slash in arg\n";
  75                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  76                 if (defined $fid) {
  77                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  78 UPDATE folders SET loc = ? WHERE fid = ?
  79 EOM
  80                         return $fid;
  81                 }
  82         # sometimes we stored trailing slash..
  83         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
  84                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
  85                 if (defined $fid) {
  86                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  87 UPDATE folders SET loc = ? WHERE fid = ?
  88 EOM
  89                         return $fid;
  90                 }
  91         }
  92         return unless $rw;
  93
  94         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
  95
  96         $fid += 1;
  97         # in case we're reusing, clobber existing stale refs:
  98         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
  99         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 100
 101         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 102         $sth->execute($fid, $folder);
 103
 104         $fid;
 105 }
 106
 107 sub set_src {
 108         my ($self, $oidhex, $folder, $id) = @_;
 109         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 110         my $sth;
 111         if (ref($id)) { # scalar name
 112                 $id = $$id;
 113                 $sth = $self->{dbh}->prepare_cached(<<'');
 114 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 115
 116         } else { # numeric ID (IMAP UID, MH number)
 117                 $sth = $self->{dbh}->prepare_cached(<<'');
 118 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 119
 120         }
 121         $sth->execute(pack('H*', $oidhex), $fid, $id);
 122 }
 123
 124 sub clear_src {
 125         my ($self, $folder, $id) = @_;
 126         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 127         my $sth;
 128         if (ref($id)) { # scalar name
 129                 $id = $$id;
 130                 $sth = $self->{dbh}->prepare_cached(<<'');
 131 DELETE FROM blob2name WHERE fid = ? AND name = ?
 132
 133         } else {
 134                 $sth = $self->{dbh}->prepare_cached(<<'');
 135 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 136
 137         }
 138         $sth->execute($fid, $id);
 139 }
 140
 141 # Maildir-only
 142 sub mv_src {
 143         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 144         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 145         my $sth = $self->{dbh}->prepare_cached(<<'');
 146 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 147
 148         $sth->execute($newbn, $fid, $oidbin, $$id);
 149 }
 150
 151 # read-only, iterates every oidbin + UID or name for a given folder
 152 sub each_src {
 153         my ($self, $folder, $cb, @args) = @_;
 154         my $dbh = $self->{dbh} //= dbh_new($self);
 155         my ($fid, $sth);
 156         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 157         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 158         $sth->execute($fid);
 159         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 160                 $cb->($oidbin, $id, @args);
 161         }
 162         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 163         $sth->execute($fid);
 164         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 165                 $cb->($oidbin, \$id, @args);
 166         }
 167 }
 168
 169 sub location_stats {
 170         my ($self, $folder) = @_;
 171         my $dbh = $self->{dbh} //= dbh_new($self);
 172         my $fid;
 173         my $ret = {};
 174         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 175         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 176 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 177
 178         $ret->{'name.count'} = $row if $row;
 179         for my $op (qw(count min max)) {
 180                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 181 SELECT $op(uid) FROM blob2num WHERE fid = ?
 182
 183                 $row or last;
 184                 $ret->{"uid.$op"} = $row;
 185         }
 186         $ret;
 187 }
 188
 189 # returns a { location => [ list-of-ids-or-names ] } mapping
 190 sub locations_for {
 191         my ($self, $oidhex) = @_;
 192         my ($fid, $sth, $id, %fid2id);
 193         my $dbh = $self->{dbh} //= dbh_new($self);
 194         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 195         $sth->execute(pack('H*', $oidhex));
 196         while (my ($fid, $uid) = $sth->fetchrow_array) {
 197                 push @{$fid2id{$fid}}, $uid;
 198         }
 199         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 200         $sth->execute(pack('H*', $oidhex));
 201         while (my ($fid, $name) = $sth->fetchrow_array) {
 202                 push @{$fid2id{$fid}}, $name;
 203         }
 204         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 205         my $ret = {};
 206         while (my ($fid, $ids) = each %fid2id) {
 207                 $sth->execute($fid);
 208                 my ($loc) = $sth->fetchrow_array;
 209                 unless (defined $loc) {
 210                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 211                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 212                                 } @$ids;
 213                         next;
 214                 }
 215                 $ret->{$loc} = $ids;
 216         }
 217         scalar(keys %$ret) ? $ret : undef;
 218 }
 219
 220 # returns a list of folders used for completion
 221 sub folders {
 222         my ($self, $pfx) = @_;
 223         my $dbh = $self->{dbh} //= dbh_new($self);
 224         my $sql = 'SELECT loc FROM folders';
 225         my @pfx;
 226         if (defined $pfx) {
 227                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 228                 @pfx = ($pfx, '\\');
 229                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 230                 $pfx[0] .= '%';
 231         }
 232         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 233 }
 234
 235 sub local_blob {
 236         my ($self, $oidhex, $vrfy) = @_;
 237         my $dbh = $self->{dbh} //= dbh_new($self);
 238         my $b2n = $dbh->prepare(<<'');
 239 SELECT f.loc,b.name FROM blob2name b
 240 LEFT JOIN folders f ON b.fid = f.fid
 241 WHERE b.oidbin = ?
 242
 243         $b2n->execute(pack('H*', $oidhex));
 244         while (my ($d, $n) = $b2n->fetchrow_array) {
 245                 substr($d, 0, length('maildir:')) = '';
 246                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 247                 # in "new/", despite (from what I understand of reading
 248                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 249                 # applies to files in "cur/".
 250                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 251                 for my $x (@try) {
 252                         my $f = "$d/$x/$n";
 253                         open my $fh, '<', $f or next;
 254                         # some (buggy) Maildir writers are non-atomic:
 255                         next unless -s $fh;
 256                         local $/;
 257                         my $raw = <$fh>;
 258                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 259                                 warn "$f changed $oidhex\n";
 260                                 next;
 261                         }
 262                         return \$raw;
 263                 }
 264         }
 265         undef;
 266 }
 267
 268 1;