lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9
  10 sub dbh_new {
  11         my ($self, $rw) = @_;
  12         my $f = $self->{filename};
  13         my $creat;
  14         if (!-f $f && $rw) {
  15                 require PublicInbox::Spawn;
  16                 open my $fh, '+>>', $f or die "failed to open $f: $!";
  17                 PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  18                 $creat = 1;
  19         }
  20         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  21                 AutoCommit => 1,
  22                 RaiseError => 1,
  23                 PrintError => 0,
  24                 ReadOnly => !$rw,
  25                 sqlite_use_immediate_transaction => 1,
  26         });
  27         # no sqlite_unicode, here, all strings are binary
  28         create_tables($dbh) if $rw;
  29         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  30         $dbh->do('PRAGMA case_sensitive_like = ON');
  31         $dbh;
  32 }
  33
  34 sub new {
  35         my ($cls, $f) = @_;
  36         bless { filename => $f, fmap => {} }, $cls;
  37 }
  38
  39 sub lms_commit { delete($_[0]->{dbh})->commit }
  40
  41 sub lms_begin { ($_[0]->{dbh} //= dbh_new($_[0], 1))->begin_work };
  42
  43 sub create_tables {
  44         my ($dbh) = @_;
  45
  46         $dbh->do(<<'');
  47 CREATE TABLE IF NOT EXISTS folders (
  48         fid INTEGER PRIMARY KEY,
  49         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  50         UNIQUE (loc)
  51 )
  52
  53         $dbh->do(<<'');
  54 CREATE TABLE IF NOT EXISTS blob2num (
  55         oidbin VARBINARY NOT NULL,
  56         fid INTEGER NOT NULL, /* folder ID */
  57         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  58         UNIQUE (oidbin, fid, uid)
  59 )
  60
  61         $dbh->do(<<'');
  62 CREATE TABLE IF NOT EXISTS blob2name (
  63         oidbin VARBINARY NOT NULL,
  64         fid INTEGER NOT NULL, /* folder ID */
  65         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  66         UNIQUE (oidbin, fid, name)
  67 )
  68
  69 }
  70
  71 sub _fid_for {
  72         my ($self, $folder, $rw) = @_;
  73         my $dbh = $self->{dbh};
  74         my ($row) = $dbh->selectrow_array(<<'', undef, $folder);
  75 SELECT fid FROM folders WHERE loc = ? LIMIT 1
  76
  77         return $row if defined $row;
  78         return unless $rw;
  79
  80         ($row) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
  81
  82         my $fid = ($row // 0) + 1;
  83         # in case we're reusing, clobber existing stale refs:
  84         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
  85         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
  86
  87         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
  88         $sth->execute($fid, $folder);
  89
  90         $fid;
  91 }
  92
  93 sub set_src {
  94         my ($self, $oidhex, $folder, $id) = @_;
  95         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
  96         my $sth;
  97         if (ref($id)) { # scalar name
  98                 $id = $$id;
  99                 $sth = $self->{dbh}->prepare_cached(<<'');
 100 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 101
 102         } else { # numeric ID (IMAP UID, MH number)
 103                 $sth = $self->{dbh}->prepare_cached(<<'');
 104 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 105
 106         }
 107         $sth->execute(pack('H*', $oidhex), $fid, $id);
 108 }
 109
 110 sub clear_src {
 111         my ($self, $folder, $id) = @_;
 112         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 113         my $sth;
 114         if (ref($id)) { # scalar name
 115                 $id = $$id;
 116                 $sth = $self->{dbh}->prepare_cached(<<'');
 117 DELETE FROM blob2name WHERE fid = ? AND name = ?
 118
 119         } else {
 120                 $sth = $self->{dbh}->prepare_cached(<<'');
 121 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 122
 123         }
 124         $sth->execute($fid, $id);
 125 }
 126
 127 # read-only, iterates every oidbin + UID or name for a given folder
 128 sub each_src {
 129         my ($self, $folder, $cb, @args) = @_;
 130         my $dbh = $self->{dbh} //= dbh_new($self);
 131         my ($fid, $sth);
 132         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 133         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 134         $sth->execute($fid);
 135         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 136                 $cb->($oidbin, $id, @args);
 137         }
 138         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 139         $sth->execute($fid);
 140         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 141                 $cb->($oidbin, \$id, @args);
 142         }
 143 }
 144
 145 sub location_stats {
 146         my ($self, $folder, $cb, @args) = @_;
 147         my $dbh = $self->{dbh} //= dbh_new($self);
 148         my $fid;
 149         my $ret = {};
 150         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 151         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 152 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 153
 154         $ret->{'name.count'} = $row if $row;
 155         for my $op (qw(count min max)) {
 156                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 157 SELECT $op(uid) FROM blob2num WHERE fid = ?
 158
 159                 $row or last;
 160                 $ret->{"uid.$op"} = $row;
 161         }
 162         $ret;
 163 }
 164
 165 # returns a { location => [ list-of-ids-or-names ] } mapping
 166 sub locations_for {
 167         my ($self, $oidhex) = @_;
 168         my ($fid, $sth, $id, %fid2id);
 169         my $dbh = $self->{dbh} //= dbh_new($self);
 170         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 171         $sth->execute(pack('H*', $oidhex));
 172         while (my ($fid, $uid) = $sth->fetchrow_array) {
 173                 push @{$fid2id{$fid}}, $uid;
 174         }
 175         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 176         $sth->execute(pack('H*', $oidhex));
 177         while (my ($fid, $name) = $sth->fetchrow_array) {
 178                 push @{$fid2id{$fid}}, $name;
 179         }
 180         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 181         my $ret = {};
 182         while (my ($fid, $ids) = each %fid2id) {
 183                 $sth->execute($fid);
 184                 my ($loc) = $sth->fetchrow_array;
 185                 unless (defined $loc) {
 186                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 187                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 188                                 } @$ids;
 189                         next;
 190                 }
 191                 $ret->{$loc} = $ids;
 192         }
 193         scalar(keys %$ret) ? $ret : undef;
 194 }
 195
 196 # returns a list of folders used for completion
 197 sub folders {
 198         my ($self, $pfx) = @_;
 199         my $dbh = $self->{dbh} //= dbh_new($self);
 200         my $sql = 'SELECT loc FROM folders';
 201         my @pfx;
 202         if (defined $pfx) {
 203                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 204                 @pfx = ($pfx, '\\');
 205                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 206                 $pfx[0] .= '%';
 207         }
 208         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 209 }
 210
 211 1;