lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::LeiCurl;
  20 use PublicInbox::OnDestroy;
  21 use Digest::SHA qw(sha256_hex);
  22
  23 our $LIVE; # pid => callback
  24 my $update_ref_stdin = $ENV{GIT_CAN_UPDATE_REF_STDIN} // 1;
  25
  26 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  27         my ($arg, $pid) = @_;
  28         my ($mrr, $lei) = @$arg;
  29         my $f = "$mrr->{dst}/mirror.done";
  30         if ($?) {
  31                 $lei->child_error($?);
  32         } elsif (!$mrr->{dry_run} && !unlink($f)) {
  33                 warn("unlink($f): $!\n") unless $!{ENOENT};
  34         } else {
  35                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  36                         require PublicInbox::LeiAddExternal;
  37                         PublicInbox::LeiAddExternal::_finish_add_external(
  38                                                         $lei, $mrr->{dst});
  39                 }
  40                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  41         }
  42         $lei->dclose;
  43 }
  44
  45 # for old installations without manifest.js.gz
  46 sub try_scrape {
  47         my ($self, $fallback_manifest) = @_;
  48         my $uri = URI->new($self->{src});
  49         my $lei = $self->{lei};
  50         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  51         my $cmd = $curl->for_uri($lei, $uri, qw(-f --compressed));
  52         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  53         my $fh = popen_rd($cmd, undef, $opt);
  54         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  55         close($fh) or return $lei->child_error($?, "@$cmd failed");
  56
  57         # we grep with URL below, we don't want Subject/From headers
  58         # making us clone random URLs.  This assumes remote instances
  59         # prior to public-inbox 1.7.0
  60         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  61         my @html = split(/<hr>/, $html);
  62         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  63         if (!@urls && $fallback_manifest) {
  64                 warn <<EOM;
  65 W: failed to extract URLs from $uri, trying manifest.js.gz...
  66 EOM
  67                 return start_clone_url($self);
  68         }
  69         my $url = $uri->as_string;
  70         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  71
  72         # since this is for old instances w/o manifest.js.gz, try v1 first
  73         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  74         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  75                 my %v2_epochs = map {
  76                         my ($n) = (m!/([0-9]+)\z!);
  77                         $n => [ URI->new($_), '' ]
  78                 } @v2_urls; # uniq
  79                 clone_v2_prep($self, \%v2_epochs);
  80                 delete local $lei->{opt}->{epoch};
  81                 clone_all($self);
  82                 return;
  83         }
  84
  85         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  86         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  87                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  88                 die <<"";
  89 E: confused by scraping <$uri>, did you mean <$url>?
  90
  91         }
  92         @urls and die <<"";
  93 E: confused by scraping <$uri>, got ambiguous results:
  94 @urls
  95
  96         die "E: scraping <$uri> revealed nothing\n";
  97 }
  98
  99 sub clone_cmd {
 100         my ($lei, $opt) = @_;
 101         my @cmd = qw(git);
 102         $opt->{$_} = $lei->{$_} for (0..2);
 103         # we support "-c $key=$val" for arbitrary git config options
 104         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 105         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 106         push @cmd, qw(clone --mirror);
 107         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 108                         ($lei->{opt}->{jobs} // 1) > 1;
 109         push @cmd, '-v' if $lei->{opt}->{verbose};
 110         # XXX any other options to support?
 111         # --reference is tricky with multiple epochs, but handled
 112         # automatically if using manifest.js.gz
 113         @cmd;
 114 }
 115
 116 sub ft_rename ($$$;$) {
 117         my ($ft, $dst, $open_mode, $fh) = @_;
 118         my @st = stat($fh // $dst);
 119         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 120         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 121         require File::Copy;
 122         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 123         $ft->unlink_on_destroy(0);
 124 }
 125
 126 sub do_reap ($;$) {
 127         my ($self, $jobs) = @_;
 128         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 129         $jobs = 1 if $jobs < 1;
 130         while (keys(%$LIVE) >= $jobs) {
 131                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 132                 if (my $x = delete $LIVE->{$pid}) {
 133                         my $cb = shift @$x;
 134                         $cb->(@$x) if $cb;
 135                 } else {
 136                         warn "reaped unknown PID=$pid ($?)\n";
 137                 }
 138         }
 139 }
 140
 141 sub _get_txt_start { # non-fatal
 142         my ($self, $endpoint, $fini) = @_;
 143         my $uri = URI->new($self->{cur_src} // $self->{src});
 144         my $lei = $self->{lei};
 145         my $path = $uri->path;
 146         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 147         $uri->path("$path/$endpoint");
 148         my $f = (split(m!/!, $endpoint))[-1];
 149         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 150         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 151         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(-f --compressed -R -o),
 152                                         $ft->filename);
 153         do_reap($self);
 154         $lei->qerr("# @$cmd");
 155         return if $self->{dry_run};
 156         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 157         $LIVE->{spawn($cmd, undef, $opt)} =
 158                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 159 }
 160
 161 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 162         my ($self, $endpoint) = @_;
 163         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 164         my $cerr = $?;
 165         $? = 0; # don't influence normal lei exit
 166         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 167         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 168         seek($fh, SEEK_SET, 0) or die "seek: $!";
 169         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 170         local $/;
 171         $self->{"txt.$endpoint"} = <$fh>;
 172         undef; # success
 173 }
 174
 175 sub _write_inbox_config {
 176         my ($self) = @_;
 177         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 178         my $dst = $self->{cur_dst} // $self->{dst};
 179         my $f = "$dst/inbox.config.example";
 180         open my $fh, '>', $f or die "open($f): $!";
 181         print $fh $buf or die "print: $!";
 182         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 183         my $mtime = delete $self->{'mtime._/text/config/raw'};
 184         $fh->flush or die "flush($f): $!";
 185         if (defined $mtime) {
 186                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
 187         }
 188         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 189         my $ibx = $self->{ibx} = {};
 190         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 191                 for (qw(address newsgroup nntpmirror)) {
 192                         $ibx->{$_} = $cfg->{"$sec.$_"};
 193                 }
 194         }
 195 }
 196
 197 sub set_description ($) {
 198         my ($self) = @_;
 199         my $dst = $self->{cur_dst} // $self->{dst};
 200         my $f = "$dst/description";
 201         open my $fh, '+>>', $f or die "open($f): $!";
 202         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 203         my $d = do { local $/; <$fh> } // die "read($f): $!";
 204         chomp(my $orig = $d);
 205         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 206                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 207                 $d = delete($self->{'txt.description'});
 208         }
 209         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 210         chomp $d;
 211         return if $d eq $orig;
 212         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 213         truncate($fh, 0) or die "truncate($f): $!";
 214         print $fh $d, "\n" or die "print($f): $!";
 215         close $fh or die "close($f): $!";
 216 }
 217
 218 sub index_cloned_inbox {
 219         my ($self, $iv) = @_;
 220         my $lei = $self->{lei};
 221
 222         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 223         # lei is useless without Xapian + SQLite
 224         if ($lei->{cmd} ne 'public-inbox-clone') {
 225                 require PublicInbox::InboxWritable;
 226                 require PublicInbox::Admin;
 227                 my $ibx = delete($self->{ibx}) // {
 228                         address => [ 'lei@example.com' ],
 229                         version => $iv,
 230                 };
 231                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 232                 PublicInbox::Inbox->new($ibx);
 233                 PublicInbox::InboxWritable->new($ibx);
 234                 my $opt = {};
 235                 for my $sw ($lei->index_opt) {
 236                         my ($k) = ($sw =~ /\A([\w-]+)/);
 237                         $opt->{$k} = $lei->{opt}->{$k};
 238                 }
 239                 # force synchronous dwaitpid for v2:
 240                 local $PublicInbox::DS::in_loop = 0;
 241                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 242                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 243                 local %ENV = (%ENV, %$env) if $env;
 244                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 245                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 246         }
 247         return if defined $self->{cur_dst}; # one of many repos to clone
 248         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 249 }
 250
 251 sub run_reap {
 252         my ($lei, $cmd, $opt) = @_;
 253         $lei->qerr("# @$cmd");
 254         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 255         my $ret = $?;
 256         $? = 0; # don't let it influence normal exit
 257         $ret;
 258 }
 259
 260 sub start_clone {
 261         my ($self, $cmd, $opt, $fini) = @_;
 262         do_reap($self);
 263         $self->{lei}->qerr("# @$cmd");
 264         return if $self->{dry_run};
 265         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 266 }
 267
 268 sub fetch_args ($$) {
 269         my ($lei, $opt) = @_;
 270         my @cmd; # (git --git-dir=...) to be added by caller
 271         $opt->{$_} = $lei->{$_} for (0..2);
 272         # we support "-c $key=$val" for arbitrary git config options
 273         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 274         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 275         push @cmd, 'fetch';
 276         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 277                         ($lei->{opt}->{jobs} // 1) > 1;
 278         push @cmd, '-v' if $lei->{opt}->{verbose};
 279         @cmd;
 280 }
 281
 282 sub fgrp_update_old ($) { # for git <1.8.5
 283         my ($fgrp) = @_;
 284         my $cmd = [ @{$fgrp->{-torsocks}}, 'git', "--git-dir=$fgrp->{cur_dst}",
 285                 fetch_args($fgrp->{lei}, my $opt = {}) ];
 286         $fgrp->{lei}->qerr("# @$cmd");
 287         do_reap($fgrp);
 288         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $fgrp, $cmd ];
 289 }
 290
 291 sub upr { # feed `git update-ref --stdin -z' verbosely
 292         my ($lei, $w, $op, $ref, $oid) = @_;
 293         $lei->qerr("# $op $ref $oid") if $lei->{opt}->{verbose};
 294         print $w "$op $ref\0$oid\0" or die "print(w): $!";
 295 }
 296
 297 sub fgrp_update {
 298         my ($fgrp) = @_;
 299         my $srcfh = delete $fgrp->{srcfh} or return;
 300         my $dstfh = delete $fgrp->{dstfh} or return;
 301         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 302         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 303         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 304         close $srcfh;
 305         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 306         close $dstfh;
 307         pipe(my ($r, $w)) or die "pipe: $!";
 308         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 309                 qw(update-ref --stdin -z) ];
 310         my $lei = $fgrp->{lei};
 311         $lei->qerr("# @$cmd");
 312         my $opt = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 313         my $pid = spawn($cmd, undef, $opt);
 314         close $r or die "close(r): $!";
 315         for my $ref (keys %dst) {
 316                 my $new = delete $src{$ref};
 317                 my $old = $dst{$ref};
 318                 if (defined $new) {
 319                         upr($lei, $w, 'update', $ref, $new) if $new ne $old;
 320                 } else {
 321                         upr($lei, $w, 'delete', $ref, $old);
 322                 }
 323         }
 324         while (my ($ref, $oid) = each %src) {
 325                 upr($lei, $w, 'create', $ref, $oid);
 326         }
 327         if (close($w)) { # git >= 1.8.5
 328                 $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd ];
 329                 do_reap($fgrp);
 330         } else { # git <1.8.5 w/o update-ref --stdin
 331                 warn "E: close(update-ref --stdin): $!\n";
 332                 $update_ref_stdin = 0;
 333                 waitpid($pid, 0) // die "waitpid(update-ref --stdin): $!";
 334                 fgrp_update_old($fgrp);
 335         }
 336 }
 337
 338 sub pack_refs {
 339         my ($self, $git_dir) = @_;
 340         do_reap($self);
 341         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 342         $self->{lei}->qerr("# @$cmd");
 343         my $opt = { 1 => $self->{lei}->{1}, 2 => $self->{lei}->{2} };
 344         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd ];
 345 }
 346
 347 sub fgrp_fetched {
 348         my ($fgrp) = @_;
 349         return if $fgrp->{dry_run} || !$LIVE;
 350         my $rn = $fgrp->{-remote};
 351         my %opt = map { $_ => $fgrp->{lei}->{$_} } (0..2);
 352         pack_refs($fgrp, $fgrp->{-osdir}); # objstore refs always packed
 353
 354         $update_ref_stdin or return fgrp_update_old($fgrp);
 355
 356         my $update_ref = PublicInbox::OnDestroy->new($$, \&fgrp_update, $fgrp);
 357
 358         my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 359                 "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 360                 "refs/remotes/$rn/" ];
 361         do_reap($fgrp);
 362         open($fgrp->{srcfh}, '+>', undef) or die "open(src): $!";
 363         $fgrp->{lei}->qerr("# @$src >SRC");
 364         my $pid = spawn($src, undef, { %opt, 1 => $fgrp->{srcfh} });
 365         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $src, $update_ref ];
 366
 367         my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 368                 '--format=%(refname)%00%(objectname)' ];
 369         do_reap($fgrp);
 370         open($fgrp->{dstfh}, '+>', undef) or die "open(dst): $!";
 371         $fgrp->{lei}->qerr("# @$dst >DST");
 372         $pid = spawn($dst, undef, { %opt, 1 => $fgrp->{dstfh} });
 373         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $dst, $update_ref ];
 374 }
 375
 376 sub fgrp_fetch {
 377         my ($fgrp, $fini) = @_;
 378         my $cmd = [ @{$fgrp->{-torsocks}}, 'git', "--git-dir=$fgrp->{-osdir}",
 379                         fetch_args($fgrp->{lei}, my $opt = {}), '--no-tags',
 380                         $fgrp->{-remote} ];
 381         $fgrp->{-fini} = $fini;
 382         do_reap($fgrp);
 383         $fgrp->{lei}->qerr("# @$cmd");
 384         return if $fgrp->{dry_run};
 385         my $fgrp_fini = PublicInbox::OnDestroy->new($$, \&fgrp_fetched, $fgrp);
 386         my $pid = spawn($cmd, undef, $opt);
 387         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd, $fgrp_fini ];
 388 }
 389
 390 # keep this idempotent for future use by public-inbox-fetch
 391 sub forkgroup_prep {
 392         my ($self, $uri) = @_;
 393         $self->{-ent} // return;
 394         my $os = $self->{-objstore} // return;
 395         my $fg = $self->{-ent}->{forkgroup} // return;
 396         my $dir = "$os/$fg.git";
 397         my @cmd = ('git', "--git-dir=$dir", 'config');
 398         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 399         if (!-d $dir) {
 400                 PublicInbox::Import::init_bare($dir);
 401                 for ('repack.useDeltaIslands=true',
 402                                 'pack.island=refs/remotes/([^/]+)/') {
 403                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
 404                 }
 405         }
 406         my $key = $self->{-key} // die 'BUG: no -key';
 407         my ($bn) = ($key =~ m{/([a-z0-9_,;=!\+\{\}\|][^/]*)(?:\.git)?\z}i);
 408         my $rn = "$bn-".substr(sha256_hex($key), 0, 16);
 409         # --no-tags is required to avoid conflicts
 410         for ("url=$uri", "fetch=+refs/*:refs/remotes/$rn/*",
 411                         'tagopt=--no-tags') {
 412                 my @kv = split(/=/, $_, 2);
 413                 $kv[0] = "remote.$rn.$kv[0]";
 414                 run_die([@cmd, @kv], undef, $opt);
 415         }
 416         $self->{-do_pack_refs} = 1; # likely coderepo
 417         if (!-d $self->{cur_dst}) {
 418                 my $alt = File::Spec->rel2abs("$dir/objects");
 419                 PublicInbox::Import::init_bare($self->{cur_dst});
 420                 my $o = "$self->{cur_dst}/objects";
 421                 my $f = "$o/info/alternates";
 422                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 423                 open my $fh, '+>>', $f or die "open($f): $!";
 424                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 425                 chomp(my @cur = <$fh>);
 426                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 427                         say $fh $l or die "say($f): $!";
 428                 }
 429                 close $fh or die "close($f): $!";
 430                 @cmd = ('git', "--git-dir=$self->{cur_dst}",
 431                         qw(remote add --mirror=fetch origin), "$uri");
 432                 my $pid = spawn(\@cmd, undef, $opt);
 433                 waitpid($pid, 0) // die "waitpid(@cmd): $!";
 434                 die "E: @cmd: \$?=$?" if ($? && ($? >> 8) != 3);
 435         }
 436         bless { %$self, -osdir => $dir, -remote => $rn }, __PACKAGE__;
 437 }
 438
 439 sub clone_v1 {
 440         my ($self, $nohang) = @_;
 441         my $lei = $self->{lei};
 442         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 443         my $uri = URI->new($self->{cur_src} // $self->{src});
 444         defined($lei->{opt}->{epoch}) and
 445                 die "$uri is a v1 inbox, --epoch is not supported\n";
 446         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 447         my $dst = $self->{cur_dst} // $self->{dst};
 448         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 449         my $cmd = [ @{$self->{-torsocks}}, clone_cmd($lei, my $opt = {}),
 450                 "$uri", $dst ];
 451         my $fgrp = forkgroup_prep($self, $uri);
 452         if (!defined($fgrp) && defined($self->{-ent})) {
 453                 if (defined(my $ref = $self->{-ent}->{reference})) {
 454                         -e "$self->{dst}$ref" and
 455                                 push @$cmd, '--reference', "$self->{dst}$ref";
 456                 }
 457         }
 458         $fgrp ? fgrp_fetch($fgrp, $fini) :
 459                 start_clone($self, $cmd, $opt, $fini);
 460
 461         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 462                                 /\A(?:always|v1)\z/s) {
 463                 _get_txt_start($self, '_/text/config/raw', $fini);
 464         }
 465
 466         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 467         $self->{'txt.description'} = $d if defined $d;
 468         (!defined($d) && !$nohang) and
 469                 _get_txt_start($self, 'description', $fini);
 470
 471         $nohang or do_reap($self, 1); # for non-manifest clone
 472 }
 473
 474 sub parse_epochs ($$) {
 475         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 476         $opt_epochs // return; # undef => all epochs
 477         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 478         undef($lo) if ($lo // '') eq '';
 479         my $re = qr/\A~?[0-9]+\z/;
 480         if (@extra || (($lo // '0') !~ $re) ||
 481                         (($hi // '0') !~ $re) ||
 482                         !(grep(defined, $lo, $hi))) {
 483                 die <<EOM;
 484 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 485 EOM
 486         }
 487         my @n = sort { $a <=> $b } keys %$v2_epochs;
 488         for (grep(defined, $lo, $hi)) {
 489                 if (/\A[0-9]+\z/) {
 490                         $_ > $n[-1] and die
 491 "`$_' exceeds maximum available epoch ($n[-1])\n";
 492                         $_ < $n[0] and die
 493 "`$_' is lower than minimum available epoch ($n[0])\n";
 494                 } elsif (/\A~([0-9]+)/) {
 495                         my $off = -$1 - 1;
 496                         $n[$off] // die "`$_' is out of range\n";
 497                         $_ = $n[$off];
 498                 } else { die "`$_' not understood\n" }
 499         }
 500         defined($lo) && defined($hi) && $lo > $hi and die
 501 "low value (`$lo') exceeds high (`$hi')\n";
 502         $lo //= $n[0] if $dotdot;
 503         $hi //= $n[-1] if $dotdot;
 504         $hi //= $lo;
 505         my $want = {};
 506         for ($lo..$hi) {
 507                 if (defined $v2_epochs->{$_}) {
 508                         $want->{$_} = 1;
 509                 } else {
 510                         warn
 511 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 512                 }
 513         }
 514         $want
 515 }
 516
 517 sub init_placeholder ($$$) {
 518         my ($src, $edst, $ent) = @_;
 519         PublicInbox::Import::init_bare($edst);
 520         my $f = "$edst/config";
 521         open my $fh, '>>', $f or die "open($f): $!";
 522         print $fh <<EOM or die "print($f): $!";
 523 [remote "origin"]
 524         url = $src
 525         fetch = +refs/*:refs/*
 526         mirror = true
 527
 528 ; This git epoch was created read-only and "public-inbox-fetch"
 529 ; will not fetch updates for it unless write permission is added.
 530 ; Hint: chmod +w $edst
 531 EOM
 532         if (defined($ent->{owner})) {
 533                 print $fh <<EOM or die "print($f): $!";
 534 [gitweb]
 535         owner = $ent->{owner}
 536 EOM
 537         }
 538         close $fh or die "close($f): $!";
 539         my %map = (head => 'HEAD', description => undef);
 540         while (my ($key, $fn) = each %map) {
 541                 my $val = $ent->{$key} // next;
 542                 $fn //= $key;
 543                 $fn = "$edst/$fn";
 544                 open $fh, '>', $fn or die "open($fn): $!";
 545                 print $fh $val, "\n" or die "print($fn): $!";
 546                 close $fh or die "close($fn): $!";
 547         }
 548 }
 549
 550 sub reap_cmd { # async, called via SIGCHLD
 551         my ($self, $cmd) = @_;
 552         my $cerr = $?;
 553         $? = 0; # don't let it influence normal exit
 554         if ($cerr) {
 555                 kill('TERM', keys %$LIVE);
 556                 $self->{lei}->child_error($cerr, "@$cmd failed");
 557         }
 558 }
 559
 560 sub v1_done { # called via OnDestroy
 561         my ($self) = @_;
 562         return if $self->{dry_run} || !$LIVE;
 563         _write_inbox_config($self);
 564         my $dst = $self->{cur_dst} // $self->{dst};
 565         if (defined(my $o = $self->{-ent} ? $self->{-ent}->{owner} : undef)) {
 566                 run_die([qw(git config -f), "$dst/config", 'gitweb.owner', $o]);
 567         }
 568         my $o = "$dst/objects";
 569         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
 570                 my $base = File::Spec->rel2abs($o);
 571                 my @l = <$fh>;
 572                 my $ft;
 573                 for (@l) {
 574                         next unless m!\A/!;
 575                         $_ = File::Spec->abs2rel($_, $base);
 576                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
 577                                                 DIR => "$o/info");
 578                 }
 579                 if ($ft) {
 580                         print $ft @l or die "print($ft): $!";
 581                         $ft->flush or die "flush($ft): $!";
 582                         ft_rename($ft, $fn, 0666, $fh);
 583                 }
 584         }
 585         pack_refs($self, $dst) if delete $self->{-do_pack_refs};
 586         eval { set_description($self) };
 587         warn $@ if $@;
 588         return if ($self->{-is_epoch} ||
 589                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 590         write_makefile($dst, 1);
 591         index_cloned_inbox($self, 1);
 592 }
 593
 594 sub v2_done { # called via OnDestroy
 595         my ($self) = @_;
 596         return if $self->{dry_run} || !$LIVE;
 597         my $dst = $self->{cur_dst} // $self->{dst};
 598         require PublicInbox::Lock;
 599         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 600         my $lck = $lk->lock_for_scope($$);
 601         _write_inbox_config($self);
 602         require PublicInbox::MultiGit;
 603         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 604         $mg->fill_alternates;
 605         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 606         for my $edst (@{delete($self->{-read_only}) // []}) {
 607                 my @st = stat($edst) or die "stat($edst): $!";
 608                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 609         }
 610         write_makefile($dst, 2);
 611         undef $lck; # unlock
 612         eval { set_description($self) };
 613         warn $@ if $@;
 614         index_cloned_inbox($self, 2);
 615 }
 616
 617 sub clone_v2_prep ($$;$) {
 618         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 619         my $lei = $self->{lei};
 620         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 621         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 622         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 623         my $dst = $self->{cur_dst} // $self->{dst};
 624         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 625         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 626         delete $task->{todo}; # $self->{todo} still exists
 627         my (@skip, $desc);
 628         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 629         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 630                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 631                 my $src = $uri->as_string;
 632                 my $edst = $dst;
 633                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 634 failed to extract epoch number from $src
 635
 636                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 637                 $edst .= "/git/$nr.git";
 638                 my $ent;
 639                 if ($m) {
 640                         $ent = $m->{$key} //
 641                                 die("BUG: `$key' not in manifest.js.gz");
 642                         if (defined(my $d = $ent->{description})) {
 643                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 644                                 $desc = $d;
 645                         }
 646                 }
 647                 if (!$want || $want->{$nr}) {
 648                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 649                         $etask->{-ent} = $ent; # may have {reference}
 650                         $etask->{cur_src} = $src;
 651                         $etask->{cur_dst} = $edst;
 652                         $etask->{-is_epoch} = $fini;
 653                         my $ref = $ent->{reference} // '';
 654                         push @{$self->{todo}->{$ref}}, $etask;
 655                         $self->{any_want}->{$key} = 1;
 656                 } else { # create a placeholder so users only need to chmod +w
 657                         init_placeholder($src, $edst, $ent);
 658                         push @{$task->{-read_only}}, $edst;
 659                         push @skip, $key;
 660                 }
 661         }
 662         # filter out the epochs we skipped
 663         $self->{-culled_manifest} = 1 if $m && delete(@$m{@skip});
 664
 665         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 666
 667         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 668                 _get_txt_start($task, '_/text/config/raw', $fini);
 669
 670         defined($desc) ? ($task->{'txt.description'} = $desc) :
 671                 _get_txt_start($task, 'description', $fini);
 672 }
 673
 674 sub decode_manifest ($$$) {
 675         my ($fh, $fn, $uri) = @_;
 676         my $js;
 677         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 678         gunzip(\$gz => \$js, MultiStream => 1) or
 679                 die "gunzip($uri): $GunzipError\n";
 680         my $m = eval { PublicInbox::Config->json->decode($js) };
 681         die "$uri: error decoding `$js': $@\n" if $@;
 682         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 683         $m;
 684 }
 685
 686 sub multi_inbox ($$$) {
 687         my ($self, $path, $m) = @_;
 688         my $incl = $self->{lei}->{opt}->{include};
 689         my $excl = $self->{lei}->{opt}->{exclude};
 690
 691         # assuming everything not v2 is v1, for now
 692         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 693         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 694         my $v2 = {};
 695
 696         for (@v2_epochs) {
 697                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 698                 push @{$v2->{$1}}, $_;
 699         }
 700         my $n = scalar(keys %$v2) + scalar(@v1);
 701         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 702         if (defined $incl) {
 703                 my $re = '(?:'.join('\\z|', map {
 704                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 705                         } @$incl).'\\z)';
 706                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 707                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 708                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
 709                 @v1 = grep(/$re/, @v1);
 710         }
 711         if (defined $excl) {
 712                 my $re = '(?:'.join('\\z|', map {
 713                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 714                         } @$excl).'\\z)';
 715                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 716                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 717                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
 718                 @v1 = grep(!/$re/, @v1);
 719         }
 720         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 721         $ret->{v1} = \@v1 if @v1;
 722         $ret->{v2} = $v2 if keys %$v2;
 723         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 724                                 join("\n\t", sort @orig)
 725                         : "Nothing available to clone\n";
 726         my $path_pfx = '';
 727
 728         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 729         if (@v2_epochs) {
 730                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 731                                 @v2_epochs) == @v2_epochs) {
 732                         $$path =~ s!\A(/[^/]+)/!/! or last;
 733                         $path_pfx .= $1;
 734                 }
 735         } elsif (@v1) {
 736                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 737                         $path_pfx .= $1;
 738                 }
 739         }
 740         ($path_pfx, $n, $ret);
 741 }
 742
 743 sub clone_all {
 744         my ($self, $m) = @_;
 745         my $todo = delete $self->{todo};
 746         my $nodep = delete $todo->{''};
 747
 748         # do not download unwanted deps
 749         my $any_want = delete $self->{any_want};
 750         my @unwanted = grep { !$any_want->{$_} } keys %$todo;
 751         my @nodep = delete(@$todo{@unwanted});
 752         push(@$nodep, @$_) for @nodep;
 753
 754         # handle no-dependency repos, first
 755         for (@$nodep) {
 756                 clone_v1($_, 1);
 757                 return if $self->{lei}->{child_error};
 758         }
 759         # resolve references, deepest, first:
 760         while (scalar keys %$todo) {
 761                 for my $x (keys %$todo) {
 762                         my ($nr, $nxt);
 763                         # resolve multi-level references
 764                         while ($m && defined($nxt = $m->{$x}->{reference})) {
 765                                 exists($todo->{$nxt}) or last;
 766                                 die <<EOM if ++$nr > 1000;
 767 E: dependency loop detected (`$x' => `$nxt')
 768 EOM
 769                                 $x = $nxt;
 770                         }
 771                         my $y = delete $todo->{$x} // next; # already done
 772                         for (@$y) {
 773                                 clone_v1($_, 1);
 774                                 return if $self->{lei}->{child_error};
 775                         }
 776                         last; # restart %$todo iteration
 777                 }
 778         }
 779         do_reap($self, 1);
 780 }
 781
 782 sub dump_manifest ($$) {
 783         my ($m, $ft) = @_;
 784         # write the smaller manifest if epochs were skipped so
 785         # users won't have to delete manifest if they +w an
 786         # epoch they no longer want to skip
 787         my $json = PublicInbox::Config->json->encode($m);
 788         my $mtime = (stat($ft))[9];
 789         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
 790         truncate($ft, 0) or die "truncate($ft): $!";
 791         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
 792         $ft->flush or die "flush($ft): $!";
 793         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
 794 }
 795
 796 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
 797 sub try_manifest {
 798         my ($self) = @_;
 799         my $uri = URI->new($self->{src});
 800         my $lei = $self->{lei};
 801         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 802         my $path = $uri->path;
 803         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 804         $uri->path($path . '/manifest.js.gz');
 805         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX',
 806                                 UNLINK => 1, TMPDIR => 1, SUFFIX => '.tmp');
 807         my $cmd = $curl->for_uri($lei, $uri, qw(-f -R -o), $ft->filename);
 808         my %opt = map { $_ => $lei->{$_} } (0..2);
 809         my $cerr = run_reap($lei, $cmd, \%opt);
 810         if ($cerr) {
 811                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
 812                 return $lei->child_error($cerr, "@$cmd failed");
 813         }
 814         my $m = eval { decode_manifest($ft, $ft, $uri) };
 815         if ($@) {
 816                 warn $@;
 817                 return try_scrape($self);
 818         }
 819         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
 820         return $lei->child_error(1, $multi) if !ref($multi);
 821         my $v2 = delete $multi->{v2};
 822         local $self->{todo} = {};
 823         if ($v2) {
 824                 for my $name (sort keys %$v2) {
 825                         my $epochs = delete $v2->{$name};
 826                         my %v2_epochs = map {
 827                                 $uri->path($n > 1 ? $path_pfx.$path.$_
 828                                                 : $path_pfx.$_);
 829                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
 830                                 $e // die "no [0-9]+\.git in `$uri'";
 831                                 $e => [ $uri->clone, $_ ];
 832                         } @$epochs;
 833                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
 834                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
 835                         local $self->{cur_src} = $1;
 836                         local $self->{cur_dst} = $self->{dst};
 837                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
 838                                                         git/[0-9]+\.git\z!x) {
 839                                 $self->{cur_dst} .= "/$1";
 840                         }
 841                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
 842 E: `$self->{cur_dst}' must not contain newline
 843 EOM
 844                         clone_v2_prep($self, \%v2_epochs, $m);
 845                         return if $self->{lei}->{child_error};
 846                 }
 847         }
 848         if (my $v1 = delete $multi->{v1}) {
 849                 my $p = $path_pfx.$path;
 850                 chop($p) if substr($p, -1, 1) eq '/';
 851                 $uri->path($p);
 852                 for my $name (@$v1) {
 853                         my $task = bless { %$self }, __PACKAGE__;
 854                         $task->{-ent} = $m->{$name} //
 855                                         die("BUG: no `$name' in manifest");
 856                         $task->{cur_src} = "$uri";
 857                         $task->{cur_dst} = $task->{dst};
 858                         $task->{-key} = $name;
 859                         if ($n > 1) {
 860                                 $task->{cur_dst} .= $name;
 861                                 $task->{cur_src} .= $name;
 862                         }
 863                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
 864 E: `$task->{cur_dst}' must not contain newline
 865 EOM
 866                         $task->{cur_src} .= '/';
 867                         my $dep = $task->{-ent}->{reference} // '';
 868                         push @{$self->{todo}->{$dep}}, $task; # for clone_all
 869                         $self->{any_want}->{$name} = 1;
 870                 }
 871         }
 872         delete local $lei->{opt}->{epoch} if defined($v2);
 873         clone_all($self, $m);
 874         return if $self->{lei}->{child_error} || $self->{dry_run};
 875
 876         # set by clone_v2_prep/-I/--exclude
 877         dump_manifest($m => $ft) if delete $self->{-culled_manifest};
 878         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
 879         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 880 }
 881
 882 sub start_clone_url {
 883         my ($self) = @_;
 884         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 885         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 886 }
 887
 888 sub do_mirror { # via wq_io_do or public-inbox-clone
 889         my ($self) = @_;
 890         my $lei = $self->{lei};
 891         umask($lei->{client_umask}) if defined $lei->{client_umask};
 892         eval {
 893                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
 894                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
 895 --inbox-config must be one of `always', `v2', `v1', or `never'
 896
 897                 if (defined(my $os = $lei->{opt}->{objstore})) {
 898                         $os = 'objstore' if $os eq ''; # --objstore w/o args
 899                         $os = "$self->{dst}/$os" if $os !~ m!\A/!;
 900                         $self->{-objstore} = $os;
 901                 }
 902                 local $LIVE;
 903                 my $iv = $lei->{opt}->{'inbox-version'} //
 904                         return start_clone_url($self);
 905                 return clone_v1($self) if $iv == 1;
 906                 die "bad --inbox-version=$iv\n" if $iv != 2;
 907                 die <<EOM if $self->{src} !~ m!://!;
 908 cloning local v2 inboxes not supported
 909 EOM
 910                 try_scrape($self, 1);
 911         };
 912         $lei->fail($@) if $@;
 913 }
 914
 915 sub start {
 916         my ($cls, $lei, $src, $dst) = @_;
 917         my $self = bless { src => $src, dst => $dst }, $cls;
 918         $lei->request_umask;
 919         my ($op_c, $ops) = $lei->workers_start($self, 1);
 920         $lei->{wq1} = $self;
 921         $self->wq_io_do('do_mirror', []);
 922         $self->wq_close;
 923         $lei->wait_wq_events($op_c, $ops);
 924 }
 925
 926 sub ipc_atfork_child {
 927         my ($self) = @_;
 928         $self->{lei}->_lei_atfork_child;
 929         $self->SUPER::ipc_atfork_child;
 930 }
 931
 932 sub write_makefile {
 933         my ($dir, $ibx_ver) = @_;
 934         my $f = "$dir/Makefile";
 935         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
 936                 print $fh <<EOM or die "print($f) $!";
 937 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
 938 # manpage for more information on the format.  This Makefile is
 939 # intended as a familiar wrapper for users unfamiliar with
 940 # public-inbox-* commands.
 941 #
 942 # See the respective manpages for public-inbox-fetch(1),
 943 # public-inbox-index(1), etc for more information on
 944 # some of the commands used by this Makefile.
 945 #
 946 # This Makefile will not be modified nor read by public-inbox,
 947 # so you may edit it freely with your own convenience targets
 948 # and notes.  public-inbox-fetch will recreate it if removed.
 949 EOM
 950                 print $fh <<'EOM' or die "print($f): $!";
 951 # the default target:
 952 help :
 953         @echo Common targets:
 954         @echo '    make fetch        - fetch from remote git repostorie(s)'
 955         @echo '    make update       - fetch and update index '
 956         @echo
 957         @echo Rarely needed targets:
 958         @echo '    make reindex      - may be needed for new features/bugfixes'
 959         @echo '    make compact      - rewrite Xapian storage to save space'
 960         @echo '    make index        - initial index after clone
 961
 962 fetch :
 963         public-inbox-fetch
 964 update :
 965         @if ! public-inbox-fetch --exit-code; \
 966         then \
 967                 c=$$?; \
 968                 test $$c -eq 127 && exit 0; \
 969                 exit $$c; \
 970         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
 971         then \
 972                 public-inbox-index; \
 973         else \
 974                 echo 'public-inbox index not initialized'; \
 975                 echo 'see public-inbox-index(1) man page'; \
 976         fi
 977 index :
 978         public-inbox-index
 979 reindex :
 980         public-inbox-index --reindex
 981 compact :
 982         public-inbox-compact
 983
 984 .PHONY : help fetch update index reindex compact
 985 EOM
 986                 close $fh or die "close($f): $!";
 987         } else {
 988                 die "open($f): $!" unless $!{EEXIST};
 989         }
 990 }
 991
 992 1;