lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use DBI;
   9 use PublicInbox::ContentHash qw(git_sha);
  10 use Carp ();
  11
  12 sub dbh_new {
  13         my ($self, $rw) = @_;
  14         my $f = $self->{filename};
  15         my $creat = $rw && !-s $f;
  16         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  17                 AutoCommit => 1,
  18                 RaiseError => 1,
  19                 PrintError => 0,
  20                 ReadOnly => !$rw,
  21                 sqlite_use_immediate_transaction => 1,
  22         });
  23         # no sqlite_unicode, here, all strings are binary
  24         create_tables($dbh) if $rw;
  25         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  26         $dbh->do('PRAGMA case_sensitive_like = ON');
  27         $dbh;
  28 }
  29
  30 sub new {
  31         my ($cls, $f) = @_;
  32         bless { filename => $f, fmap => {} }, $cls;
  33 }
  34
  35 sub lms_commit { delete($_[0]->{dbh})->commit }
  36
  37 sub lms_begin { ($_[0]->{dbh} //= dbh_new($_[0], 1))->begin_work };
  38
  39 sub create_tables {
  40         my ($dbh) = @_;
  41
  42         $dbh->do(<<'');
  43 CREATE TABLE IF NOT EXISTS folders (
  44         fid INTEGER PRIMARY KEY,
  45         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  46         UNIQUE (loc)
  47 )
  48
  49         $dbh->do(<<'');
  50 CREATE TABLE IF NOT EXISTS blob2num (
  51         oidbin VARBINARY NOT NULL,
  52         fid INTEGER NOT NULL, /* folder ID */
  53         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  54         UNIQUE (oidbin, fid, uid)
  55 )
  56
  57         $dbh->do(<<'');
  58 CREATE TABLE IF NOT EXISTS blob2name (
  59         oidbin VARBINARY NOT NULL,
  60         fid INTEGER NOT NULL, /* folder ID */
  61         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  62         UNIQUE (oidbin, fid, name)
  63 )
  64
  65 }
  66
  67 sub fid_for {
  68         my ($self, $folder, $rw) = @_;
  69         my $dbh = $self->{dbh} //= dbh_new($self, $rw);
  70         my $sel = 'SELECT fid FROM folders WHERE loc = ? LIMIT 1';
  71         my ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  72         return $fid if defined $fid;
  73
  74         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
  75                 warn "folder: $folder/ had trailing slash in arg\n";
  76                 ($fid) = $dbh->selectrow_array($sel, undef, $folder);
  77                 if (defined $fid) {
  78                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  79 UPDATE folders SET loc = ? WHERE fid = ?
  80 EOM
  81                         return $fid;
  82                 }
  83         # sometimes we stored trailing slash..
  84         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
  85                 ($fid) = $dbh->selectrow_array($sel, undef, "$folder/");
  86                 if (defined $fid) {
  87                         $dbh->do(<<EOM, undef, $folder, $fid) if $rw;
  88 UPDATE folders SET loc = ? WHERE fid = ?
  89 EOM
  90                         return $fid;
  91                 }
  92         } elsif ($rw && $folder =~ m!\Aimaps?://!i) {
  93                 require PublicInbox::URIimap;
  94                 PublicInbox::URIimap->new($folder)->uidvalidity //
  95                         Carp::croak("BUG: $folder has no UIDVALIDITY");
  96         }
  97         return unless $rw;
  98
  99         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 100
 101         $fid += 1;
 102         # in case we're reusing, clobber existing stale refs:
 103         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 104         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 105
 106         my $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 107         $sth->execute($fid, $folder);
 108
 109         $fid;
 110 }
 111
 112 sub set_src {
 113         my ($self, $oidhex, $folder, $id) = @_;
 114         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 115         my $sth;
 116         if (ref($id)) { # scalar name
 117                 $id = $$id;
 118                 $sth = $self->{dbh}->prepare_cached(<<'');
 119 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 120
 121         } else { # numeric ID (IMAP UID, MH number)
 122                 $sth = $self->{dbh}->prepare_cached(<<'');
 123 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 124
 125         }
 126         $sth->execute(pack('H*', $oidhex), $fid, $id);
 127 }
 128
 129 sub clear_src {
 130         my ($self, $folder, $id) = @_;
 131         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 132         my $sth;
 133         if (ref($id)) { # scalar name
 134                 $id = $$id;
 135                 $sth = $self->{dbh}->prepare_cached(<<'');
 136 DELETE FROM blob2name WHERE fid = ? AND name = ?
 137
 138         } else {
 139                 $sth = $self->{dbh}->prepare_cached(<<'');
 140 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 141
 142         }
 143         $sth->execute($fid, $id);
 144 }
 145
 146 # Maildir-only
 147 sub mv_src {
 148         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 149         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 150         my $sth = $self->{dbh}->prepare_cached(<<'');
 151 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 152
 153         $sth->execute($newbn, $fid, $oidbin, $$id);
 154 }
 155
 156 # read-only, iterates every oidbin + UID or name for a given folder
 157 sub each_src {
 158         my ($self, $folder, $cb, @args) = @_;
 159         my $dbh = $self->{dbh} //= dbh_new($self);
 160         my ($fid, $sth);
 161         if (ref($folder) eq 'HASH') {
 162                 $fid = $folder->{fid} // die "BUG: no `fid'";
 163         } else {
 164                 $fid = $self->{fmap}->{$folder} //=
 165                         fid_for($self, $folder) // return;
 166         }
 167         $sth = $dbh->prepare('SELECT oidbin,uid FROM blob2num WHERE fid = ?');
 168         $sth->execute($fid);
 169         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 170                 $cb->($oidbin, $id, @args);
 171         }
 172         $sth = $dbh->prepare('SELECT oidbin,name FROM blob2name WHERE fid = ?');
 173         $sth->execute($fid);
 174         while (my ($oidbin, $id) = $sth->fetchrow_array) {
 175                 $cb->($oidbin, \$id, @args);
 176         }
 177 }
 178
 179 sub location_stats {
 180         my ($self, $folder) = @_;
 181         my $dbh = $self->{dbh} //= dbh_new($self);
 182         my $fid;
 183         my $ret = {};
 184         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 185         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 186 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 187
 188         $ret->{'name.count'} = $row if $row;
 189         for my $op (qw(count min max)) {
 190                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 191 SELECT $op(uid) FROM blob2num WHERE fid = ?
 192
 193                 $row or last;
 194                 $ret->{"uid.$op"} = $row;
 195         }
 196         $ret;
 197 }
 198
 199 # returns a { location => [ list-of-ids-or-names ] } mapping
 200 sub locations_for {
 201         my ($self, $oidhex) = @_;
 202         my ($fid, $sth, $id, %fid2id);
 203         my $dbh = $self->{dbh} //= dbh_new($self);
 204         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 205         $sth->execute(pack('H*', $oidhex));
 206         while (my ($fid, $uid) = $sth->fetchrow_array) {
 207                 push @{$fid2id{$fid}}, $uid;
 208         }
 209         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 210         $sth->execute(pack('H*', $oidhex));
 211         while (my ($fid, $name) = $sth->fetchrow_array) {
 212                 push @{$fid2id{$fid}}, $name;
 213         }
 214         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 215         my $ret = {};
 216         while (my ($fid, $ids) = each %fid2id) {
 217                 $sth->execute($fid);
 218                 my ($loc) = $sth->fetchrow_array;
 219                 unless (defined $loc) {
 220                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 221                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 222                                 } @$ids;
 223                         next;
 224                 }
 225                 $ret->{$loc} = $ids;
 226         }
 227         scalar(keys %$ret) ? $ret : undef;
 228 }
 229
 230 # returns a list of folders used for completion
 231 sub folders {
 232         my ($self, $pfx) = @_;
 233         my $dbh = $self->{dbh} //= dbh_new($self);
 234         my $sql = 'SELECT loc FROM folders';
 235         my @pfx;
 236         if (defined $pfx) {
 237                 $sql .= ' WHERE loc LIKE ? ESCAPE ?';
 238                 @pfx = ($pfx, '\\');
 239                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
 240                 $pfx[0] .= '%';
 241         }
 242         map { $_->[0] } @{$dbh->selectall_arrayref($sql, undef, @pfx)};
 243 }
 244
 245 sub local_blob {
 246         my ($self, $oidhex, $vrfy) = @_;
 247         my $dbh = $self->{dbh} //= dbh_new($self);
 248         my $b2n = $dbh->prepare(<<'');
 249 SELECT f.loc,b.name FROM blob2name b
 250 LEFT JOIN folders f ON b.fid = f.fid
 251 WHERE b.oidbin = ?
 252
 253         $b2n->execute(pack('H*', $oidhex));
 254         while (my ($d, $n) = $b2n->fetchrow_array) {
 255                 substr($d, 0, length('maildir:')) = '';
 256                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 257                 # in "new/", despite (from what I understand of reading
 258                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 259                 # applies to files in "cur/".
 260                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 261                 for my $x (@try) {
 262                         my $f = "$d/$x/$n";
 263                         open my $fh, '<', $f or next;
 264                         # some (buggy) Maildir writers are non-atomic:
 265                         next unless -s $fh;
 266                         local $/;
 267                         my $raw = <$fh>;
 268                         if ($vrfy && git_sha(1, \$raw)->hexdigest ne $oidhex) {
 269                                 warn "$f changed $oidhex\n";
 270                                 next;
 271                         }
 272                         return \$raw;
 273                 }
 274         }
 275         undef;
 276 }
 277
 278 sub match_imap_url {
 279         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 280         $all //= [ $self->folders ];
 281         require PublicInbox::URIimap;
 282         my $want = PublicInbox::URIimap->new($url)->canonical;
 283         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 284         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 285                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 286         my @match;
 287         for my $x (@uri) {
 288                 next if $x->mailbox ne $want->mailbox;
 289                 next if $x->host ne $want->host;
 290                 next if $x->port != $want->port;
 291                 my $x_uidval = $x->uidvalidity;
 292                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 293
 294                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 295                 if (defined($x->auth) && !defined($want->auth) &&
 296                                 !defined($want->user)) {
 297                         push @match, $x;
 298                 # or maybe user was forgotten on CLI:
 299                 } elsif (defined($x->user) && !defined($want->user)) {
 300                         push @match, $x;
 301                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 302                         push @match, $x;
 303                 }
 304         }
 305         return @match if wantarray;
 306         scalar(@match) <= 1 ? $match[0] :
 307                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 308 }
 309
 310 # map CLI args to folder table entries, returns undef on failure
 311 sub arg2folder {
 312         my ($self, $lei, $folders) = @_;
 313         my @all = $self->folders;
 314         my %all = map { $_ => 1 } @all;
 315         my ($err, @no);
 316         for (@$folders) {
 317                 next if $all{$_}; # ok
 318                 if (m!\A(maildir|mh):(.+)!i) {
 319                         my $type = lc $1;
 320                         my $d = "$type:".$lei->abs_path($2);
 321                         push(@no, $_) unless $all{$d};
 322                         $_ = $d;
 323                 } elsif (-d "$_/new" && -d "$_/cur") {
 324                         my $d = 'maildir:'.$lei->abs_path($_);
 325                         push(@no, $_) unless $all{$d};
 326                         $_ = $d;
 327                 } elsif (m!\Aimaps?://!i) {
 328                         my $orig = $_;
 329                         my $res = match_imap_url($self, $orig, \@all);
 330                         if (ref $res) {
 331                                 $_ = $$res;
 332                                 push(@{$err->{qerr}}, <<EOM);
 333 # using `$res' instead of `$orig'
 334 EOM
 335                         } else {
 336                                 $lei->err($res) if defined $res;
 337                                 push @no, $orig;
 338                         }
 339                 } else {
 340                         push @no, $_;
 341                 }
 342         }
 343         if (@no) {
 344                 my $no = join("\n\t", @no);
 345                 $err->{fail} = <<EOF;
 346 No sync information for: $no
 347 Run `lei ls-mail-sync' to display valid choices
 348 EOF
 349         }
 350         $err;
 351 }
 352
 353 sub forget_folder {
 354         my ($self, $folder) = @_;
 355         my ($fid, $sth);
 356         $fid = delete($self->{fmap}->{$folder}) //
 357                 fid_for($self, $folder) // return;
 358         my $dbh = $self->{dbh};
 359         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 360         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 361         $dbh->do('DELETE FROM folders WHERE fid = ?', undef, $fid);
 362 }
 363
 364 sub imap_oid2 ($$$) {
 365         my ($self, $uri, $uid) = @_; # $uri MUST have UIDVALIDITY
 366         my $fid = $self->{fmap}->{"$uri"} //= fid_for($self, "$uri") // return;
 367         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 368 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ?
 369 EOM
 370         $sth->execute($fid, $uid);
 371         my ($oidbin) = $sth->fetchrow_array;
 372         $oidbin ? unpack('H*', $oidbin) : undef;
 373 }
 374
 375 sub imap_oid {
 376         my ($self, $lei, $uid_uri) = @_;
 377         my $mailbox_uri = $uid_uri->clone;
 378         $mailbox_uri->uid(undef);
 379         my $folders = [ $$mailbox_uri ];
 380         if (my $err = $self->arg2folder($lei, $folders)) {
 381                 if ($err->{fail}) {
 382                         $lei->qerr("# no sync information for $mailbox_uri");
 383                         return;
 384                 }
 385                 $lei->qerr(@{$err->{qerr}}) if $err->{qerr};
 386         }
 387         imap_oid2($self, $folders->[0], $uid_uri->uid);
 388 }
 389
 390
 391 # FIXME: something with "lei <up|q>" is causing uncommitted transaction
 392 # warnings, not sure what...
 393 sub DESTROY {
 394         my ($self) = @_;
 395         my $dbh = delete($self->{dbh}) or return;
 396         return if $dbh->{ReadOnly};
 397         use Carp;
 398         undef $dbh;
 399         warn "BUG $$ $0 $self {dbh} OPEN ppid=".getppid.' '.Carp::longmess();
 400 }
 401
 402 1;