lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10
  11 sub dbh_new {
  12         my ($self, $rw) = @_;
  13         my $f = $self->{filename};
  14         my $creat;
  15         if (!-f $f && $rw) {
  16                 require PublicInbox::Spawn;
  17                 open my $fh, '+>>', $f or die "failed to open $f: $!";
  18                 PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  19                 $creat = 1;
  20         }
  21         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  22                 AutoCommit => 1,
  23                 RaiseError => 1,
  24                 PrintError => 0,
  25                 ReadOnly => !$rw,
  26                 sqlite_use_immediate_transaction => 1,
  27         });
  28         # no sqlite_unicode, here, all strings are binary
  29         create_tables($dbh) if $rw;
  30         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  31         $dbh->do('PRAGMA case_sensitive_like = ON');
  32         $dbh;
  33 }
  34
  35 sub new {
  36         my ($cls, $f) = @_;
  37         bless { filename => $f, fmap => {} }, $cls;
  38 }
  39
  40 sub lms_commit { delete($_[0]->{dbh})->commit }
  41
  42 sub lms_begin { ($_[0]->{dbh} //= dbh_new($_[0], 1))->begin_work };
  43
  44 sub create_tables {
  45         my ($dbh) = @_;
  46
  47         $dbh->do(<<'');
  48 CREATE TABLE IF NOT EXISTS folders (
  49         fid INTEGER PRIMARY KEY,
  50         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  51         UNIQUE (loc)
  52 )
  53
  54         $dbh->do(<<'');
  55 CREATE TABLE IF NOT EXISTS blob2num (
  56         oidbin VARBINARY NOT NULL,
  57         fid INTEGER NOT NULL, /* folder ID */
  58         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  59         UNIQUE (oidbin, fid, uid)
  60 )
  61
  62         $dbh->do(<<'');
  63 CREATE TABLE IF NOT EXISTS blob2name (
  64         oidbin VARBINARY NOT NULL,
  65         fid INTEGER NOT NULL, /* folder ID */
  66         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  67         UNIQUE (oidbin, fid, name)
  68 )
  69
  70 }
  71
  72 sub _fid_for {
  73         my ($self, $folder, $rw) = @_;
  74         my $dbh = $self->{dbh};
  75         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  76         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  77         return $fid if defined $fid;
  78
  79         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  80                 warn "folder: $folder/ had trailing slash in arg\n";
  81                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  82                 if (defined $fid) {
  83                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  84 UPDATE folders SET loc = ? WHERE fid = ?
  85 EOM
  86                         return $fid;
  87                 }
  88         # sometimes we stored trailing slash..
  89         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
  90                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
  91                 if (defined $fid) {
  92                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  93 UPDATE folders SET loc = ? WHERE fid = ?
  94 EOM
  95                         return $fid;
  96                 }
  97         }
  98         return unless $rw;
  99
 100         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 101
 102         $fid += 1;
 103         # in case we're reusing, clobber existing stale refs:
 104         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 105         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 106
 107         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 108         $sth->execute($fid, $folder);
 109
 110         $fid;
 111 }
 112
 113 sub set_src {
 114         my ($self, $oidhex, $folder, $id) = @_;
 115         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 116         my $sth;
 117         if (ref($id)) { # scalar name
 118                 $id = $$id;
 119                 $sth = $self->{dbh}->prepare_cached(<<'');
 120 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 121
 122         } else { # numeric ID (IMAP UID, MH number)
 123                 $sth = $self->{dbh}->prepare_cached(<<'');
 124 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 125
 126         }
 127         $sth->execute(pack('H*', $oidhex), $fid, $id);
 128 }
 129
 130 sub clear_src {
 131         my ($self, $folder, $id) = @_;
 132         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 133         my $sth;
 134         if (ref($id)) { # scalar name
 135                 $id = $$id;
 136                 $sth = $self->{dbh}->prepare_cached(<<'');
 137 DELETE FROM blob2name WHERE fid = ? AND name = ?
 138
 139         } else {
 140                 $sth = $self->{dbh}->prepare_cached(<<'');
 141 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 142
 143         }
 144         $sth->execute($fid, $id);
 145 }
 146
 147 # read-only, iterates every oidbin + UID or name for a given folder
 148 sub each_src {
 149         my ($self, $folder, $cb, @args) = @_;
 150         my $dbh = $self->{dbh} //= dbh_new($self);
 151         my ($fid, $sth);
 152         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 153         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 154         $sth->execute($fid);
 155         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 156                 $cb->($oidbin, $id, @args);
 157         }
 158         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 159         $sth->execute($fid);
 160         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 161                 $cb->($oidbin, \$id, @args);
 162         }
 163 }
 164
 165 sub location_stats {
 166         my ($self, $folder) = @_;
 167         my $dbh = $self->{dbh} //= dbh_new($self);
 168         my $fid;
 169         my $ret = {};
 170         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 171         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 172 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 173
 174         $ret->{'name.count'} = $row if $row;
 175         for my $op (qw(count min max)) {
 176                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 177 SELECT $op(uid) FROM blob2num WHERE fid = ?
 178
 179                 $row or last;
 180                 $ret->{"uid.$op"} = $row;
 181         }
 182         $ret;
 183 }
 184
 185 # returns a { location => [ list-of-ids-or-names ] } mapping
 186 sub locations_for {
 187         my ($self, $oidhex) = @_;
 188         my ($fid, $sth, $id, %fid2id);
 189         my $dbh = $self->{dbh} //= dbh_new($self);
 190         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 191         $sth->execute(pack('H*', $oidhex));
 192         while (my ($fid, $uid) = $sth->fetchrow_array) {
 193                 push @{$fid2id{$fid}}, $uid;
 194         }
 195         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 196         $sth->execute(pack('H*', $oidhex));
 197         while (my ($fid, $name) = $sth->fetchrow_array) {
 198                 push @{$fid2id{$fid}}, $name;
 199         }
 200         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 201         my $ret = {};
 202         while (my ($fid, $ids) = each %fid2id) {
 203                 $sth->execute($fid);
 204                 my ($loc) = $sth->fetchrow_array;
 205                 unless (defined $loc) {
 206                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 207                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 208                                 } @$ids;
 209                         next;
 210                 }
 211                 $ret->{$loc} = $ids;
 212         }
 213         scalar(keys %$ret) ? $ret : undef;
 214 }
 215
 216 # returns a list of folders used for completion
 217 sub folders {
 218         my ($self, $pfx) = @_;
 219         my $dbh = $self->{dbh} //= dbh_new($self);
 220         my $sql = 'SELECT loc FROM folders';
 221         my @pfx;
 222         if (defined $pfx) {
 223                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 224                 @pfx = ($pfx, '\\');
 225                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 226                 $pfx[0] .= '%';
 227         }
 228         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 229 }
 230
 231 sub local_blob {
 232         my ($self, $oidhex, $vrfy) = @_;
 233         my $dbh = $self->{dbh} //= dbh_new($self);
 234         my $b2n = $dbh->prepare(<<'');
 235 SELECT f.loc,b.name FROM blob2name b
 236 LEFT JOIN folders f ON b.fid = f.fid
 237 WHERE b.oidbin = ?
 238
 239         $b2n->execute(pack('H*', $oidhex));
 240         while (my ($d, $n) = $b2n->fetchrow_array) {
 241                 substr($d, 0, length('maildir:')) = '';
 242                 my $f = "$d/" . ($n =~ /:2,[a-zA-Z]*\z/ ? "cur/$n" : "new/$n");
 243                 open my $fh, '<', $f or next;
 244                 if (-s $fh) {
 245                         local $/;
 246                         my $raw = <$fh>;
 247                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 248                                 warn "$f changed $oidhex\n";
 249                                 next;
 250                         }
 251                         return \$raw;
 252                 }
 253         }
 254         undef;
 255 }
 256
 257 1;