lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::Lock);
   9 use DBI;
  10 use PublicInbox::ContentHash qw(git_sha);
  11 use Carp ();
  12
  13 sub dbh_new {
  14         my ($self, $rw) = @_;
  15         my $f = $self->{filename};
  16         my $creat = $rw && !-s $f;
  17         if ($creat) {
  18                 require PublicInbox::Spawn;
  19                 open my $fh, '+>>', $f or Carp::croak "open($f): $!";
  20                 PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  21         }
  22         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  23                 AutoCommit => 1,
  24                 RaiseError => 1,
  25                 PrintError => 0,
  26                 ReadOnly => !$rw,
  27                 sqlite_use_immediate_transaction => 1,
  28         });
  29         # no sqlite_unicode, here, all strings are binary
  30         create_tables($self, $dbh) if $rw;
  31         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  32         $dbh->do('PRAGMA case_sensitive_like = ON');
  33         $dbh;
  34 }
  35
  36 sub new {
  37         my ($cls, $f) = @_;
  38         bless {
  39                 filename => $f,
  40                 fmap => {},
  41                 lock_path => "$f.flock",
  42         }, $cls;
  43 }
  44
  45 sub lms_write_prepare { ($_[0]->{dbh} //= dbh_new($_[0], 1)); $_[0] }
  46
  47 sub lms_pause {
  48         my ($self) = @_;
  49         $self->{fmap} = {};
  50         delete $self->{dbh};
  51 }
  52
  53 sub create_tables {
  54         my ($self, $dbh) = @_;
  55         my $lk = $self->lock_for_scope;
  56
  57         $dbh->do(<<'');
  58 CREATE TABLE IF NOT EXISTS folders (
  59         fid INTEGER PRIMARY KEY,
  60         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  61         UNIQUE (loc)
  62 )
  63
  64         $dbh->do(<<'');
  65 CREATE TABLE IF NOT EXISTS blob2num (
  66         oidbin VARBINARY NOT NULL,
  67         fid INTEGER NOT NULL, /* folder ID */
  68         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  69         /* not UNIQUE(fid, uid), since we may have broken servers */
  70         UNIQUE (oidbin, fid, uid)
  71 )
  72
  73         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  74         $dbh->do(<<'');
  75 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  76
  77         $dbh->do(<<'');
  78 CREATE TABLE IF NOT EXISTS blob2name (
  79         oidbin VARBINARY NOT NULL,
  80         fid INTEGER NOT NULL, /* folder ID */
  81         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  82         /* not UNIQUE(fid, name), since we may have broken software */
  83         UNIQUE (oidbin, fid, name)
  84 )
  85
  86         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  87         $dbh->do(<<'');
  88 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  89
  90 }
  91
  92 sub fid_for {
  93         my ($self, $folder, $rw) = @_;
  94         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  95         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  96         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  97         return $fid if defined $fid;
  98
  99         # caller had trailing slash (LeiToMail)
 100         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
 101                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
 102                 if (defined $fid) {
 103                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 104 UPDATE folders SET loc = ? WHERE fid = ?
 105 EOM
 106                         return $fid;
 107                 }
 108         # sometimes we stored trailing slash..
 109         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
 110                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
 111                 if (defined $fid) {
 112                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
 113 UPDATE folders SET loc = ? WHERE fid = ?
 114 EOM
 115                         return $fid;
 116                 }
 117         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
 118                 require PublicInbox::URIimap;
 119                 PublicInbox::URIimap->new($folder)->uidvalidity //
 120                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 121         }
 122         return unless $rw;
 123
 124         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 125
 126         $fid += 1;
 127         # in case we're reusing, clobber existing stale refs:
 128         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 129         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 130
 131         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 132         $sth->execute($fid, $folder);
 133
 134         $fid;
 135 }
 136
 137 sub add_folders {
 138         my ($self, @folders) = @_;
 139         my $lk = $self->lock_for_scope;
 140         for my $f (@folders) { $self->{fmap}->{$f} //= fid_for($self, $f, 1) }
 141 }
 142
 143 sub set_src {
 144         my ($self, $oidbin, $folder, $id) = @_;
 145         my $lk = $self->lock_for_scope;
 146         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 147         my $sth;
 148         if (ref($id)) { # scalar name
 149                 $id = $$id;
 150                 $sth = $self->{dbh}->prepare_cached(<<'');
 151 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 152
 153         } else { # numeric ID (IMAP UID, MH number)
 154                 $sth = $self->{dbh}->prepare_cached(<<'');
 155 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 156
 157         }
 158         $sth->execute($oidbin, $fid, $id);
 159 }
 160
 161 sub clear_src {
 162         my ($self, $folder, $id) = @_;
 163         my $lk = $self->lock_for_scope;
 164         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 165         my $sth;
 166         if (ref($id)) { # scalar name
 167                 $id = $$id;
 168                 $sth = $self->{dbh}->prepare_cached(<<'');
 169 DELETE FROM blob2name WHERE fid = ? AND name = ?
 170
 171         } else {
 172                 $sth = $self->{dbh}->prepare_cached(<<'');
 173 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 174
 175         }
 176         $sth->execute($fid, $id);
 177 }
 178
 179 # Maildir-only
 180 sub mv_src {
 181         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 182         my $lk = $self->lock_for_scope;
 183         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 184         my $sth = $self->{dbh}->prepare_cached(<<'');
 185 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 186
 187         my $nr = $sth->execute($newbn, $fid, $oidbin, $$id);
 188         if ($nr == 0) { # may race with a clear_src, ensure new value exists
 189                 $sth = $self->{dbh}->prepare_cached(<<'');
 190 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 191
 192                 $sth->execute($oidbin, $fid, $newbn);
 193         }
 194 }
 195
 196 # read-only, iterates every oidbin + UID or name for a given folder
 197 sub each_src {
 198         my ($self, $folder, $cb, @args) = @_;
 199         my $dbh = $self->{dbh} //= dbh_new($self);
 200         my $fid;
 201         if (ref($folder) eq 'HASH') {
 202                 $fid = $folder->{fid} // die "BUG: no `fid'";
 203         } else {
 204                 $fid = $self->{fmap}->{$folder} //=
 205                         fid_for($self, $folder) // return;
 206         }
 207
 208         # minimize implicit txn time to avoid blocking writers by
 209         # batching SELECTs.  This looks wonky but is necessary since
 210         # $cb-> may access the DB on its own.
 211         my $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 212 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ?
 213 ORDER BY _rowid_ ASC LIMIT 1000
 214
 215         my $min = @$ary ? $ary->[-1]->[0] : undef;
 216         while (defined $min) {
 217                 for my $row (@$ary) { $cb->($row->[1], $row->[2], @args) }
 218
 219                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 220 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ? AND _rowid_ > ?
 221 ORDER BY _rowid_ ASC LIMIT 1000
 222
 223                 $min = @$ary ? $ary->[-1]->[0] : undef;
 224         }
 225
 226         $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 227 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ?
 228 ORDER BY _rowid_ ASC LIMIT 1000
 229
 230         $min = @$ary ? $ary->[-1]->[0] : undef;
 231         while (defined $min) {
 232                 for my $row (@$ary) { $cb->($row->[1], \($row->[2]), @args) }
 233
 234                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 235 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ? AND _rowid_ > ?
 236 ORDER BY _rowid_ ASC LIMIT 1000
 237
 238                 $min = @$ary ? $ary->[-1]->[0] : undef;
 239         }
 240 }
 241
 242 sub location_stats {
 243         my ($self, $folder) = @_;
 244         my $dbh = $self->{dbh} //= dbh_new($self);
 245         my $fid;
 246         my $ret = {};
 247         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 248         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 249 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 250
 251         $ret->{'name.count'} = $row if $row;
 252         my $ntype = ($folder =~ m!\A(?:nntps?|s?news)://!i) ? 'article' :
 253                 (($folder =~ m!\Aimaps?://!i) ? 'uid' : "TODO<$folder>");
 254         for my $op (qw(count min max)) {
 255                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 256 SELECT $op(uid) FROM blob2num WHERE fid = ?
 257
 258                 $row or last;
 259                 $ret->{"$ntype.$op"} = $row;
 260         }
 261         $ret;
 262 }
 263
 264 # returns a { location => [ list-of-ids-or-names ] } mapping
 265 sub locations_for {
 266         my ($self, $oidbin) = @_;
 267         my ($fid, $sth, $id, %fid2id);
 268         my $dbh = $self->{dbh} //= dbh_new($self);
 269         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 270         $sth->execute($oidbin);
 271         while (my ($fid, $uid) = $sth->fetchrow_array) {
 272                 push @{$fid2id{$fid}}, $uid;
 273         }
 274         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 275         $sth->execute($oidbin);
 276         while (my ($fid, $name) = $sth->fetchrow_array) {
 277                 push @{$fid2id{$fid}}, $name;
 278         }
 279         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 280         my $ret = {};
 281         while (my ($fid, $ids) = each %fid2id) {
 282                 $sth->execute($fid);
 283                 my ($loc) = $sth->fetchrow_array;
 284                 unless (defined $loc) {
 285                         my $oidhex = unpack('H*', $oidbin);
 286                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 287                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 288                                 } @$ids;
 289                         next;
 290                 }
 291                 $ret->{$loc} = $ids;
 292         }
 293         scalar(keys %$ret) ? $ret : undef;
 294 }
 295
 296 # returns a list of folders used for completion
 297 sub folders {
 298         my ($self, $pfx) = @_;
 299         my $dbh = $self->{dbh} //= dbh_new($self);
 300         my $sql = 'SELECT loc FROM folders';
 301         my @pfx;
 302         if (defined $pfx) {
 303                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 304                 @pfx = ($pfx, '\\');
 305                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 306                 $pfx[0] .= '%';
 307         }
 308         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 309 }
 310
 311 sub local_blob {
 312         my ($self, $oidhex, $vrfy) = @_;
 313         my $dbh = $self->{dbh} //= dbh_new($self);
 314         my $b2n = $dbh->prepare(<<'');
 315 SELECT f.loc,b.name FROM blob2name b
 316 LEFT JOIN folders f ON b.fid = f.fid
 317 WHERE b.oidbin = ?
 318
 319         $b2n->execute(pack('H*', $oidhex));
 320         while (my ($d, $n) = $b2n->fetchrow_array) {
 321                 substr($d, 0, length('maildir:')) = '';
 322                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 323                 # in "new/", despite (from what I understand of reading
 324                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 325                 # applies to files in "cur/".
 326                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 327                 for my $x (@try) {
 328                         my $f = "$d/$x/$n";
 329                         open my $fh, '<', $f or next;
 330                         # some (buggy) Maildir writers are non-atomic:
 331                         next unless -s $fh;
 332                         local $/;
 333                         my $raw = <$fh>;
 334                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 335                                 warn "$f changed $oidhex\n";
 336                                 next;
 337                         }
 338                         return \$raw;
 339                 }
 340         }
 341         undef;
 342 }
 343
 344 sub match_imap_url {
 345         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 346         $all //= [ $self->folders ];
 347         require PublicInbox::URIimap;
 348         my $want = PublicInbox::URIimap->new($url)->canonical;
 349         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 350         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 351                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 352         my @match;
 353         for my $x (@uri) {
 354                 next if $x->mailbox ne $want->mailbox;
 355                 next if $x->host ne $want->host;
 356                 next if $x->port != $want->port;
 357                 my $x_uidval = $x->uidvalidity;
 358                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 359
 360                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 361                 if (defined($x->auth) && !defined($want->auth) &&
 362                                 !defined($want->user)) {
 363                         push @match, $x;
 364                 # or maybe user was forgotten on CLI:
 365                 } elsif (defined($x->user) && !defined($want->user)) {
 366                         push @match, $x;
 367                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 368                         push @match, $x;
 369                 }
 370         }
 371         return @match if wantarray;
 372         scalar(@match) <= 1 ? $match[0] :
 373                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 374 }
 375
 376 sub match_nntp_url ($$$) {
 377         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 378         $all //= [ $self->folders ];
 379         require PublicInbox::URInntps;
 380         my $want = PublicInbox::URInntps->new($url)->canonical;
 381         my ($s, $h, $p) = ($want->scheme, $want->host, $want->port);
 382         my $ng = $want->group; # force scalar (no article ranges)
 383         my @uri = map { PublicInbox::URInntps->new($_)->canonical }
 384                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$ng\E\b!, @$all);
 385         my @match;
 386         for my $x (@uri) {
 387                 next if $x->group ne $ng || $x->host ne $h || $x->port != $p;
 388                 # maybe user was forgotten on CLI:
 389                 if (defined($x->userinfo) && !defined($want->userinfo)) {
 390                         push @match, $x;
 391                 } elsif (($x->userinfo//"\0") eq ($want->userinfo//"\0")) {
 392                         push @match, $x;
 393                 }
 394         }
 395         return @match if wantarray;
 396         scalar(@match) <= 1 ? $match[0] :
 397                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 398 }
 399
 400 # returns undef on failure, number on success
 401 sub group2folders {
 402         my ($self, $lei, $all, $folders) = @_;
 403         return $lei->fail(<<EOM) if @$folders;
 404 --all= not compatible with @$folders on command-line
 405 EOM
 406         my %x = map { $_ => $_ } split(/,/, $all);
 407         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 408         push(@ok, '') if $all eq '';
 409         my @no = keys %x;
 410         if (@no) {
 411                 @no = (join(',', @no));
 412                 return $lei->fail(<<EOM);
 413 --all=@no not accepted (must be `local' and/or `remote')
 414 EOM
 415         }
 416         my (%seen, @inc);
 417         my @all = $self->folders;
 418         for my $ok (@ok) {
 419                 if ($ok eq 'local') {
 420                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 421                 } elsif ($ok eq 'remote') {
 422                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 423                 } elsif ($ok ne '') {
 424                         return $lei->fail("--all=$all not understood");
 425                 } else {
 426                         @inc = @all;
 427                 }
 428                 push(@$folders, (grep { !$seen{$_}++ } @inc));
 429         }
 430         scalar(@$folders) || $lei->fail(<<EOM);
 431 no --mail-sync folders known to lei
 432 EOM
 433 }
 434
 435 # map CLI args to folder table entries, returns undef on failure
 436 sub arg2folder {
 437         my ($self, $lei, $folders) = @_;
 438         my @all = $self->folders;
 439         my %all = map { $_ => 1 } @all;
 440         my ($err, @no);
 441         for (@$folders) {
 442                 next if $all{$_}; # ok
 443                 if (m!\A(maildir|mh):(.+)!i) {
 444                         my $type = lc $1;
 445                         my $d = "$type:".$lei->abs_path($2);
 446                         push(@no, $_) unless $all{$d};
 447                         $_ = $d;
 448                 } elsif (-d "$_/new" && -d "$_/cur") {
 449                         my $d = 'maildir:'.$lei->abs_path($_);
 450                         push(@no, $_) unless $all{$d};
 451                         $_ = $d;
 452                 } elsif (m!\Aimaps?://!i) {
 453                         my $orig = $_;
 454                         my $res = match_imap_url($self, $orig, \@all);
 455                         if (ref $res) {
 456                                 $_ = $$res;
 457                                 push(@{$err->{qerr}}, <<EOM);
 458 # using `$res' instead of `$orig'
 459 EOM
 460                         } else {
 461                                 $lei->err($res) if defined $res;
 462                                 push @no, $orig;
 463                         }
 464                 } elsif (m!\A(?:nntps?|s?news)://!i) {
 465                         my $orig = $_;
 466                         my $res = match_nntp_url($self, $orig, \@all);
 467                         if (ref $res) {
 468                                 $_ = $$res;
 469                                 push(@{$err->{qerr}}, <<EOM);
 470 # using `$res' instead of `$orig'
 471 EOM
 472                         } else {
 473                                 $lei->err($res) if defined $res;
 474                                 push @no, $orig;
 475                         }
 476                 } else {
 477                         push @no, $_;
 478                 }
 479         }
 480         if (@no) {
 481                 my $no = join("\n\t", @no);
 482                 $err->{fail} = <<EOF;
 483 No sync information for: $no
 484 Run `lei ls-mail-sync' to display valid choices
 485 EOF
 486         }
 487         $err;
 488 }
 489
 490 sub forget_folders {
 491         my ($self, @folders) = @_;
 492         my $lk = $self->lock_for_scope;
 493         for my $folder (@folders) {
 494                 my $fid = delete($self->{fmap}->{$folder}) //
 495                         fid_for($self, $folder) // next;
 496                 for my $t (qw(blob2name blob2num folders)) {
 497                         $self->{dbh}->do("DELETE FROM $t WHERE fid = ?",
 498                                         undef, $fid);
 499                 }
 500         }
 501 }
 502
 503 # only used for changing canonicalization errors
 504 sub rename_folder {
 505         my ($self, $old, $new) = @_;
 506         my $lk = $self->lock_for_scope;
 507         my $ofid = delete($self->{fmap}->{$old}) //
 508                 fid_for($self, $old) // return;
 509         eval {
 510                 $self->{dbh}->do(<<EOM, undef, $new, $ofid);
 511 UPDATE folders SET loc = ? WHERE fid = ?
 512 EOM
 513         };
 514         if ($@ =~ /\bunique\b/i) {
 515                 my $nfid = $self->{fmap}->{$new} // fid_for($self, $new);
 516                 for my $t (qw(blob2name blob2num)) {
 517                         $self->{dbh}->do(<<EOM, undef, $nfid, $ofid);
 518 UPDATE OR REPLACE $t SET fid = ? WHERE fid = ?
 519 EOM
 520                 }
 521                 $self->{dbh}->do(<<EOM, undef, $ofid);
 522 DELETE FROM folders WHERE fid = ?
 523 EOM
 524         }
 525 }
 526
 527 sub num_oidbin ($$$) {
 528         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY if IMAP
 529         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return ();
 530         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 531 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ? ORDER BY _rowid_
 532 EOM
 533         $sth->execute($fid, $uid);
 534         map { $_->[0] } @{$sth->fetchall_arrayref};
 535 }
 536
 537 sub name_oidbin ($$$) {
 538         my ($self, $mdir, $nm) = @_;
 539         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 540         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 541 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 542 EOM
 543         $sth->execute($fid, $nm);
 544         map { $_->[0] } @{$sth->fetchall_arrayref};
 545 }
 546
 547 sub imap_oidhex {
 548         my ($self, $lei, $uid_uri) = @_;
 549         my $mailbox_uri = $uid_uri->clone;
 550         $mailbox_uri->uid(undef);
 551         my $folders = [ $$mailbox_uri ];
 552         if (my $err = $self->arg2folder($lei, $folders)) {
 553                 if ($err->{fail}) {
 554                         $lei->qerr("# no sync information for $mailbox_uri");
 555                 }
 556                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
 557         }
 558         map { unpack('H*',$_) } num_oidbin($self, $folders->[0], $uid_uri->uid)
 559 }
 560
 561 1;