lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::LeiCurl;
  20 use PublicInbox::OnDestroy;
  21
  22 our $LIVE; # pid => callback
  23
  24 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  25         my ($arg, $pid) = @_;
  26         my ($mrr, $lei) = @$arg;
  27         my $f = "$mrr->{dst}/mirror.done";
  28         if ($?) {
  29                 $lei->child_error($?);
  30         } elsif (!$mrr->{dry_run} && !unlink($f)) {
  31                 warn("unlink($f): $!\n") unless $!{ENOENT};
  32         } else {
  33                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  34                         # calls _finish_add_external
  35                         $lei->lazy_cb('add-external', '_finish_'
  36                                         )->($lei, $mrr->{dst});
  37                 }
  38                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  39         }
  40         $lei->dclose;
  41 }
  42
  43 # for old installations without manifest.js.gz
  44 sub try_scrape {
  45         my ($self, $fallback_manifest) = @_;
  46         my $uri = URI->new($self->{src});
  47         my $lei = $self->{lei};
  48         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  49         my $cmd = $curl->for_uri($lei, $uri, qw(-f --compressed));
  50         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  51         my $fh = popen_rd($cmd, undef, $opt);
  52         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  53         close($fh) or return $lei->child_error($?, "@$cmd failed");
  54
  55         # we grep with URL below, we don't want Subject/From headers
  56         # making us clone random URLs.  This assumes remote instances
  57         # prior to public-inbox 1.7.0
  58         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  59         my @html = split(/<hr>/, $html);
  60         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  61         if (!@urls && $fallback_manifest) {
  62                 warn <<EOM;
  63 W: failed to extract URLs from $uri, trying manifest.js.gz...
  64 EOM
  65                 return start_clone_url($self);
  66         }
  67         my $url = $uri->as_string;
  68         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  69
  70         # since this is for old instances w/o manifest.js.gz, try v1 first
  71         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  72         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  73                 my %v2_epochs = map {
  74                         my ($n) = (m!/([0-9]+)\z!);
  75                         $n => [ URI->new($_), '' ]
  76                 } @v2_urls; # uniq
  77                 clone_v2_prep($self, \%v2_epochs);
  78                 delete local $lei->{opt}->{epoch};
  79                 clone_all($self);
  80                 return;
  81         }
  82
  83         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  84         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  85                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  86                 die <<"";
  87 E: confused by scraping <$uri>, did you mean <$url>?
  88
  89         }
  90         @urls and die <<"";
  91 E: confused by scraping <$uri>, got ambiguous results:
  92 @urls
  93
  94         die "E: scraping <$uri> revealed nothing\n";
  95 }
  96
  97 sub clone_cmd {
  98         my ($lei, $opt) = @_;
  99         my @cmd = qw(git);
 100         $opt->{$_} = $lei->{$_} for (0..2);
 101         # we support "-c $key=$val" for arbitrary git config options
 102         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 103         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 104         push @cmd, qw(clone --mirror);
 105         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 106                         ($lei->{opt}->{jobs} // 1) > 1;
 107         push @cmd, '-v' if $lei->{opt}->{verbose};
 108         # XXX any other options to support?
 109         # --reference is tricky with multiple epochs, but handled
 110         # automatically if using manifest.js.gz
 111         @cmd;
 112 }
 113
 114 sub ft_rename ($$$) {
 115         my ($ft, $dst, $open_mode) = @_;
 116         my @st = stat($dst);
 117         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 118         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 119         require File::Copy;
 120         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 121         $ft->unlink_on_destroy(0);
 122 }
 123
 124 sub _get_txt_start { # non-fatal
 125         my ($self, $endpoint, $fini) = @_;
 126         my $uri = URI->new($self->{cur_src} // $self->{src});
 127         my $lei = $self->{lei};
 128         my $path = $uri->path;
 129         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 130         $uri->path("$path/$endpoint");
 131         my $f = (split(m!/!, $endpoint))[-1];
 132         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 133         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 134         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(-f --compressed -R -o),
 135                                         $ft->filename);
 136         my $jobs = $lei->{opt}->{jobs} // 1;
 137         reap_live() while keys(%$LIVE) >= $jobs;
 138         $lei->qerr("# @$cmd");
 139         return if $self->{dry_run};
 140         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 141         $LIVE->{spawn($cmd, undef, $opt)} =
 142                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 143 }
 144
 145 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 146         my ($self, $endpoint) = @_;
 147         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 148         my $cerr = $?;
 149         $? = 0; # don't influence normal lei exit
 150         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 151         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 152         seek($fh, SEEK_SET, 0) or die "seek: $!";
 153         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 154         local $/;
 155         $self->{"txt.$endpoint"} = <$fh>;
 156         undef; # success
 157 }
 158
 159 sub _write_inbox_config {
 160         my ($self) = @_;
 161         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 162         my $dst = $self->{cur_dst} // $self->{dst};
 163         my $f = "$dst/inbox.config.example";
 164         open my $fh, '>', $f or die "open($f): $!";
 165         print $fh $buf or die "print: $!";
 166         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 167         my $mtime = delete $self->{'mtime._/text/config/raw'};
 168         $fh->flush or die "flush($f): $!";
 169         if (defined $mtime) {
 170                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
 171         }
 172         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 173         my $ibx = $self->{ibx} = {};
 174         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 175                 for (qw(address newsgroup nntpmirror)) {
 176                         $ibx->{$_} = $cfg->{"$sec.$_"};
 177                 }
 178         }
 179 }
 180
 181 sub set_description ($) {
 182         my ($self) = @_;
 183         my $dst = $self->{cur_dst} // $self->{dst};
 184         my $f = "$dst/description";
 185         open my $fh, '+>>', $f or die "open($f): $!";
 186         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 187         my $d = do { local $/; <$fh> } // die "read($f): $!";
 188         chomp(my $orig = $d);
 189         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 190                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 191                 $d = delete($self->{'txt.description'});
 192         }
 193         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 194         chomp $d;
 195         return if $d eq $orig;
 196         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 197         truncate($fh, 0) or die "truncate($f): $!";
 198         print $fh $d, "\n" or die "print($f): $!";
 199         close $fh or die "close($f): $!";
 200 }
 201
 202 sub index_cloned_inbox {
 203         my ($self, $iv) = @_;
 204         my $lei = $self->{lei};
 205         eval { set_description($self) };
 206         warn $@ if $@;
 207
 208         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 209         # lei is useless without Xapian + SQLite
 210         if ($lei->{cmd} ne 'public-inbox-clone') {
 211                 require PublicInbox::InboxWritable;
 212                 require PublicInbox::Admin;
 213                 my $ibx = delete($self->{ibx}) // {
 214                         address => [ 'lei@example.com' ],
 215                         version => $iv,
 216                 };
 217                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 218                 PublicInbox::Inbox->new($ibx);
 219                 PublicInbox::InboxWritable->new($ibx);
 220                 my $opt = {};
 221                 for my $sw ($lei->index_opt) {
 222                         my ($k) = ($sw =~ /\A([\w-]+)/);
 223                         $opt->{$k} = $lei->{opt}->{$k};
 224                 }
 225                 # force synchronous dwaitpid for v2:
 226                 local $PublicInbox::DS::in_loop = 0;
 227                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 228                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 229                 local %ENV = (%ENV, %$env) if $env;
 230                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 231                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 232         }
 233         return if defined $self->{cur_dst}; # one of many repos to clone
 234         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 235 }
 236
 237 sub run_reap {
 238         my ($lei, $cmd, $opt) = @_;
 239         $lei->qerr("# @$cmd");
 240         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 241         my $ret = $?;
 242         $? = 0; # don't let it influence normal exit
 243         $ret;
 244 }
 245
 246 sub start_clone {
 247         my ($self, $cmd, $opt, $fini) = @_;
 248         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
 249         reap_live() while keys(%$LIVE) >= $jobs;
 250         $self->{lei}->qerr("# @$cmd");
 251         return if $self->{dry_run};
 252         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_clone, $self, $cmd, $fini ]
 253 }
 254
 255 sub clone_v1 {
 256         my ($self, $nohang) = @_;
 257         my $lei = $self->{lei};
 258         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 259         my $uri = URI->new($self->{cur_src} // $self->{src});
 260         defined($lei->{opt}->{epoch}) and
 261                 die "$uri is a v1 inbox, --epoch is not supported\n";
 262         my $pfx = $curl->torsocks($lei, $uri) or return;
 263         my $dst = $self->{cur_dst} // $self->{dst};
 264         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 265         my $cmd = [ @$pfx, clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 266         my $ref = $self->{-ent} ? $self->{-ent}->{reference} : undef;
 267         defined($ref) && -e "$self->{dst}$ref" and
 268                 push @$cmd, '--reference', "$self->{dst}$ref";
 269         start_clone($self, $cmd, $opt, $fini);
 270
 271         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 272                                 /\A(?:always|v1)\z/s) {
 273                 _get_txt_start($self, '_/text/config/raw', $fini);
 274         }
 275
 276         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 277         $self->{'txt.description'} = $d if defined $d;
 278         (!defined($d) && !$nohang) and
 279                 _get_txt_start($self, 'description', $fini);
 280
 281         reap_live() until ($nohang || !keys(%$LIVE)); # for non-manifest clone
 282 }
 283
 284 sub parse_epochs ($$) {
 285         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 286         $opt_epochs // return; # undef => all epochs
 287         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 288         undef($lo) if ($lo // '') eq '';
 289         my $re = qr/\A~?[0-9]+\z/;
 290         if (@extra || (($lo // '0') !~ $re) ||
 291                         (($hi // '0') !~ $re) ||
 292                         !(grep(defined, $lo, $hi))) {
 293                 die <<EOM;
 294 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 295 EOM
 296         }
 297         my @n = sort { $a <=> $b } keys %$v2_epochs;
 298         for (grep(defined, $lo, $hi)) {
 299                 if (/\A[0-9]+\z/) {
 300                         $_ > $n[-1] and die
 301 "`$_' exceeds maximum available epoch ($n[-1])\n";
 302                         $_ < $n[0] and die
 303 "`$_' is lower than minimum available epoch ($n[0])\n";
 304                 } elsif (/\A~([0-9]+)/) {
 305                         my $off = -$1 - 1;
 306                         $n[$off] // die "`$_' is out of range\n";
 307                         $_ = $n[$off];
 308                 } else { die "`$_' not understood\n" }
 309         }
 310         defined($lo) && defined($hi) && $lo > $hi and die
 311 "low value (`$lo') exceeds high (`$hi')\n";
 312         $lo //= $n[0] if $dotdot;
 313         $hi //= $n[-1] if $dotdot;
 314         $hi //= $lo;
 315         my $want = {};
 316         for ($lo..$hi) {
 317                 if (defined $v2_epochs->{$_}) {
 318                         $want->{$_} = 1;
 319                 } else {
 320                         warn
 321 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 322                 }
 323         }
 324         $want
 325 }
 326
 327 sub init_placeholder ($$$) {
 328         my ($src, $edst, $ent) = @_;
 329         PublicInbox::Import::init_bare($edst);
 330         my $f = "$edst/config";
 331         open my $fh, '>>', $f or die "open($f): $!";
 332         print $fh <<EOM or die "print($f): $!";
 333 [remote "origin"]
 334         url = $src
 335         fetch = +refs/*:refs/*
 336         mirror = true
 337
 338 ; This git epoch was created read-only and "public-inbox-fetch"
 339 ; will not fetch updates for it unless write permission is added.
 340 ; Hint: chmod +w $edst
 341 EOM
 342         if (defined($ent->{owner})) {
 343                 print $fh <<EOM or die "print($f): $!";
 344 [gitweb]
 345         owner = $ent->{owner}
 346 EOM
 347         }
 348         close $fh or die "close($f): $!";
 349         my %map = (head => 'HEAD', description => undef);
 350         while (my ($key, $fn) = each %map) {
 351                 my $val = $ent->{$key} // next;
 352                 $fn //= $key;
 353                 $fn = "$edst/$fn";
 354                 open $fh, '>', $fn or die "open($fn): $!";
 355                 print $fh $val, "\n" or die "print($fn): $!";
 356                 close $fh or die "close($fn): $!";
 357         }
 358 }
 359
 360 sub reap_clone { # async, called via SIGCHLD
 361         my ($self, $cmd) = @_;
 362         my $cerr = $?;
 363         $? = 0; # don't let it influence normal exit
 364         if ($cerr) {
 365                 kill('TERM', keys %$LIVE);
 366                 $self->{lei}->child_error($cerr, "@$cmd failed");
 367         }
 368 }
 369
 370 sub v1_done { # called via OnDestroy
 371         my ($self) = @_;
 372         return if $self->{dry_run} || !$LIVE;
 373         _write_inbox_config($self);
 374         my $dst = $self->{cur_dst} // $self->{dst};
 375         if (defined(my $o = $self->{-ent} ? $self->{-ent}->{owner} : undef)) {
 376                 run_die([qw(git config -f), "$dst/config", 'gitweb.owner', $o]);
 377         }
 378         my $o = "$dst/objects";
 379         if (open(my $fh, '<', "$o/info/alternates")) {
 380                 chomp(my @l = <$fh>);
 381                 for (@l) { $_ = File::Spec->abs2rel($_, $o)."\n" }
 382                 my $f = File::Temp->new(TEMPLATE => '.XXXX', DIR => "$o/info");
 383                 print $f @l;
 384                 $f->flush or die "flush($f): $!";
 385                 rename($f->filename, "$o/info/alternates") or
 386                         die "rename($f, $o/info/alternates): $!";
 387                 $f->unlink_on_destroy(0);
 388         }
 389         return if ($self->{-is_epoch} ||
 390                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 391         write_makefile($dst, 1);
 392         index_cloned_inbox($self, 1);
 393 }
 394
 395 sub v2_done { # called via OnDestroy
 396         my ($self) = @_;
 397         return if $self->{dry_run} || !$LIVE;
 398         my $dst = $self->{cur_dst} // $self->{dst};
 399         require PublicInbox::Lock;
 400         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 401         my $lck = $lk->lock_for_scope($$);
 402         _write_inbox_config($self);
 403         require PublicInbox::MultiGit;
 404         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 405         $mg->fill_alternates;
 406         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 407         for my $edst (@{delete($self->{-read_only}) // []}) {
 408                 my @st = stat($edst) or die "stat($edst): $!";
 409                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 410         }
 411         write_makefile($dst, 2);
 412         undef $lck; # unlock
 413         index_cloned_inbox($self, 2);
 414 }
 415
 416 sub reap_live {
 417         my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 418         if (my $x = delete $LIVE->{$pid}) {
 419                 my $cb = shift @$x;
 420                 $cb->(@$x);
 421         } else {
 422                 warn "reaped unknown PID=$pid ($?)\n";
 423         }
 424 }
 425
 426 sub clone_v2_prep ($$;$) {
 427         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 428         my $lei = $self->{lei};
 429         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 430         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 431         my $pfx = $curl->torsocks($lei, $first_uri) or return;
 432         my $dst = $self->{cur_dst} // $self->{dst};
 433         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 434         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 435         delete $task->{todo}; # $self->{todo} still exists
 436         my (@src_edst, @skip, $desc, @entv);
 437         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 438                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 439                 my $src = $uri->as_string;
 440                 my $edst = $dst;
 441                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 442 failed to extract epoch number from $src
 443
 444                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 445                 $edst .= "/git/$nr.git";
 446                 my $ent;
 447                 if ($m) {
 448                         $ent = $m->{$key} //
 449                                 die("BUG: `$key' not in manifest.js.gz");
 450                         if (defined(my $d = $ent->{description})) {
 451                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 452                                 $desc = $d;
 453                         }
 454                 }
 455                 if (!$want || $want->{$nr}) {
 456                         push @src_edst, $src, $edst;
 457                         push @entv, $edst, $ent;
 458                         $self->{any_want}->{$key} = 1;
 459                 } else { # create a placeholder so users only need to chmod +w
 460                         init_placeholder($src, $edst, $ent);
 461                         push @{$task->{-read_only}}, $edst;
 462                         push @skip, $key;
 463                 }
 464         }
 465         # filter out the epochs we skipped
 466         $self->{-culled_manifest} = 1 if $m && delete(@$m{@skip});
 467
 468         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 469
 470         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 471
 472         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 473                 _get_txt_start($task, '_/text/config/raw', $fini);
 474
 475         defined($desc) ? ($task->{'txt.description'} = $desc) :
 476                 _get_txt_start($task, 'description', $fini);
 477         while (@entv) {
 478                 my ($edst, $ent) = splice(@entv, 0, 2);
 479                 my $etask = bless { %$task }, __PACKAGE__;
 480                 $etask->{-ent} = $ent; # may have {reference}
 481                 $etask->{cur_src} = shift @src_edst // die 'BUG: no cur_src';
 482                 $etask->{cur_dst} = shift @src_edst // die 'BUG: no cur_dst';
 483                 $etask->{cur_dst} eq $edst or
 484                         die "BUG: `$etask->{cur_dst}' != `$edst'";
 485                 $etask->{-is_epoch} = $fini;
 486                 push @{$self->{todo}->{($ent->{reference} // '')}}, $etask;
 487         }
 488 }
 489
 490 sub decode_manifest ($$$) {
 491         my ($fh, $fn, $uri) = @_;
 492         my $js;
 493         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 494         gunzip(\$gz => \$js, MultiStream => 1) or
 495                 die "gunzip($uri): $GunzipError\n";
 496         my $m = eval { PublicInbox::Config->json->decode($js) };
 497         die "$uri: error decoding `$js': $@\n" if $@;
 498         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 499         $m;
 500 }
 501
 502 sub multi_inbox ($$$) {
 503         my ($self, $path, $m) = @_;
 504         my $incl = $self->{lei}->{opt}->{include};
 505         my $excl = $self->{lei}->{opt}->{exclude};
 506
 507         # assuming everything not v2 is v1, for now
 508         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 509         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 510         my $v2 = {};
 511
 512         for (@v2_epochs) {
 513                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 514                 push @{$v2->{$1}}, $_;
 515         }
 516         my $n = scalar(keys %$v2) + scalar(@v1);
 517         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 518         if (defined $incl) {
 519                 my $re = '(?:'.join('\\z|', map {
 520                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 521                         } @$incl).'\\z)';
 522                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 523                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 524                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
 525                 @v1 = grep(/$re/, @v1);
 526         }
 527         if (defined $excl) {
 528                 my $re = '(?:'.join('\\z|', map {
 529                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 530                         } @$excl).'\\z)';
 531                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 532                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 533                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
 534                 @v1 = grep(!/$re/, @v1);
 535         }
 536         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 537         $ret->{v1} = \@v1 if @v1;
 538         $ret->{v2} = $v2 if keys %$v2;
 539         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 540                                 join("\n\t", sort @orig)
 541                         : "Nothing available to clone\n";
 542         my $path_pfx = '';
 543
 544         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 545         if (@v2_epochs) {
 546                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 547                                 @v2_epochs) == @v2_epochs) {
 548                         $$path =~ s!\A(/[^/]+)/!/! or last;
 549                         $path_pfx .= $1;
 550                 }
 551         } elsif (@v1) {
 552                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 553                         $path_pfx .= $1;
 554                 }
 555         }
 556         ($path_pfx, $n, $ret);
 557 }
 558
 559 sub clone_all {
 560         my ($self, $m) = @_;
 561         my $todo = delete $self->{todo};
 562         my $nodep = delete $todo->{''};
 563
 564         # do not download unwanted deps
 565         my $any_want = delete $self->{any_want};
 566         my @unwanted = grep { !$any_want->{$_} } keys %$todo;
 567         my @nodep = delete(@$todo{@unwanted});
 568         push(@$nodep, @$_) for @nodep;
 569
 570         # handle no-dependency repos, first
 571         for (@$nodep) {
 572                 clone_v1($_, 1);
 573                 return if $self->{lei}->{child_error};
 574         }
 575         # resolve references, deepest, first:
 576         while (scalar keys %$todo) {
 577                 for my $x (keys %$todo) {
 578                         my ($nr, $nxt);
 579                         # resolve multi-level references
 580                         while ($m && defined($nxt = $m->{$x}->{reference})) {
 581                                 exists($todo->{$nxt}) or last;
 582                                 die <<EOM if ++$nr > 1000;
 583 E: dependency loop detected (`$x' => `$nxt')
 584 EOM
 585                                 $x = $nxt;
 586                         }
 587                         my $y = delete $todo->{$x} // next; # already done
 588                         for (@$y) {
 589                                 clone_v1($_, 1);
 590                                 return if $self->{lei}->{child_error};
 591                         }
 592                         last; # restart %$todo iteration
 593                 }
 594         }
 595         reap_live() while keys(%$LIVE);
 596 }
 597
 598 sub dump_manifest ($$) {
 599         my ($m, $ft) = @_;
 600         # write the smaller manifest if epochs were skipped so
 601         # users won't have to delete manifest if they +w an
 602         # epoch they no longer want to skip
 603         my $json = PublicInbox::Config->json->encode($m);
 604         my $mtime = (stat($ft))[9];
 605         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
 606         truncate($ft, 0) or die "truncate($ft): $!";
 607         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
 608         $ft->flush or die "flush($ft): $!";
 609         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
 610 }
 611
 612 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
 613 sub try_manifest {
 614         my ($self) = @_;
 615         my $uri = URI->new($self->{src});
 616         my $lei = $self->{lei};
 617         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 618         my $path = $uri->path;
 619         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 620         $uri->path($path . '/manifest.js.gz');
 621         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX',
 622                                 UNLINK => 1, TMPDIR => 1, SUFFIX => '.tmp');
 623         my $cmd = $curl->for_uri($lei, $uri, qw(-f -R -o), $ft->filename);
 624         my %opt = map { $_ => $lei->{$_} } (0..2);
 625         my $cerr = run_reap($lei, $cmd, \%opt);
 626         if ($cerr) {
 627                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
 628                 return $lei->child_error($cerr, "@$cmd failed");
 629         }
 630         my $m = eval { decode_manifest($ft, $ft, $uri) };
 631         if ($@) {
 632                 warn $@;
 633                 return try_scrape($self);
 634         }
 635         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
 636         return $lei->child_error(1, $multi) if !ref($multi);
 637         my $v2 = delete $multi->{v2};
 638         local $self->{todo} = {};
 639         if ($v2) {
 640                 for my $name (sort keys %$v2) {
 641                         my $epochs = delete $v2->{$name};
 642                         my %v2_epochs = map {
 643                                 $uri->path($n > 1 ? $path_pfx.$path.$_
 644                                                 : $path_pfx.$_);
 645                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
 646                                 $e // die "no [0-9]+\.git in `$uri'";
 647                                 $e => [ $uri->clone, $_ ];
 648                         } @$epochs;
 649                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
 650                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
 651                         local $self->{cur_src} = $1;
 652                         local $self->{cur_dst} = $self->{dst};
 653                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
 654                                                         git/[0-9]+\.git\z!x) {
 655                                 $self->{cur_dst} .= "/$1";
 656                         }
 657                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
 658 E: `$self->{cur_dst}' must not contain newline
 659 EOM
 660                         clone_v2_prep($self, \%v2_epochs, $m);
 661                         return if $self->{lei}->{child_error};
 662                 }
 663         }
 664         if (my $v1 = delete $multi->{v1}) {
 665                 my $p = $path_pfx.$path;
 666                 chop($p) if substr($p, -1, 1) eq '/';
 667                 $uri->path($p);
 668                 for my $name (@$v1) {
 669                         my $task = bless { %$self }, __PACKAGE__;
 670                         $task->{-ent} = $m->{$name} //
 671                                         die("BUG: no `$name' in manifest");
 672                         $task->{cur_src} = "$uri";
 673                         $task->{cur_dst} = $task->{dst};
 674                         if ($n > 1) {
 675                                 $task->{cur_dst} .= $name;
 676                                 $task->{cur_src} .= $name;
 677                         }
 678                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
 679 E: `$task->{cur_dst}' must not contain newline
 680 EOM
 681                         $task->{cur_src} .= '/';
 682                         my $dep = $task->{-ent}->{reference} // '';
 683                         push @{$self->{todo}->{$dep}}, $task; # for clone_all
 684                         $self->{any_want}->{$name} = 1;
 685                 }
 686         }
 687         delete local $lei->{opt}->{epoch} if defined($v2);
 688         clone_all($self, $m);
 689         return if $self->{lei}->{child_error} || $self->{dry_run};
 690
 691         # set by clone_v2_prep/-I/--exclude
 692         dump_manifest($m => $ft) if delete $self->{-culled_manifest};
 693         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
 694         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 695 }
 696
 697 sub start_clone_url {
 698         my ($self) = @_;
 699         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 700         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 701 }
 702
 703 sub do_mirror { # via wq_io_do or public-inbox-clone
 704         my ($self) = @_;
 705         my $lei = $self->{lei};
 706         umask($lei->{client_umask}) if defined $lei->{client_umask};
 707         eval {
 708                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
 709                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
 710 --inbox-config must be one of `always', `v2', `v1', or `never'
 711
 712                 local $LIVE;
 713                 my $iv = $lei->{opt}->{'inbox-version'} //
 714                         return start_clone_url($self);
 715                 return clone_v1($self) if $iv == 1;
 716                 die "bad --inbox-version=$iv\n" if $iv != 2;
 717                 die <<EOM if $self->{src} !~ m!://!;
 718 cloning local v2 inboxes not supported
 719 EOM
 720                 try_scrape($self, 1);
 721         };
 722         $lei->fail($@) if $@;
 723 }
 724
 725 sub start {
 726         my ($cls, $lei, $src, $dst) = @_;
 727         my $self = bless { src => $src, dst => $dst }, $cls;
 728         $lei->request_umask;
 729         my ($op_c, $ops) = $lei->workers_start($self, 1);
 730         $lei->{wq1} = $self;
 731         $self->wq_io_do('do_mirror', []);
 732         $self->wq_close;
 733         $lei->wait_wq_events($op_c, $ops);
 734 }
 735
 736 sub ipc_atfork_child {
 737         my ($self) = @_;
 738         $self->{lei}->_lei_atfork_child;
 739         $self->SUPER::ipc_atfork_child;
 740 }
 741
 742 sub write_makefile {
 743         my ($dir, $ibx_ver) = @_;
 744         my $f = "$dir/Makefile";
 745         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
 746                 print $fh <<EOM or die "print($f) $!";
 747 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
 748 # manpage for more information on the format.  This Makefile is
 749 # intended as a familiar wrapper for users unfamiliar with
 750 # public-inbox-* commands.
 751 #
 752 # See the respective manpages for public-inbox-fetch(1),
 753 # public-inbox-index(1), etc for more information on
 754 # some of the commands used by this Makefile.
 755 #
 756 # This Makefile will not be modified nor read by public-inbox,
 757 # so you may edit it freely with your own convenience targets
 758 # and notes.  public-inbox-fetch will recreate it if removed.
 759 EOM
 760                 print $fh <<'EOM' or die "print($f): $!";
 761 # the default target:
 762 help :
 763         @echo Common targets:
 764         @echo '    make fetch        - fetch from remote git repostorie(s)'
 765         @echo '    make update       - fetch and update index '
 766         @echo
 767         @echo Rarely needed targets:
 768         @echo '    make reindex      - may be needed for new features/bugfixes'
 769         @echo '    make compact      - rewrite Xapian storage to save space'
 770         @echo '    make index        - initial index after clone
 771
 772 fetch :
 773         public-inbox-fetch
 774 update :
 775         @if ! public-inbox-fetch --exit-code; \
 776         then \
 777                 c=$$?; \
 778                 test $$c -eq 127 && exit 0; \
 779                 exit $$c; \
 780         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
 781         then \
 782                 public-inbox-index; \
 783         else \
 784                 echo 'public-inbox index not initialized'; \
 785                 echo 'see public-inbox-index(1) man page'; \
 786         fi
 787 index :
 788         public-inbox-index
 789 reindex :
 790         public-inbox-index --reindex
 791 compact :
 792         public-inbox-compact
 793
 794 .PHONY : help fetch update index reindex compact
 795 EOM
 796                 close $fh or die "close($f): $!";
 797         } else {
 798                 die "open($f): $!" unless $!{EEXIST};
 799         }
 800 }
 801
 802 1;