lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Config;
  10 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
  11 use IO::Compress::Gzip qw(gzip $GzipError);
  12 use PublicInbox::Spawn qw(popen_rd spawn);
  13 use File::Temp ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 our %LIVE;
  17
  18 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  19         my ($arg, $pid) = @_;
  20         my ($mrr, $lei) = @$arg;
  21         my $f = "$mrr->{dst}/mirror.done";
  22         if ($?) {
  23                 $lei->child_error($?);
  24         } elsif (!unlink($f)) {
  25                 warn("unlink($f): $!\n") unless $!{ENOENT};
  26         } else {
  27                 if ($lei->{cmd} ne 'public-inbox-clone') {
  28                         # calls _finish_add_external
  29                         $lei->lazy_cb('add-external', '_finish_'
  30                                         )->($lei, $mrr->{dst});
  31                 }
  32                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  33         }
  34         $lei->dclose;
  35 }
  36
  37 # for old installations without manifest.js.gz
  38 sub try_scrape {
  39         my ($self) = @_;
  40         my $uri = URI->new($self->{src});
  41         my $lei = $self->{lei};
  42         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  43         my $cmd = $curl->for_uri($lei, $uri, '--compressed');
  44         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  45         my $fh = popen_rd($cmd, undef, $opt);
  46         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  47         close($fh) or return $lei->child_error($?, "@$cmd failed");
  48
  49         # we grep with URL below, we don't want Subject/From headers
  50         # making us clone random URLs
  51         my @html = split(/<hr>/, $html);
  52         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  53         my $url = $uri->as_string;
  54         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  55
  56         # since this is for old instances w/o manifest.js.gz, try v1 first
  57         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  58         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  59                 my %v2_epochs = map {
  60                         my ($n) = (m!/([0-9]+)\z!);
  61                         $n => [ URI->new($_), '' ]
  62                 } @v2_urls; # uniq
  63                 clone_v2($self, \%v2_epochs);
  64                 reap_live() while keys(%LIVE);
  65                 return;
  66         }
  67
  68         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  69         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  70                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  71                 die <<"";
  72 E: confused by scraping <$uri>, did you mean <$url>?
  73
  74         }
  75         @urls and die <<"";
  76 E: confused by scraping <$uri>, got ambiguous results:
  77 @urls
  78
  79         die "E: scraping <$uri> revealed nothing\n";
  80 }
  81
  82 sub clone_cmd {
  83         my ($lei, $opt) = @_;
  84         my @cmd = qw(git);
  85         $opt->{$_} = $lei->{$_} for (0..2);
  86         # we support "-c $key=$val" for arbitrary git config options
  87         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
  88         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
  89         push @cmd, qw(clone --mirror);
  90         push @cmd, '-q' if $lei->{opt}->{quiet} ||
  91                         ($lei->{opt}->{jobs} // 1) > 1;
  92         push @cmd, '-v' if $lei->{opt}->{verbose};
  93         # XXX any other options to support?
  94         # --reference is tricky with multiple epochs...
  95         @cmd;
  96 }
  97
  98 sub ft_rename ($$$) {
  99         my ($ft, $dst, $open_mode) = @_;
 100         my $fn = $ft->filename;
 101         my @st = stat($dst);
 102         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 103         chmod($mode, $ft) or croak "E: chmod $fn: $!";
 104         rename($fn, $dst) or croak "E: rename($fn => $ft): $!";
 105         $ft->unlink_on_destroy(0);
 106 }
 107
 108 sub _get_txt_start { # non-fatal
 109         my ($self, $endpoint, $fini) = @_;
 110         my $uri = URI->new($self->{cur_src} // $self->{src});
 111         my $lei = $self->{lei};
 112         my $path = $uri->path;
 113         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 114         $uri->path("$path/$endpoint");
 115         my $f = (split(m!/!, $endpoint))[-1];
 116         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 117         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 118         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(--compressed -R -o),
 119                                         $ft->filename);
 120         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 121         $lei->qerr("# @$cmd");
 122         my $jobs = $lei->{opt}->{jobs} // 1;
 123         reap_live() while keys(%LIVE) >= $jobs;
 124         $LIVE{spawn($cmd, undef, $opt)} =
 125                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 126 }
 127
 128 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 129         my ($self, $endpoint) = @_;
 130         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 131         my $cerr = $?;
 132         $? = 0; # don't influence normal lei exit
 133         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 134         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 135         seek($fh, SEEK_SET, 0) or die "seek: $!";
 136         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 137         local $/;
 138         $self->{"txt.$endpoint"} = <$fh>;
 139         undef; # success
 140 }
 141
 142 sub _write_inbox_config {
 143         my ($self) = @_;
 144         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 145         my $dst = $self->{cur_dst} // $self->{dst};
 146         my $f = "$dst/inbox.config.example";
 147         open my $fh, '>', $f or die "open($f): $!";
 148         print $fh $buf or die "print: $!";
 149         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 150         my $mtime = delete $self->{'mtime._/text/config/raw'};
 151         $fh->flush or die "flush($f): $!";
 152         if (defined $mtime) {
 153                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
 154         }
 155         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 156         my $ibx = $self->{ibx} = {};
 157         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 158                 for (qw(address newsgroup nntpmirror)) {
 159                         $ibx->{$_} = $cfg->{"$sec.$_"};
 160                 }
 161         }
 162 }
 163
 164 sub set_description ($) {
 165         my ($self) = @_;
 166         my $dst = $self->{cur_dst} // $self->{dst};
 167         my $f = "$dst/description";
 168         open my $fh, '+>>', $f or die "open($f): $!";
 169         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 170         my $d = do { local $/; <$fh> } // die "read($f): $!";
 171         my $orig = $d;
 172         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 173                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 174                 $d = delete($self->{'txt.description'});
 175         }
 176         $d //= 'mirror of '.($self->{cur_src} // $self->{src})."\n";
 177         return if $d eq $orig;
 178         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 179         truncate($fh, 0) or die "truncate($f): $!";
 180         print $fh $d or die "print($f): $!";
 181         close $fh or die "close($f): $!";
 182 }
 183
 184 sub index_cloned_inbox {
 185         my ($self, $iv) = @_;
 186         my $lei = $self->{lei};
 187         eval { set_description($self) };
 188         warn $@ if $@;
 189
 190         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 191         # lei is useless without Xapian + SQLite
 192         if ($lei->{cmd} ne 'public-inbox-clone') {
 193                 my $ibx = delete($self->{ibx}) // {
 194                         address => [ 'lei@example.com' ],
 195                         version => $iv,
 196                 };
 197                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 198                 PublicInbox::Inbox->new($ibx);
 199                 PublicInbox::InboxWritable->new($ibx);
 200                 my $opt = {};
 201                 for my $sw ($lei->index_opt) {
 202                         my ($k) = ($sw =~ /\A([\w-]+)/);
 203                         $opt->{$k} = $lei->{opt}->{$k};
 204                 }
 205                 # force synchronous dwaitpid for v2:
 206                 local $PublicInbox::DS::in_loop = 0;
 207                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 208                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 209                 local %ENV = (%ENV, %$env) if $env;
 210                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 211                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 212         }
 213         return if defined $self->{cur_dst};
 214         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 215 }
 216
 217 sub run_reap {
 218         my ($lei, $cmd, $opt) = @_;
 219         $lei->qerr("# @$cmd");
 220         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 221         my $ret = $?;
 222         $? = 0; # don't let it influence normal exit
 223         $ret;
 224 }
 225
 226 sub clone_v1 {
 227         my ($self, $nohang) = @_;
 228         my $lei = $self->{lei};
 229         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 230         my $uri = URI->new($self->{cur_src} // $self->{src});
 231         defined($lei->{opt}->{epoch}) and
 232                 die "$uri is a v1 inbox, --epoch is not supported\n";
 233         my $pfx = $curl->torsocks($lei, $uri) or return;
 234         my $dst = $self->{cur_dst} // $self->{dst};
 235         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 236         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
 237         my $cmd = [ @$pfx, clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 238         $lei->qerr("# @$cmd");
 239         $LIVE{spawn($cmd, undef, $opt)} = [ \&reap_clone, $lei, $cmd, $fini ];
 240         reap_live() while keys(%LIVE) >= $jobs;
 241
 242         _get_txt_start($self, '_/text/config/raw', $fini);
 243         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 244         defined($d) ? ($self->{'txt.description'} = $d) :
 245                 _get_txt_start($self, 'description', $fini);
 246
 247         reap_live() until ($nohang || !keys(%LIVE)); # for non-manifest clone
 248 }
 249
 250 sub parse_epochs ($$) {
 251         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 252         $opt_epochs // return; # undef => all epochs
 253         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 254         undef($lo) if ($lo // '') eq '';
 255         my $re = qr/\A~?[0-9]+\z/;
 256         if (@extra || (($lo // '0') !~ $re) ||
 257                         (($hi // '0') !~ $re) ||
 258                         !(grep(defined, $lo, $hi))) {
 259                 die <<EOM;
 260 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 261 EOM
 262         }
 263         my @n = sort { $a <=> $b } keys %$v2_epochs;
 264         for (grep(defined, $lo, $hi)) {
 265                 if (/\A[0-9]+\z/) {
 266                         $_ > $n[-1] and die
 267 "`$_' exceeds maximum available epoch ($n[-1])\n";
 268                         $_ < $n[0] and die
 269 "`$_' is lower than minimum available epoch ($n[0])\n";
 270                 } elsif (/\A~([0-9]+)/) {
 271                         my $off = -$1 - 1;
 272                         $n[$off] // die "`$_' is out of range\n";
 273                         $_ = $n[$off];
 274                 } else { die "`$_' not understood\n" }
 275         }
 276         defined($lo) && defined($hi) && $lo > $hi and die
 277 "low value (`$lo') exceeds high (`$hi')\n";
 278         $lo //= $n[0] if $dotdot;
 279         $hi //= $n[-1] if $dotdot;
 280         $hi //= $lo;
 281         my $want = {};
 282         for ($lo..$hi) {
 283                 if (defined $v2_epochs->{$_}) {
 284                         $want->{$_} = 1;
 285                 } else {
 286                         warn
 287 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 288                 }
 289         }
 290         $want
 291 }
 292
 293 sub init_placeholder ($$) {
 294         my ($src, $edst) = @_;
 295         PublicInbox::Import::init_bare($edst);
 296         my $f = "$edst/config";
 297         open my $fh, '>>', $f or die "open($f): $!";
 298         print $fh <<EOM or die "print($f): $!";
 299 [remote "origin"]
 300         url = $src
 301         fetch = +refs/*:refs/*
 302         mirror = true
 303
 304 ; This git epoch was created read-only and "public-inbox-fetch"
 305 ; will not fetch updates for it unless write permission is added.
 306 EOM
 307         close $fh or die "close:($f): $!";
 308 }
 309
 310 sub reap_clone { # async, called via SIGCHLD
 311         my ($lei, $cmd) = @_;
 312         my $cerr = $?;
 313         $? = 0; # don't let it influence normal exit
 314         if ($cerr) {
 315                 kill('TERM', keys %LIVE);
 316                 $lei->child_error($cerr, "@$cmd failed");
 317         }
 318 }
 319
 320 sub v1_done { # called via OnDestroy
 321         my ($self) = @_;
 322         _write_inbox_config($self);
 323         write_makefile($self->{cur_dst} // $self->{dst}, 1);
 324         index_cloned_inbox($self, 1);
 325 }
 326
 327 sub v2_done { # called via OnDestroy
 328         my ($self) = @_;
 329         _write_inbox_config($self);
 330         require PublicInbox::MultiGit;
 331         my $dst = $self->{cur_dst} // $self->{dst};
 332         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 333         $mg->fill_alternates;
 334         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 335         for my $edst (@{delete($self->{-read_only}) // []}) {
 336                 my @st = stat($edst) or die "stat($edst): $!";
 337                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 338         }
 339         write_makefile($dst, 2);
 340         delete $self->{-locked} // die "BUG: $dst not locked"; # unlock
 341         index_cloned_inbox($self, 2);
 342 }
 343
 344 sub reap_live {
 345         my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 346         if (my $x = delete $LIVE{$pid}) {
 347                 my $cb = shift @$x;
 348                 $cb->(@$x);
 349         } else {
 350                 warn "reaped unknown PID=$pid ($?)\n";
 351         }
 352 }
 353
 354 sub clone_v2 ($$;$) {
 355         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 356         my $lei = $self->{lei};
 357         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 358         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 359         my $pfx = $curl->torsocks($lei, $first_uri) or return;
 360         my $dst = $self->{cur_dst} // $self->{dst};
 361         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 362         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 363         my (@src_edst, @skip);
 364         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 365                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 366                 my $src = $uri->as_string;
 367                 my $edst = $dst;
 368                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 369 failed to extract epoch number from $src
 370
 371                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 372                 $edst .= "/git/$nr.git";
 373                 if (!$want || $want->{$nr}) {
 374                         push @src_edst, $src, $edst;
 375                 } else { # create a placeholder so users only need to chmod +w
 376                         init_placeholder($src, $edst);
 377                         push @{$task->{-read_only}}, $edst;
 378                         push @skip, $key;
 379                 }
 380         }
 381         # filter out the epochs we skipped
 382         $self->{-culled_manifest} = 1 if delete(@$m{@skip});
 383
 384         if (!-d $dst || !mkdir($dst)) {
 385                 require File::Path;
 386                 File::Path::mkpath($dst);
 387                 -d $dst or die "mkpath($dst): $!\n";
 388         }
 389         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 390         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 391
 392         _get_txt_start($task, '_/text/config/raw', $fini);
 393         _get_txt_start($self, 'description', $fini);
 394
 395         $task->{-locked} = $lk->lock_for_scope($$);
 396         my @cmd = clone_cmd($lei, my $opt = {});
 397         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
 398         do {
 399                 reap_live() while keys(%LIVE) >= $jobs;
 400                 while (keys(%LIVE) < $jobs && @src_edst &&
 401                                 !$lei->{child_error}) {
 402                         my $cmd = [ @$pfx, @cmd, splice(@src_edst, 0, 2) ];
 403                         $lei->qerr("# @$cmd");
 404                         $LIVE{spawn($cmd, undef, $opt)} = [ \&reap_clone,
 405                                                         $lei, $cmd, $fini ];
 406                 }
 407         } while (@src_edst && !$lei->{child_error});
 408 }
 409
 410 sub decode_manifest ($$$) {
 411         my ($fh, $fn, $uri) = @_;
 412         my $js;
 413         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 414         gunzip(\$gz => \$js, MultiStream => 1) or
 415                 die "gunzip($uri): $GunzipError\n";
 416         my $m = eval { PublicInbox::Config->json->decode($js) };
 417         die "$uri: error decoding `$js': $@\n" if $@;
 418         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 419         $m;
 420 }
 421
 422 sub multi_inbox ($$$) {
 423         my ($self, $path, $m) = @_;
 424         my $incl = $self->{lei}->{opt}->{include};
 425         my $excl = $self->{lei}->{opt}->{exclude};
 426
 427         # assuming everything not v2 is v1, for now
 428         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 429         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 430         my $v2 = {};
 431
 432         for (@v2_epochs) {
 433                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 434                 push @{$v2->{$1}}, $_;
 435         }
 436         my $n = scalar(keys %$v2) + scalar(@v1);
 437         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 438         if (defined $incl) {
 439                 my $re = '(?:'.join('|', map {
 440                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E\z/
 441                         } @$incl).')';
 442                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 443                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 444                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
 445                 @v1 = grep(/$re/, @v1);
 446         }
 447         if (defined $excl) {
 448                 my $re = '(?:'.join('|', map {
 449                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E\z/
 450                         } @$excl).')';
 451                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 452                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 453                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
 454                 @v1 = grep(!/$re/, @v1);
 455         }
 456         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 457         $ret->{v1} = \@v1 if @v1;
 458         $ret->{v2} = $v2 if keys %$v2;
 459         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 460                                 join("\n\t", sort @orig)
 461                         : "Nothing available to clone\n";
 462         my $path_pfx = '';
 463
 464         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 465         if (@v2_epochs) {
 466                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 467                                 @v2_epochs) == @v2_epochs) {
 468                         $$path =~ s!\A(/[^/]+)/!/! or last;
 469                         $path_pfx .= $1;
 470                 }
 471         } elsif (@v1) {
 472                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 473                         $path_pfx .= $1;
 474                 }
 475         }
 476         ($path_pfx, $n, $ret);
 477 }
 478
 479 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
 480 sub try_manifest {
 481         my ($self) = @_;
 482         my $uri = URI->new($self->{src});
 483         my $lei = $self->{lei};
 484         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 485         my $path = $uri->path;
 486         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 487         $uri->path($path . '/manifest.js.gz');
 488         my $pdir = $lei->rel2abs($self->{dst});
 489         $pdir =~ s!/[^/]+/?\z!!;
 490         my $ft = File::Temp->new(TEMPLATE => 'm-XXXX',
 491                                 UNLINK => 1, DIR => $pdir, SUFFIX => '.tmp');
 492         my $fn = $ft->filename;
 493         my ($bn) = ($fn =~ m!/([^/]+)\z!);
 494         my $cmd = $curl->for_uri($lei, $uri, '-R', '-o', $bn);
 495         my $opt = { -C => $pdir };
 496         $opt->{$_} = $lei->{$_} for (0..2);
 497         my $cerr = run_reap($lei, $cmd, $opt);
 498         local %LIVE;
 499         if ($cerr) {
 500                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
 501                 return $lei->child_error($cerr, "@$cmd failed");
 502         }
 503         my $m = eval { decode_manifest($ft, $fn, $uri) };
 504         if ($@) {
 505                 warn $@;
 506                 return try_scrape($self);
 507         }
 508         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
 509         return $lei->child_error(1, $multi) if !ref($multi);
 510         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
 511         if (my $v2 = delete $multi->{v2}) {
 512                 for my $name (sort keys %$v2) {
 513                         my $epochs = delete $v2->{$name};
 514                         my %v2_epochs = map {
 515                                 $uri->path($n > 1 ? $path_pfx.$path.$_
 516                                                 : $path_pfx.$_);
 517                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
 518                                 $e // die "no [0-9]+\.git in `$uri'";
 519                                 $e => [ $uri->clone, $_ ];
 520                         } @$epochs;
 521                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
 522                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
 523                         local $self->{cur_src} = $1;
 524                         local $self->{cur_dst} = $self->{dst};
 525                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
 526                                                         git/[0-9]+\.git\z!x) {
 527                                 $self->{cur_dst} .= "/$1";
 528                         }
 529                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
 530 E: `$self->{cur_dst}' must not contain newline
 531 EOM
 532                         clone_v2($self, \%v2_epochs, $m);
 533                         reap_live() while keys(%LIVE) >= $jobs;
 534                         return if $self->{lei}->{child_error};
 535                 }
 536         }
 537         if (my $v1 = delete $multi->{v1}) {
 538                 my $p = $path_pfx.$path;
 539                 chop($p) if substr($p, -1, 1) eq '/';
 540                 $uri->path($p);
 541                 for my $name (@$v1) {
 542                         reap_live() while keys(%LIVE) >= $jobs;
 543                         return if $self->{lei}->{child_error};
 544
 545                         my $task = bless { %$self }, __PACKAGE__;
 546                         $task->{-ent} = $m->{$name} //
 547                                         die("BUG: no `$name' in manifest");
 548                         $task->{cur_src} = "$uri";
 549                         $task->{cur_dst} = $task->{dst};
 550                         if ($n > 1) {
 551                                 $task->{cur_dst} .= $name;
 552                                 $task->{cur_src} .= $name;
 553                         }
 554                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
 555 E: `$task->{cur_dst}' must not contain newline
 556 EOM
 557                         $task->{cur_src} .= '/';
 558                         clone_v1($task, 1);
 559                 }
 560         }
 561         reap_live() while keys(%LIVE);
 562         return if $self->{lei}->{child_error};
 563
 564         if (delete $self->{-culled_manifest}) { # set by clone_v2/-I/--exclude
 565                 # write the smaller manifest if epochs were skipped so
 566                 # users won't have to delete manifest if they +w an
 567                 # epoch they no longer want to skip
 568                 my $json = PublicInbox::Config->json->encode($m);
 569                 my $mtime = (stat($fn))[9];
 570                 gzip(\$json => $fn) or die "gzip: $GzipError";
 571                 utime($mtime, $mtime, $fn) or die "utime(..., $fn): $!";
 572         }
 573         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
 574         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 575 }
 576
 577 sub start_clone_url {
 578         my ($self) = @_;
 579         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 580         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 581 }
 582
 583 sub do_mirror { # via wq_io_do
 584         my ($self) = @_;
 585         my $lei = $self->{lei};
 586         umask($lei->{client_umask}) if defined $lei->{client_umask};
 587         eval {
 588                 my $iv = $lei->{opt}->{'inbox-version'};
 589                 if (defined $iv) {
 590                         local %LIVE;
 591                         return clone_v1($self) if $iv == 1;
 592                         return try_scrape($self) if $iv == 2;
 593                         die "bad --inbox-version=$iv\n";
 594                 }
 595                 return start_clone_url($self) if $self->{src} =~ m!://!;
 596                 die "TODO: cloning local directories not supported, yet";
 597         };
 598         $lei->fail($@) if $@;
 599 }
 600
 601 sub start {
 602         my ($cls, $lei, $src, $dst) = @_;
 603         my $self = bless { src => $src, dst => $dst }, $cls;
 604         if ($src =~ m!https?://!) {
 605                 require URI;
 606                 require PublicInbox::LeiCurl;
 607         }
 608         require PublicInbox::Lock;
 609         require PublicInbox::Inbox;
 610         require PublicInbox::Admin;
 611         require PublicInbox::InboxWritable;
 612         $lei->request_umask;
 613         my ($op_c, $ops) = $lei->workers_start($self, 1);
 614         $lei->{wq1} = $self;
 615         $self->wq_io_do('do_mirror', []);
 616         $self->wq_close;
 617         $lei->wait_wq_events($op_c, $ops);
 618 }
 619
 620 sub ipc_atfork_child {
 621         my ($self) = @_;
 622         $self->{lei}->_lei_atfork_child;
 623         $self->SUPER::ipc_atfork_child;
 624 }
 625
 626 sub write_makefile {
 627         my ($dir, $ibx_ver) = @_;
 628         my $f = "$dir/Makefile";
 629         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
 630                 print $fh <<EOM or die "print($f) $!";
 631 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
 632 # manpage for more information on the format.  This Makefile is
 633 # intended as a familiar wrapper for users unfamiliar with
 634 # public-inbox-* commands.
 635 #
 636 # See the respective manpages for public-inbox-fetch(1),
 637 # public-inbox-index(1), etc for more information on
 638 # some of the commands used by this Makefile.
 639 #
 640 # This Makefile will not be modified nor read by public-inbox,
 641 # so you may edit it freely with your own convenience targets
 642 # and notes.  public-inbox-fetch will recreate it if removed.
 643 EOM
 644                 print $fh <<'EOM' or die "print($f): $!";
 645 # the default target:
 646 help :
 647         @echo Common targets:
 648         @echo '    make fetch        - fetch from remote git repostorie(s)'
 649         @echo '    make update       - fetch and update index '
 650         @echo
 651         @echo Rarely needed targets:
 652         @echo '    make reindex      - may be needed for new features/bugfixes'
 653         @echo '    make compact      - rewrite Xapian storage to save space'
 654
 655 fetch :
 656         public-inbox-fetch
 657 update :
 658         @if ! public-inbox-fetch --exit-code; \
 659         then \
 660                 c=$$?; \
 661                 test $$c -eq 127 && exit 0; \
 662                 exit $$c; \
 663         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
 664         then \
 665                 public-inbox-index; \
 666         else \
 667                 echo 'public-inbox index not initialized'; \
 668                 echo 'see public-inbox-index(1) man page'; \
 669         fi
 670 reindex :
 671         public-inbox-index --reindex
 672 compact :
 673         public-inbox-compact
 674
 675 .PHONY : help fetch update reindex compact
 676 EOM
 677                 close $fh or die "close($f): $!";
 678         } else {
 679                 die "open($f): $!" unless $!{EEXIST};
 680         }
 681 }
 682
 683 1;