lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::LeiCurl;
  20 use PublicInbox::OnDestroy;
  21 use Digest::SHA qw(sha256_hex);
  22
  23 our $LIVE; # pid => callback
  24
  25 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  26         my ($arg, $pid) = @_;
  27         my ($mrr, $lei) = @$arg;
  28         my $f = "$mrr->{dst}/mirror.done";
  29         if ($?) {
  30                 $lei->child_error($?);
  31         } elsif (!$mrr->{dry_run} && !unlink($f)) {
  32                 warn("unlink($f): $!\n") unless $!{ENOENT};
  33         } else {
  34                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  35                         require PublicInbox::LeiAddExternal;
  36                         PublicInbox::LeiAddExternal::_finish_add_external(
  37                                                         $lei, $mrr->{dst});
  38                 }
  39                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  40         }
  41         $lei->dclose;
  42 }
  43
  44 # for old installations without manifest.js.gz
  45 sub try_scrape {
  46         my ($self, $fallback_manifest) = @_;
  47         my $uri = URI->new($self->{src});
  48         my $lei = $self->{lei};
  49         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  50         my $cmd = $curl->for_uri($lei, $uri, qw(-f --compressed));
  51         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  52         my $fh = popen_rd($cmd, undef, $opt);
  53         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  54         close($fh) or return $lei->child_error($?, "@$cmd failed");
  55
  56         # we grep with URL below, we don't want Subject/From headers
  57         # making us clone random URLs.  This assumes remote instances
  58         # prior to public-inbox 1.7.0
  59         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  60         my @html = split(/<hr>/, $html);
  61         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  62         if (!@urls && $fallback_manifest) {
  63                 warn <<EOM;
  64 W: failed to extract URLs from $uri, trying manifest.js.gz...
  65 EOM
  66                 return start_clone_url($self);
  67         }
  68         my $url = $uri->as_string;
  69         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  70
  71         # since this is for old instances w/o manifest.js.gz, try v1 first
  72         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  73         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  74                 my %v2_epochs = map {
  75                         my ($n) = (m!/([0-9]+)\z!);
  76                         $n => [ URI->new($_), '' ]
  77                 } @v2_urls; # uniq
  78                 clone_v2_prep($self, \%v2_epochs);
  79                 delete local $lei->{opt}->{epoch};
  80                 clone_all($self);
  81                 return;
  82         }
  83
  84         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  85         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  86                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  87                 die <<"";
  88 E: confused by scraping <$uri>, did you mean <$url>?
  89
  90         }
  91         @urls and die <<"";
  92 E: confused by scraping <$uri>, got ambiguous results:
  93 @urls
  94
  95         die "E: scraping <$uri> revealed nothing\n";
  96 }
  97
  98 sub clone_cmd {
  99         my ($lei, $opt) = @_;
 100         my @cmd = qw(git);
 101         $opt->{$_} = $lei->{$_} for (0..2);
 102         # we support "-c $key=$val" for arbitrary git config options
 103         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 104         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 105         push @cmd, qw(clone --mirror);
 106         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 107                         ($lei->{opt}->{jobs} // 1) > 1;
 108         push @cmd, '-v' if $lei->{opt}->{verbose};
 109         # XXX any other options to support?
 110         # --reference is tricky with multiple epochs, but handled
 111         # automatically if using manifest.js.gz
 112         @cmd;
 113 }
 114
 115 sub ft_rename ($$$;$) {
 116         my ($ft, $dst, $open_mode, $fh) = @_;
 117         my @st = stat($fh // $dst);
 118         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 119         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 120         require File::Copy;
 121         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 122         $ft->unlink_on_destroy(0);
 123 }
 124
 125 sub do_reap ($;$) {
 126         my ($self, $jobs) = @_;
 127         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 128         $jobs = 1 if $jobs < 1;
 129         while (keys(%$LIVE) >= $jobs) {
 130                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 131                 if (my $x = delete $LIVE->{$pid}) {
 132                         my $cb = shift @$x;
 133                         $cb->(@$x) if $cb;
 134                 } else {
 135                         warn "reaped unknown PID=$pid ($?)\n";
 136                 }
 137         }
 138 }
 139
 140 sub _get_txt_start { # non-fatal
 141         my ($self, $endpoint, $fini) = @_;
 142         my $uri = URI->new($self->{cur_src} // $self->{src});
 143         my $lei = $self->{lei};
 144         my $path = $uri->path;
 145         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 146         $uri->path("$path/$endpoint");
 147         my $f = (split(m!/!, $endpoint))[-1];
 148         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 149         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 150         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(-f --compressed -R -o),
 151                                         $ft->filename);
 152         do_reap($self);
 153         $lei->qerr("# @$cmd");
 154         return if $self->{dry_run};
 155         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 156         $LIVE->{spawn($cmd, undef, $opt)} =
 157                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 158 }
 159
 160 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 161         my ($self, $endpoint) = @_;
 162         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 163         my $cerr = $?;
 164         $? = 0; # don't influence normal lei exit
 165         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 166         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 167         seek($fh, SEEK_SET, 0) or die "seek: $!";
 168         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 169         local $/;
 170         $self->{"txt.$endpoint"} = <$fh>;
 171         undef; # success
 172 }
 173
 174 sub _write_inbox_config {
 175         my ($self) = @_;
 176         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 177         my $dst = $self->{cur_dst} // $self->{dst};
 178         my $f = "$dst/inbox.config.example";
 179         open my $fh, '>', $f or die "open($f): $!";
 180         print $fh $buf or die "print: $!";
 181         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 182         my $mtime = delete $self->{'mtime._/text/config/raw'};
 183         $fh->flush or die "flush($f): $!";
 184         if (defined $mtime) {
 185                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
 186         }
 187         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 188         my $ibx = $self->{ibx} = {};
 189         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 190                 for (qw(address newsgroup nntpmirror)) {
 191                         $ibx->{$_} = $cfg->{"$sec.$_"};
 192                 }
 193         }
 194 }
 195
 196 sub set_description ($) {
 197         my ($self) = @_;
 198         my $dst = $self->{cur_dst} // $self->{dst};
 199         my $f = "$dst/description";
 200         open my $fh, '+>>', $f or die "open($f): $!";
 201         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 202         my $d = do { local $/; <$fh> } // die "read($f): $!";
 203         chomp(my $orig = $d);
 204         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 205                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 206                 $d = delete($self->{'txt.description'});
 207         }
 208         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 209         chomp $d;
 210         return if $d eq $orig;
 211         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 212         truncate($fh, 0) or die "truncate($f): $!";
 213         print $fh $d, "\n" or die "print($f): $!";
 214         close $fh or die "close($f): $!";
 215 }
 216
 217 sub index_cloned_inbox {
 218         my ($self, $iv) = @_;
 219         my $lei = $self->{lei};
 220
 221         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 222         # lei is useless without Xapian + SQLite
 223         if ($lei->{cmd} ne 'public-inbox-clone') {
 224                 require PublicInbox::InboxWritable;
 225                 require PublicInbox::Admin;
 226                 my $ibx = delete($self->{ibx}) // {
 227                         address => [ 'lei@example.com' ],
 228                         version => $iv,
 229                 };
 230                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 231                 PublicInbox::Inbox->new($ibx);
 232                 PublicInbox::InboxWritable->new($ibx);
 233                 my $opt = {};
 234                 for my $sw ($lei->index_opt) {
 235                         my ($k) = ($sw =~ /\A([\w-]+)/);
 236                         $opt->{$k} = $lei->{opt}->{$k};
 237                 }
 238                 # force synchronous dwaitpid for v2:
 239                 local $PublicInbox::DS::in_loop = 0;
 240                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 241                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 242                 local %ENV = (%ENV, %$env) if $env;
 243                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 244                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 245         }
 246         return if defined $self->{cur_dst}; # one of many repos to clone
 247         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 248 }
 249
 250 sub run_reap {
 251         my ($lei, $cmd, $opt) = @_;
 252         $lei->qerr("# @$cmd");
 253         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 254         my $ret = $?;
 255         $? = 0; # don't let it influence normal exit
 256         $ret;
 257 }
 258
 259 sub start_clone {
 260         my ($self, $cmd, $opt, $fini) = @_;
 261         do_reap($self);
 262         $self->{lei}->qerr("# @$cmd");
 263         return if $self->{dry_run};
 264         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 265 }
 266
 267 sub fetch_args ($$) {
 268         my ($lei, $opt) = @_;
 269         my @cmd; # (git --git-dir=...) to be added by caller
 270         $opt->{$_} = $lei->{$_} for (0..2);
 271         # we support "-c $key=$val" for arbitrary git config options
 272         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 273         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 274         push @cmd, 'fetch';
 275         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 276                         ($lei->{opt}->{jobs} // 1) > 1;
 277         push @cmd, '-v' if $lei->{opt}->{verbose};
 278         @cmd;
 279 }
 280
 281 sub upr { # feed `git update-ref --stdin -z' verbosely
 282         my ($lei, $w, $op, $ref, $oid) = @_;
 283         $lei->qerr("# $op $ref $oid") if $lei->{opt}->{verbose};
 284         print $w "$op $ref\0$oid\0" or die "print(w): $!";
 285 }
 286
 287 sub fgrp_update {
 288         my ($fgrp) = @_;
 289         my $srcfh = delete $fgrp->{srcfh} or return;
 290         my $dstfh = delete $fgrp->{dstfh} or return;
 291         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 292         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 293         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 294         close $srcfh;
 295         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 296         close $dstfh;
 297         pipe(my ($r, $w)) or die "pipe: $!";
 298         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 299                 qw(update-ref --stdin -z) ];
 300         my $lei = $fgrp->{lei};
 301         $lei->qerr("# @$cmd");
 302         my $opt = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 303         my $pid = spawn($cmd, undef, $opt);
 304         close $r or die "close(r): $!";
 305         for my $ref (keys %dst) {
 306                 my $new = delete $src{$ref};
 307                 my $old = $dst{$ref};
 308                 if (defined $new) {
 309                         upr($lei, $w, 'update', $ref, $new) if $new ne $old;
 310                 } else {
 311                         upr($lei, $w, 'delete', $ref, $old);
 312                 }
 313         }
 314         while (my ($ref, $oid) = each %src) {
 315                 upr($lei, $w, 'create', $ref, $oid);
 316         }
 317         close($w) or warn "E: close(update-ref --stdin): $! (need git 1.8.5+)\n";
 318         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd ];
 319         pack_refs($fgrp, $fgrp->{cur_dst});
 320 }
 321
 322 sub pack_refs {
 323         my ($self, $git_dir) = @_;
 324         do_reap($self);
 325         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 326         $self->{lei}->qerr("# @$cmd");
 327         return if $self->{dry_run};
 328         my $opt = { 1 => $self->{lei}->{1}, 2 => $self->{lei}->{2} };
 329         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd ];
 330 }
 331
 332 sub fgrpv_done {
 333         my ($fgrpv) = @_;
 334         return if !$LIVE;
 335         my $pid;
 336         my $first = $fgrpv->[0] // die 'BUG: no fgrpv->[0]';
 337         pack_refs($first, $first->{-osdir}); # objstore refs always packed
 338         for my $fgrp (@$fgrpv) {
 339                 my $rn = $fgrp->{-remote};
 340                 my %opt = map { $_ => $fgrp->{lei}->{$_} } (0..2);
 341
 342                 my $update_ref = $fgrp->{dry_run} ? undef :
 343                         PublicInbox::OnDestroy->new($$, \&fgrp_update, $fgrp);
 344
 345                 my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 346                         "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 347                         "refs/remotes/$rn/" ];
 348                 do_reap($fgrp);
 349                 $fgrp->{lei}->qerr("# @$src >SRC");
 350                 if ($update_ref) {
 351                         open(my $fh, '+>', undef) or die "open(src): $!";
 352                         $pid = spawn($src, undef, { %opt, 1 => $fh });
 353                         $fgrp->{srcfh} = $fh;
 354                         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $src, $update_ref ]
 355                 }
 356                 my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 357                         '--format=%(refname)%00%(objectname)' ];
 358                 do_reap($fgrp);
 359                 $fgrp->{lei}->qerr("# @$dst >DST");
 360                 if ($update_ref) {
 361                         open(my $fh, '+>', undef) or die "open(dst): $!";
 362                         $pid = spawn($dst, undef, { %opt, 1 => $fh });
 363                         $fgrp->{dstfh} = $fh;
 364                         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $dst, $update_ref ]
 365                 }
 366         }
 367 }
 368
 369 sub fgrp_fetch_all {
 370         my ($self) = @_;
 371         my $todo = delete $self->{fgrp_todo} or return;
 372         keys(%$todo) or return;
 373
 374         # Rely on the fgrptmp remote groups in the config file rather
 375         # than listing all remotes since the remote name list may exceed
 376         # system argv limits:
 377         my $grp = 'fgrptmp';
 378
 379         my @git = (@{$self->{-torsocks}}, 'git');
 380         my $j = $self->{lei}->{opt}->{jobs};
 381         my $opt = {};
 382         my @fetch = do {
 383                 local $self->{lei}->{opt}->{jobs} = 1;
 384                 (fetch_args($self->{lei}, $opt),
 385                         qw(--no-tags --multiple));
 386         };
 387         push(@fetch, "-j$j") if $j;
 388         my $pid;
 389         while (my ($osdir, $fgrpv) = each %$todo) {
 390                 my $f = "$osdir/config";
 391
 392                 # clobber group from previous run atomically
 393                 my $cmd = ['git', "--git-dir=$osdir", qw(config -f),
 394                                 $f, '--unset-all', "remotes.$grp"];
 395                 $self->{lei}->qerr("# @$cmd");
 396                 if (!$self->{dry_run}) {
 397                         $pid = spawn($cmd);
 398                         waitpid($pid, 0) // die "waitpid: $!";
 399                         die "E: @$cmd: \$?=$?" if ($? && ($? >> 8) != 5);
 400
 401                         # update the config atomically via O_APPEND while
 402                         # respecting git-config locking
 403                         sysopen(my $lk, "$f.lock", O_CREAT|O_EXCL|O_WRONLY)
 404                                 or die "open($f.lock): $!";
 405                         open my $fh, '>>', $f or die "open(>>$f): $!";
 406                         $fh->autoflush(1);
 407                         my $buf = join('', "[remotes]\n",
 408                                 map { "\t$grp = $_->{-remote}\n" } @$fgrpv);
 409                         print $fh $buf or die "print($f): $!";
 410                         close $fh or die "close($f): $!";
 411                         unlink("$f.lock") or die "unlink($f.lock): $!";
 412                 }
 413
 414                 $cmd = [ @git, "--git-dir=$osdir", @fetch, $grp ];
 415                 do_reap($self);
 416                 $self->{lei}->qerr("# @$cmd");
 417                 my $end = PublicInbox::OnDestroy->new($$, \&fgrpv_done, $fgrpv);
 418                 return if $self->{dry_run};
 419                 $pid = spawn($cmd, undef, $opt);
 420                 $LIVE->{$pid} = [ \&reap_cmd, $self, $cmd, $end ];
 421         }
 422 }
 423
 424 # keep this idempotent for future use by public-inbox-fetch
 425 sub forkgroup_prep {
 426         my ($self, $uri) = @_;
 427         $self->{-ent} // return;
 428         my $os = $self->{-objstore} // return;
 429         my $fg = $self->{-ent}->{forkgroup} // return;
 430         my $dir = "$os/$fg.git";
 431         my @cmd = ('git', "--git-dir=$dir", 'config');
 432         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 433         if (!-d $dir && !$self->{dry_run}) {
 434                 PublicInbox::Import::init_bare($dir);
 435                 for ('repack.useDeltaIslands=true',
 436                                 'pack.island=refs/remotes/([^/]+)/') {
 437                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
 438                 }
 439         }
 440         my $key = $self->{-key} // die 'BUG: no -key';
 441         my $rn = $key;
 442         $rn =~ s!\A[\./]+!!s;
 443         $rn =~ s/\.*?(?:\.git)?\.*?\z//s;
 444         $rn =~ s![\@\{\}/:\?\[\]\^~\s\f[:cntrl:]\*]!_!isg;
 445         $rn .= '-'.substr(sha256_hex($key), 0, 16);
 446         unless ($self->{dry_run}) {
 447                 # --no-tags is required to avoid conflicts
 448                 for ("url=$uri", "fetch=+refs/*:refs/remotes/$rn/*",
 449                                 'tagopt=--no-tags') {
 450                         my @kv = split(/=/, $_, 2);
 451                         $kv[0] = "remote.$rn.$kv[0]";
 452                         run_die([@cmd, @kv], undef, $opt);
 453                 }
 454         }
 455         if (!-d $self->{cur_dst} && !$self->{dry_run}) {
 456                 my $alt = File::Spec->rel2abs("$dir/objects");
 457                 PublicInbox::Import::init_bare($self->{cur_dst});
 458                 my $o = "$self->{cur_dst}/objects";
 459                 my $f = "$o/info/alternates";
 460                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 461                 open my $fh, '+>>', $f or die "open($f): $!";
 462                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 463                 chomp(my @cur = <$fh>);
 464                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 465                         say $fh $l or die "say($f): $!";
 466                 }
 467                 close $fh or die "close($f): $!";
 468                 $f = "$self->{cur_dst}/config";
 469                 open $fh, '+>>', $f or die "open:($f): $!";
 470                 print $fh <<EOM or die "print($f): $!";
 471 ; rely on the "$rn" remote in the
 472 ; $fg fork group for fetches
 473 ; only uncomment the following iff you detach from fork groups
 474 ; [remote "origin"]
 475 ;       url = $uri
 476 ;       fetch = +refs/*:refs/*
 477 ;       mirror = true
 478 EOM
 479                 close $fh or die "close($f): $!";
 480         }
 481         bless { %$self, -osdir => $dir, -remote => $rn }, __PACKAGE__;
 482 }
 483
 484 sub clone_v1 {
 485         my ($self, $nohang) = @_;
 486         my $lei = $self->{lei};
 487         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 488         my $uri = URI->new($self->{cur_src} // $self->{src});
 489         defined($lei->{opt}->{epoch}) and
 490                 die "$uri is a v1 inbox, --epoch is not supported\n";
 491         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 492         my $dst = $self->{cur_dst} // $self->{dst};
 493         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 494         if (my $fgrp = forkgroup_prep($self, $uri)) {
 495                 $fgrp->{-fini} = $fini;
 496                 push @{$self->{fgrp_todo}->{$fgrp->{-osdir}}}, $fgrp;
 497         } else { # normal fetch
 498                 my $cmd = [ @{$self->{-torsocks}},
 499                                 clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 500                 if (defined($self->{-ent})) {
 501                         if (defined(my $ref = $self->{-ent}->{reference})) {
 502                                 -e "$self->{dst}$ref" and
 503                                         push @$cmd, '--reference',
 504                                                 "$self->{dst}$ref";
 505                         }
 506                 }
 507                 start_clone($self, $cmd, $opt, $fini);
 508         }
 509         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 510                                 /\A(?:always|v1)\z/s) {
 511                 _get_txt_start($self, '_/text/config/raw', $fini);
 512         }
 513
 514         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 515         $self->{'txt.description'} = $d if defined $d;
 516         (!defined($d) && !$nohang) and
 517                 _get_txt_start($self, 'description', $fini);
 518
 519         $nohang or do_reap($self, 1); # for non-manifest clone
 520 }
 521
 522 sub parse_epochs ($$) {
 523         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 524         $opt_epochs // return; # undef => all epochs
 525         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 526         undef($lo) if ($lo // '') eq '';
 527         my $re = qr/\A~?[0-9]+\z/;
 528         if (@extra || (($lo // '0') !~ $re) ||
 529                         (($hi // '0') !~ $re) ||
 530                         !(grep(defined, $lo, $hi))) {
 531                 die <<EOM;
 532 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 533 EOM
 534         }
 535         my @n = sort { $a <=> $b } keys %$v2_epochs;
 536         for (grep(defined, $lo, $hi)) {
 537                 if (/\A[0-9]+\z/) {
 538                         $_ > $n[-1] and die
 539 "`$_' exceeds maximum available epoch ($n[-1])\n";
 540                         $_ < $n[0] and die
 541 "`$_' is lower than minimum available epoch ($n[0])\n";
 542                 } elsif (/\A~([0-9]+)/) {
 543                         my $off = -$1 - 1;
 544                         $n[$off] // die "`$_' is out of range\n";
 545                         $_ = $n[$off];
 546                 } else { die "`$_' not understood\n" }
 547         }
 548         defined($lo) && defined($hi) && $lo > $hi and die
 549 "low value (`$lo') exceeds high (`$hi')\n";
 550         $lo //= $n[0] if $dotdot;
 551         $hi //= $n[-1] if $dotdot;
 552         $hi //= $lo;
 553         my $want = {};
 554         for ($lo..$hi) {
 555                 if (defined $v2_epochs->{$_}) {
 556                         $want->{$_} = 1;
 557                 } else {
 558                         warn
 559 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 560                 }
 561         }
 562         $want
 563 }
 564
 565 sub init_placeholder ($$$) {
 566         my ($src, $edst, $ent) = @_;
 567         PublicInbox::Import::init_bare($edst);
 568         my $f = "$edst/config";
 569         open my $fh, '>>', $f or die "open($f): $!";
 570         print $fh <<EOM or die "print($f): $!";
 571 [remote "origin"]
 572         url = $src
 573         fetch = +refs/*:refs/*
 574         mirror = true
 575
 576 ; This git epoch was created read-only and "public-inbox-fetch"
 577 ; will not fetch updates for it unless write permission is added.
 578 ; Hint: chmod +w $edst
 579 EOM
 580         if (defined($ent->{owner})) {
 581                 print $fh <<EOM or die "print($f): $!";
 582 [gitweb]
 583         owner = $ent->{owner}
 584 EOM
 585         }
 586         close $fh or die "close($f): $!";
 587         my %map = (head => 'HEAD', description => undef);
 588         while (my ($key, $fn) = each %map) {
 589                 my $val = $ent->{$key} // next;
 590                 $fn //= $key;
 591                 $fn = "$edst/$fn";
 592                 open $fh, '>', $fn or die "open($fn): $!";
 593                 print $fh $val, "\n" or die "print($fn): $!";
 594                 close $fh or die "close($fn): $!";
 595         }
 596 }
 597
 598 sub reap_cmd { # async, called via SIGCHLD
 599         my ($self, $cmd) = @_;
 600         my $cerr = $?;
 601         $? = 0; # don't let it influence normal exit
 602         if ($cerr) {
 603                 kill('TERM', keys %$LIVE);
 604                 $self->{lei}->child_error($cerr, "@$cmd failed");
 605         }
 606 }
 607
 608 sub v1_done { # called via OnDestroy
 609         my ($self) = @_;
 610         return if $self->{dry_run} || !$LIVE;
 611         _write_inbox_config($self);
 612         my $dst = $self->{cur_dst} // $self->{dst};
 613         if (defined(my $o = $self->{-ent} ? $self->{-ent}->{owner} : undef)) {
 614                 run_die([qw(git config -f), "$dst/config", 'gitweb.owner', $o]);
 615         }
 616         my $o = "$dst/objects";
 617         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
 618                 my $base = File::Spec->rel2abs($o);
 619                 my @l = <$fh>;
 620                 my $ft;
 621                 for (@l) {
 622                         next unless m!\A/!;
 623                         $_ = File::Spec->abs2rel($_, $base);
 624                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
 625                                                 DIR => "$o/info");
 626                 }
 627                 if ($ft) {
 628                         print $ft @l or die "print($ft): $!";
 629                         $ft->flush or die "flush($ft): $!";
 630                         ft_rename($ft, $fn, 0666, $fh);
 631                 }
 632         }
 633         eval { set_description($self) };
 634         warn $@ if $@;
 635         return if ($self->{-is_epoch} ||
 636                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 637         write_makefile($dst, 1);
 638         index_cloned_inbox($self, 1);
 639 }
 640
 641 sub v2_done { # called via OnDestroy
 642         my ($self) = @_;
 643         return if $self->{dry_run} || !$LIVE;
 644         my $dst = $self->{cur_dst} // $self->{dst};
 645         require PublicInbox::Lock;
 646         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 647         my $lck = $lk->lock_for_scope($$);
 648         _write_inbox_config($self);
 649         require PublicInbox::MultiGit;
 650         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 651         $mg->fill_alternates;
 652         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 653         for my $edst (@{delete($self->{-read_only}) // []}) {
 654                 my @st = stat($edst) or die "stat($edst): $!";
 655                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 656         }
 657         write_makefile($dst, 2);
 658         undef $lck; # unlock
 659         eval { set_description($self) };
 660         warn $@ if $@;
 661         index_cloned_inbox($self, 2);
 662 }
 663
 664 sub clone_v2_prep ($$;$) {
 665         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 666         my $lei = $self->{lei};
 667         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 668         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 669         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 670         my $dst = $self->{cur_dst} // $self->{dst};
 671         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 672         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 673         delete $task->{todo}; # $self->{todo} still exists
 674         my (@skip, $desc);
 675         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 676         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 677                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 678                 my $src = $uri->as_string;
 679                 my $edst = $dst;
 680                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 681 failed to extract epoch number from $src
 682
 683                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 684                 $edst .= "/git/$nr.git";
 685                 my $ent;
 686                 if ($m) {
 687                         $ent = $m->{$key} //
 688                                 die("BUG: `$key' not in manifest.js.gz");
 689                         if (defined(my $d = $ent->{description})) {
 690                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 691                                 $desc = $d;
 692                         }
 693                 }
 694                 if (!$want || $want->{$nr}) {
 695                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 696                         $etask->{-ent} = $ent; # may have {reference}
 697                         $etask->{cur_src} = $src;
 698                         $etask->{cur_dst} = $edst;
 699                         $etask->{-is_epoch} = $fini;
 700                         my $ref = $ent->{reference} // '';
 701                         push @{$self->{todo}->{$ref}}, $etask;
 702                         $self->{any_want}->{$key} = 1;
 703                 } else { # create a placeholder so users only need to chmod +w
 704                         init_placeholder($src, $edst, $ent);
 705                         push @{$task->{-read_only}}, $edst;
 706                         push @skip, $key;
 707                 }
 708         }
 709         # filter out the epochs we skipped
 710         $self->{-culled_manifest} = 1 if $m && delete(@$m{@skip});
 711
 712         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 713
 714         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 715                 _get_txt_start($task, '_/text/config/raw', $fini);
 716
 717         defined($desc) ? ($task->{'txt.description'} = $desc) :
 718                 _get_txt_start($task, 'description', $fini);
 719 }
 720
 721 sub decode_manifest ($$$) {
 722         my ($fh, $fn, $uri) = @_;
 723         my $js;
 724         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 725         gunzip(\$gz => \$js, MultiStream => 1) or
 726                 die "gunzip($uri): $GunzipError\n";
 727         my $m = eval { PublicInbox::Config->json->decode($js) };
 728         die "$uri: error decoding `$js': $@\n" if $@;
 729         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 730         $m;
 731 }
 732
 733 sub multi_inbox ($$$) {
 734         my ($self, $path, $m) = @_;
 735         my $incl = $self->{lei}->{opt}->{include};
 736         my $excl = $self->{lei}->{opt}->{exclude};
 737
 738         # assuming everything not v2 is v1, for now
 739         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 740         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 741         my $v2 = {};
 742
 743         for (@v2_epochs) {
 744                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 745                 push @{$v2->{$1}}, $_;
 746         }
 747         my $n = scalar(keys %$v2) + scalar(@v1);
 748         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 749         if (defined $incl) {
 750                 my $re = '(?:'.join('\\z|', map {
 751                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 752                         } @$incl).'\\z)';
 753                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 754                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 755                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
 756                 @v1 = grep(/$re/, @v1);
 757         }
 758         if (defined $excl) {
 759                 my $re = '(?:'.join('\\z|', map {
 760                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 761                         } @$excl).'\\z)';
 762                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 763                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 764                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
 765                 @v1 = grep(!/$re/, @v1);
 766         }
 767         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 768         $ret->{v1} = \@v1 if @v1;
 769         $ret->{v2} = $v2 if keys %$v2;
 770         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 771                                 join("\n\t", sort @orig)
 772                         : "Nothing available to clone\n";
 773         my $path_pfx = '';
 774
 775         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 776         if (@v2_epochs) {
 777                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 778                                 @v2_epochs) == @v2_epochs) {
 779                         $$path =~ s!\A(/[^/]+)/!/! or last;
 780                         $path_pfx .= $1;
 781                 }
 782         } elsif (@v1) {
 783                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 784                         $path_pfx .= $1;
 785                 }
 786         }
 787         ($path_pfx, $n, $ret);
 788 }
 789
 790 sub clone_all {
 791         my ($self, $m) = @_;
 792         my $todo = delete $self->{todo};
 793         my $nodep = delete $todo->{''};
 794
 795         # do not download unwanted deps
 796         my $any_want = delete $self->{any_want};
 797         my @unwanted = grep { !$any_want->{$_} } keys %$todo;
 798         my @nodep = delete(@$todo{@unwanted});
 799         push(@$nodep, @$_) for @nodep;
 800
 801         # handle no-dependency repos, first
 802         for (@$nodep) {
 803                 clone_v1($_, 1);
 804                 return if $self->{lei}->{child_error};
 805         }
 806         # resolve references, deepest, first:
 807         while (scalar keys %$todo) {
 808                 for my $x (keys %$todo) {
 809                         my ($nr, $nxt);
 810                         # resolve multi-level references
 811                         while ($m && defined($nxt = $m->{$x}->{reference})) {
 812                                 exists($todo->{$nxt}) or last;
 813                                 die <<EOM if ++$nr > 1000;
 814 E: dependency loop detected (`$x' => `$nxt')
 815 EOM
 816                                 $x = $nxt;
 817                         }
 818                         my $y = delete $todo->{$x} // next; # already done
 819                         for (@$y) {
 820                                 clone_v1($_, 1);
 821                                 return if $self->{lei}->{child_error};
 822                         }
 823                         last; # restart %$todo iteration
 824                 }
 825         }
 826         fgrp_fetch_all($self);
 827         do_reap($self, 1);
 828 }
 829
 830 sub dump_manifest ($$) {
 831         my ($m, $ft) = @_;
 832         # write the smaller manifest if epochs were skipped so
 833         # users won't have to delete manifest if they +w an
 834         # epoch they no longer want to skip
 835         my $json = PublicInbox::Config->json->encode($m);
 836         my $mtime = (stat($ft))[9];
 837         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
 838         truncate($ft, 0) or die "truncate($ft): $!";
 839         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
 840         $ft->flush or die "flush($ft): $!";
 841         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
 842 }
 843
 844 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
 845 sub try_manifest {
 846         my ($self) = @_;
 847         my $uri = URI->new($self->{src});
 848         my $lei = $self->{lei};
 849         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 850         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 851         my $path = $uri->path;
 852         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 853         $uri->path($path . '/manifest.js.gz');
 854         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX',
 855                                 UNLINK => 1, TMPDIR => 1, SUFFIX => '.tmp');
 856         my $cmd = $curl->for_uri($lei, $uri, qw(-f -R -o), $ft->filename);
 857         my %opt = map { $_ => $lei->{$_} } (0..2);
 858         my $cerr = run_reap($lei, $cmd, \%opt);
 859         if ($cerr) {
 860                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
 861                 return $lei->child_error($cerr, "@$cmd failed");
 862         }
 863         my $m = eval { decode_manifest($ft, $ft, $uri) };
 864         if ($@) {
 865                 warn $@;
 866                 return try_scrape($self);
 867         }
 868         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
 869         return $lei->child_error(1, $multi) if !ref($multi);
 870         my $v2 = delete $multi->{v2};
 871         local $self->{todo} = {};
 872         local $self->{fgrp_todo} = {}; # { objstore_dir => [fgrp, ...] }
 873         if ($v2) {
 874                 for my $name (sort keys %$v2) {
 875                         my $epochs = delete $v2->{$name};
 876                         my %v2_epochs = map {
 877                                 $uri->path($n > 1 ? $path_pfx.$path.$_
 878                                                 : $path_pfx.$_);
 879                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
 880                                 $e // die "no [0-9]+\.git in `$uri'";
 881                                 $e => [ $uri->clone, $_ ];
 882                         } @$epochs;
 883                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
 884                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
 885                         local $self->{cur_src} = $1;
 886                         local $self->{cur_dst} = $self->{dst};
 887                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
 888                                                         git/[0-9]+\.git\z!x) {
 889                                 $self->{cur_dst} .= "/$1";
 890                         }
 891                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
 892 E: `$self->{cur_dst}' must not contain newline
 893 EOM
 894                         clone_v2_prep($self, \%v2_epochs, $m);
 895                         return if $self->{lei}->{child_error};
 896                 }
 897         }
 898         if (my $v1 = delete $multi->{v1}) {
 899                 my $p = $path_pfx.$path;
 900                 chop($p) if substr($p, -1, 1) eq '/';
 901                 $uri->path($p);
 902                 for my $name (@$v1) {
 903                         my $task = bless { %$self }, __PACKAGE__;
 904                         $task->{-ent} = $m->{$name} //
 905                                         die("BUG: no `$name' in manifest");
 906                         $task->{cur_src} = "$uri";
 907                         $task->{cur_dst} = $task->{dst};
 908                         $task->{-key} = $name;
 909                         if ($n > 1) {
 910                                 $task->{cur_dst} .= $name;
 911                                 $task->{cur_src} .= $name;
 912                         }
 913                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
 914 E: `$task->{cur_dst}' must not contain newline
 915 EOM
 916                         $task->{cur_src} .= '/';
 917                         my $dep = $task->{-ent}->{reference} // '';
 918                         push @{$self->{todo}->{$dep}}, $task; # for clone_all
 919                         $self->{any_want}->{$name} = 1;
 920                 }
 921         }
 922         delete local $lei->{opt}->{epoch} if defined($v2);
 923         clone_all($self, $m);
 924         return if $self->{lei}->{child_error} || $self->{dry_run};
 925
 926         # set by clone_v2_prep/-I/--exclude
 927         dump_manifest($m => $ft) if delete $self->{-culled_manifest};
 928         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
 929         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 930 }
 931
 932 sub start_clone_url {
 933         my ($self) = @_;
 934         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 935         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 936 }
 937
 938 sub do_mirror { # via wq_io_do or public-inbox-clone
 939         my ($self) = @_;
 940         my $lei = $self->{lei};
 941         $self->{dry_run} = 1 if $lei->{opt}->{'dry-run'};
 942         umask($lei->{client_umask}) if defined $lei->{client_umask};
 943         eval {
 944                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
 945                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
 946 --inbox-config must be one of `always', `v2', `v1', or `never'
 947
 948                 if (defined(my $os = $lei->{opt}->{objstore})) {
 949                         $os = 'objstore' if $os eq ''; # --objstore w/o args
 950                         $os = "$self->{dst}/$os" if $os !~ m!\A/!;
 951                         $self->{-objstore} = $os;
 952                 }
 953                 local $LIVE;
 954                 my $iv = $lei->{opt}->{'inbox-version'} //
 955                         return start_clone_url($self);
 956                 return clone_v1($self) if $iv == 1;
 957                 die "bad --inbox-version=$iv\n" if $iv != 2;
 958                 die <<EOM if $self->{src} !~ m!://!;
 959 cloning local v2 inboxes not supported
 960 EOM
 961                 try_scrape($self, 1);
 962         };
 963         $lei->fail($@) if $@;
 964 }
 965
 966 sub start {
 967         my ($cls, $lei, $src, $dst) = @_;
 968         my $self = bless { src => $src, dst => $dst }, $cls;
 969         $lei->request_umask;
 970         my ($op_c, $ops) = $lei->workers_start($self, 1);
 971         $lei->{wq1} = $self;
 972         $self->wq_io_do('do_mirror', []);
 973         $self->wq_close;
 974         $lei->wait_wq_events($op_c, $ops);
 975 }
 976
 977 sub ipc_atfork_child {
 978         my ($self) = @_;
 979         $self->{lei}->_lei_atfork_child;
 980         $self->SUPER::ipc_atfork_child;
 981 }
 982
 983 sub write_makefile {
 984         my ($dir, $ibx_ver) = @_;
 985         my $f = "$dir/Makefile";
 986         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
 987                 print $fh <<EOM or die "print($f) $!";
 988 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
 989 # manpage for more information on the format.  This Makefile is
 990 # intended as a familiar wrapper for users unfamiliar with
 991 # public-inbox-* commands.
 992 #
 993 # See the respective manpages for public-inbox-fetch(1),
 994 # public-inbox-index(1), etc for more information on
 995 # some of the commands used by this Makefile.
 996 #
 997 # This Makefile will not be modified nor read by public-inbox,
 998 # so you may edit it freely with your own convenience targets
 999 # and notes.  public-inbox-fetch will recreate it if removed.
1000 EOM
1001                 print $fh <<'EOM' or die "print($f): $!";
1002 # the default target:
1003 help :
1004         @echo Common targets:
1005         @echo '    make fetch        - fetch from remote git repostorie(s)'
1006         @echo '    make update       - fetch and update index '
1007         @echo
1008         @echo Rarely needed targets:
1009         @echo '    make reindex      - may be needed for new features/bugfixes'
1010         @echo '    make compact      - rewrite Xapian storage to save space'
1011         @echo '    make index        - initial index after clone
1012
1013 fetch :
1014         public-inbox-fetch
1015 update :
1016         @if ! public-inbox-fetch --exit-code; \
1017         then \
1018                 c=$$?; \
1019                 test $$c -eq 127 && exit 0; \
1020                 exit $$c; \
1021         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
1022         then \
1023                 public-inbox-index; \
1024         else \
1025                 echo 'public-inbox index not initialized'; \
1026                 echo 'see public-inbox-index(1) man page'; \
1027         fi
1028 index :
1029         public-inbox-index
1030 reindex :
1031         public-inbox-index --reindex
1032 compact :
1033         public-inbox-compact
1034
1035 .PHONY : help fetch update index reindex compact
1036 EOM
1037                 close $fh or die "close($f): $!";
1038         } else {
1039                 die "open($f): $!" unless $!{EEXIST};
1040         }
1041 }
1042
1043 1;