lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::LeiCurl;
  20 use PublicInbox::OnDestroy;
  21 use Digest::SHA qw(sha256_hex);
  22
  23 our $LIVE; # pid => callback
  24 my $update_ref_stdin = $ENV{GIT_CAN_UPDATE_REF_STDIN} // 1;
  25
  26 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  27         my ($arg, $pid) = @_;
  28         my ($mrr, $lei) = @$arg;
  29         my $f = "$mrr->{dst}/mirror.done";
  30         if ($?) {
  31                 $lei->child_error($?);
  32         } elsif (!$mrr->{dry_run} && !unlink($f)) {
  33                 warn("unlink($f): $!\n") unless $!{ENOENT};
  34         } else {
  35                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  36                         require PublicInbox::LeiAddExternal;
  37                         PublicInbox::LeiAddExternal::_finish_add_external(
  38                                                         $lei, $mrr->{dst});
  39                 }
  40                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  41         }
  42         $lei->dclose;
  43 }
  44
  45 # for old installations without manifest.js.gz
  46 sub try_scrape {
  47         my ($self, $fallback_manifest) = @_;
  48         my $uri = URI->new($self->{src});
  49         my $lei = $self->{lei};
  50         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  51         my $cmd = $curl->for_uri($lei, $uri, qw(-f --compressed));
  52         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  53         my $fh = popen_rd($cmd, undef, $opt);
  54         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  55         close($fh) or return $lei->child_error($?, "@$cmd failed");
  56
  57         # we grep with URL below, we don't want Subject/From headers
  58         # making us clone random URLs.  This assumes remote instances
  59         # prior to public-inbox 1.7.0
  60         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  61         my @html = split(/<hr>/, $html);
  62         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  63         if (!@urls && $fallback_manifest) {
  64                 warn <<EOM;
  65 W: failed to extract URLs from $uri, trying manifest.js.gz...
  66 EOM
  67                 return start_clone_url($self);
  68         }
  69         my $url = $uri->as_string;
  70         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  71
  72         # since this is for old instances w/o manifest.js.gz, try v1 first
  73         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  74         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  75                 my %v2_epochs = map {
  76                         my ($n) = (m!/([0-9]+)\z!);
  77                         $n => [ URI->new($_), '' ]
  78                 } @v2_urls; # uniq
  79                 clone_v2_prep($self, \%v2_epochs);
  80                 delete local $lei->{opt}->{epoch};
  81                 clone_all($self);
  82                 return;
  83         }
  84
  85         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  86         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  87                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  88                 die <<"";
  89 E: confused by scraping <$uri>, did you mean <$url>?
  90
  91         }
  92         @urls and die <<"";
  93 E: confused by scraping <$uri>, got ambiguous results:
  94 @urls
  95
  96         die "E: scraping <$uri> revealed nothing\n";
  97 }
  98
  99 sub clone_cmd {
 100         my ($lei, $opt) = @_;
 101         my @cmd = qw(git);
 102         $opt->{$_} = $lei->{$_} for (0..2);
 103         # we support "-c $key=$val" for arbitrary git config options
 104         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 105         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 106         push @cmd, qw(clone --mirror);
 107         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 108                         ($lei->{opt}->{jobs} // 1) > 1;
 109         push @cmd, '-v' if $lei->{opt}->{verbose};
 110         # XXX any other options to support?
 111         # --reference is tricky with multiple epochs, but handled
 112         # automatically if using manifest.js.gz
 113         @cmd;
 114 }
 115
 116 sub ft_rename ($$$) {
 117         my ($ft, $dst, $open_mode) = @_;
 118         my @st = stat($dst);
 119         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 120         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 121         require File::Copy;
 122         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 123         $ft->unlink_on_destroy(0);
 124 }
 125
 126 sub do_reap ($;$) {
 127         my ($self, $jobs) = @_;
 128         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 129         $jobs = 1 if $jobs < 1;
 130         while (keys(%$LIVE) >= $jobs) {
 131                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 132                 if (my $x = delete $LIVE->{$pid}) {
 133                         my $cb = shift @$x;
 134                         $cb->(@$x) if $cb;
 135                 } else {
 136                         warn "reaped unknown PID=$pid ($?)\n";
 137                 }
 138         }
 139 }
 140
 141 sub _get_txt_start { # non-fatal
 142         my ($self, $endpoint, $fini) = @_;
 143         my $uri = URI->new($self->{cur_src} // $self->{src});
 144         my $lei = $self->{lei};
 145         my $path = $uri->path;
 146         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 147         $uri->path("$path/$endpoint");
 148         my $f = (split(m!/!, $endpoint))[-1];
 149         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 150         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 151         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(-f --compressed -R -o),
 152                                         $ft->filename);
 153         do_reap($self);
 154         $lei->qerr("# @$cmd");
 155         return if $self->{dry_run};
 156         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 157         $LIVE->{spawn($cmd, undef, $opt)} =
 158                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 159 }
 160
 161 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 162         my ($self, $endpoint) = @_;
 163         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 164         my $cerr = $?;
 165         $? = 0; # don't influence normal lei exit
 166         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 167         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 168         seek($fh, SEEK_SET, 0) or die "seek: $!";
 169         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 170         local $/;
 171         $self->{"txt.$endpoint"} = <$fh>;
 172         undef; # success
 173 }
 174
 175 sub _write_inbox_config {
 176         my ($self) = @_;
 177         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 178         my $dst = $self->{cur_dst} // $self->{dst};
 179         my $f = "$dst/inbox.config.example";
 180         open my $fh, '>', $f or die "open($f): $!";
 181         print $fh $buf or die "print: $!";
 182         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 183         my $mtime = delete $self->{'mtime._/text/config/raw'};
 184         $fh->flush or die "flush($f): $!";
 185         if (defined $mtime) {
 186                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
 187         }
 188         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 189         my $ibx = $self->{ibx} = {};
 190         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 191                 for (qw(address newsgroup nntpmirror)) {
 192                         $ibx->{$_} = $cfg->{"$sec.$_"};
 193                 }
 194         }
 195 }
 196
 197 sub set_description ($) {
 198         my ($self) = @_;
 199         my $dst = $self->{cur_dst} // $self->{dst};
 200         my $f = "$dst/description";
 201         open my $fh, '+>>', $f or die "open($f): $!";
 202         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 203         my $d = do { local $/; <$fh> } // die "read($f): $!";
 204         chomp(my $orig = $d);
 205         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 206                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 207                 $d = delete($self->{'txt.description'});
 208         }
 209         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 210         chomp $d;
 211         return if $d eq $orig;
 212         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 213         truncate($fh, 0) or die "truncate($f): $!";
 214         print $fh $d, "\n" or die "print($f): $!";
 215         close $fh or die "close($f): $!";
 216 }
 217
 218 sub index_cloned_inbox {
 219         my ($self, $iv) = @_;
 220         my $lei = $self->{lei};
 221
 222         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 223         # lei is useless without Xapian + SQLite
 224         if ($lei->{cmd} ne 'public-inbox-clone') {
 225                 require PublicInbox::InboxWritable;
 226                 require PublicInbox::Admin;
 227                 my $ibx = delete($self->{ibx}) // {
 228                         address => [ 'lei@example.com' ],
 229                         version => $iv,
 230                 };
 231                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 232                 PublicInbox::Inbox->new($ibx);
 233                 PublicInbox::InboxWritable->new($ibx);
 234                 my $opt = {};
 235                 for my $sw ($lei->index_opt) {
 236                         my ($k) = ($sw =~ /\A([\w-]+)/);
 237                         $opt->{$k} = $lei->{opt}->{$k};
 238                 }
 239                 # force synchronous dwaitpid for v2:
 240                 local $PublicInbox::DS::in_loop = 0;
 241                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 242                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 243                 local %ENV = (%ENV, %$env) if $env;
 244                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 245                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 246         }
 247         return if defined $self->{cur_dst}; # one of many repos to clone
 248         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 249 }
 250
 251 sub run_reap {
 252         my ($lei, $cmd, $opt) = @_;
 253         $lei->qerr("# @$cmd");
 254         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 255         my $ret = $?;
 256         $? = 0; # don't let it influence normal exit
 257         $ret;
 258 }
 259
 260 sub start_clone {
 261         my ($self, $cmd, $opt, $fini) = @_;
 262         do_reap($self);
 263         $self->{lei}->qerr("# @$cmd");
 264         return if $self->{dry_run};
 265         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 266 }
 267
 268 sub fetch_args ($$) {
 269         my ($lei, $opt) = @_;
 270         my @cmd; # (git --git-dir=...) to be added by caller
 271         $opt->{$_} = $lei->{$_} for (0..2);
 272         # we support "-c $key=$val" for arbitrary git config options
 273         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 274         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 275         push @cmd, 'fetch';
 276         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 277                         ($lei->{opt}->{jobs} // 1) > 1;
 278         push @cmd, '-v' if $lei->{opt}->{verbose};
 279         @cmd;
 280 }
 281
 282 sub fgrp_update_old ($) { # for git <1.8.5
 283         my ($fgrp) = @_;
 284         my $cmd = [ @{$fgrp->{-torsocks}}, 'git', "--git-dir=$fgrp->{cur_dst}",
 285                 fetch_args($fgrp->{lei}, my $opt = {}) ];
 286         $fgrp->{lei}->qerr("# @$cmd");
 287         do_reap($fgrp);
 288         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $fgrp, $cmd ];
 289 }
 290
 291 sub upr { # feed `git update-ref --stdin -z' verbosely
 292         my ($fgrp, $w, $op, $ref, $oid) = @_;
 293         $fgrp->{lei}->qerr("# $op $ref $oid");
 294         print $w "$op $ref\0$oid\0" or die "print(w): $!";
 295 }
 296
 297 sub fgrp_update {
 298         my ($fgrp) = @_;
 299         my $srcfh = delete $fgrp->{srcfh} or return;
 300         my $dstfh = delete $fgrp->{dstfh} or return;
 301         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 302         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 303         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 304         close $srcfh;
 305         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 306         close $dstfh;
 307         pipe(my ($r, $w)) or die "pipe: $!";
 308         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 309                 qw(update-ref --stdin -z) ];
 310         $fgrp->{lei}->qerr("# @$cmd");
 311         my $opt = { 0 => $r, 1 => $fgrp->{lei}->{1}, 2 => $fgrp->{lei}->{2} };
 312         my $pid = spawn($cmd, undef, $opt);
 313         close $r or die "close(r): $!";
 314         for my $ref (keys %dst) {
 315                 my $new = delete $src{$ref};
 316                 my $old = $dst{$ref};
 317                 if (defined $new) {
 318                         upr($fgrp, $w, 'update', $ref, $new) if $new ne $old;
 319                 } else {
 320                         upr($fgrp, $w, 'delete', $ref, $old);
 321                 }
 322         }
 323         while (my ($ref, $oid) = each %src) {
 324                 upr($fgrp, $w, 'create', $ref, $oid);
 325         }
 326         if (close($w)) { # git >= 1.8.5
 327                 $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd ];
 328                 do_reap($fgrp);
 329         } else { # git <1.8.5 w/o update-ref --stdin
 330                 warn "E: close(update-ref --stdin): $!\n";
 331                 $update_ref_stdin = 0;
 332                 waitpid($pid, 0) // die "waitpid(update-ref --stdin): $!";
 333                 fgrp_update_old($fgrp);
 334         }
 335 }
 336
 337 sub pack_refs {
 338         my ($self, $git_dir) = @_;
 339         do_reap($self);
 340         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 341         $self->{lei}->qerr("# @$cmd");
 342         my $opt = { 1 => $self->{lei}->{1}, 2 => $self->{lei}->{2} };
 343         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd ];
 344 }
 345
 346 sub fgrp_fetched {
 347         my ($fgrp) = @_;
 348         return if $fgrp->{dry_run} || !$LIVE;
 349         my $rn = $fgrp->{-remote};
 350         my %opt = map { $_ => $fgrp->{lei}->{$_} } (0..2);
 351         pack_refs($fgrp, $fgrp->{-osdir}); # objstore refs always packed
 352
 353         $update_ref_stdin or return fgrp_update_old($fgrp);
 354
 355         my $update_ref = PublicInbox::OnDestroy->new($$, \&fgrp_update, $fgrp);
 356
 357         my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 358                 "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 359                 "refs/remotes/$rn/" ];
 360         do_reap($fgrp);
 361         open($fgrp->{srcfh}, '+>', undef) or die "open(src): $!";
 362         $fgrp->{lei}->qerr("# @$src >SRC");
 363         my $pid = spawn($src, undef, { %opt, 1 => $fgrp->{srcfh} });
 364         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $src, $update_ref ];
 365
 366         my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 367                 '--format=%(refname)%00%(objectname)' ];
 368         do_reap($fgrp);
 369         open($fgrp->{dstfh}, '+>', undef) or die "open(dst): $!";
 370         $fgrp->{lei}->qerr("# @$dst >DST");
 371         $pid = spawn($dst, undef, { %opt, 1 => $fgrp->{dstfh} });
 372         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $dst, $update_ref ];
 373 }
 374
 375 sub fgrp_fetch {
 376         my ($fgrp, $fini) = @_;
 377         my $cmd = [ @{$fgrp->{-torsocks}}, 'git', "--git-dir=$fgrp->{-osdir}",
 378                         fetch_args($fgrp->{lei}, my $opt = {}),
 379                         $fgrp->{-remote} ];
 380         $fgrp->{-fini} = $fini;
 381         do_reap($fgrp);
 382         $fgrp->{lei}->qerr("# @$cmd");
 383         return if $fgrp->{dry_run};
 384         my $fgrp_fini = PublicInbox::OnDestroy->new($$, \&fgrp_fetched, $fgrp);
 385         my $pid = spawn($cmd, undef, $opt);
 386         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd, $fgrp_fini ];
 387 }
 388
 389 # keep this idempotent for future use by public-inbox-fetch
 390 sub forkgroup_prep {
 391         my ($self, $uri) = @_;
 392         $self->{-ent} // return;
 393         my $os = $self->{-objstore} // return;
 394         my $fg = $self->{-ent}->{forkgroup} // return;
 395         my $dir = "$os/$fg.git";
 396         my @cmd = ('git', "--git-dir=$dir", 'config');
 397         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 398         if (!-d $dir) {
 399                 PublicInbox::Import::init_bare($dir);
 400                 for ('repack.useDeltaIslands=true',
 401                                 'pack.island=refs/remotes/([^/]+)/') {
 402                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
 403                 }
 404         }
 405         my $key = $self->{-key} // die 'BUG: no -key';
 406         my ($bn) = ($key =~ m{/([a-z0-9_,;=!\+\{\}\|][^/]*)(?:\.git)?\z}i);
 407         my $rn = "$bn-".substr(sha256_hex($key), 0, 16);
 408         for ("url=$uri", "fetch=+refs/*:refs/remotes/$rn/*") {
 409                 my @kv = split(/=/, $_, 2);
 410                 $kv[0] = "remote.$rn.$kv[0]";
 411                 run_die([@cmd, @kv], undef, $opt);
 412         }
 413         $self->{-do_pack_refs} = 1; # likely coderepo
 414         if (!-d $self->{cur_dst}) {
 415                 my $alt = File::Spec->rel2abs("$dir/objects");
 416                 PublicInbox::Import::init_bare($self->{cur_dst});
 417                 my $o = "$self->{cur_dst}/objects";
 418                 my $f = "$o/info/alternates";
 419                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 420                 open my $fh, '+>>', $f or die "open($f): $!";
 421                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 422                 chomp(my @cur = <$fh>);
 423                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 424                         say $fh $l or die "say($f): $!";
 425                 }
 426                 close $fh or die "close($f): $!";
 427                 @cmd = ('git', "--git-dir=$self->{cur_dst}",
 428                         qw(remote add --mirror=fetch origin), "$uri");
 429                 my $pid = spawn(\@cmd, undef, $opt);
 430                 waitpid($pid, 0) // die "waitpid(@cmd): $!";
 431                 die "E: @cmd: \$?=$?" if ($? && ($? >> 8) != 3);
 432         }
 433         bless { %$self, -osdir => $dir, -remote => $rn }, __PACKAGE__;
 434 }
 435
 436 sub clone_v1 {
 437         my ($self, $nohang) = @_;
 438         my $lei = $self->{lei};
 439         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 440         my $uri = URI->new($self->{cur_src} // $self->{src});
 441         defined($lei->{opt}->{epoch}) and
 442                 die "$uri is a v1 inbox, --epoch is not supported\n";
 443         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 444         my $dst = $self->{cur_dst} // $self->{dst};
 445         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 446         my $cmd = [ @{$self->{-torsocks}}, clone_cmd($lei, my $opt = {}),
 447                 "$uri", $dst ];
 448         my $fgrp = forkgroup_prep($self, $uri);
 449         if (!defined($fgrp) && defined($self->{-ent})) {
 450                 if (defined(my $ref = $self->{-ent}->{reference})) {
 451                         -e "$self->{dst}$ref" and
 452                                 push @$cmd, '--reference', "$self->{dst}$ref";
 453                 }
 454         }
 455         $fgrp ? fgrp_fetch($fgrp, $fini) :
 456                 start_clone($self, $cmd, $opt, $fini);
 457
 458         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 459                                 /\A(?:always|v1)\z/s) {
 460                 _get_txt_start($self, '_/text/config/raw', $fini);
 461         }
 462
 463         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 464         $self->{'txt.description'} = $d if defined $d;
 465         (!defined($d) && !$nohang) and
 466                 _get_txt_start($self, 'description', $fini);
 467
 468         $nohang or do_reap($self, 1); # for non-manifest clone
 469 }
 470
 471 sub parse_epochs ($$) {
 472         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 473         $opt_epochs // return; # undef => all epochs
 474         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 475         undef($lo) if ($lo // '') eq '';
 476         my $re = qr/\A~?[0-9]+\z/;
 477         if (@extra || (($lo // '0') !~ $re) ||
 478                         (($hi // '0') !~ $re) ||
 479                         !(grep(defined, $lo, $hi))) {
 480                 die <<EOM;
 481 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 482 EOM
 483         }
 484         my @n = sort { $a <=> $b } keys %$v2_epochs;
 485         for (grep(defined, $lo, $hi)) {
 486                 if (/\A[0-9]+\z/) {
 487                         $_ > $n[-1] and die
 488 "`$_' exceeds maximum available epoch ($n[-1])\n";
 489                         $_ < $n[0] and die
 490 "`$_' is lower than minimum available epoch ($n[0])\n";
 491                 } elsif (/\A~([0-9]+)/) {
 492                         my $off = -$1 - 1;
 493                         $n[$off] // die "`$_' is out of range\n";
 494                         $_ = $n[$off];
 495                 } else { die "`$_' not understood\n" }
 496         }
 497         defined($lo) && defined($hi) && $lo > $hi and die
 498 "low value (`$lo') exceeds high (`$hi')\n";
 499         $lo //= $n[0] if $dotdot;
 500         $hi //= $n[-1] if $dotdot;
 501         $hi //= $lo;
 502         my $want = {};
 503         for ($lo..$hi) {
 504                 if (defined $v2_epochs->{$_}) {
 505                         $want->{$_} = 1;
 506                 } else {
 507                         warn
 508 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 509                 }
 510         }
 511         $want
 512 }
 513
 514 sub init_placeholder ($$$) {
 515         my ($src, $edst, $ent) = @_;
 516         PublicInbox::Import::init_bare($edst);
 517         my $f = "$edst/config";
 518         open my $fh, '>>', $f or die "open($f): $!";
 519         print $fh <<EOM or die "print($f): $!";
 520 [remote "origin"]
 521         url = $src
 522         fetch = +refs/*:refs/*
 523         mirror = true
 524
 525 ; This git epoch was created read-only and "public-inbox-fetch"
 526 ; will not fetch updates for it unless write permission is added.
 527 ; Hint: chmod +w $edst
 528 EOM
 529         if (defined($ent->{owner})) {
 530                 print $fh <<EOM or die "print($f): $!";
 531 [gitweb]
 532         owner = $ent->{owner}
 533 EOM
 534         }
 535         close $fh or die "close($f): $!";
 536         my %map = (head => 'HEAD', description => undef);
 537         while (my ($key, $fn) = each %map) {
 538                 my $val = $ent->{$key} // next;
 539                 $fn //= $key;
 540                 $fn = "$edst/$fn";
 541                 open $fh, '>', $fn or die "open($fn): $!";
 542                 print $fh $val, "\n" or die "print($fn): $!";
 543                 close $fh or die "close($fn): $!";
 544         }
 545 }
 546
 547 sub reap_cmd { # async, called via SIGCHLD
 548         my ($self, $cmd) = @_;
 549         my $cerr = $?;
 550         $? = 0; # don't let it influence normal exit
 551         if ($cerr) {
 552                 kill('TERM', keys %$LIVE);
 553                 $self->{lei}->child_error($cerr, "@$cmd failed");
 554         }
 555 }
 556
 557 sub v1_done { # called via OnDestroy
 558         my ($self) = @_;
 559         return if $self->{dry_run} || !$LIVE;
 560         _write_inbox_config($self);
 561         my $dst = $self->{cur_dst} // $self->{dst};
 562         if (defined(my $o = $self->{-ent} ? $self->{-ent}->{owner} : undef)) {
 563                 run_die([qw(git config -f), "$dst/config", 'gitweb.owner', $o]);
 564         }
 565         my $o = "$dst/objects";
 566         if (open(my $fh, '<', "$o/info/alternates")) {
 567                 my $base = File::Spec->rel2abs($o);
 568                 chomp(my @l = <$fh>);
 569                 for (@l) {
 570                         $_ = File::Spec->abs2rel($_, $base) if m!\A/!;
 571                         $_ .= "\n";
 572                 }
 573                 my $f = File::Temp->new(TEMPLATE => '.XXXX', DIR => "$o/info");
 574                 print $f @l;
 575                 $f->flush or die "flush($f): $!";
 576                 rename($f->filename, "$o/info/alternates") or
 577                         die "rename($f, $o/info/alternates): $!";
 578                 $f->unlink_on_destroy(0);
 579         }
 580         pack_refs($self, $dst) if delete $self->{-do_pack_refs};
 581         eval { set_description($self) };
 582         warn $@ if $@;
 583         return if ($self->{-is_epoch} ||
 584                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 585         write_makefile($dst, 1);
 586         index_cloned_inbox($self, 1);
 587 }
 588
 589 sub v2_done { # called via OnDestroy
 590         my ($self) = @_;
 591         return if $self->{dry_run} || !$LIVE;
 592         my $dst = $self->{cur_dst} // $self->{dst};
 593         require PublicInbox::Lock;
 594         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 595         my $lck = $lk->lock_for_scope($$);
 596         _write_inbox_config($self);
 597         require PublicInbox::MultiGit;
 598         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 599         $mg->fill_alternates;
 600         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 601         for my $edst (@{delete($self->{-read_only}) // []}) {
 602                 my @st = stat($edst) or die "stat($edst): $!";
 603                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 604         }
 605         write_makefile($dst, 2);
 606         undef $lck; # unlock
 607         eval { set_description($self) };
 608         warn $@ if $@;
 609         index_cloned_inbox($self, 2);
 610 }
 611
 612 sub clone_v2_prep ($$;$) {
 613         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 614         my $lei = $self->{lei};
 615         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 616         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 617         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 618         my $dst = $self->{cur_dst} // $self->{dst};
 619         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 620         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 621         delete $task->{todo}; # $self->{todo} still exists
 622         my (@skip, $desc);
 623         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 624         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 625                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 626                 my $src = $uri->as_string;
 627                 my $edst = $dst;
 628                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 629 failed to extract epoch number from $src
 630
 631                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 632                 $edst .= "/git/$nr.git";
 633                 my $ent;
 634                 if ($m) {
 635                         $ent = $m->{$key} //
 636                                 die("BUG: `$key' not in manifest.js.gz");
 637                         if (defined(my $d = $ent->{description})) {
 638                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 639                                 $desc = $d;
 640                         }
 641                 }
 642                 if (!$want || $want->{$nr}) {
 643                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 644                         $etask->{-ent} = $ent; # may have {reference}
 645                         $etask->{cur_src} = $src;
 646                         $etask->{cur_dst} = $edst;
 647                         $etask->{-is_epoch} = $fini;
 648                         my $ref = $ent->{reference} // '';
 649                         push @{$self->{todo}->{$ref}}, $etask;
 650                         $self->{any_want}->{$key} = 1;
 651                 } else { # create a placeholder so users only need to chmod +w
 652                         init_placeholder($src, $edst, $ent);
 653                         push @{$task->{-read_only}}, $edst;
 654                         push @skip, $key;
 655                 }
 656         }
 657         # filter out the epochs we skipped
 658         $self->{-culled_manifest} = 1 if $m && delete(@$m{@skip});
 659
 660         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 661
 662         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 663                 _get_txt_start($task, '_/text/config/raw', $fini);
 664
 665         defined($desc) ? ($task->{'txt.description'} = $desc) :
 666                 _get_txt_start($task, 'description', $fini);
 667 }
 668
 669 sub decode_manifest ($$$) {
 670         my ($fh, $fn, $uri) = @_;
 671         my $js;
 672         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 673         gunzip(\$gz => \$js, MultiStream => 1) or
 674                 die "gunzip($uri): $GunzipError\n";
 675         my $m = eval { PublicInbox::Config->json->decode($js) };
 676         die "$uri: error decoding `$js': $@\n" if $@;
 677         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 678         $m;
 679 }
 680
 681 sub multi_inbox ($$$) {
 682         my ($self, $path, $m) = @_;
 683         my $incl = $self->{lei}->{opt}->{include};
 684         my $excl = $self->{lei}->{opt}->{exclude};
 685
 686         # assuming everything not v2 is v1, for now
 687         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 688         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 689         my $v2 = {};
 690
 691         for (@v2_epochs) {
 692                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 693                 push @{$v2->{$1}}, $_;
 694         }
 695         my $n = scalar(keys %$v2) + scalar(@v1);
 696         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 697         if (defined $incl) {
 698                 my $re = '(?:'.join('\\z|', map {
 699                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 700                         } @$incl).'\\z)';
 701                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 702                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 703                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
 704                 @v1 = grep(/$re/, @v1);
 705         }
 706         if (defined $excl) {
 707                 my $re = '(?:'.join('\\z|', map {
 708                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 709                         } @$excl).'\\z)';
 710                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 711                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 712                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
 713                 @v1 = grep(!/$re/, @v1);
 714         }
 715         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 716         $ret->{v1} = \@v1 if @v1;
 717         $ret->{v2} = $v2 if keys %$v2;
 718         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 719                                 join("\n\t", sort @orig)
 720                         : "Nothing available to clone\n";
 721         my $path_pfx = '';
 722
 723         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 724         if (@v2_epochs) {
 725                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 726                                 @v2_epochs) == @v2_epochs) {
 727                         $$path =~ s!\A(/[^/]+)/!/! or last;
 728                         $path_pfx .= $1;
 729                 }
 730         } elsif (@v1) {
 731                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 732                         $path_pfx .= $1;
 733                 }
 734         }
 735         ($path_pfx, $n, $ret);
 736 }
 737
 738 sub clone_all {
 739         my ($self, $m) = @_;
 740         my $todo = delete $self->{todo};
 741         my $nodep = delete $todo->{''};
 742
 743         # do not download unwanted deps
 744         my $any_want = delete $self->{any_want};
 745         my @unwanted = grep { !$any_want->{$_} } keys %$todo;
 746         my @nodep = delete(@$todo{@unwanted});
 747         push(@$nodep, @$_) for @nodep;
 748
 749         # handle no-dependency repos, first
 750         for (@$nodep) {
 751                 clone_v1($_, 1);
 752                 return if $self->{lei}->{child_error};
 753         }
 754         # resolve references, deepest, first:
 755         while (scalar keys %$todo) {
 756                 for my $x (keys %$todo) {
 757                         my ($nr, $nxt);
 758                         # resolve multi-level references
 759                         while ($m && defined($nxt = $m->{$x}->{reference})) {
 760                                 exists($todo->{$nxt}) or last;
 761                                 die <<EOM if ++$nr > 1000;
 762 E: dependency loop detected (`$x' => `$nxt')
 763 EOM
 764                                 $x = $nxt;
 765                         }
 766                         my $y = delete $todo->{$x} // next; # already done
 767                         for (@$y) {
 768                                 clone_v1($_, 1);
 769                                 return if $self->{lei}->{child_error};
 770                         }
 771                         last; # restart %$todo iteration
 772                 }
 773         }
 774         do_reap($self, 1);
 775 }
 776
 777 sub dump_manifest ($$) {
 778         my ($m, $ft) = @_;
 779         # write the smaller manifest if epochs were skipped so
 780         # users won't have to delete manifest if they +w an
 781         # epoch they no longer want to skip
 782         my $json = PublicInbox::Config->json->encode($m);
 783         my $mtime = (stat($ft))[9];
 784         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
 785         truncate($ft, 0) or die "truncate($ft): $!";
 786         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
 787         $ft->flush or die "flush($ft): $!";
 788         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
 789 }
 790
 791 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
 792 sub try_manifest {
 793         my ($self) = @_;
 794         my $uri = URI->new($self->{src});
 795         my $lei = $self->{lei};
 796         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 797         my $path = $uri->path;
 798         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 799         $uri->path($path . '/manifest.js.gz');
 800         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX',
 801                                 UNLINK => 1, TMPDIR => 1, SUFFIX => '.tmp');
 802         my $cmd = $curl->for_uri($lei, $uri, qw(-f -R -o), $ft->filename);
 803         my %opt = map { $_ => $lei->{$_} } (0..2);
 804         my $cerr = run_reap($lei, $cmd, \%opt);
 805         if ($cerr) {
 806                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
 807                 return $lei->child_error($cerr, "@$cmd failed");
 808         }
 809         my $m = eval { decode_manifest($ft, $ft, $uri) };
 810         if ($@) {
 811                 warn $@;
 812                 return try_scrape($self);
 813         }
 814         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
 815         return $lei->child_error(1, $multi) if !ref($multi);
 816         my $v2 = delete $multi->{v2};
 817         local $self->{todo} = {};
 818         if ($v2) {
 819                 for my $name (sort keys %$v2) {
 820                         my $epochs = delete $v2->{$name};
 821                         my %v2_epochs = map {
 822                                 $uri->path($n > 1 ? $path_pfx.$path.$_
 823                                                 : $path_pfx.$_);
 824                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
 825                                 $e // die "no [0-9]+\.git in `$uri'";
 826                                 $e => [ $uri->clone, $_ ];
 827                         } @$epochs;
 828                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
 829                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
 830                         local $self->{cur_src} = $1;
 831                         local $self->{cur_dst} = $self->{dst};
 832                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
 833                                                         git/[0-9]+\.git\z!x) {
 834                                 $self->{cur_dst} .= "/$1";
 835                         }
 836                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
 837 E: `$self->{cur_dst}' must not contain newline
 838 EOM
 839                         clone_v2_prep($self, \%v2_epochs, $m);
 840                         return if $self->{lei}->{child_error};
 841                 }
 842         }
 843         if (my $v1 = delete $multi->{v1}) {
 844                 my $p = $path_pfx.$path;
 845                 chop($p) if substr($p, -1, 1) eq '/';
 846                 $uri->path($p);
 847                 for my $name (@$v1) {
 848                         my $task = bless { %$self }, __PACKAGE__;
 849                         $task->{-ent} = $m->{$name} //
 850                                         die("BUG: no `$name' in manifest");
 851                         $task->{cur_src} = "$uri";
 852                         $task->{cur_dst} = $task->{dst};
 853                         $task->{-key} = $name;
 854                         if ($n > 1) {
 855                                 $task->{cur_dst} .= $name;
 856                                 $task->{cur_src} .= $name;
 857                         }
 858                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
 859 E: `$task->{cur_dst}' must not contain newline
 860 EOM
 861                         $task->{cur_src} .= '/';
 862                         my $dep = $task->{-ent}->{reference} // '';
 863                         push @{$self->{todo}->{$dep}}, $task; # for clone_all
 864                         $self->{any_want}->{$name} = 1;
 865                 }
 866         }
 867         delete local $lei->{opt}->{epoch} if defined($v2);
 868         clone_all($self, $m);
 869         return if $self->{lei}->{child_error} || $self->{dry_run};
 870
 871         # set by clone_v2_prep/-I/--exclude
 872         dump_manifest($m => $ft) if delete $self->{-culled_manifest};
 873         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
 874         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 875 }
 876
 877 sub start_clone_url {
 878         my ($self) = @_;
 879         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 880         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 881 }
 882
 883 sub do_mirror { # via wq_io_do or public-inbox-clone
 884         my ($self) = @_;
 885         my $lei = $self->{lei};
 886         umask($lei->{client_umask}) if defined $lei->{client_umask};
 887         eval {
 888                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
 889                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
 890 --inbox-config must be one of `always', `v2', `v1', or `never'
 891
 892                 if (defined(my $os = $lei->{opt}->{objstore})) {
 893                         $os = 'objstore' if $os eq ''; # --objstore w/o args
 894                         $os = "$self->{dst}/$os" if $os !~ m!\A/!;
 895                         $self->{-objstore} = $os;
 896                 }
 897                 local $LIVE;
 898                 my $iv = $lei->{opt}->{'inbox-version'} //
 899                         return start_clone_url($self);
 900                 return clone_v1($self) if $iv == 1;
 901                 die "bad --inbox-version=$iv\n" if $iv != 2;
 902                 die <<EOM if $self->{src} !~ m!://!;
 903 cloning local v2 inboxes not supported
 904 EOM
 905                 try_scrape($self, 1);
 906         };
 907         $lei->fail($@) if $@;
 908 }
 909
 910 sub start {
 911         my ($cls, $lei, $src, $dst) = @_;
 912         my $self = bless { src => $src, dst => $dst }, $cls;
 913         $lei->request_umask;
 914         my ($op_c, $ops) = $lei->workers_start($self, 1);
 915         $lei->{wq1} = $self;
 916         $self->wq_io_do('do_mirror', []);
 917         $self->wq_close;
 918         $lei->wait_wq_events($op_c, $ops);
 919 }
 920
 921 sub ipc_atfork_child {
 922         my ($self) = @_;
 923         $self->{lei}->_lei_atfork_child;
 924         $self->SUPER::ipc_atfork_child;
 925 }
 926
 927 sub write_makefile {
 928         my ($dir, $ibx_ver) = @_;
 929         my $f = "$dir/Makefile";
 930         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
 931                 print $fh <<EOM or die "print($f) $!";
 932 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
 933 # manpage for more information on the format.  This Makefile is
 934 # intended as a familiar wrapper for users unfamiliar with
 935 # public-inbox-* commands.
 936 #
 937 # See the respective manpages for public-inbox-fetch(1),
 938 # public-inbox-index(1), etc for more information on
 939 # some of the commands used by this Makefile.
 940 #
 941 # This Makefile will not be modified nor read by public-inbox,
 942 # so you may edit it freely with your own convenience targets
 943 # and notes.  public-inbox-fetch will recreate it if removed.
 944 EOM
 945                 print $fh <<'EOM' or die "print($f): $!";
 946 # the default target:
 947 help :
 948         @echo Common targets:
 949         @echo '    make fetch        - fetch from remote git repostorie(s)'
 950         @echo '    make update       - fetch and update index '
 951         @echo
 952         @echo Rarely needed targets:
 953         @echo '    make reindex      - may be needed for new features/bugfixes'
 954         @echo '    make compact      - rewrite Xapian storage to save space'
 955         @echo '    make index        - initial index after clone
 956
 957 fetch :
 958         public-inbox-fetch
 959 update :
 960         @if ! public-inbox-fetch --exit-code; \
 961         then \
 962                 c=$$?; \
 963                 test $$c -eq 127 && exit 0; \
 964                 exit $$c; \
 965         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
 966         then \
 967                 public-inbox-index; \
 968         else \
 969                 echo 'public-inbox index not initialized'; \
 970                 echo 'see public-inbox-index(1) man page'; \
 971         fi
 972 index :
 973         public-inbox-index
 974 reindex :
 975         public-inbox-index --reindex
 976 compact :
 977         public-inbox-compact
 978
 979 .PHONY : help fetch update index reindex compact
 980 EOM
 981                 close $fh or die "close($f): $!";
 982         } else {
 983                 die "open($f): $!" unless $!{EEXIST};
 984         }
 985 }
 986
 987 1;