lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10 use Carp ();
  11
  12 sub dbh_new {
  13         my ($self, $rw) = @_;
  14         my $f = $self->{filename};
  15         my $creat = $rw && !-s $f;
  16         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  17                 AutoCommit => 1,
  18                 RaiseError => 1,
  19                 PrintError => 0,
  20                 ReadOnly => !$rw,
  21                 sqlite_use_immediate_transaction => 1,
  22         });
  23         # no sqlite_unicode, here, all strings are binary
  24         create_tables($dbh) if $rw;
  25         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  26         $dbh->do('PRAGMA case_sensitive_like = ON');
  27         $dbh;
  28 }
  29
  30 sub new {
  31         my ($cls, $f) = @_;
  32         bless { filename => $f, fmap => {} }, $cls;
  33 }
  34
  35 sub lms_commit { delete($_[0]->{dbh})->commit }
  36
  37 sub lms_begin { ($_[0]->{dbh} //= dbh_new($_[0], 1))->begin_work };
  38
  39 sub create_tables {
  40         my ($dbh) = @_;
  41
  42         $dbh->do(<<'');
  43 CREATE TABLE IF NOT EXISTS folders (
  44         fid INTEGER PRIMARY KEY,
  45         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  46         UNIQUE (loc)
  47 )
  48
  49         $dbh->do(<<'');
  50 CREATE TABLE IF NOT EXISTS blob2num (
  51         oidbin VARBINARY NOT NULL,
  52         fid INTEGER NOT NULL, /* folder ID */
  53         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  54         UNIQUE (oidbin, fid, uid)
  55 )
  56
  57         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  58         $dbh->do(<<'');
  59 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  60
  61         $dbh->do(<<'');
  62 CREATE TABLE IF NOT EXISTS blob2name (
  63         oidbin VARBINARY NOT NULL,
  64         fid INTEGER NOT NULL, /* folder ID */
  65         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  66         UNIQUE (oidbin, fid, name)
  67 )
  68
  69         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  70         $dbh->do(<<'');
  71 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  72
  73 }
  74
  75 sub fid_for {
  76         my ($self, $folder, $rw) = @_;
  77         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  78         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  79         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  80         return $fid if defined $fid;
  81
  82         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  83                 warn "folder: $folder/ had trailing slash in arg\n";
  84                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  85                 if (defined $fid) {
  86                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  87 UPDATE folders SET loc = ? WHERE fid = ?
  88 EOM
  89                         return $fid;
  90                 }
  91         # sometimes we stored trailing slash..
  92         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
  93                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
  94                 if (defined $fid) {
  95                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  96 UPDATE folders SET loc = ? WHERE fid = ?
  97 EOM
  98                         return $fid;
  99                 }
 100         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
 101                 require PublicInbox::URIimap;
 102                 PublicInbox::URIimap->new($folder)->uidvalidity //
 103                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 104         }
 105         return unless $rw;
 106
 107         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 108
 109         $fid += 1;
 110         # in case we're reusing, clobber existing stale refs:
 111         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 112         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 113
 114         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 115         $sth->execute($fid, $folder);
 116
 117         $fid;
 118 }
 119
 120 sub set_src {
 121         my ($self, $oidhex, $folder, $id) = @_;
 122         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 123         my $sth;
 124         if (ref($id)) { # scalar name
 125                 $id = $$id;
 126                 $sth = $self->{dbh}->prepare_cached(<<'');
 127 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 128
 129         } else { # numeric ID (IMAP UID, MH number)
 130                 $sth = $self->{dbh}->prepare_cached(<<'');
 131 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 132
 133         }
 134         $sth->execute(pack('H*', $oidhex), $fid, $id);
 135 }
 136
 137 sub clear_src {
 138         my ($self, $folder, $id) = @_;
 139         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 140         my $sth;
 141         if (ref($id)) { # scalar name
 142                 $id = $$id;
 143                 $sth = $self->{dbh}->prepare_cached(<<'');
 144 DELETE FROM blob2name WHERE fid = ? AND name = ?
 145
 146         } else {
 147                 $sth = $self->{dbh}->prepare_cached(<<'');
 148 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 149
 150         }
 151         $sth->execute($fid, $id);
 152 }
 153
 154 # Maildir-only
 155 sub mv_src {
 156         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 157         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 158         my $sth = $self->{dbh}->prepare_cached(<<'');
 159 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 160
 161         $sth->execute($newbn, $fid, $oidbin, $$id);
 162 }
 163
 164 # read-only, iterates every oidbin + UID or name for a given folder
 165 sub each_src {
 166         my ($self, $folder, $cb, @args) = @_;
 167         my $dbh = $self->{dbh} //= dbh_new($self);
 168         my ($fid, $sth);
 169         if (ref($folder) eq 'HASH') {
 170                 $fid = $folder->{fid} // die "BUG: no `fid'";
 171         } else {
 172                 $fid = $self->{fmap}->{$folder} //=
 173                         fid_for($self, $folder) // return;
 174         }
 175         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 176         $sth->execute($fid);
 177         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 178                 $cb->($oidbin, $id, @args);
 179         }
 180         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 181         $sth->execute($fid);
 182         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 183                 $cb->($oidbin, \$id, @args);
 184         }
 185 }
 186
 187 sub location_stats {
 188         my ($self, $folder) = @_;
 189         my $dbh = $self->{dbh} //= dbh_new($self);
 190         my $fid;
 191         my $ret = {};
 192         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 193         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 194 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 195
 196         $ret->{'name.count'} = $row if $row;
 197         for my $op (qw(count min max)) {
 198                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 199 SELECT $op(uid) FROM blob2num WHERE fid = ?
 200
 201                 $row or last;
 202                 $ret->{"uid.$op"} = $row;
 203         }
 204         $ret;
 205 }
 206
 207 # returns a { location => [ list-of-ids-or-names ] } mapping
 208 sub locations_for {
 209         my ($self, $oidbin) = @_;
 210         my ($fid, $sth, $id, %fid2id);
 211         my $dbh = $self->{dbh} //= dbh_new($self);
 212         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 213         $sth->execute($oidbin);
 214         while (my ($fid, $uid) = $sth->fetchrow_array) {
 215                 push @{$fid2id{$fid}}, $uid;
 216         }
 217         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 218         $sth->execute($oidbin);
 219         while (my ($fid, $name) = $sth->fetchrow_array) {
 220                 push @{$fid2id{$fid}}, $name;
 221         }
 222         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 223         my $ret = {};
 224         while (my ($fid, $ids) = each %fid2id) {
 225                 $sth->execute($fid);
 226                 my ($loc) = $sth->fetchrow_array;
 227                 unless (defined $loc) {
 228                         my $oidhex = unpack('H*', $oidbin);
 229                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 230                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 231                                 } @$ids;
 232                         next;
 233                 }
 234                 $ret->{$loc} = $ids;
 235         }
 236         scalar(keys %$ret) ? $ret : undef;
 237 }
 238
 239 # returns a list of folders used for completion
 240 sub folders {
 241         my ($self, $pfx) = @_;
 242         my $dbh = $self->{dbh} //= dbh_new($self);
 243         my $sql = 'SELECT loc FROM folders';
 244         my @pfx;
 245         if (defined $pfx) {
 246                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 247                 @pfx = ($pfx, '\\');
 248                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 249                 $pfx[0] .= '%';
 250         }
 251         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 252 }
 253
 254 sub local_blob {
 255         my ($self, $oidhex, $vrfy) = @_;
 256         my $dbh = $self->{dbh} //= dbh_new($self);
 257         my $b2n = $dbh->prepare(<<'');
 258 SELECT f.loc,b.name FROM blob2name b
 259 LEFT JOIN folders f ON b.fid = f.fid
 260 WHERE b.oidbin = ?
 261
 262         $b2n->execute(pack('H*', $oidhex));
 263         while (my ($d, $n) = $b2n->fetchrow_array) {
 264                 substr($d, 0, length('maildir:')) = '';
 265                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 266                 # in "new/", despite (from what I understand of reading
 267                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 268                 # applies to files in "cur/".
 269                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 270                 for my $x (@try) {
 271                         my $f = "$d/$x/$n";
 272                         open my $fh, '<', $f or next;
 273                         # some (buggy) Maildir writers are non-atomic:
 274                         next unless -s $fh;
 275                         local $/;
 276                         my $raw = <$fh>;
 277                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 278                                 warn "$f changed $oidhex\n";
 279                                 next;
 280                         }
 281                         return \$raw;
 282                 }
 283         }
 284         undef;
 285 }
 286
 287 sub match_imap_url {
 288         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 289         $all //= [ $self->folders ];
 290         require PublicInbox::URIimap;
 291         my $want = PublicInbox::URIimap->new($url)->canonical;
 292         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 293         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 294                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 295         my @match;
 296         for my $x (@uri) {
 297                 next if $x->mailbox ne $want->mailbox;
 298                 next if $x->host ne $want->host;
 299                 next if $x->port != $want->port;
 300                 my $x_uidval = $x->uidvalidity;
 301                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 302
 303                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 304                 if (defined($x->auth) && !defined($want->auth) &&
 305                                 !defined($want->user)) {
 306                         push @match, $x;
 307                 # or maybe user was forgotten on CLI:
 308                 } elsif (defined($x->user) && !defined($want->user)) {
 309                         push @match, $x;
 310                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 311                         push @match, $x;
 312                 }
 313         }
 314         return @match if wantarray;
 315         scalar(@match) <= 1 ? $match[0] :
 316                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 317 }
 318
 319 # returns undef on failure, number on success
 320 sub group2folders {
 321         my ($self, $lei, $all, $folders) = @_;
 322         return $lei->fail(<<EOM) if @$folders;
 323 --all= not compatible with @$folders on command-line
 324 EOM
 325         my %x = map { $_ => $_ } split(/,/, $all);
 326         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 327         my @no = keys %x;
 328         if (@no) {
 329                 @no = (join(',', @no));
 330                 return $lei->fail(<<EOM);
 331 --all=@no not accepted (must be `local' and/or `remote')
 332 EOM
 333         }
 334         my (%seen, @inc);
 335         my @all = $self->folders;
 336         for my $ok (@ok) {
 337                 if ($ok eq 'local') {
 338                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 339                 } elsif ($ok eq 'remote') {
 340                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 341                 } elsif ($ok ne '') {
 342                         return $lei->fail("--all=$all not understood");
 343                 } else {
 344                         @inc = @all;
 345                 }
 346                 for (@inc) {
 347                         push(@$folders, $_) unless $seen{$_}++;
 348                 }
 349         }
 350         scalar(@$folders) || $lei->fail(<<EOM);
 351 no --mail-sync folders known to lei
 352 EOM
 353 }
 354
 355 # map CLI args to folder table entries, returns undef on failure
 356 sub arg2folder {
 357         my ($self, $lei, $folders) = @_;
 358         my @all = $self->folders;
 359         my %all = map { $_ => 1 } @all;
 360         my ($err, @no);
 361         for (@$folders) {
 362                 next if $all{$_}; # ok
 363                 if (m!\A(maildir|mh):(.+)!i) {
 364                         my $type = lc $1;
 365                         my $d = "$type:".$lei->abs_path($2);
 366                         push(@no, $_) unless $all{$d};
 367                         $_ = $d;
 368                 } elsif (-d "$_/new" && -d "$_/cur") {
 369                         my $d = 'maildir:'.$lei->abs_path($_);
 370                         push(@no, $_) unless $all{$d};
 371                         $_ = $d;
 372                 } elsif (m!\Aimaps?://!i) {
 373                         my $orig = $_;
 374                         my $res = match_imap_url($self, $orig, \@all);
 375                         if (ref $res) {
 376                                 $_ = $$res;
 377                                 push(@{$err->{qerr}}, <<EOM);
 378 # using `$res' instead of `$orig'
 379 EOM
 380                         } else {
 381                                 $lei->err($res) if defined $res;
 382                                 push @no, $orig;
 383                         }
 384                 } else {
 385                         push @no, $_;
 386                 }
 387         }
 388         if (@no) {
 389                 my $no = join("\n\t", @no);
 390                 $err->{fail} = <<EOF;
 391 No sync information for: $no
 392 Run `lei ls-mail-sync' to display valid choices
 393 EOF
 394         }
 395         $err;
 396 }
 397
 398 sub forget_folder {
 399         my ($self, $folder) = @_;
 400         my ($fid, $sth);
 401         $fid = delete($self->{fmap}->{$folder}) //
 402                 fid_for($self, $folder) // return;
 403         my $dbh = $self->{dbh};
 404         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 405         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 406         $dbh->do('DELETE FROM folders WHERE fid = ?', undef, $fid);
 407 }
 408
 409 sub imap_oidbin ($$$) {
 410         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY
 411         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return;
 412         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 413 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ?
 414 EOM
 415         $sth->execute($fid, $uid);
 416         $sth->fetchrow_array;
 417 }
 418
 419 sub name_oidbin ($$$) {
 420         my ($self, $mdir, $nm) = @_;
 421         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 422         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 423 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 424 EOM
 425         $sth->execute($fid, $nm);
 426         $sth->fetchrow_array;
 427 }
 428
 429 sub imap_oid {
 430         my ($self, $lei, $uid_uri) = @_;
 431         my $mailbox_uri = $uid_uri->clone;
 432         $mailbox_uri->uid(undef);
 433         my $folders = [ $$mailbox_uri ];
 434         if (my $err = $self->arg2folder($lei, $folders)) {
 435                 if ($err->{fail}) {
 436                         $lei->qerr("# no sync information for $mailbox_uri");
 437                         return;
 438                 }
 439                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
 440         }
 441         my $oidbin = imap_oidbin($self, $folders->[0], $uid_uri->uid);
 442         $oidbin ? unpack('H*', $oidbin) : undef;
 443 }
 444
 445 # FIXED? something with "lei <up|q>" is causing uncommitted transaction
 446 # TODO: remove soon
 447 sub DESTROY {
 448         my ($self) = @_;
 449         my $dbh = delete($self->{dbh}) or return;
 450         return if $dbh->{ReadOnly};
 451         undef $dbh;
 452         warn "BUG $$ $0 $self {dbh} OPEN ppid=".getppid.' '.Carp::longmess();
 453 }
 454
 455 1;