lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10
  11 sub dbh_new {
  12         my ($self, $rw) = @_;
  13         my $f = $self->{filename};
  14         my $creat = $rw && !-s $f;
  15         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  16                 AutoCommit => 1,
  17                 RaiseError => 1,
  18                 PrintError => 0,
  19                 ReadOnly => !$rw,
  20                 sqlite_use_immediate_transaction => 1,
  21         });
  22         # no sqlite_unicode, here, all strings are binary
  23         create_tables($dbh) if $rw;
  24         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  25         $dbh->do('PRAGMA case_sensitive_like = ON');
  26         $dbh;
  27 }
  28
  29 sub new {
  30         my ($cls, $f) = @_;
  31         bless { filename => $f, fmap => {} }, $cls;
  32 }
  33
  34 sub lms_commit { delete($_[0]->{dbh})->commit }
  35
  36 sub lms_begin { ($_[0]->{dbh} //= dbh_new($_[0], 1))->begin_work };
  37
  38 sub create_tables {
  39         my ($dbh) = @_;
  40
  41         $dbh->do(<<'');
  42 CREATE TABLE IF NOT EXISTS folders (
  43         fid INTEGER PRIMARY KEY,
  44         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  45         UNIQUE (loc)
  46 )
  47
  48         $dbh->do(<<'');
  49 CREATE TABLE IF NOT EXISTS blob2num (
  50         oidbin VARBINARY NOT NULL,
  51         fid INTEGER NOT NULL, /* folder ID */
  52         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  53         UNIQUE (oidbin, fid, uid)
  54 )
  55
  56         $dbh->do(<<'');
  57 CREATE TABLE IF NOT EXISTS blob2name (
  58         oidbin VARBINARY NOT NULL,
  59         fid INTEGER NOT NULL, /* folder ID */
  60         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  61         UNIQUE (oidbin, fid, name)
  62 )
  63
  64 }
  65
  66 sub _fid_for {
  67         my ($self, $folder, $rw) = @_;
  68         my $dbh = $self->{dbh};
  69         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  70         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  71         return $fid if defined $fid;
  72
  73         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  74                 warn "folder: $folder/ had trailing slash in arg\n";
  75                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  76                 if (defined $fid) {
  77                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  78 UPDATE folders SET loc = ? WHERE fid = ?
  79 EOM
  80                         return $fid;
  81                 }
  82         # sometimes we stored trailing slash..
  83         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
  84                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
  85                 if (defined $fid) {
  86                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  87 UPDATE folders SET loc = ? WHERE fid = ?
  88 EOM
  89                         return $fid;
  90                 }
  91         }
  92         return unless $rw;
  93
  94         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
  95
  96         $fid += 1;
  97         # in case we're reusing, clobber existing stale refs:
  98         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
  99         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 100
 101         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 102         $sth->execute($fid, $folder);
 103
 104         $fid;
 105 }
 106
 107 sub set_src {
 108         my ($self, $oidhex, $folder, $id) = @_;
 109         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 110         my $sth;
 111         if (ref($id)) { # scalar name
 112                 $id = $$id;
 113                 $sth = $self->{dbh}->prepare_cached(<<'');
 114 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 115
 116         } else { # numeric ID (IMAP UID, MH number)
 117                 $sth = $self->{dbh}->prepare_cached(<<'');
 118 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 119
 120         }
 121         $sth->execute(pack('H*', $oidhex), $fid, $id);
 122 }
 123
 124 sub clear_src {
 125         my ($self, $folder, $id) = @_;
 126         my $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder, 1);
 127         my $sth;
 128         if (ref($id)) { # scalar name
 129                 $id = $$id;
 130                 $sth = $self->{dbh}->prepare_cached(<<'');
 131 DELETE FROM blob2name WHERE fid = ? AND name = ?
 132
 133         } else {
 134                 $sth = $self->{dbh}->prepare_cached(<<'');
 135 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 136
 137         }
 138         $sth->execute($fid, $id);
 139 }
 140
 141 # read-only, iterates every oidbin + UID or name for a given folder
 142 sub each_src {
 143         my ($self, $folder, $cb, @args) = @_;
 144         my $dbh = $self->{dbh} //= dbh_new($self);
 145         my ($fid, $sth);
 146         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 147         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 148         $sth->execute($fid);
 149         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 150                 $cb->($oidbin, $id, @args);
 151         }
 152         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 153         $sth->execute($fid);
 154         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 155                 $cb->($oidbin, \$id, @args);
 156         }
 157 }
 158
 159 sub location_stats {
 160         my ($self, $folder) = @_;
 161         my $dbh = $self->{dbh} //= dbh_new($self);
 162         my $fid;
 163         my $ret = {};
 164         $fid = $self->{fmap}->{$folder} //= _fid_for($self, $folder) // return;
 165         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 166 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 167
 168         $ret->{'name.count'} = $row if $row;
 169         for my $op (qw(count min max)) {
 170                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 171 SELECT $op(uid) FROM blob2num WHERE fid = ?
 172
 173                 $row or last;
 174                 $ret->{"uid.$op"} = $row;
 175         }
 176         $ret;
 177 }
 178
 179 # returns a { location => [ list-of-ids-or-names ] } mapping
 180 sub locations_for {
 181         my ($self, $oidhex) = @_;
 182         my ($fid, $sth, $id, %fid2id);
 183         my $dbh = $self->{dbh} //= dbh_new($self);
 184         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 185         $sth->execute(pack('H*', $oidhex));
 186         while (my ($fid, $uid) = $sth->fetchrow_array) {
 187                 push @{$fid2id{$fid}}, $uid;
 188         }
 189         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 190         $sth->execute(pack('H*', $oidhex));
 191         while (my ($fid, $name) = $sth->fetchrow_array) {
 192                 push @{$fid2id{$fid}}, $name;
 193         }
 194         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 195         my $ret = {};
 196         while (my ($fid, $ids) = each %fid2id) {
 197                 $sth->execute($fid);
 198                 my ($loc) = $sth->fetchrow_array;
 199                 unless (defined $loc) {
 200                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 201                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 202                                 } @$ids;
 203                         next;
 204                 }
 205                 $ret->{$loc} = $ids;
 206         }
 207         scalar(keys %$ret) ? $ret : undef;
 208 }
 209
 210 # returns a list of folders used for completion
 211 sub folders {
 212         my ($self, $pfx) = @_;
 213         my $dbh = $self->{dbh} //= dbh_new($self);
 214         my $sql = 'SELECT loc FROM folders';
 215         my @pfx;
 216         if (defined $pfx) {
 217                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 218                 @pfx = ($pfx, '\\');
 219                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 220                 $pfx[0] .= '%';
 221         }
 222         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 223 }
 224
 225 sub local_blob {
 226         my ($self, $oidhex, $vrfy) = @_;
 227         my $dbh = $self->{dbh} //= dbh_new($self);
 228         my $b2n = $dbh->prepare(<<'');
 229 SELECT f.loc,b.name FROM blob2name b
 230 LEFT JOIN folders f ON b.fid = f.fid
 231 WHERE b.oidbin = ?
 232
 233         $b2n->execute(pack('H*', $oidhex));
 234         while (my ($d, $n) = $b2n->fetchrow_array) {
 235                 substr($d, 0, length('maildir:')) = '';
 236                 my $f = "$d/" . ($n =~ /:2,[a-zA-Z]*\z/ ? "cur/$n" : "new/$n");
 237                 open my $fh, '<', $f or next;
 238                 if (-s $fh) {
 239                         local $/;
 240                         my $raw = <$fh>;
 241                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 242                                 warn "$f changed $oidhex\n";
 243                                 next;
 244                         }
 245                         return \$raw;
 246                 }
 247         }
 248         undef;
 249 }
 250
 251 1;