lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10 use Carp ();
  11
  12 sub dbh_new {
  13         my ($self, $rw) = @_;
  14         my $f = $self->{filename};
  15         my $creat = $rw && !-s $f;
  16         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  17                 AutoCommit => 1,
  18                 RaiseError => 1,
  19                 PrintError => 0,
  20                 ReadOnly => !$rw,
  21                 sqlite_use_immediate_transaction => 1,
  22         });
  23         # no sqlite_unicode, here, all strings are binary
  24         create_tables($dbh) if $rw;
  25         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  26         $dbh->do('PRAGMA case_sensitive_like = ON');
  27         $dbh;
  28 }
  29
  30 sub new {
  31         my ($cls, $f) = @_;
  32         bless { filename => $f, fmap => {} }, $cls;
  33 }
  34
  35 sub lms_commit { delete($_[0]->{dbh})->commit }
  36
  37 sub lms_begin { ($_[0]->{dbh} //= dbh_new($_[0], 1))->begin_work };
  38
  39 sub create_tables {
  40         my ($dbh) = @_;
  41
  42         $dbh->do(<<'');
  43 CREATE TABLE IF NOT EXISTS folders (
  44         fid INTEGER PRIMARY KEY,
  45         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  46         UNIQUE (loc)
  47 )
  48
  49         $dbh->do(<<'');
  50 CREATE TABLE IF NOT EXISTS blob2num (
  51         oidbin VARBINARY NOT NULL,
  52         fid INTEGER NOT NULL, /* folder ID */
  53         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  54         UNIQUE (oidbin, fid, uid)
  55 )
  56
  57         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  58         $dbh->do(<<'');
  59 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  60
  61         $dbh->do(<<'');
  62 CREATE TABLE IF NOT EXISTS blob2name (
  63         oidbin VARBINARY NOT NULL,
  64         fid INTEGER NOT NULL, /* folder ID */
  65         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  66         UNIQUE (oidbin, fid, name)
  67 )
  68
  69         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  70         $dbh->do(<<'');
  71 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  72
  73 }
  74
  75 sub fid_for {
  76         my ($self, $folder, $rw) = @_;
  77         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  78         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  79         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  80         return $fid if defined $fid;
  81
  82         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  83                 warn "folder: $folder/ had trailing slash in arg\n";
  84                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  85                 if (defined $fid) {
  86                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  87 UPDATE folders SET loc = ? WHERE fid = ?
  88 EOM
  89                         return $fid;
  90                 }
  91         # sometimes we stored trailing slash..
  92         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
  93                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
  94                 if (defined $fid) {
  95                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  96 UPDATE folders SET loc = ? WHERE fid = ?
  97 EOM
  98                         return $fid;
  99                 }
 100         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
 101                 require PublicInbox::URIimap;
 102                 PublicInbox::URIimap->new($folder)->uidvalidity //
 103                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 104         }
 105         return unless $rw;
 106
 107         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 108
 109         $fid += 1;
 110         # in case we're reusing, clobber existing stale refs:
 111         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 112         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 113
 114         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 115         $sth->execute($fid, $folder);
 116
 117         $fid;
 118 }
 119
 120 sub set_src {
 121         my ($self, $oidhex, $folder, $id) = @_;
 122         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 123         my $sth;
 124         if (ref($id)) { # scalar name
 125                 $id = $$id;
 126                 $sth = $self->{dbh}->prepare_cached(<<'');
 127 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 128
 129         } else { # numeric ID (IMAP UID, MH number)
 130                 $sth = $self->{dbh}->prepare_cached(<<'');
 131 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 132
 133         }
 134         $sth->execute(pack('H*', $oidhex), $fid, $id);
 135 }
 136
 137 sub clear_src {
 138         my ($self, $folder, $id) = @_;
 139         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 140         my $sth;
 141         if (ref($id)) { # scalar name
 142                 $id = $$id;
 143                 $sth = $self->{dbh}->prepare_cached(<<'');
 144 DELETE FROM blob2name WHERE fid = ? AND name = ?
 145
 146         } else {
 147                 $sth = $self->{dbh}->prepare_cached(<<'');
 148 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 149
 150         }
 151         $sth->execute($fid, $id);
 152 }
 153
 154 # Maildir-only
 155 sub mv_src {
 156         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 157         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 158         my $sth = $self->{dbh}->prepare_cached(<<'');
 159 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 160
 161         my $nr = $sth->execute($newbn, $fid, $oidbin, $$id);
 162         if ($nr == 0) { # may race with a clear_src, ensure new value exists
 163                 $sth = $self->{dbh}->prepare_cached(<<'');
 164 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 165
 166                 $sth->execute($oidbin, $fid, $newbn);
 167         }
 168 }
 169
 170 # read-only, iterates every oidbin + UID or name for a given folder
 171 sub each_src {
 172         my ($self, $folder, $cb, @args) = @_;
 173         my $dbh = $self->{dbh} //= dbh_new($self);
 174         my ($fid, $sth);
 175         if (ref($folder) eq 'HASH') {
 176                 $fid = $folder->{fid} // die "BUG: no `fid'";
 177         } else {
 178                 $fid = $self->{fmap}->{$folder} //=
 179                         fid_for($self, $folder) // return;
 180         }
 181         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 182         $sth->execute($fid);
 183         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 184                 $cb->($oidbin, $id, @args);
 185         }
 186         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 187         $sth->execute($fid);
 188         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 189                 $cb->($oidbin, \$id, @args);
 190         }
 191 }
 192
 193 sub location_stats {
 194         my ($self, $folder) = @_;
 195         my $dbh = $self->{dbh} //= dbh_new($self);
 196         my $fid;
 197         my $ret = {};
 198         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 199         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 200 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 201
 202         $ret->{'name.count'} = $row if $row;
 203         for my $op (qw(count min max)) {
 204                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 205 SELECT $op(uid) FROM blob2num WHERE fid = ?
 206
 207                 $row or last;
 208                 $ret->{"uid.$op"} = $row;
 209         }
 210         $ret;
 211 }
 212
 213 # returns a { location => [ list-of-ids-or-names ] } mapping
 214 sub locations_for {
 215         my ($self, $oidbin) = @_;
 216         my ($fid, $sth, $id, %fid2id);
 217         my $dbh = $self->{dbh} //= dbh_new($self);
 218         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 219         $sth->execute($oidbin);
 220         while (my ($fid, $uid) = $sth->fetchrow_array) {
 221                 push @{$fid2id{$fid}}, $uid;
 222         }
 223         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 224         $sth->execute($oidbin);
 225         while (my ($fid, $name) = $sth->fetchrow_array) {
 226                 push @{$fid2id{$fid}}, $name;
 227         }
 228         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 229         my $ret = {};
 230         while (my ($fid, $ids) = each %fid2id) {
 231                 $sth->execute($fid);
 232                 my ($loc) = $sth->fetchrow_array;
 233                 unless (defined $loc) {
 234                         my $oidhex = unpack('H*', $oidbin);
 235                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 236                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 237                                 } @$ids;
 238                         next;
 239                 }
 240                 $ret->{$loc} = $ids;
 241         }
 242         scalar(keys %$ret) ? $ret : undef;
 243 }
 244
 245 # returns a list of folders used for completion
 246 sub folders {
 247         my ($self, $pfx) = @_;
 248         my $dbh = $self->{dbh} //= dbh_new($self);
 249         my $sql = 'SELECT loc FROM folders';
 250         my @pfx;
 251         if (defined $pfx) {
 252                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 253                 @pfx = ($pfx, '\\');
 254                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 255                 $pfx[0] .= '%';
 256         }
 257         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 258 }
 259
 260 sub local_blob {
 261         my ($self, $oidhex, $vrfy) = @_;
 262         my $dbh = $self->{dbh} //= dbh_new($self);
 263         my $b2n = $dbh->prepare(<<'');
 264 SELECT f.loc,b.name FROM blob2name b
 265 LEFT JOIN folders f ON b.fid = f.fid
 266 WHERE b.oidbin = ?
 267
 268         $b2n->execute(pack('H*', $oidhex));
 269         while (my ($d, $n) = $b2n->fetchrow_array) {
 270                 substr($d, 0, length('maildir:')) = '';
 271                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 272                 # in "new/", despite (from what I understand of reading
 273                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 274                 # applies to files in "cur/".
 275                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 276                 for my $x (@try) {
 277                         my $f = "$d/$x/$n";
 278                         open my $fh, '<', $f or next;
 279                         # some (buggy) Maildir writers are non-atomic:
 280                         next unless -s $fh;
 281                         local $/;
 282                         my $raw = <$fh>;
 283                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 284                                 warn "$f changed $oidhex\n";
 285                                 next;
 286                         }
 287                         return \$raw;
 288                 }
 289         }
 290         undef;
 291 }
 292
 293 sub match_imap_url {
 294         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 295         $all //= [ $self->folders ];
 296         require PublicInbox::URIimap;
 297         my $want = PublicInbox::URIimap->new($url)->canonical;
 298         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 299         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 300                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 301         my @match;
 302         for my $x (@uri) {
 303                 next if $x->mailbox ne $want->mailbox;
 304                 next if $x->host ne $want->host;
 305                 next if $x->port != $want->port;
 306                 my $x_uidval = $x->uidvalidity;
 307                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 308
 309                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 310                 if (defined($x->auth) && !defined($want->auth) &&
 311                                 !defined($want->user)) {
 312                         push @match, $x;
 313                 # or maybe user was forgotten on CLI:
 314                 } elsif (defined($x->user) && !defined($want->user)) {
 315                         push @match, $x;
 316                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 317                         push @match, $x;
 318                 }
 319         }
 320         return @match if wantarray;
 321         scalar(@match) <= 1 ? $match[0] :
 322                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 323 }
 324
 325 # returns undef on failure, number on success
 326 sub group2folders {
 327         my ($self, $lei, $all, $folders) = @_;
 328         return $lei->fail(<<EOM) if @$folders;
 329 --all= not compatible with @$folders on command-line
 330 EOM
 331         my %x = map { $_ => $_ } split(/,/, $all);
 332         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 333         my @no = keys %x;
 334         if (@no) {
 335                 @no = (join(',', @no));
 336                 return $lei->fail(<<EOM);
 337 --all=@no not accepted (must be `local' and/or `remote')
 338 EOM
 339         }
 340         my (%seen, @inc);
 341         my @all = $self->folders;
 342         for my $ok (@ok) {
 343                 if ($ok eq 'local') {
 344                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 345                 } elsif ($ok eq 'remote') {
 346                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 347                 } elsif ($ok ne '') {
 348                         return $lei->fail("--all=$all not understood");
 349                 } else {
 350                         @inc = @all;
 351                 }
 352                 for (@inc) {
 353                         push(@$folders, $_) unless $seen{$_}++;
 354                 }
 355         }
 356         scalar(@$folders) || $lei->fail(<<EOM);
 357 no --mail-sync folders known to lei
 358 EOM
 359 }
 360
 361 # map CLI args to folder table entries, returns undef on failure
 362 sub arg2folder {
 363         my ($self, $lei, $folders) = @_;
 364         my @all = $self->folders;
 365         my %all = map { $_ => 1 } @all;
 366         my ($err, @no);
 367         for (@$folders) {
 368                 next if $all{$_}; # ok
 369                 if (m!\A(maildir|mh):(.+)!i) {
 370                         my $type = lc $1;
 371                         my $d = "$type:".$lei->abs_path($2);
 372                         push(@no, $_) unless $all{$d};
 373                         $_ = $d;
 374                 } elsif (-d "$_/new" && -d "$_/cur") {
 375                         my $d = 'maildir:'.$lei->abs_path($_);
 376                         push(@no, $_) unless $all{$d};
 377                         $_ = $d;
 378                 } elsif (m!\Aimaps?://!i) {
 379                         my $orig = $_;
 380                         my $res = match_imap_url($self, $orig, \@all);
 381                         if (ref $res) {
 382                                 $_ = $$res;
 383                                 push(@{$err->{qerr}}, <<EOM);
 384 # using `$res' instead of `$orig'
 385 EOM
 386                         } else {
 387                                 $lei->err($res) if defined $res;
 388                                 push @no, $orig;
 389                         }
 390                 } else {
 391                         push @no, $_;
 392                 }
 393         }
 394         if (@no) {
 395                 my $no = join("\n\t", @no);
 396                 $err->{fail} = <<EOF;
 397 No sync information for: $no
 398 Run `lei ls-mail-sync' to display valid choices
 399 EOF
 400         }
 401         $err;
 402 }
 403
 404 sub forget_folder {
 405         my ($self, $folder) = @_;
 406         my ($fid, $sth);
 407         $fid = delete($self->{fmap}->{$folder}) //
 408                 fid_for($self, $folder) // return;
 409         my $dbh = $self->{dbh};
 410         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 411         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 412         $dbh->do('DELETE FROM folders WHERE fid = ?', undef, $fid);
 413 }
 414
 415 sub imap_oidbin ($$$) {
 416         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY
 417         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return;
 418         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 419 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ?
 420 EOM
 421         $sth->execute($fid, $uid);
 422         $sth->fetchrow_array;
 423 }
 424
 425 sub name_oidbin ($$$) {
 426         my ($self, $mdir, $nm) = @_;
 427         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 428         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 429 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 430 EOM
 431         $sth->execute($fid, $nm);
 432         $sth->fetchrow_array;
 433 }
 434
 435 sub imap_oid {
 436         my ($self, $lei, $uid_uri) = @_;
 437         my $mailbox_uri = $uid_uri->clone;
 438         $mailbox_uri->uid(undef);
 439         my $folders = [ $$mailbox_uri ];
 440         if (my $err = $self->arg2folder($lei, $folders)) {
 441                 if ($err->{fail}) {
 442                         $lei->qerr("# no sync information for $mailbox_uri");
 443                         return;
 444                 }
 445                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
 446         }
 447         my $oidbin = imap_oidbin($self, $folders->[0], $uid_uri->uid);
 448         $oidbin ? unpack('H*', $oidbin) : undef;
 449 }
 450
 451 # FIXED? something with "lei <up|q>" is causing uncommitted transaction
 452 # TODO: remove soon
 453 sub DESTROY {
 454         my ($self) = @_;
 455         my $dbh = delete($self->{dbh}) or return;
 456         return if $dbh->{ReadOnly};
 457         undef $dbh;
 458         warn "BUG $$ $0 $self {dbh} OPEN ppid=".getppid.' '.Carp::longmess();
 459 }
 460
 461 1;