lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10 use Carp ();
  11
  12 sub dbh_new {
  13         my ($self, $rw) = @_;
  14         my $f = $self->{filename};
  15         my $creat = $rw && !-s $f;
  16         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  17                 AutoCommit => 1,
  18                 RaiseError => 1,
  19                 PrintError => 0,
  20                 ReadOnly => !$rw,
  21                 sqlite_use_immediate_transaction => 1,
  22         });
  23         # no sqlite_unicode, here, all strings are binary
  24         create_tables($dbh) if $rw;
  25         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  26         $dbh->do('PRAGMA case_sensitive_like = ON');
  27         $dbh;
  28 }
  29
  30 sub new {
  31         my ($cls, $f) = @_;
  32         bless { filename => $f, fmap => {} }, $cls;
  33 }
  34
  35 sub lms_write_prepare { ($_[0]->{dbh} //= dbh_new($_[0], 1)) };
  36
  37 sub create_tables {
  38         my ($dbh) = @_;
  39
  40         $dbh->do(<<'');
  41 CREATE TABLE IF NOT EXISTS folders (
  42         fid INTEGER PRIMARY KEY,
  43         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  44         UNIQUE (loc)
  45 )
  46
  47         $dbh->do(<<'');
  48 CREATE TABLE IF NOT EXISTS blob2num (
  49         oidbin VARBINARY NOT NULL,
  50         fid INTEGER NOT NULL, /* folder ID */
  51         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  52         UNIQUE (oidbin, fid, uid)
  53 )
  54
  55         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  56         $dbh->do(<<'');
  57 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  58
  59         $dbh->do(<<'');
  60 CREATE TABLE IF NOT EXISTS blob2name (
  61         oidbin VARBINARY NOT NULL,
  62         fid INTEGER NOT NULL, /* folder ID */
  63         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  64         UNIQUE (oidbin, fid, name)
  65 )
  66
  67         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  68         $dbh->do(<<'');
  69 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  70
  71 }
  72
  73 sub fid_for {
  74         my ($self, $folder, $rw) = @_;
  75         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  76         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  77         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  78         return $fid if defined $fid;
  79
  80         # caller had trailing slash (LeiToMail)
  81         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  82                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  83                 if (defined $fid) {
  84                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  85 UPDATE folders SET loc = ? WHERE fid = ?
  86 EOM
  87                         return $fid;
  88                 }
  89         # sometimes we stored trailing slash..
  90         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
  91                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
  92                 if (defined $fid) {
  93                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  94 UPDATE folders SET loc = ? WHERE fid = ?
  95 EOM
  96                         return $fid;
  97                 }
  98         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
  99                 require PublicInbox::URIimap;
 100                 PublicInbox::URIimap->new($folder)->uidvalidity //
 101                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 102         }
 103         return unless $rw;
 104
 105         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 106
 107         $fid += 1;
 108         # in case we're reusing, clobber existing stale refs:
 109         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 110         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 111
 112         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 113         $sth->execute($fid, $folder);
 114
 115         $fid;
 116 }
 117
 118 sub set_src {
 119         my ($self, $oidbin, $folder, $id) = @_;
 120         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 121         my $sth;
 122         if (ref($id)) { # scalar name
 123                 $id = $$id;
 124                 $sth = $self->{dbh}->prepare_cached(<<'');
 125 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 126
 127         } else { # numeric ID (IMAP UID, MH number)
 128                 $sth = $self->{dbh}->prepare_cached(<<'');
 129 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 130
 131         }
 132         $sth->execute($oidbin, $fid, $id);
 133 }
 134
 135 sub clear_src {
 136         my ($self, $folder, $id) = @_;
 137         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 138         my $sth;
 139         if (ref($id)) { # scalar name
 140                 $id = $$id;
 141                 $sth = $self->{dbh}->prepare_cached(<<'');
 142 DELETE FROM blob2name WHERE fid = ? AND name = ?
 143
 144         } else {
 145                 $sth = $self->{dbh}->prepare_cached(<<'');
 146 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 147
 148         }
 149         $sth->execute($fid, $id);
 150 }
 151
 152 # Maildir-only
 153 sub mv_src {
 154         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 155         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 156         my $sth = $self->{dbh}->prepare_cached(<<'');
 157 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 158
 159         my $nr = $sth->execute($newbn, $fid, $oidbin, $$id);
 160         if ($nr == 0) { # may race with a clear_src, ensure new value exists
 161                 $sth = $self->{dbh}->prepare_cached(<<'');
 162 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 163
 164                 $sth->execute($oidbin, $fid, $newbn);
 165         }
 166 }
 167
 168 # read-only, iterates every oidbin + UID or name for a given folder
 169 sub each_src {
 170         my ($self, $folder, $cb, @args) = @_;
 171         my $dbh = $self->{dbh} //= dbh_new($self);
 172         my ($fid, $sth);
 173         if (ref($folder) eq 'HASH') {
 174                 $fid = $folder->{fid} // die "BUG: no `fid'";
 175         } else {
 176                 $fid = $self->{fmap}->{$folder} //=
 177                         fid_for($self, $folder) // return;
 178         }
 179         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 180         $sth->execute($fid);
 181         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 182                 $cb->($oidbin, $id, @args);
 183         }
 184         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 185         $sth->execute($fid);
 186         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 187                 $cb->($oidbin, \$id, @args);
 188         }
 189 }
 190
 191 sub location_stats {
 192         my ($self, $folder) = @_;
 193         my $dbh = $self->{dbh} //= dbh_new($self);
 194         my $fid;
 195         my $ret = {};
 196         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 197         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 198 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 199
 200         $ret->{'name.count'} = $row if $row;
 201         for my $op (qw(count min max)) {
 202                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 203 SELECT $op(uid) FROM blob2num WHERE fid = ?
 204
 205                 $row or last;
 206                 $ret->{"uid.$op"} = $row;
 207         }
 208         $ret;
 209 }
 210
 211 # returns a { location => [ list-of-ids-or-names ] } mapping
 212 sub locations_for {
 213         my ($self, $oidbin) = @_;
 214         my ($fid, $sth, $id, %fid2id);
 215         my $dbh = $self->{dbh} //= dbh_new($self);
 216         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 217         $sth->execute($oidbin);
 218         while (my ($fid, $uid) = $sth->fetchrow_array) {
 219                 push @{$fid2id{$fid}}, $uid;
 220         }
 221         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 222         $sth->execute($oidbin);
 223         while (my ($fid, $name) = $sth->fetchrow_array) {
 224                 push @{$fid2id{$fid}}, $name;
 225         }
 226         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 227         my $ret = {};
 228         while (my ($fid, $ids) = each %fid2id) {
 229                 $sth->execute($fid);
 230                 my ($loc) = $sth->fetchrow_array;
 231                 unless (defined $loc) {
 232                         my $oidhex = unpack('H*', $oidbin);
 233                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 234                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 235                                 } @$ids;
 236                         next;
 237                 }
 238                 $ret->{$loc} = $ids;
 239         }
 240         scalar(keys %$ret) ? $ret : undef;
 241 }
 242
 243 # returns a list of folders used for completion
 244 sub folders {
 245         my ($self, $pfx) = @_;
 246         my $dbh = $self->{dbh} //= dbh_new($self);
 247         my $sql = 'SELECT loc FROM folders';
 248         my @pfx;
 249         if (defined $pfx) {
 250                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 251                 @pfx = ($pfx, '\\');
 252                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 253                 $pfx[0] .= '%';
 254         }
 255         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 256 }
 257
 258 sub local_blob {
 259         my ($self, $oidhex, $vrfy) = @_;
 260         my $dbh = $self->{dbh} //= dbh_new($self);
 261         my $b2n = $dbh->prepare(<<'');
 262 SELECT f.loc,b.name FROM blob2name b
 263 LEFT JOIN folders f ON b.fid = f.fid
 264 WHERE b.oidbin = ?
 265
 266         $b2n->execute(pack('H*', $oidhex));
 267         while (my ($d, $n) = $b2n->fetchrow_array) {
 268                 substr($d, 0, length('maildir:')) = '';
 269                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 270                 # in "new/", despite (from what I understand of reading
 271                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 272                 # applies to files in "cur/".
 273                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 274                 for my $x (@try) {
 275                         my $f = "$d/$x/$n";
 276                         open my $fh, '<', $f or next;
 277                         # some (buggy) Maildir writers are non-atomic:
 278                         next unless -s $fh;
 279                         local $/;
 280                         my $raw = <$fh>;
 281                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 282                                 warn "$f changed $oidhex\n";
 283                                 next;
 284                         }
 285                         return \$raw;
 286                 }
 287         }
 288         undef;
 289 }
 290
 291 sub match_imap_url {
 292         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 293         $all //= [ $self->folders ];
 294         require PublicInbox::URIimap;
 295         my $want = PublicInbox::URIimap->new($url)->canonical;
 296         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 297         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 298                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 299         my @match;
 300         for my $x (@uri) {
 301                 next if $x->mailbox ne $want->mailbox;
 302                 next if $x->host ne $want->host;
 303                 next if $x->port != $want->port;
 304                 my $x_uidval = $x->uidvalidity;
 305                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 306
 307                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 308                 if (defined($x->auth) && !defined($want->auth) &&
 309                                 !defined($want->user)) {
 310                         push @match, $x;
 311                 # or maybe user was forgotten on CLI:
 312                 } elsif (defined($x->user) && !defined($want->user)) {
 313                         push @match, $x;
 314                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 315                         push @match, $x;
 316                 }
 317         }
 318         return @match if wantarray;
 319         scalar(@match) <= 1 ? $match[0] :
 320                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 321 }
 322
 323 # returns undef on failure, number on success
 324 sub group2folders {
 325         my ($self, $lei, $all, $folders) = @_;
 326         return $lei->fail(<<EOM) if @$folders;
 327 --all= not compatible with @$folders on command-line
 328 EOM
 329         my %x = map { $_ => $_ } split(/,/, $all);
 330         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 331         push(@ok, '') if $all eq '';
 332         my @no = keys %x;
 333         if (@no) {
 334                 @no = (join(',', @no));
 335                 return $lei->fail(<<EOM);
 336 --all=@no not accepted (must be `local' and/or `remote')
 337 EOM
 338         }
 339         my (%seen, @inc);
 340         my @all = $self->folders;
 341         for my $ok (@ok) {
 342                 if ($ok eq 'local') {
 343                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 344                 } elsif ($ok eq 'remote') {
 345                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 346                 } elsif ($ok ne '') {
 347                         return $lei->fail("--all=$all not understood");
 348                 } else {
 349                         @inc = @all;
 350                 }
 351                 push(@$folders, (grep { !$seen{$_}++ } @inc));
 352         }
 353         scalar(@$folders) || $lei->fail(<<EOM);
 354 no --mail-sync folders known to lei
 355 EOM
 356 }
 357
 358 # map CLI args to folder table entries, returns undef on failure
 359 sub arg2folder {
 360         my ($self, $lei, $folders) = @_;
 361         my @all = $self->folders;
 362         my %all = map { $_ => 1 } @all;
 363         my ($err, @no);
 364         for (@$folders) {
 365                 next if $all{$_}; # ok
 366                 if (m!\A(maildir|mh):(.+)!i) {
 367                         my $type = lc $1;
 368                         my $d = "$type:".$lei->abs_path($2);
 369                         push(@no, $_) unless $all{$d};
 370                         $_ = $d;
 371                 } elsif (-d "$_/new" && -d "$_/cur") {
 372                         my $d = 'maildir:'.$lei->abs_path($_);
 373                         push(@no, $_) unless $all{$d};
 374                         $_ = $d;
 375                 } elsif (m!\Aimaps?://!i) {
 376                         my $orig = $_;
 377                         my $res = match_imap_url($self, $orig, \@all);
 378                         if (ref $res) {
 379                                 $_ = $$res;
 380                                 push(@{$err->{qerr}}, <<EOM);
 381 # using `$res' instead of `$orig'
 382 EOM
 383                         } else {
 384                                 $lei->err($res) if defined $res;
 385                                 push @no, $orig;
 386                         }
 387                 } else {
 388                         push @no, $_;
 389                 }
 390         }
 391         if (@no) {
 392                 my $no = join("\n\t", @no);
 393                 $err->{fail} = <<EOF;
 394 No sync information for: $no
 395 Run `lei ls-mail-sync' to display valid choices
 396 EOF
 397         }
 398         $err;
 399 }
 400
 401 sub forget_folder {
 402         my ($self, $folder) = @_;
 403         my $fid = delete($self->{fmap}->{$folder}) //
 404                 fid_for($self, $folder) // return;
 405         for my $t (qw(blob2name blob2num folders)) {
 406                 $self->{dbh}->do("DELETE FROM $t WHERE fid = ?", undef, $fid);
 407         }
 408 }
 409
 410 # only used for changing canonicalization errors
 411 sub rename_folder {
 412         my ($self, $old, $new) = @_;
 413         my $ofid = delete($self->{fmap}->{$old}) //
 414                 fid_for($self, $old) // return;
 415         eval {
 416                 $self->{dbh}->do(<<EOM, undef, $new, $ofid);
 417 UPDATE folders SET loc = ? WHERE fid = ?
 418 EOM
 419         };
 420         if ($@ =~ /\bunique\b/i) {
 421                 my $nfid = $self->{fmap}->{$new} // fid_for($self, $new);
 422                 for my $t (qw(blob2name blob2num)) {
 423                         $self->{dbh}->do(<<EOM, undef, $nfid, $ofid);
 424 UPDATE OR REPLACE $t SET fid = ? WHERE fid = ?
 425 EOM
 426                 }
 427                 $self->{dbh}->do(<<EOM, undef, $ofid);
 428 DELETE FROM folders WHERE fid = ?
 429 EOM
 430         }
 431 }
 432
 433 sub imap_oidbin ($$$) {
 434         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY
 435         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return;
 436         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 437 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ?
 438 EOM
 439         $sth->execute($fid, $uid);
 440         $sth->fetchrow_array;
 441 }
 442
 443 sub name_oidbin ($$$) {
 444         my ($self, $mdir, $nm) = @_;
 445         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 446         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 447 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 448 EOM
 449         $sth->execute($fid, $nm);
 450         $sth->fetchrow_array;
 451 }
 452
 453 sub imap_oid {
 454         my ($self, $lei, $uid_uri) = @_;
 455         my $mailbox_uri = $uid_uri->clone;
 456         $mailbox_uri->uid(undef);
 457         my $folders = [ $$mailbox_uri ];
 458         if (my $err = $self->arg2folder($lei, $folders)) {
 459                 if ($err->{fail}) {
 460                         $lei->qerr("# no sync information for $mailbox_uri");
 461                         return;
 462                 }
 463                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
 464         }
 465         my $oidbin = imap_oidbin($self, $folders->[0], $uid_uri->uid);
 466         $oidbin ? unpack('H*', $oidbin) : undef;
 467 }
 468
 469 1;