lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10 use Carp ();
  11
  12 sub dbh_new {
  13         my ($self, $rw) = @_;
  14         my $f = $self->{filename};
  15         my $creat = $rw && !-s $f;
  16         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  17                 AutoCommit => 1,
  18                 RaiseError => 1,
  19                 PrintError => 0,
  20                 ReadOnly => !$rw,
  21                 sqlite_use_immediate_transaction => 1,
  22         });
  23         # no sqlite_unicode, here, all strings are binary
  24         create_tables($dbh) if $rw;
  25         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  26         $dbh->do('PRAGMA case_sensitive_like = ON');
  27         $dbh;
  28 }
  29
  30 sub new {
  31         my ($cls, $f) = @_;
  32         bless { filename => $f, fmap => {} }, $cls;
  33 }
  34
  35 sub lms_commit { delete($_[0]->{dbh})->commit }
  36
  37 sub lms_begin { ($_[0]->{dbh} //= dbh_new($_[0], 1))->begin_work };
  38
  39 sub create_tables {
  40         my ($dbh) = @_;
  41
  42         $dbh->do(<<'');
  43 CREATE TABLE IF NOT EXISTS folders (
  44         fid INTEGER PRIMARY KEY,
  45         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  46         UNIQUE (loc)
  47 )
  48
  49         $dbh->do(<<'');
  50 CREATE TABLE IF NOT EXISTS blob2num (
  51         oidbin VARBINARY NOT NULL,
  52         fid INTEGER NOT NULL, /* folder ID */
  53         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  54         UNIQUE (oidbin, fid, uid)
  55 )
  56
  57         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  58         $dbh->do(<<'');
  59 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  60
  61         $dbh->do(<<'');
  62 CREATE TABLE IF NOT EXISTS blob2name (
  63         oidbin VARBINARY NOT NULL,
  64         fid INTEGER NOT NULL, /* folder ID */
  65         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  66         UNIQUE (oidbin, fid, name)
  67 )
  68
  69 }
  70
  71 sub fid_for {
  72         my ($self, $folder, $rw) = @_;
  73         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  74         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  75         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  76         return $fid if defined $fid;
  77
  78         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  79                 warn "folder: $folder/ had trailing slash in arg\n";
  80                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  81                 if (defined $fid) {
  82                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  83 UPDATE folders SET loc = ? WHERE fid = ?
  84 EOM
  85                         return $fid;
  86                 }
  87         # sometimes we stored trailing slash..
  88         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
  89                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
  90                 if (defined $fid) {
  91                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  92 UPDATE folders SET loc = ? WHERE fid = ?
  93 EOM
  94                         return $fid;
  95                 }
  96         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
  97                 require PublicInbox::URIimap;
  98                 PublicInbox::URIimap->new($folder)->uidvalidity //
  99                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 100         }
 101         return unless $rw;
 102
 103         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 104
 105         $fid += 1;
 106         # in case we're reusing, clobber existing stale refs:
 107         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 108         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 109
 110         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 111         $sth->execute($fid, $folder);
 112
 113         $fid;
 114 }
 115
 116 sub set_src {
 117         my ($self, $oidhex, $folder, $id) = @_;
 118         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 119         my $sth;
 120         if (ref($id)) { # scalar name
 121                 $id = $$id;
 122                 $sth = $self->{dbh}->prepare_cached(<<'');
 123 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 124
 125         } else { # numeric ID (IMAP UID, MH number)
 126                 $sth = $self->{dbh}->prepare_cached(<<'');
 127 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 128
 129         }
 130         $sth->execute(pack('H*', $oidhex), $fid, $id);
 131 }
 132
 133 sub clear_src {
 134         my ($self, $folder, $id) = @_;
 135         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 136         my $sth;
 137         if (ref($id)) { # scalar name
 138                 $id = $$id;
 139                 $sth = $self->{dbh}->prepare_cached(<<'');
 140 DELETE FROM blob2name WHERE fid = ? AND name = ?
 141
 142         } else {
 143                 $sth = $self->{dbh}->prepare_cached(<<'');
 144 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 145
 146         }
 147         $sth->execute($fid, $id);
 148 }
 149
 150 # Maildir-only
 151 sub mv_src {
 152         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 153         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 154         my $sth = $self->{dbh}->prepare_cached(<<'');
 155 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 156
 157         $sth->execute($newbn, $fid, $oidbin, $$id);
 158 }
 159
 160 # read-only, iterates every oidbin + UID or name for a given folder
 161 sub each_src {
 162         my ($self, $folder, $cb, @args) = @_;
 163         my $dbh = $self->{dbh} //= dbh_new($self);
 164         my ($fid, $sth);
 165         if (ref($folder) eq 'HASH') {
 166                 $fid = $folder->{fid} // die "BUG: no `fid'";
 167         } else {
 168                 $fid = $self->{fmap}->{$folder} //=
 169                         fid_for($self, $folder) // return;
 170         }
 171         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 172         $sth->execute($fid);
 173         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 174                 $cb->($oidbin, $id, @args);
 175         }
 176         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 177         $sth->execute($fid);
 178         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 179                 $cb->($oidbin, \$id, @args);
 180         }
 181 }
 182
 183 sub location_stats {
 184         my ($self, $folder) = @_;
 185         my $dbh = $self->{dbh} //= dbh_new($self);
 186         my $fid;
 187         my $ret = {};
 188         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 189         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 190 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 191
 192         $ret->{'name.count'} = $row if $row;
 193         for my $op (qw(count min max)) {
 194                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 195 SELECT $op(uid) FROM blob2num WHERE fid = ?
 196
 197                 $row or last;
 198                 $ret->{"uid.$op"} = $row;
 199         }
 200         $ret;
 201 }
 202
 203 # returns a { location => [ list-of-ids-or-names ] } mapping
 204 sub locations_for {
 205         my ($self, $oidhex) = @_;
 206         my ($fid, $sth, $id, %fid2id);
 207         my $dbh = $self->{dbh} //= dbh_new($self);
 208         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 209         $sth->execute(pack('H*', $oidhex));
 210         while (my ($fid, $uid) = $sth->fetchrow_array) {
 211                 push @{$fid2id{$fid}}, $uid;
 212         }
 213         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 214         $sth->execute(pack('H*', $oidhex));
 215         while (my ($fid, $name) = $sth->fetchrow_array) {
 216                 push @{$fid2id{$fid}}, $name;
 217         }
 218         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 219         my $ret = {};
 220         while (my ($fid, $ids) = each %fid2id) {
 221                 $sth->execute($fid);
 222                 my ($loc) = $sth->fetchrow_array;
 223                 unless (defined $loc) {
 224                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 225                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 226                                 } @$ids;
 227                         next;
 228                 }
 229                 $ret->{$loc} = $ids;
 230         }
 231         scalar(keys %$ret) ? $ret : undef;
 232 }
 233
 234 # returns a list of folders used for completion
 235 sub folders {
 236         my ($self, $pfx) = @_;
 237         my $dbh = $self->{dbh} //= dbh_new($self);
 238         my $sql = 'SELECT loc FROM folders';
 239         my @pfx;
 240         if (defined $pfx) {
 241                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 242                 @pfx = ($pfx, '\\');
 243                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 244                 $pfx[0] .= '%';
 245         }
 246         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 247 }
 248
 249 sub local_blob {
 250         my ($self, $oidhex, $vrfy) = @_;
 251         my $dbh = $self->{dbh} //= dbh_new($self);
 252         my $b2n = $dbh->prepare(<<'');
 253 SELECT f.loc,b.name FROM blob2name b
 254 LEFT JOIN folders f ON b.fid = f.fid
 255 WHERE b.oidbin = ?
 256
 257         $b2n->execute(pack('H*', $oidhex));
 258         while (my ($d, $n) = $b2n->fetchrow_array) {
 259                 substr($d, 0, length('maildir:')) = '';
 260                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 261                 # in "new/", despite (from what I understand of reading
 262                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 263                 # applies to files in "cur/".
 264                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 265                 for my $x (@try) {
 266                         my $f = "$d/$x/$n";
 267                         open my $fh, '<', $f or next;
 268                         # some (buggy) Maildir writers are non-atomic:
 269                         next unless -s $fh;
 270                         local $/;
 271                         my $raw = <$fh>;
 272                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 273                                 warn "$f changed $oidhex\n";
 274                                 next;
 275                         }
 276                         return \$raw;
 277                 }
 278         }
 279         undef;
 280 }
 281
 282 sub match_imap_url {
 283         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 284         $all //= [ $self->folders ];
 285         require PublicInbox::URIimap;
 286         my $want = PublicInbox::URIimap->new($url)->canonical;
 287         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 288         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 289                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 290         my @match;
 291         for my $x (@uri) {
 292                 next if $x->mailbox ne $want->mailbox;
 293                 next if $x->host ne $want->host;
 294                 next if $x->port != $want->port;
 295                 my $x_uidval = $x->uidvalidity;
 296                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 297
 298                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 299                 if (defined($x->auth) && !defined($want->auth) &&
 300                                 !defined($want->user)) {
 301                         push @match, $x;
 302                 # or maybe user was forgotten on CLI:
 303                 } elsif (defined($x->user) && !defined($want->user)) {
 304                         push @match, $x;
 305                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 306                         push @match, $x;
 307                 }
 308         }
 309         return @match if wantarray;
 310         scalar(@match) <= 1 ? $match[0] :
 311                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 312 }
 313
 314 # map CLI args to folder table entries, returns undef on failure
 315 sub arg2folder {
 316         my ($self, $lei, $folders) = @_;
 317         my @all = $self->folders;
 318         my %all = map { $_ => 1 } @all;
 319         my ($err, @no);
 320         for (@$folders) {
 321                 next if $all{$_}; # ok
 322                 if (m!\A(maildir|mh):(.+)!i) {
 323                         my $type = lc $1;
 324                         my $d = "$type:".$lei->abs_path($2);
 325                         push(@no, $_) unless $all{$d};
 326                         $_ = $d;
 327                 } elsif (-d "$_/new" && -d "$_/cur") {
 328                         my $d = 'maildir:'.$lei->abs_path($_);
 329                         push(@no, $_) unless $all{$d};
 330                         $_ = $d;
 331                 } elsif (m!\Aimaps?://!i) {
 332                         my $orig = $_;
 333                         my $res = match_imap_url($self, $orig, \@all);
 334                         if (ref $res) {
 335                                 $_ = $$res;
 336                                 push(@{$err->{qerr}}, <<EOM);
 337 # using `$res' instead of `$orig'
 338 EOM
 339                         } else {
 340                                 $lei->err($res) if defined $res;
 341                                 push @no, $orig;
 342                         }
 343                 } else {
 344                         push @no, $_;
 345                 }
 346         }
 347         if (@no) {
 348                 my $no = join("\n\t", @no);
 349                 $err->{fail} = <<EOF;
 350 No sync information for: $no
 351 Run `lei ls-mail-sync' to display valid choices
 352 EOF
 353         }
 354         $err;
 355 }
 356
 357 sub forget_folder {
 358         my ($self, $folder) = @_;
 359         my ($fid, $sth);
 360         $fid = delete($self->{fmap}->{$folder}) //
 361                 fid_for($self, $folder) // return;
 362         my $dbh = $self->{dbh};
 363         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 364         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 365         $dbh->do('DELETE FROM folders WHERE fid = ?', undef, $fid);
 366 }
 367
 368 sub imap_oidbin ($$$) {
 369         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY
 370         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return;
 371         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 372 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ?
 373 EOM
 374         $sth->execute($fid, $uid);
 375         $sth->fetchrow_array;
 376 }
 377
 378 sub imap_oid {
 379         my ($self, $lei, $uid_uri) = @_;
 380         my $mailbox_uri = $uid_uri->clone;
 381         $mailbox_uri->uid(undef);
 382         my $folders = [ $$mailbox_uri ];
 383         if (my $err = $self->arg2folder($lei, $folders)) {
 384                 if ($err->{fail}) {
 385                         $lei->qerr("# no sync information for $mailbox_uri");
 386                         return;
 387                 }
 388                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
 389         }
 390         my $oidbin = imap_oidbin($self, $folders->[0], $uid_uri->uid);
 391         $oidbin ? unpack('H*', $oidbin) : undef;
 392 }
 393
 394 # FIXME: something with "lei <up|q>" is causing uncommitted transaction
 395 # warnings, not sure what...
 396 sub DESTROY {
 397         my ($self) = @_;
 398         my $dbh = delete($self->{dbh}) or return;
 399         return if $dbh->{ReadOnly};
 400         use Carp;
 401         undef $dbh;
 402         warn "BUG $$ $0 $self {dbh} OPEN ppid=".getppid.' '.Carp::longmess();
 403 }
 404
 405 1;