lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::LeiCurl;
  20 use PublicInbox::OnDestroy;
  21 use Digest::SHA qw(sha256_hex sha1_hex);
  22 use POSIX qw(strftime);
  23
  24 our $LIVE; # pid => callback
  25 our $FGRP_TODO; # objstore -> [ fgrp mirror objects ]
  26 our $TODO; # reference => [ non-fgrp mirror objects ]
  27 our @PUH; # post-update hooks
  28
  29 sub keep_going ($) {
  30         $LIVE && (!$_[0]->{lei}->{child_error} ||
  31                 $_[0]->{lei}->{opt}->{'keep-going'});
  32 }
  33
  34 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  35         my ($arg, $pid) = @_;
  36         my ($mrr, $lei) = @$arg;
  37         if ($?) {
  38                 $lei->child_error($?);
  39         } elsif (!$lei->{child_error}) {
  40                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  41                         require PublicInbox::LeiAddExternal;
  42                         PublicInbox::LeiAddExternal::_finish_add_external(
  43                                                         $lei, $mrr->{dst});
  44                 }
  45                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  46         }
  47         $lei->dclose;
  48 }
  49
  50 # for old installations without manifest.js.gz
  51 sub try_scrape {
  52         my ($self, $fallback_manifest) = @_;
  53         my $uri = URI->new($self->{src});
  54         my $lei = $self->{lei};
  55         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  56         my $cmd = $curl->for_uri($lei, $uri, '--compressed');
  57         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  58         my $fh = popen_rd($cmd, undef, $opt);
  59         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  60         close($fh) or return $lei->child_error($?, "@$cmd failed");
  61
  62         # we grep with URL below, we don't want Subject/From headers
  63         # making us clone random URLs.  This assumes remote instances
  64         # prior to public-inbox 1.7.0
  65         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  66         my @html = split(/<hr>/, $html);
  67         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  68         if (!@urls && $fallback_manifest) {
  69                 warn <<EOM;
  70 W: failed to extract URLs from $uri, trying manifest.js.gz...
  71 EOM
  72                 return start_clone_url($self);
  73         }
  74         my $url = $uri->as_string;
  75         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  76
  77         # since this is for old instances w/o manifest.js.gz, try v1 first
  78         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  79         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  80                 my %v2_epochs = map {
  81                         my ($n) = (m!/([0-9]+)\z!);
  82                         $n => [ URI->new($_), '' ]
  83                 } @v2_urls; # uniq
  84                 clone_v2_prep($self, \%v2_epochs);
  85                 delete local $lei->{opt}->{epoch};
  86                 clone_all($self);
  87                 return;
  88         }
  89
  90         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  91         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  92                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  93                 die <<"";
  94 E: confused by scraping <$uri>, did you mean <$url>?
  95
  96         }
  97         @urls and die <<"";
  98 E: confused by scraping <$uri>, got ambiguous results:
  99 @urls
 100
 101         die "E: scraping <$uri> revealed nothing\n";
 102 }
 103
 104 sub clone_cmd {
 105         my ($lei, $opt) = @_;
 106         my @cmd = qw(git);
 107         $opt->{$_} = $lei->{$_} for (0..2);
 108         # we support "-c $key=$val" for arbitrary git config options
 109         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 110         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 111         push @cmd, qw(clone --mirror);
 112         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 113                         ($lei->{opt}->{jobs} // 1) > 1;
 114         push @cmd, '-v' if $lei->{opt}->{verbose};
 115         # XXX any other options to support?
 116         # --reference is tricky with multiple epochs, but handled
 117         # automatically if using manifest.js.gz
 118         @cmd;
 119 }
 120
 121 sub ft_rename ($$$;$) {
 122         my ($ft, $dst, $open_mode, $fh) = @_;
 123         my @st = stat($fh // $dst);
 124         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 125         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 126         require File::Copy;
 127         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 128         $ft->unlink_on_destroy(0);
 129 }
 130
 131 sub do_reap ($;$) {
 132         my ($self, $jobs) = @_;
 133         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 134         $jobs = 1 if $jobs < 1;
 135         while (keys(%$LIVE) >= $jobs) {
 136                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 137                 if (my $x = delete $LIVE->{$pid}) {
 138                         my $cb = shift @$x;
 139                         $cb->(@$x) if $cb;
 140                 } else {
 141                         warn "reaped unknown PID=$pid ($?)\n";
 142                 }
 143         }
 144 }
 145
 146 sub _get_txt_start { # non-fatal
 147         my ($self, $endpoint, $fini) = @_;
 148         my $uri = URI->new($self->{cur_src} // $self->{src});
 149         my $lei = $self->{lei};
 150         my $path = $uri->path;
 151         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 152         $uri->path("$path/$endpoint");
 153         my $f = (split(m!/!, $endpoint))[-1];
 154         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 155         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 156         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(--compressed -R -o),
 157                                         $ft->filename);
 158         do_reap($self);
 159         $lei->qerr("# @$cmd");
 160         return if $self->{dry_run};
 161         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 162         $LIVE->{spawn($cmd, undef, $opt)} =
 163                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 164 }
 165
 166 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 167         my ($self, $endpoint) = @_;
 168         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 169         my $cerr = $?;
 170         $? = 0; # don't influence normal lei exit
 171         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 172         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 173         seek($fh, SEEK_SET, 0) or die "seek: $!";
 174         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 175         local $/;
 176         $self->{"txt.$endpoint"} = <$fh>;
 177         undef; # success
 178 }
 179
 180 sub _write_inbox_config {
 181         my ($self) = @_;
 182         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 183         my $dst = $self->{cur_dst} // $self->{dst};
 184         my $f = "$dst/inbox.config.example";
 185         my $mtime = delete $self->{'mtime._/text/config/raw'};
 186         if (sysopen(my $fh, $f, O_CREAT|O_EXCL|O_WRONLY)) {
 187                 print $fh $buf or die "print: $!";
 188                 chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 189                 $fh->flush or die "flush($f): $!";
 190                 if (defined $mtime) {
 191                         utime($mtime, $mtime, $fh) or die "utime($f): $!";
 192                 }
 193         } elsif (!$!{EEXIST}) {
 194                 die "open($f): $!";
 195         }
 196         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 197         my $ibx = $self->{ibx} = {};
 198         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 199                 for (qw(address newsgroup nntpmirror)) {
 200                         $ibx->{$_} = $cfg->{"$sec.$_"};
 201                 }
 202         }
 203 }
 204
 205 sub set_description ($) {
 206         my ($self) = @_;
 207         my $dst = $self->{cur_dst} // $self->{dst};
 208         chomp(my $orig = PublicInbox::Git::try_cat("$dst/description"));
 209         my $d = $orig;
 210         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 211                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 212                 $d = delete($self->{'txt.description'});
 213         }
 214         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 215         atomic_write($dst, 'description', $d."\n") if $d ne $orig;
 216 }
 217
 218 sub index_cloned_inbox {
 219         my ($self, $iv) = @_;
 220         my $lei = $self->{lei};
 221
 222         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 223         # lei is useless without Xapian + SQLite
 224         if ($lei->{cmd} ne 'public-inbox-clone') {
 225                 require PublicInbox::InboxWritable;
 226                 require PublicInbox::Admin;
 227                 my $ibx = delete($self->{ibx}) // {
 228                         address => [ 'lei@example.com' ],
 229                         version => $iv,
 230                 };
 231                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 232                 PublicInbox::Inbox->new($ibx);
 233                 PublicInbox::InboxWritable->new($ibx);
 234                 my $opt = {};
 235                 for my $sw ($lei->index_opt) {
 236                         my ($k) = ($sw =~ /\A([\w-]+)/);
 237                         $opt->{$k} = $lei->{opt}->{$k};
 238                 }
 239                 # force synchronous dwaitpid for v2:
 240                 local $PublicInbox::DS::in_loop = 0;
 241                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 242                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 243                 local %ENV = (%ENV, %$env) if $env;
 244                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 245                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 246         }
 247         return if defined $self->{cur_dst}; # one of many repos to clone
 248 }
 249
 250 sub run_reap {
 251         my ($lei, $cmd, $opt) = @_;
 252         $lei->qerr("# @$cmd");
 253         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 254         my $ret = $?;
 255         $? = 0; # don't let it influence normal exit
 256         $ret;
 257 }
 258
 259 sub start_cmd {
 260         my ($self, $cmd, $opt, $fini) = @_;
 261         do_reap($self);
 262         $self->{lei}->qerr("# @$cmd");
 263         return if $self->{dry_run};
 264         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 265 }
 266
 267 sub fetch_args ($$) {
 268         my ($lei, $opt) = @_;
 269         my @cmd; # (git --git-dir=...) to be added by caller
 270         $opt->{$_} = $lei->{$_} for (0..2);
 271         # we support "-c $key=$val" for arbitrary git config options
 272         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 273         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 274         push @cmd, 'fetch';
 275         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 276                         ($lei->{opt}->{jobs} // 1) > 1;
 277         push @cmd, '-v' if $lei->{opt}->{verbose};
 278         push(@cmd, '-p') if $lei->{opt}->{prune};
 279         @cmd;
 280 }
 281
 282 sub upr { # feed `git update-ref --stdin -z' verbosely
 283         my ($lei, $w, $op, @rest) = @_; # ($ref, $oid) = @rest
 284         $lei->qerr("# $op @rest") if $lei->{opt}->{verbose};
 285         print $w "$op ", join("\0", @rest, '') or die "print(w): $!";
 286 }
 287
 288 sub fgrp_update {
 289         my ($fgrp) = @_;
 290         return if !keep_going($fgrp);
 291         my $srcfh = delete $fgrp->{srcfh} or return;
 292         my $dstfh = delete $fgrp->{dstfh} or return;
 293         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 294         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 295         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 296         close $srcfh;
 297         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 298         close $dstfh;
 299         pipe(my ($r, $w)) or die "pipe: $!";
 300         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 301                 qw(update-ref --stdin -z) ];
 302         my $lei = $fgrp->{lei};
 303         my $pack = PublicInbox::OnDestroy->new($$, \&satellite_done, $fgrp);
 304         start_cmd($fgrp, $cmd, { 0 => $r, 2 => $lei->{2} }, $pack);
 305         close $r or die "close(r): $!";
 306         return if $fgrp->{dry_run};
 307         for my $ref (keys %dst) {
 308                 my $new = delete $src{$ref};
 309                 my $old = $dst{$ref};
 310                 if (defined $new) {
 311                         $new eq $old or
 312                                 upr($lei, $w, 'update', $ref, $new, $old);
 313                 } else {
 314                         upr($lei, $w, 'delete', $ref, $old);
 315                 }
 316         }
 317         while (my ($ref, $oid) = each %src) {
 318                 upr($lei, $w, 'create', $ref, $oid);
 319         }
 320         close($w) or warn "E: close(update-ref --stdin): $! (need git 1.8.5+)\n";
 321 }
 322
 323 sub satellite_done {
 324         my ($fgrp) = @_;
 325         pack_refs($fgrp, $fgrp->{cur_dst});
 326         run_puh($fgrp);
 327 }
 328
 329 sub pack_refs {
 330         my ($self, $git_dir) = @_;
 331         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 332         start_cmd($self, $cmd, { 2 => $self->{lei}->{2} });
 333 }
 334
 335 sub fgrpv_done {
 336         my ($fgrpv) = @_;
 337         return if !$LIVE;
 338         my $first = $fgrpv->[0] // die 'BUG: no fgrpv->[0]';
 339         return if !keep_going($first);
 340         pack_refs($first, $first->{-osdir}); # objstore refs always packed
 341         for my $fgrp (@$fgrpv) {
 342                 my $rn = $fgrp->{-remote};
 343                 my %opt = ( 2 => $fgrp->{lei}->{2} );
 344
 345                 my $update_ref = PublicInbox::OnDestroy->new($$,
 346                                                         \&fgrp_update, $fgrp);
 347
 348                 my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 349                         "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 350                         "refs/remotes/$rn/" ];
 351                 open(my $sfh, '+>', undef) or die "open(src): $!";
 352                 $fgrp->{srcfh} = $sfh;
 353                 start_cmd($fgrp, $src, { %opt, 1 => $sfh }, $update_ref);
 354                 my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 355                         '--format=%(refname)%00%(objectname)' ];
 356                 open(my $dfh, '+>', undef) or die "open(dst): $!";
 357                 $fgrp->{dstfh} = $dfh;
 358                 start_cmd($fgrp, $dst, { %opt, 1 => $dfh }, $update_ref);
 359         }
 360 }
 361
 362 sub fgrp_fetch_all {
 363         my ($self) = @_;
 364         my $todo = $FGRP_TODO;
 365         $FGRP_TODO = \'BUG on further use';
 366         keys(%$todo) or return;
 367
 368         # Rely on the fgrptmp remote groups in the config file rather
 369         # than listing all remotes since the remote name list may exceed
 370         # system argv limits:
 371         my $grp = 'fgrptmp';
 372
 373         my @git = (@{$self->{-torsocks}}, 'git');
 374         my $j = $self->{lei}->{opt}->{jobs};
 375         my $opt = {};
 376         my @fetch = do {
 377                 local $self->{lei}->{opt}->{jobs} = 1;
 378                 (fetch_args($self->{lei}, $opt),
 379                         qw(--no-tags --multiple));
 380         };
 381         push(@fetch, "-j$j") if $j;
 382         while (my ($osdir, $fgrpv) = each %$todo) {
 383                 my $f = "$osdir/config";
 384                 return if !keep_going($self);
 385
 386                 # clobber group from previous run atomically
 387                 my $cmd = ['git', "--git-dir=$osdir", qw(config -f),
 388                                 $f, '--unset-all', "remotes.$grp"];
 389                 $self->{lei}->qerr("# @$cmd");
 390                 if (!$self->{dry_run}) {
 391                         my $pid = spawn($cmd, undef, { 2 => $self->{lei}->{2} });
 392                         waitpid($pid, 0) // die "waitpid: $!";
 393                         die "E: @$cmd: \$?=$?" if ($? && ($? >> 8) != 5);
 394
 395                         # update the config atomically via O_APPEND while
 396                         # respecting git-config locking
 397                         sysopen(my $lk, "$f.lock", O_CREAT|O_EXCL|O_WRONLY)
 398                                 or die "open($f.lock): $!";
 399                         open my $fh, '>>', $f or die "open(>>$f): $!";
 400                         $fh->autoflush(1);
 401                         my $buf = join('', "[remotes]\n",
 402                                 map { "\t$grp = $_->{-remote}\n" } @$fgrpv);
 403                         print $fh $buf or die "print($f): $!";
 404                         close $fh or die "close($f): $!";
 405                         unlink("$f.lock") or die "unlink($f.lock): $!";
 406                 }
 407
 408                 $cmd = [ @git, "--git-dir=$osdir", @fetch, $grp ];
 409                 my $end = PublicInbox::OnDestroy->new($$, \&fgrpv_done, $fgrpv);
 410                 start_cmd($self, $cmd, $opt, $end);
 411         }
 412 }
 413
 414 # keep this idempotent for future use by public-inbox-fetch
 415 sub forkgroup_prep {
 416         my ($self, $uri) = @_;
 417         $self->{-ent} // return;
 418         my $os = $self->{-objstore} // return;
 419         my $fg = $self->{-ent}->{forkgroup} // return;
 420         my $dir = "$os/$fg.git";
 421         if (!-d $dir && !$self->{dry_run}) {
 422                 PublicInbox::Import::init_bare($dir);
 423                 my @cmd = ('git', "--git-dir=$dir", 'config');
 424                 my $opt = { 2 => $self->{lei}->{2} };
 425                 for ('repack.useDeltaIslands=true',
 426                                 'pack.island=refs/remotes/([^/]+)/') {
 427                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
 428                 }
 429         }
 430         my $key = $self->{-key} // die 'BUG: no -key';
 431         my $rn = substr(sha256_hex($key), 0, 16);
 432         if (!-d $self->{cur_dst} && !$self->{dry_run}) {
 433                 PublicInbox::Import::init_bare($self->{cur_dst});
 434                 my $f = "$self->{cur_dst}/config";
 435                 open my $fh, '+>>', $f or die "open:($f): $!";
 436                 print $fh <<EOM or die "print($f): $!";
 437 ; rely on the "$rn" remote in the
 438 ; $fg fork group for fetches
 439 ; only uncomment the following iff you detach from fork groups
 440 ; [remote "origin"]
 441 ;       url = $uri
 442 ;       fetch = +refs/*:refs/*
 443 ;       mirror = true
 444 EOM
 445                 close $fh or die "close($f): $!";
 446         }
 447         if (!$self->{dry_run}) {
 448                 my $alt = File::Spec->rel2abs("$dir/objects");
 449                 my $o = "$self->{cur_dst}/objects";
 450                 my $f = "$o/info/alternates";
 451                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 452                 open my $fh, '+>>', $f or die "open($f): $!";
 453                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 454                 chomp(my @cur = <$fh>);
 455                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 456                         say $fh $l or die "say($f): $!";
 457                 }
 458                 close $fh or die "close($f): $!";
 459         }
 460         bless {
 461                 %$self, -osdir => $dir, -remote => $rn, -uri => $uri
 462         }, __PACKAGE__;
 463 }
 464
 465 sub fp_done {
 466         my ($self, $cmd, $cb, @arg) = @_;
 467         if ($?) {
 468                 $self->{lei}->err("@$cmd failed (\$?=$?) (non-fatal)");
 469                 $? = 0; # don't let it influence normal exit
 470         }
 471         return if !keep_going($self);
 472         my $fh = delete $self->{-show_ref} // die 'BUG: no show-ref output';
 473         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 474         $self->{-ent} // die 'BUG: no -ent';
 475         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 476         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 477         return $cb->($self, @arg) if $A ne $B;
 478         $self->{lei}->qerr("# $self->{-key} up-to-date");
 479 }
 480
 481 sub cmp_fp_do {
 482         my ($self, $cb, @arg) = @_;
 483         # $cb is either resume_fetch or fgrp_enqueue
 484         $self->{-ent} // return $cb->($self, @arg);
 485         my $new = $self->{-ent}->{fingerprint} // return $cb->($self, @arg);
 486         my $key = $self->{-key} // die 'BUG: no -key';
 487         if (my $cur_ent = $self->{-local_manifest}->{$key}) {
 488                 # runs go_fetch->DESTROY run if eq
 489                 return if $cur_ent->{fingerprint} eq $new;
 490         }
 491         my $dst = $self->{cur_dst} // $self->{dst};
 492         my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 493         my $opt = { 2 => $self->{lei}->{2} };
 494         open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 495         $self->{-show_ref} = $opt->{1};
 496         do_reap($self);
 497         $self->{lei}->qerr("# @$cmd");
 498         $LIVE->{spawn($cmd, undef, $opt)} = [ \&fp_done, $self, $cmd,
 499                                                 $cb, @arg ];
 500 }
 501
 502 sub resume_fetch {
 503         my ($self, $uri, $fini) = @_;
 504         return if !keep_going($self);
 505         my $dst = $self->{cur_dst} // $self->{dst};
 506         my @git = ('git', "--git-dir=$dst");
 507         my $opt = { 2 => $self->{lei}->{2} };
 508         my $rn = 'origin'; # configurable?
 509         for ("url=$uri", "fetch=+refs/*:refs/*", 'mirror=true') {
 510                 my @kv = split(/=/, $_, 2);
 511                 $kv[0] = "remote.$rn.$kv[0]";
 512                 next if $self->{dry_run};
 513                 run_die([@git, 'config', @kv], undef, $opt);
 514         }
 515         my $cmd = [ @{$self->{-torsocks}}, @git,
 516                         fetch_args($self->{lei}, $opt), $rn ];
 517         push @$cmd, '-P' if $self->{lei}->{prune}; # --prune-tags implied
 518         my $run_puh = PublicInbox::OnDestroy->new($$, \&run_puh, $self, $fini);
 519         start_cmd($self, $cmd, $opt, $run_puh);
 520 }
 521
 522 sub fgrp_enqueue {
 523         my ($fgrp, $end) = @_; # $end calls fgrp_fetch_all
 524         return if !keep_going($fgrp);
 525         my $opt = { 2 => $fgrp->{lei}->{2} };
 526         # --no-tags is required to avoid conflicts
 527         my $u = $fgrp->{-uri} // die 'BUG: no {-uri}';
 528         my $rn = $fgrp->{-remote} // die 'BUG: no {-remote}';
 529         my @cmd = ('git', "--git-dir=$fgrp->{-osdir}", 'config');
 530         for ("url=$u", "fetch=+refs/*:refs/remotes/$rn/*", 'tagopt=--no-tags') {
 531                 my @kv = split(/=/, $_, 2);
 532                 $kv[0] = "remote.$rn.$kv[0]";
 533                 $fgrp->{dry_run} ? $fgrp->{lei}->qerr("# @cmd @kv") :
 534                                 run_die([@cmd, @kv], undef, $opt);
 535         }
 536         push @{$FGRP_TODO->{$fgrp->{-osdir}}}, $fgrp;
 537 }
 538
 539 sub clone_v1 {
 540         my ($self, $end) = @_;
 541         my $lei = $self->{lei};
 542         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 543         my $uri = URI->new($self->{cur_src} // $self->{src});
 544         my $path = $uri->path;
 545         $path =~ s!/*\z!! and $uri->path($path);
 546         defined($lei->{opt}->{epoch}) and
 547                 die "$uri is a v1 inbox, --epoch is not supported\n";
 548         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 549         my $dst = $self->{cur_dst} // $self->{dst};
 550         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 551         my $resume = -d $dst;
 552         if (my $fgrp = forkgroup_prep($self, $uri)) {
 553                 $fgrp->{-fini} = $fini;
 554                 $resume ? cmp_fp_do($fgrp, \&fgrp_enqueue, $end)
 555                         : fgrp_enqueue($fgrp, $end);
 556         } elsif ($resume) {
 557                 cmp_fp_do($self, \&resume_fetch, $uri, $fini);
 558         } else { # normal clone
 559                 my $cmd = [ @{$self->{-torsocks}},
 560                                 clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 561                 if (defined($self->{-ent})) {
 562                         if (defined(my $ref = $self->{-ent}->{reference})) {
 563                                 -e "$self->{dst}$ref" and
 564                                         push @$cmd, '--reference',
 565                                                 "$self->{dst}$ref";
 566                         }
 567                 }
 568                 start_cmd($self, $cmd, $opt, PublicInbox::OnDestroy->new($$,
 569                                                 \&run_puh, $self, $fini));
 570         }
 571         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 572                                 /\A(?:always|v1)\z/s) {
 573                 _get_txt_start($self, '_/text/config/raw', $fini);
 574         }
 575
 576         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 577         $self->{'txt.description'} = $d if defined $d;
 578         (!defined($d) && !$end) and
 579                 _get_txt_start($self, 'description', $fini);
 580
 581         $end or do_reap($self, 1); # for non-manifest clone
 582 }
 583
 584 sub parse_epochs ($$) {
 585         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 586         $opt_epochs // return; # undef => all epochs
 587         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 588         undef($lo) if ($lo // '') eq '';
 589         my $re = qr/\A~?[0-9]+\z/;
 590         if (@extra || (($lo // '0') !~ $re) ||
 591                         (($hi // '0') !~ $re) ||
 592                         !(grep(defined, $lo, $hi))) {
 593                 die <<EOM;
 594 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 595 EOM
 596         }
 597         my @n = sort { $a <=> $b } keys %$v2_epochs;
 598         for (grep(defined, $lo, $hi)) {
 599                 if (/\A[0-9]+\z/) {
 600                         $_ > $n[-1] and die
 601 "`$_' exceeds maximum available epoch ($n[-1])\n";
 602                         $_ < $n[0] and die
 603 "`$_' is lower than minimum available epoch ($n[0])\n";
 604                 } elsif (/\A~([0-9]+)/) {
 605                         my $off = -$1 - 1;
 606                         $n[$off] // die "`$_' is out of range\n";
 607                         $_ = $n[$off];
 608                 } else { die "`$_' not understood\n" }
 609         }
 610         defined($lo) && defined($hi) && $lo > $hi and die
 611 "low value (`$lo') exceeds high (`$hi')\n";
 612         $lo //= $n[0] if $dotdot;
 613         $hi //= $n[-1] if $dotdot;
 614         $hi //= $lo;
 615         my $want = {};
 616         for ($lo..$hi) {
 617                 if (defined $v2_epochs->{$_}) {
 618                         $want->{$_} = 1;
 619                 } else {
 620                         warn
 621 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 622                 }
 623         }
 624         $want
 625 }
 626
 627 sub init_placeholder ($$$) {
 628         my ($src, $edst, $ent) = @_;
 629         PublicInbox::Import::init_bare($edst);
 630         my $f = "$edst/config";
 631         open my $fh, '>>', $f or die "open($f): $!";
 632         print $fh <<EOM or die "print($f): $!";
 633 [remote "origin"]
 634         url = $src
 635         fetch = +refs/*:refs/*
 636         mirror = true
 637
 638 ; This git epoch was created read-only and "public-inbox-fetch"
 639 ; will not fetch updates for it unless write permission is added.
 640 ; Hint: chmod +w $edst
 641 EOM
 642         if (defined($ent->{owner})) {
 643                 print $fh <<EOM or die "print($f): $!";
 644 [gitweb]
 645         owner = $ent->{owner}
 646 EOM
 647         }
 648         close $fh or die "close($f): $!";
 649         my %map = (head => 'HEAD', description => undef);
 650         while (my ($key, $fn) = each %map) {
 651                 my $val = $ent->{$key} // next;
 652                 $fn //= $key;
 653                 $fn = "$edst/$fn";
 654                 open $fh, '>', $fn or die "open($fn): $!";
 655                 print $fh $val, "\n" or die "print($fn): $!";
 656                 close $fh or die "close($fn): $!";
 657         }
 658 }
 659
 660 sub reap_cmd { # async, called via SIGCHLD
 661         my ($self, $cmd) = @_;
 662         my $cerr = $?;
 663         $? = 0; # don't let it influence normal exit
 664         $self->{lei}->child_error($cerr, "@$cmd failed (\$?=$cerr)") if $cerr;
 665 }
 666
 667 sub up_fp_done {
 668         my ($self) = @_;
 669         return if !keep_going($self);
 670         my $fh = delete $self->{-show_ref_up} // die 'BUG: no show-ref output';
 671         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 672         $self->{-ent} // die 'BUG: no -ent';
 673         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 674         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 675         return if $A eq $B;
 676         $self->{-ent}->{fingerprint} = $B;
 677         push @{$self->{chg}->{fp_mismatch}}, $self->{-key};
 678 }
 679
 680 sub atomic_write ($$$) {
 681         my ($dn, $bn, $raw) = @_;
 682         my $ft = File::Temp->new(DIR => $dn, TEMPLATE => "$bn-XXXX");
 683         print $ft $raw or die "print($ft): $!";
 684         $ft->flush or die "flush($ft): $!";
 685         ft_rename($ft, "$dn/$bn", 0666);
 686 }
 687
 688 sub run_next_puh {
 689         my ($self) = @_;
 690         my $puh = shift @{$self->{-puh_todo}} // return delete($self->{-fini});
 691         my $fini = PublicInbox::OnDestroy->new($$, \&run_next_puh, $self);
 692         my $cmd = [ @$puh, ($self->{cur_dst} // $self->{dst}) ];
 693         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 694         start_cmd($self, $cmd, undef, $opt, $fini);
 695 }
 696
 697 sub run_puh {
 698         my ($self, $fini) = @_;
 699         $self->{-fini} = $fini;
 700         @{$self->{-puh_todo}} = @PUH;
 701         run_next_puh($self);
 702 }
 703
 704 # modifies the to-be-written manifest entry, and sets values from it, too
 705 sub update_ent {
 706         my ($self) = @_;
 707         my $key = $self->{-key} // die 'BUG: no -key';
 708         my $new = $self->{-ent}->{fingerprint};
 709         my $cur = $self->{-local_manifest}->{$key}->{fingerprint} // "\0";
 710         my $dst = $self->{cur_dst} // $self->{dst};
 711         if (defined($new) && $new ne $cur) {
 712                 my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 713                 my $opt = { 2 => $self->{lei}->{2} };
 714                 open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 715                 $self->{-show_ref_up} = $opt->{1};
 716                 my $done = PublicInbox::OnDestroy->new($$, \&up_fp_done, $self);
 717                 start_cmd($self, $cmd, $opt, $done);
 718         }
 719         $new = $self->{-ent}->{head};
 720         $cur = $self->{-local_manifest}->{$key}->{head} // "\0";
 721         if (defined($new) && $new ne $cur) {
 722                 # n.b. grokmirror writes raw contents to $dst/HEAD w/o locking
 723                 my $cmd = [ 'git', "--git-dir=$dst" ];
 724                 if ($new =~ s/\Aref: //) {
 725                         push @$cmd, qw(symbolic-ref HEAD), $new;
 726                 } elsif ($new =~ /\A[a-f0-9]{40,}\z/) {
 727                         push @$cmd, qw(update-ref --no-deref HEAD), $new;
 728                 } else {
 729                         undef $cmd;
 730                         warn "W: $key: {head} => `$new' not understood\n";
 731                 }
 732                 start_cmd($self, $cmd, { 2 => $self->{lei}->{2} }) if $cmd;
 733         }
 734         if (my $symlinks = $self->{-ent}->{symlinks}) {
 735                 my $top = File::Spec->rel2abs($self->{dst});
 736                 push @{$self->{-new_symlinks}}, @$symlinks;
 737                 for my $p (@$symlinks) {
 738                         my $ln = "$top/$p";
 739                         $ln =~ tr!/!/!s;
 740                         my (undef, $dn, $bn) = File::Spec->splitpath($ln);
 741                         File::Path::mkpath($dn);
 742                         my $tgt = "$top/$key";
 743                         $tgt = File::Spec->abs2rel($tgt, $dn);
 744                         if (lstat($ln)) {
 745                                 if (-l _) {
 746                                         next if readlink($ln) eq $tgt;
 747                                         unlink($ln) or die "unlink($ln): $!";
 748                                 } else {
 749                                         push @{$self->{chg}->{badlink}}, $p;
 750                                 }
 751                         }
 752                         symlink($tgt, $ln) or die "symlink($tgt, $ln): $!";
 753                 }
 754         }
 755         if (defined(my $t = $self->{-ent}->{modified})) {
 756                 my ($dn, $bn) = ("$dst/info/web", 'last-modified');
 757                 my $orig = PublicInbox::Git::try_cat("$dn/$bn");
 758                 $t = strftime('%F %T', gmtime($t))." +0000\n";
 759                 File::Path::mkpath($dn);
 760                 atomic_write($dn, $bn, $t) if $orig ne $t;
 761         }
 762
 763         $new = $self->{-ent}->{owner} // return;
 764         $cur = $self->{-local_manifest}->{$key}->{owner} // "\0";
 765         return if $cur eq $new;
 766         my $cmd = [ qw(git config -f), "$dst/config", 'gitweb.owner', $new ];
 767         start_cmd($self, $cmd, { 2 => $self->{lei}->{2} });
 768 }
 769
 770 sub v1_done { # called via OnDestroy
 771         my ($self) = @_;
 772         return if $self->{dry_run} || !keep_going($self);
 773         _write_inbox_config($self);
 774         my $dst = $self->{cur_dst} // $self->{dst};
 775         update_ent($self) if $self->{-ent};
 776         my $o = "$dst/objects";
 777         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
 778                 my $base = File::Spec->rel2abs($o);
 779                 my @l = <$fh>;
 780                 my $ft;
 781                 for (@l) {
 782                         next unless m!\A/!;
 783                         $_ = File::Spec->abs2rel($_, $base);
 784                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
 785                                                 DIR => "$o/info");
 786                 }
 787                 if ($ft) {
 788                         print $ft @l or die "print($ft): $!";
 789                         $ft->flush or die "flush($ft): $!";
 790                         ft_rename($ft, $fn, 0666, $fh);
 791                 }
 792         }
 793         eval { set_description($self) };
 794         warn $@ if $@;
 795         return if ($self->{-is_epoch} ||
 796                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 797         write_makefile($dst, 1);
 798         index_cloned_inbox($self, 1);
 799 }
 800
 801 sub v2_done { # called via OnDestroy
 802         my ($self) = @_;
 803         return if $self->{dry_run} || !keep_going($self);
 804         my $dst = $self->{cur_dst} // $self->{dst};
 805         require PublicInbox::Lock;
 806         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 807         my $lck = $lk->lock_for_scope($$);
 808         _write_inbox_config($self);
 809         require PublicInbox::MultiGit;
 810         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 811         $mg->fill_alternates;
 812         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 813         for my $edst (@{delete($self->{-read_only}) // []}) {
 814                 my @st = stat($edst) or die "stat($edst): $!";
 815                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 816         }
 817         write_makefile($dst, 2);
 818         undef $lck; # unlock
 819         eval { set_description($self) };
 820         warn $@ if $@;
 821         index_cloned_inbox($self, 2);
 822 }
 823
 824 sub clone_v2_prep ($$;$) {
 825         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 826         my $lei = $self->{lei};
 827         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 828         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 829         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 830         my $dst = $self->{cur_dst} // $self->{dst};
 831         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 832         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 833         my (@skip, $desc);
 834         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 835         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 836                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 837                 my $src = $uri->as_string;
 838                 my $edst = $dst;
 839                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 840 failed to extract epoch number from $src
 841
 842                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 843                 $edst .= "/git/$nr.git";
 844                 my $ent;
 845                 if ($m) {
 846                         $ent = $m->{$key} //
 847                                 die("BUG: `$key' not in manifest.js.gz");
 848                         if (defined(my $d = $ent->{description})) {
 849                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 850                                 $desc = $d;
 851                         }
 852                 }
 853                 if (!$want || $want->{$nr}) {
 854                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 855                         $etask->{-ent} = $ent; # may have {reference}
 856                         $etask->{cur_src} = $src;
 857                         $etask->{cur_dst} = $edst;
 858                         $etask->{-is_epoch} = $fini;
 859                         my $ref = $ent->{reference} // '';
 860                         push @{$TODO->{$ref}}, $etask;
 861                         $self->{any_want}->{$key} = 1;
 862                 } else { # create a placeholder so users only need to chmod +w
 863                         init_placeholder($src, $edst, $ent);
 864                         push @{$task->{-read_only}}, $edst;
 865                         push @skip, $key;
 866                 }
 867         }
 868         # filter out the epochs we skipped
 869         $self->{chg}->{manifest} = 1 if $m && delete(@$m{@skip});
 870
 871         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 872
 873         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 874                 _get_txt_start($task, '_/text/config/raw', $fini);
 875
 876         defined($desc) ? ($task->{'txt.description'} = $desc) :
 877                 _get_txt_start($task, 'description', $fini);
 878 }
 879
 880 sub decode_manifest ($$$) {
 881         my ($fh, $fn, $uri) = @_;
 882         my $js;
 883         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 884         gunzip(\$gz => \$js, MultiStream => 1) or
 885                 die "gunzip($uri): $GunzipError\n";
 886         my $m = eval { PublicInbox::Config->json->decode($js) };
 887         die "$uri: error decoding `$js': $@\n" if $@;
 888         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 889         $m;
 890 }
 891
 892 sub load_current_manifest ($) {
 893         my ($self) = @_;
 894         my $fn = $self->{-manifest} // return;
 895         if (open(my $fh, '<', $fn)) {
 896                 decode_manifest($fh, $fn, $fn);
 897         } elsif ($!{ENOENT}) { # non-fatal, we can just do it slowly
 898                 warn "open($fn): $!\n" if !$self->{-initial_clone};
 899                 undef;
 900         } else {
 901                 die "open($fn): $!\n";
 902         }
 903 }
 904
 905 sub multi_inbox ($$$) {
 906         my ($self, $path, $m) = @_;
 907         my $incl = $self->{lei}->{opt}->{include};
 908         my $excl = $self->{lei}->{opt}->{exclude};
 909
 910         # assuming everything not v2 is v1, for now
 911         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 912         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 913         my $v2 = {};
 914
 915         for (@v2_epochs) {
 916                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 917                 push @{$v2->{$1}}, $_;
 918         }
 919         my $n = scalar(keys %$v2) + scalar(@v1);
 920         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 921         if (defined $incl) {
 922                 my $re = '(?:'.join('\\z|', map {
 923                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 924                         } @$incl).'\\z)';
 925                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 926                 delete @$m{map { @$_ } @gone} and $self->{chg}->{manifest} = 1;
 927                 delete @$m{grep(!/$re/, @v1)} and $self->{chg}->{manifest} = 1;
 928                 @v1 = grep(/$re/, @v1);
 929         }
 930         if (defined $excl) {
 931                 my $re = '(?:'.join('\\z|', map {
 932                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 933                         } @$excl).'\\z)';
 934                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 935                 delete @$m{map { @$_ } @gone} and $self->{chg}->{manifest} = 1;
 936                 delete @$m{grep(/$re/, @v1)} and $self->{chg}->{manifest} = 1;
 937                 @v1 = grep(!/$re/, @v1);
 938         }
 939         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 940         $ret->{v1} = \@v1 if @v1;
 941         $ret->{v2} = $v2 if keys %$v2;
 942         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 943                                 join("\n\t", sort @orig)
 944                         : "Nothing available to clone\n";
 945         my $path_pfx = '';
 946
 947         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 948         if (@v2_epochs) {
 949                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 950                                 @v2_epochs) == @v2_epochs) {
 951                         $$path =~ s!\A(/[^/]+)/!/! or last;
 952                         $path_pfx .= $1;
 953                 }
 954         } elsif (@v1) {
 955                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 956                         $path_pfx .= $1;
 957                 }
 958         }
 959         ($path_pfx, $n, $ret);
 960 }
 961
 962 sub clone_all {
 963         my ($self, $m) = @_;
 964         my $todo = $TODO;
 965         $TODO = \'BUG on further use';
 966         my $end = PublicInbox::OnDestroy->new($$, \&fgrp_fetch_all, $self);
 967         {
 968                 my $nodep = delete $todo->{''};
 969
 970                 # do not download unwanted deps
 971                 my $any_want = delete $self->{any_want};
 972                 my @unwanted = grep { !$any_want->{$_} } keys %$todo;
 973                 my @nodep = delete(@$todo{@unwanted});
 974                 push(@$nodep, @$_) for @nodep;
 975
 976                 # handle no-dependency repos, first
 977                 for (@$nodep) {
 978                         clone_v1($_, $end);
 979                         return if !keep_going($self);
 980                 }
 981         }
 982         # resolve references, deepest, first:
 983         while (scalar keys %$todo) {
 984                 for my $x (keys %$todo) {
 985                         my ($nr, $nxt);
 986                         # resolve multi-level references
 987                         while ($m && defined($nxt = $m->{$x}->{reference})) {
 988                                 exists($todo->{$nxt}) or last;
 989                                 if (++$nr > 1000) {
 990                                         $m->{$x}->{reference} = undef;
 991                                         $m->{$nxt}->{reference} = undef;
 992                                         warn <<EOM
 993 E: dependency loop detected (`$x' => `$nxt'), breaking
 994 EOM
 995                                 }
 996                                 $x = $nxt;
 997                         }
 998                         my $y = delete $todo->{$x} // next; # already done
 999                         for (@$y) {
1000                                 clone_v1($_, $end);
1001                                 return if !keep_going($self);
1002                         }
1003                         last; # restart %$todo iteration
1004                 }
1005         }
1006
1007         # $end->DESTROY will call fgrp_fetch_all once all references
1008         # in $LIVE are gone, and do_reap will eventually drain $LIVE
1009         $end = undef;
1010         do_reap($self, 1);
1011 }
1012
1013 sub dump_manifest ($$) {
1014         my ($m, $ft) = @_;
1015         # write the smaller manifest if epochs were skipped so
1016         # users won't have to delete manifest if they +w an
1017         # epoch they no longer want to skip
1018         my $json = PublicInbox::Config->json->encode($m);
1019         my $mtime = (stat($ft))[9];
1020         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
1021         truncate($ft, 0) or die "truncate($ft): $!";
1022         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
1023         $ft->flush or die "flush($ft): $!";
1024         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
1025 }
1026
1027 sub dump_project_list ($$) {
1028         my ($self, $m) = @_;
1029         my $f = $self->{'-project-list'} // return;
1030         my $old = PublicInbox::Git::try_cat($f);
1031         my %new;
1032
1033         open my $dh, '<', '.' or die "open(.): $!";
1034         chdir($self->{dst}) or die "chdir($self->{dst}): $!";
1035         my @local = grep { -e $_ ? ($new{$_} = undef) : 1 } split(/\n/s, $old);
1036         chdir($dh) or die "chdir(restore): $!";
1037
1038         $new{substr($_, 1)} = 1 for keys %$m; # drop leading '/'
1039         my @list = sort keys %new;
1040         my @remote = grep { !defined($new{$_}) } @list;
1041         my %lnk = map { substr($_, 1) => undef } @{$self->{-new_symlinks}};
1042         @remote = grep { !exists($lnk{$_}) } @remote;
1043
1044         warn <<EOM if @remote;
1045 The following local repositories are ignored/gone from $self->{src}:
1046 EOM
1047         warn "\t", $_, "\n" for @remote;
1048         warn <<EOM if @local;
1049 The following repos in $f no longer exist on the filesystem:
1050 EOM
1051         warn "\t", $_, "\n" for @local;
1052
1053         my (undef, $dn, $bn) = File::Spec->splitpath($f);
1054         atomic_write($dn, $bn, join("\n", @list, ''));
1055 }
1056
1057 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
1058 sub try_manifest {
1059         my ($self) = @_;
1060         my $uri = URI->new($self->{src});
1061         my $lei = $self->{lei};
1062         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
1063         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
1064         my $path = $uri->path;
1065         chop($path) eq '/' or die "BUG: $uri not canonicalized";
1066         $uri->path($path . '/manifest.js.gz');
1067         my $manifest = $self->{-manifest} // "$self->{dst}/manifest.js.gz";
1068         my %opt = (UNLINK => 1, SUFFIX => '.tmp', TMPDIR => 1);
1069         if (!$self->{dry_run} && $manifest =~ m!\A(.+?)/[^/]+\z! and -d $1) {
1070                 $opt{DIR} = $1; # allows fast rename(2) w/o EXDEV
1071                 delete $opt{TMPDIR};
1072         }
1073         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX', %opt);
1074         my $cmd = $curl->for_uri($lei, $uri, qw(-R -o), $ft->filename);
1075         push(@$cmd, '-z', $manifest) if -f $manifest;
1076         my $mf_url = "$uri";
1077         %opt = map { $_ => $lei->{$_} } (0..2);
1078         my $cerr = run_reap($lei, $cmd, \%opt);
1079         if ($cerr) {
1080                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
1081                 return $lei->child_error($cerr, "@$cmd failed");
1082         }
1083
1084         # bail out if curl -z/--timecond hit 304 Not Modified, $ft will be empty
1085         return $lei->qerr("# $manifest unchanged") if -f $manifest && !-s $ft;
1086
1087         my $m = eval { decode_manifest($ft, $ft, $uri) };
1088         if ($@) {
1089                 warn $@;
1090                 return try_scrape($self);
1091         }
1092         local $self->{chg} = {};
1093         local $self->{-local_manifest} = load_current_manifest($self);
1094         local $self->{-new_symlinks} = [];
1095         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
1096         return $lei->child_error(1, $multi) if !ref($multi);
1097         my $v2 = delete $multi->{v2};
1098         if ($v2) {
1099                 for my $name (sort keys %$v2) {
1100                         my $epochs = delete $v2->{$name};
1101                         my %v2_epochs = map {
1102                                 $uri->path($n > 1 ? $path_pfx.$path.$_
1103                                                 : $path_pfx.$_);
1104                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
1105                                 $e // die "no [0-9]+\.git in `$uri'";
1106                                 $e => [ $uri->clone, $_ ];
1107                         } @$epochs;
1108                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
1109                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
1110                         local $self->{cur_src} = $1;
1111                         local $self->{cur_dst} = $self->{dst};
1112                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
1113                                                         git/[0-9]+\.git\z!x) {
1114                                 $self->{cur_dst} .= "/$1";
1115                         }
1116                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
1117 E: `$self->{cur_dst}' must not contain newline
1118 EOM
1119                         clone_v2_prep($self, \%v2_epochs, $m);
1120                         return if !keep_going($self);
1121                 }
1122         }
1123         if (my $v1 = delete $multi->{v1}) {
1124                 my $p = $path_pfx.$path;
1125                 chop($p) if substr($p, -1, 1) eq '/';
1126                 $uri->path($p);
1127                 for my $name (@$v1) {
1128                         my $task = bless { %$self }, __PACKAGE__;
1129                         $task->{-ent} = $m->{$name} //
1130                                         die("BUG: no `$name' in manifest");
1131                         $task->{cur_src} = "$uri";
1132                         $task->{cur_dst} = $task->{dst};
1133                         $task->{-key} = $name;
1134                         if ($n > 1) {
1135                                 $task->{cur_dst} .= $name;
1136                                 $task->{cur_src} .= $name;
1137                         }
1138                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
1139 E: `$task->{cur_dst}' must not contain newline
1140 EOM
1141                         $task->{cur_src} .= '/';
1142                         my $dep = $task->{-ent}->{reference} // '';
1143                         push @{$TODO->{$dep}}, $task; # for clone_all
1144                         $self->{any_want}->{$name} = 1;
1145                 }
1146         }
1147         delete local $lei->{opt}->{epoch} if defined($v2);
1148         clone_all($self, $m);
1149         return if $self->{dry_run} || !keep_going($self);
1150
1151         # set by clone_v2_prep/-I/--exclude
1152         my $mis = delete $self->{chg}->{fp_mismatch};
1153         if ($mis) {
1154                 my $t = (stat($ft))[9];
1155                 $t = strftime('%F %k:%M:%S %z', localtime($t));
1156                 warn <<EOM;
1157 W: Fingerprints for the following repositories do not match
1158 W: $mf_url @ $t:
1159 W: These repositories may have updated since $t:
1160 EOM
1161                 warn "\t", $_, "\n" for @$mis;
1162                 warn <<EOM if !$self->{lei}->{opt}->{prune};
1163 W: The above fingerprints may never match without --prune
1164 EOM
1165         }
1166         dump_manifest($m => $ft) if delete($self->{chg}->{manifest}) || $mis;
1167         my $bad = delete $self->{chg}->{badlink};
1168         warn(<<EOM, map { ("\t", $_, "\n") } @$bad) if $bad;
1169 W: The following exist and have not been converted to symlinks
1170 EOM
1171         dump_project_list($self, $m);
1172         ft_rename($ft, $manifest, 0666);
1173 }
1174
1175 sub start_clone_url {
1176         my ($self) = @_;
1177         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
1178         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
1179 }
1180
1181 sub do_mirror { # via wq_io_do or public-inbox-clone
1182         my ($self) = @_;
1183         my $lei = $self->{lei};
1184         $self->{dry_run} = 1 if $lei->{opt}->{'dry-run'};
1185         umask($lei->{client_umask}) if defined $lei->{client_umask};
1186         $self->{-initial_clone} = 1 if !-d $self->{dst};
1187         local @PUH;
1188         if (defined(my $puh = $lei->{opt}->{'post-update-hook'})) {
1189                 require Text::ParseWords;
1190                 @PUH = map { [ Text::ParseWords::shellwords($_) ] } @$puh;
1191         }
1192         eval {
1193                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
1194                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
1195 --inbox-config must be one of `always', `v2', `v1', or `never'
1196
1197                 # we support these switches with '' (empty string).
1198                 # defaults match example conf distributed with grokmirror
1199                 my @pairs = qw(objstore objstore manifest manifest.js.gz
1200                                 project-list projects.list);
1201                 while (@pairs) {
1202                         my ($k, $default) = splice(@pairs, 0, 2);
1203                         my $v = $lei->{opt}->{$k} // next;
1204                         $v = $default if $v eq '';
1205                         $v = "$self->{dst}/$v" if $v !~ m!\A\.{0,2}/!;
1206                         $self->{"-$k"} = $v;
1207                 }
1208
1209                 local $LIVE = {};
1210                 local $TODO = {};
1211                 local $FGRP_TODO = {};
1212                 my $iv = $lei->{opt}->{'inbox-version'} //
1213                         return start_clone_url($self);
1214                 return clone_v1($self) if $iv == 1;
1215                 die "bad --inbox-version=$iv\n" if $iv != 2;
1216                 die <<EOM if $self->{src} !~ m!://!;
1217 cloning local v2 inboxes not supported
1218 EOM
1219                 try_scrape($self, 1);
1220         };
1221         $lei->fail($@) if $@;
1222 }
1223
1224 sub start {
1225         my ($cls, $lei, $src, $dst) = @_;
1226         my $self = bless { src => $src, dst => $dst }, $cls;
1227         $lei->request_umask;
1228         my ($op_c, $ops) = $lei->workers_start($self, 1);
1229         $lei->{wq1} = $self;
1230         $self->wq_io_do('do_mirror', []);
1231         $self->wq_close;
1232         $lei->wait_wq_events($op_c, $ops);
1233 }
1234
1235 sub ipc_atfork_child {
1236         my ($self) = @_;
1237         $self->{lei}->_lei_atfork_child;
1238         $self->SUPER::ipc_atfork_child;
1239 }
1240
1241 sub write_makefile {
1242         my ($dir, $ibx_ver) = @_;
1243         my $f = "$dir/Makefile";
1244         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
1245                 print $fh <<EOM or die "print($f) $!";
1246 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
1247 # manpage for more information on the format.  This Makefile is
1248 # intended as a familiar wrapper for users unfamiliar with
1249 # public-inbox-* commands.
1250 #
1251 # See the respective manpages for public-inbox-fetch(1),
1252 # public-inbox-index(1), etc for more information on
1253 # some of the commands used by this Makefile.
1254 #
1255 # This Makefile will not be modified nor read by public-inbox,
1256 # so you may edit it freely with your own convenience targets
1257 # and notes.  public-inbox-fetch will recreate it if removed.
1258 EOM
1259                 print $fh <<'EOM' or die "print($f): $!";
1260 # the default target:
1261 help :
1262         @echo Common targets:
1263         @echo '    make fetch        - fetch from remote git repostorie(s)'
1264         @echo '    make update       - fetch and update index '
1265         @echo
1266         @echo Rarely needed targets:
1267         @echo '    make reindex      - may be needed for new features/bugfixes'
1268         @echo '    make compact      - rewrite Xapian storage to save space'
1269         @echo '    make index        - initial index after clone
1270
1271 fetch :
1272         public-inbox-fetch
1273 update :
1274         @if ! public-inbox-fetch --exit-code; \
1275         then \
1276                 c=$$?; \
1277                 test $$c -eq 127 && exit 0; \
1278                 exit $$c; \
1279         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
1280         then \
1281                 public-inbox-index; \
1282         else \
1283                 echo 'public-inbox index not initialized'; \
1284                 echo 'see public-inbox-index(1) man page'; \
1285         fi
1286 index :
1287         public-inbox-index
1288 reindex :
1289         public-inbox-index --reindex
1290 compact :
1291         public-inbox-compact
1292
1293 .PHONY : help fetch update index reindex compact
1294 EOM
1295                 close $fh or die "close($f): $!";
1296         } else {
1297                 die "open($f): $!" unless $!{EEXIST};
1298         }
1299 }
1300
1301 1;