lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::Git;
  20 use PublicInbox::LeiCurl;
  21 use PublicInbox::OnDestroy;
  22 use PublicInbox::SHA qw(sha256_hex sha1_hex);
  23 use POSIX qw(strftime);
  24
  25 our $LIVE; # pid => callback
  26 our $FGRP_TODO; # objstore -> [[ to resume ], [ to clone ]]
  27 our $TODO; # reference => [ non-fgrp mirror objects ]
  28 our @PUH; # post-update hooks
  29
  30 sub keep_going ($) {
  31         $LIVE && (!$_[0]->{lei}->{child_error} ||
  32                 $_[0]->{lei}->{opt}->{'keep-going'});
  33 }
  34
  35 sub _wq_done_wait { # awaitpid cb (via wq_eof)
  36         my ($pid, $mrr, $lei) = @_;
  37         if ($?) {
  38                 $lei->child_error($?);
  39         } elsif (!$lei->{child_error}) {
  40                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  41                         require PublicInbox::LeiAddExternal;
  42                         PublicInbox::LeiAddExternal::_finish_add_external(
  43                                                         $lei, $mrr->{dst});
  44                 }
  45                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  46         }
  47         $lei->dclose;
  48 }
  49
  50 # for old installations without manifest.js.gz
  51 sub try_scrape {
  52         my ($self, $fallback_manifest) = @_;
  53         my $uri = URI->new($self->{src});
  54         my $lei = $self->{lei};
  55         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  56         my $cmd = $curl->for_uri($lei, $uri, '--compressed');
  57         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  58         my $fh = popen_rd($cmd, undef, $opt);
  59         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  60         close($fh) or return $lei->child_error($?, "@$cmd failed");
  61
  62         # we grep with URL below, we don't want Subject/From headers
  63         # making us clone random URLs.  This assumes remote instances
  64         # prior to public-inbox 1.7.0
  65         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  66         my @html = split(/<hr>/, $html);
  67         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  68         if (!@urls && $fallback_manifest) {
  69                 warn <<EOM;
  70 W: failed to extract URLs from $uri, trying manifest.js.gz...
  71 EOM
  72                 return start_clone_url($self);
  73         }
  74         my $url = $uri->as_string;
  75         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  76
  77         # since this is for old instances w/o manifest.js.gz, try v1 first
  78         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  79         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  80                 my %v2_epochs = map {
  81                         my ($n) = (m!/([0-9]+)\z!);
  82                         $n => [ URI->new($_), '' ]
  83                 } @v2_urls; # uniq
  84                 clone_v2_prep($self, \%v2_epochs);
  85                 delete local $lei->{opt}->{epoch};
  86                 clone_all($self);
  87                 return;
  88         }
  89
  90         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  91         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  92                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  93                 die <<"";
  94 E: confused by scraping <$uri>, did you mean <$url>?
  95
  96         }
  97         @urls and die <<"";
  98 E: confused by scraping <$uri>, got ambiguous results:
  99 @urls
 100
 101         die "E: scraping <$uri> revealed nothing\n";
 102 }
 103
 104 sub clone_cmd {
 105         my ($lei, $opt) = @_;
 106         my @cmd = qw(git);
 107         $opt->{$_} = $lei->{$_} for (0..2);
 108         # we support "-c $key=$val" for arbitrary git config options
 109         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 110         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 111         push @cmd, qw(clone --mirror);
 112         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 113                         ($lei->{opt}->{jobs} // 1) > 1;
 114         push @cmd, '-v' if $lei->{opt}->{verbose};
 115         # XXX any other options to support?
 116         # --reference is tricky with multiple epochs, but handled
 117         # automatically if using manifest.js.gz
 118         @cmd;
 119 }
 120
 121 sub ft_rename ($$$;$) {
 122         my ($ft, $dst, $open_mode, $fh) = @_;
 123         my @st = stat($fh // $dst);
 124         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 125         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 126         require File::Copy;
 127         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 128         $ft->unlink_on_destroy(0);
 129 }
 130
 131 sub do_reap ($;$) {
 132         my ($self, $jobs) = @_;
 133         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 134         $jobs = 1 if $jobs < 1;
 135         while (keys(%$LIVE) >= $jobs) {
 136                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 137                 if (my $x = delete $LIVE->{$pid}) {
 138                         my $cb = shift @$x;
 139                         $cb->(@$x) if $cb;
 140                 } else {
 141                         warn "reaped unknown PID=$pid ($?)\n";
 142                 }
 143         }
 144 }
 145
 146 sub _get_txt_start { # non-fatal
 147         my ($self, $endpoint, $fini) = @_;
 148         my $uri = URI->new($self->{cur_src} // $self->{src});
 149         my $lei = $self->{lei};
 150         my $path = $uri->path;
 151         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 152         $uri->path("$path/$endpoint");
 153         my $f = (split(m!/!, $endpoint))[-1];
 154         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 155         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 156         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(--compressed -R -o),
 157                                         $ft->filename);
 158         do_reap($self);
 159         $lei->qerr("# @$cmd");
 160         return if $self->{dry_run};
 161         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 162         $LIVE->{spawn($cmd, undef, $opt)} =
 163                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 164 }
 165
 166 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 167         my ($self, $endpoint) = @_;
 168         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 169         my $cerr = $?;
 170         $? = 0; # don't influence normal lei exit
 171         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 172         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 173         seek($fh, SEEK_SET, 0) or die "seek: $!";
 174         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 175         local $/;
 176         $self->{"txt.$endpoint"} = <$fh>;
 177         undef; # success
 178 }
 179
 180 sub _write_inbox_config {
 181         my ($self) = @_;
 182         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 183         my $dst = $self->{cur_dst} // $self->{dst};
 184         my $f = "$dst/inbox.config.example";
 185         my $mtime = delete $self->{'mtime._/text/config/raw'};
 186         if (sysopen(my $fh, $f, O_CREAT|O_EXCL|O_WRONLY)) {
 187                 print $fh $buf or die "print: $!";
 188                 chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 189                 $fh->flush or die "flush($f): $!";
 190                 if (defined $mtime) {
 191                         utime($mtime, $mtime, $fh) or die "utime($f): $!";
 192                 }
 193         } elsif (!$!{EEXIST}) {
 194                 die "open($f): $!";
 195         }
 196         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 197         my $ibx = $self->{ibx} = {};
 198         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 199                 for (qw(address newsgroup nntpmirror)) {
 200                         $ibx->{$_} = $cfg->{"$sec.$_"};
 201                 }
 202         }
 203 }
 204
 205 sub set_description ($) {
 206         my ($self) = @_;
 207         my $dst = $self->{cur_dst} // $self->{dst};
 208         chomp(my $orig = PublicInbox::Git::try_cat("$dst/description"));
 209         my $d = $orig;
 210         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 211                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 212                 $d = delete($self->{'txt.description'});
 213         }
 214         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 215         atomic_write($dst, 'description', $d."\n") if $d ne $orig;
 216 }
 217
 218 sub index_cloned_inbox {
 219         my ($self, $iv) = @_;
 220         my $lei = $self->{lei};
 221
 222         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 223         # lei is useless without Xapian + SQLite
 224         if ($lei->{cmd} ne 'public-inbox-clone') {
 225                 require PublicInbox::InboxWritable;
 226                 require PublicInbox::Admin;
 227                 my $ibx = delete($self->{ibx}) // {
 228                         address => [ 'lei@example.com' ],
 229                         version => $iv,
 230                 };
 231                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 232                 PublicInbox::Inbox->new($ibx);
 233                 PublicInbox::InboxWritable->new($ibx);
 234                 my $opt = {};
 235                 for my $sw ($lei->index_opt) {
 236                         my ($k) = ($sw =~ /\A([\w-]+)/);
 237                         $opt->{$k} = $lei->{opt}->{$k};
 238                 }
 239                 # force synchronous awaitpid for v2:
 240                 local $PublicInbox::DS::in_loop = 0;
 241                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 242                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 243                 local %ENV = (%ENV, %$env) if $env;
 244                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 245                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 246         }
 247         return if defined $self->{cur_dst}; # one of many repos to clone
 248 }
 249
 250 sub run_reap {
 251         my ($lei, $cmd, $opt) = @_;
 252         $lei->qerr("# @$cmd");
 253         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 254         my $ret = $?;
 255         $? = 0; # don't let it influence normal exit
 256         $ret;
 257 }
 258
 259 sub start_cmd {
 260         my ($self, $cmd, $opt, $fini) = @_;
 261         do_reap($self);
 262         utf8::decode(my $msg = "# @$cmd");
 263         $self->{lei}->qerr($msg);
 264         return if $self->{dry_run};
 265         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 266 }
 267
 268 sub fetch_args ($$) {
 269         my ($lei, $opt) = @_;
 270         my @cmd; # (git --git-dir=...) to be added by caller
 271         $opt->{$_} = $lei->{$_} for (0..2);
 272         # we support "-c $key=$val" for arbitrary git config options
 273         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 274         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 275         push @cmd, 'fetch';
 276         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 277                         ($lei->{opt}->{jobs} // 1) > 1;
 278         push @cmd, '-v' if $lei->{opt}->{verbose};
 279         push(@cmd, '-p') if $lei->{opt}->{prune};
 280         PublicInbox::Git::version() >= ((2 << 24) | (29 << 16)) and
 281                 push(@cmd, '--no-write-fetch-head');
 282         @cmd;
 283 }
 284
 285 sub upr { # feed `git update-ref --stdin -z' verbosely
 286         my ($lei, $w, $op, @rest) = @_; # ($ref, $oid) = @rest
 287         $lei->qerr("# $op @rest") if $lei->{opt}->{verbose};
 288         print $w "$op ", join("\0", @rest, '') or die "print(w): $!";
 289 }
 290
 291 sub start_update_ref {
 292         my ($fgrp) = @_;
 293         pipe(my ($r, $w)) or die "pipe: $!";
 294         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 295                 qw(update-ref --stdin -z) ];
 296         my $pack = PublicInbox::OnDestroy->new($$, \&satellite_done, $fgrp);
 297         start_cmd($fgrp, $cmd, { 0 => $r, 2 => $fgrp->{lei}->{2} }, $pack);
 298         close $r or die "close(r): $!";
 299         $fgrp->{dry_run} ? undef : $w;
 300 }
 301
 302 sub upref_warn { warn "E: close(update-ref --stdin): $! (need git 1.8.5+)\n" }
 303
 304 sub fgrp_update {
 305         my ($fgrp) = @_;
 306         return if !keep_going($fgrp);
 307         my $srcfh = delete $fgrp->{srcfh} or return;
 308         my $dstfh = delete $fgrp->{dstfh} or return;
 309         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 310         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 311         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 312         close $srcfh;
 313         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 314         close $dstfh;
 315         my $w = start_update_ref($fgrp) or return;
 316         my $lei = $fgrp->{lei};
 317         my $ndel;
 318         for my $ref (keys %dst) {
 319                 my $new = delete $src{$ref};
 320                 my $old = $dst{$ref};
 321                 if (defined $new) {
 322                         $new eq $old or
 323                                 upr($lei, $w, 'update', $ref, $new, $old);
 324                 } else {
 325                         upr($lei, $w, 'delete', $ref, $old);
 326                         ++$ndel;
 327                 }
 328         }
 329         # git's ref files backend doesn't allow directory/file conflicts
 330         # between `delete' and `create' ops:
 331         if ($ndel && scalar(keys %src)) {
 332                 $fgrp->{-create_refs} = \%src;
 333         } else {
 334                 while (my ($ref, $oid) = each %src) {
 335                         upr($lei, $w, 'create', $ref, $oid);
 336                 }
 337         }
 338         close($w) or upref_warn();
 339 }
 340
 341 sub satellite_done {
 342         my ($fgrp) = @_;
 343         if (my $create = delete $fgrp->{-create_refs}) {
 344                 my $w = start_update_ref($fgrp) or return;
 345                 while (my ($ref, $oid) = each %$create) {
 346                         upr($fgrp->{lei}, $w, 'create', $ref, $oid);
 347                 }
 348                 close($w) or upref_warn();
 349         } else {
 350                 pack_refs($fgrp, $fgrp->{cur_dst});
 351                 run_puh($fgrp);
 352         }
 353 }
 354
 355 sub pack_refs {
 356         my ($self, $git_dir) = @_;
 357         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 358         start_cmd($self, $cmd, { 2 => $self->{lei}->{2} });
 359 }
 360
 361 sub fgrpv_done {
 362         my ($fgrpv) = @_;
 363         return if !$LIVE;
 364         my $first = $fgrpv->[0] // die 'BUG: no fgrpv->[0]';
 365         return if !keep_going($first);
 366         pack_refs($first, $first->{-osdir}); # objstore refs always packed
 367         for my $fgrp (@$fgrpv) {
 368                 my $rn = $fgrp->{-remote};
 369                 my %opt = ( 2 => $fgrp->{lei}->{2} );
 370
 371                 my $update_ref = PublicInbox::OnDestroy->new($$,
 372                                                         \&fgrp_update, $fgrp);
 373
 374                 my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 375                         "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 376                         "refs/remotes/$rn/" ];
 377                 open(my $sfh, '+>', undef) or die "open(src): $!";
 378                 $fgrp->{srcfh} = $sfh;
 379                 start_cmd($fgrp, $src, { %opt, 1 => $sfh }, $update_ref);
 380                 my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 381                         '--format=%(refname)%00%(objectname)' ];
 382                 open(my $dfh, '+>', undef) or die "open(dst): $!";
 383                 $fgrp->{dstfh} = $dfh;
 384                 start_cmd($fgrp, $dst, { %opt, 1 => $dfh }, $update_ref);
 385         }
 386 }
 387
 388 sub fgrp_fetch_all {
 389         my ($self) = @_;
 390         my $todo = $FGRP_TODO;
 391         $FGRP_TODO = \'BUG on further use';
 392         keys(%$todo) or return;
 393
 394         # Rely on the fgrptmp remote groups in the config file rather
 395         # than listing all remotes since the remote name list may exceed
 396         # system argv limits:
 397         my $grp = 'fgrptmp';
 398
 399         my @git = (@{$self->{-torsocks}}, 'git');
 400         my $j = $self->{lei}->{opt}->{jobs};
 401         my $opt = {};
 402         my @fetch = do {
 403                 local $self->{lei}->{opt}->{jobs} = 1;
 404                 (fetch_args($self->{lei}, $opt), qw(--no-tags --multiple));
 405         };
 406         push(@fetch, "-j$j") if $j;
 407         while (my ($osdir, $fgrp_old_new) = each %$todo) {
 408                 my $f = "$osdir/config";
 409                 return if !keep_going($self);
 410                 my ($fgrpv, $new) = @$fgrp_old_new;
 411                 @$fgrpv = sort { $b->{-sort} <=> $a->{-sort} } @$fgrpv;
 412                 push @$fgrpv, @$new; # $new is ordered by references
 413
 414                 my $cmd = ['git', "--git-dir=$osdir", qw(config -f), $f ];
 415                 # clobber group from previous run atomically
 416                 for ("remotes.$grp") { # TODO: hideRefs
 417                         my $c = [ @$cmd, '--unset-all', $_ ];
 418                         $self->{lei}->qerr("# @$c");
 419                         next if $self->{dry_run};
 420                         my $pid = spawn($c, undef, $opt);
 421                         waitpid($pid, 0) // die "waitpid: $!";
 422                         die "E: @$c \$?=$?" if ($? && ($? >> 8) != 5);
 423                 }
 424
 425                 # permanent configs:
 426                 my $cfg = PublicInbox::Config->git_config_dump($f);
 427                 for my $fgrp (@$fgrpv) {
 428                         my $u = $fgrp->{-uri} // die 'BUG: no {-uri}';
 429                         my $rn = $fgrp->{-remote} // die 'BUG: no {-remote}';
 430                         for ("url=$u", "fetch=+refs/*:refs/remotes/$rn/*",
 431                                         'tagopt=--no-tags') {
 432                                 my ($k, $v) = split(/=/, $_, 2);
 433                                 $k = "remote.$rn.$k";
 434                                 next if ($cfg->{$k} // '') eq $v;
 435                                 my $c = [@$cmd, $k, $v];
 436                                 $fgrp->{lei}->qerr("# @$c");
 437                                 next if $fgrp->{dry_run};
 438                                 run_die($c, undef, $opt);
 439                         }
 440                 }
 441
 442                 if (!$self->{dry_run}) {
 443                         # update the config atomically via O_APPEND while
 444                         # respecting git-config locking
 445                         sysopen(my $lk, "$f.lock", O_CREAT|O_EXCL|O_WRONLY)
 446                                 or die "open($f.lock): $!";
 447                         open my $fh, '>>', $f or die "open(>>$f): $!";
 448                         $fh->autoflush(1);
 449                         my $buf = join('', "[remotes]\n",
 450                                 map { "\t$grp = $_->{-remote}\n" } @$fgrpv);
 451                         print $fh $buf or die "print($f): $!";
 452                         close $fh or die "close($f): $!";
 453                         unlink("$f.lock") or die "unlink($f.lock): $!";
 454                 }
 455                 $cmd = [ @git, "--git-dir=$osdir", @fetch, $grp ];
 456                 my $end = PublicInbox::OnDestroy->new($$, \&fgrpv_done, $fgrpv);
 457                 start_cmd($self, $cmd, $opt, $end);
 458         }
 459 }
 460
 461 # keep this idempotent for future use by public-inbox-fetch
 462 sub forkgroup_prep {
 463         my ($self, $uri) = @_;
 464         $self->{-ent} // return;
 465         my $os = $self->{-objstore} // return;
 466         my $fg = $self->{-ent}->{forkgroup} // return;
 467         my $dir = "$os/$fg.git";
 468         if (!-d $dir && !$self->{dry_run}) {
 469                 PublicInbox::Import::init_bare($dir);
 470                 my $f = "$dir/config";
 471                 open my $fh, '+>>', $f or die "open:($f): $!";
 472                 print $fh <<EOM or die "print($f): $!";
 473 [repack]
 474         useDeltaIslands = true
 475 [pack]
 476         island = refs/remotes/([^/]+)/
 477 EOM
 478                 close $fh or die "close($f): $!";
 479         }
 480         my $key = $self->{-key} // die 'BUG: no -key';
 481         my $rn = substr(sha256_hex($key), 0, 16);
 482         if (!-d $self->{cur_dst} && !$self->{dry_run}) {
 483                 PublicInbox::Import::init_bare($self->{cur_dst});
 484                 my $f = "$self->{cur_dst}/config";
 485                 open my $fh, '+>>', $f or die "open:($f): $!";
 486                 print $fh <<EOM or die "print($f): $!";
 487 ; rely on the "$rn" remote in the
 488 ; $fg fork group for fetches
 489 ; only uncomment the following iff you detach from fork groups
 490 ; [remote "origin"]
 491 ;       url = $uri
 492 ;       fetch = +refs/*:refs/*
 493 ;       mirror = true
 494 EOM
 495                 close $fh or die "close($f): $!";
 496         }
 497         if (!$self->{dry_run}) {
 498                 my $alt = File::Spec->rel2abs("$dir/objects");
 499                 my $o = "$self->{cur_dst}/objects";
 500                 my $f = "$o/info/alternates";
 501                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 502                 open my $fh, '+>>', $f or die "open($f): $!";
 503                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 504                 chomp(my @cur = <$fh>);
 505                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 506                         say $fh $l or die "say($f): $!";
 507                 }
 508                 close $fh or die "close($f): $!";
 509         }
 510         bless {
 511                 %$self, -osdir => $dir, -remote => $rn, -uri => $uri
 512         }, __PACKAGE__;
 513 }
 514
 515 sub fp_done {
 516         my ($self, $cmd, $cb, @arg) = @_;
 517         if ($?) {
 518                 $self->{lei}->err("@$cmd failed (\$?=$?) (non-fatal)");
 519                 $? = 0; # don't let it influence normal exit
 520         }
 521         return if !keep_going($self);
 522         my $fh = delete $self->{-show_ref} // die 'BUG: no show-ref output';
 523         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 524         $self->{-ent} // die 'BUG: no -ent';
 525         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 526         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 527         return $cb->($self, @arg) if $A ne $B;
 528         $self->{lei}->qerr("# $self->{-key} up-to-date");
 529 }
 530
 531 sub cmp_fp_do {
 532         my ($self, $cb, @arg) = @_;
 533         # $cb is either resume_fetch or fgrp_enqueue
 534         $self->{-ent} // return $cb->($self, @arg);
 535         my $new = $self->{-ent}->{fingerprint} // return $cb->($self, @arg);
 536         my $key = $self->{-key} // die 'BUG: no -key';
 537         if (my $cur_ent = $self->{-local_manifest}->{$key}) {
 538                 # runs go_fetch->DESTROY run if eq
 539                 return if $cur_ent->{fingerprint} eq $new;
 540         }
 541         my $dst = $self->{cur_dst} // $self->{dst};
 542         my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 543         my $opt = { 2 => $self->{lei}->{2} };
 544         open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 545         $self->{-show_ref} = $opt->{1};
 546         do_reap($self);
 547         $self->{lei}->qerr("# @$cmd");
 548         $LIVE->{spawn($cmd, undef, $opt)} = [ \&fp_done, $self, $cmd,
 549                                                 $cb, @arg ];
 550 }
 551
 552 sub resume_fetch {
 553         my ($self, $uri, $fini) = @_;
 554         return if !keep_going($self);
 555         my $dst = $self->{cur_dst} // $self->{dst};
 556         my @git = ('git', "--git-dir=$dst");
 557         my $opt = { 2 => $self->{lei}->{2} };
 558         my $rn = 'random'.int(rand(1 << 30));
 559         for ("url=$uri", "fetch=+refs/*:refs/*", 'mirror=true') {
 560                 push @git, '-c', "remote.$rn.$_";
 561         }
 562         my $cmd = [ @{$self->{-torsocks}}, @git,
 563                         fetch_args($self->{lei}, $opt), $rn ];
 564         push @$cmd, '-P' if $self->{lei}->{prune}; # --prune-tags implied
 565         my $run_puh = PublicInbox::OnDestroy->new($$, \&run_puh, $self, $fini);
 566         ++$self->{chg}->{nr_chg};
 567         start_cmd($self, $cmd, $opt, $run_puh);
 568 }
 569
 570 sub fgrp_enqueue {
 571         my ($fgrp, $end) = @_; # $end calls fgrp_fetch_all
 572         return if !keep_going($fgrp);
 573         ++$fgrp->{chg}->{nr_chg};
 574         my $dst = $FGRP_TODO->{$fgrp->{-osdir}} //= [ [], [] ]; # [ old, new ]
 575         push @{$dst->[defined($fgrp->{-sort} ? 0 : 1)]}, $fgrp;
 576 }
 577
 578 sub clone_v1 {
 579         my ($self, $end) = @_;
 580         my $lei = $self->{lei};
 581         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 582         my $uri = URI->new($self->{cur_src} // $self->{src});
 583         my $path = $uri->path;
 584         $path =~ s!/*\z!! and $uri->path($path);
 585         defined($lei->{opt}->{epoch}) and
 586                 die "$uri is a v1 inbox, --epoch is not supported\n";
 587         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 588         my $dst = $self->{cur_dst} // $self->{dst};
 589         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 590         my $resume = -d $dst;
 591         if (my $fgrp = forkgroup_prep($self, $uri)) {
 592                 $fgrp->{-fini} = $fini;
 593                 if ($resume) {
 594                         $fgrp->{-sort} = $fgrp->{-ent}->{modified};
 595                         cmp_fp_do($fgrp, \&fgrp_enqueue, $end);
 596                 } else { # new repo, save for last
 597                         fgrp_enqueue($fgrp, $end);
 598                 }
 599         } elsif ($resume) {
 600                 cmp_fp_do($self, \&resume_fetch, $uri, $fini);
 601         } else { # normal clone
 602                 my $cmd = [ @{$self->{-torsocks}},
 603                                 clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 604                 if (defined($self->{-ent})) {
 605                         if (defined(my $ref = $self->{-ent}->{reference})) {
 606                                 -e "$self->{dst}$ref" and
 607                                         push @$cmd, '--reference',
 608                                                 "$self->{dst}$ref";
 609                         }
 610                 }
 611                 ++$self->{chg}->{nr_chg};
 612                 start_cmd($self, $cmd, $opt, PublicInbox::OnDestroy->new($$,
 613                                                 \&run_puh, $self, $fini));
 614         }
 615         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 616                                 /\A(?:always|v1)\z/s) {
 617                 _get_txt_start($self, '_/text/config/raw', $fini);
 618         }
 619
 620         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 621         $self->{'txt.description'} = $d if defined $d;
 622         (!defined($d) && !$end) and
 623                 _get_txt_start($self, 'description', $fini);
 624
 625         $end or do_reap($self, 1); # for non-manifest clone
 626 }
 627
 628 sub parse_epochs ($$) {
 629         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 630         $opt_epochs // return; # undef => all epochs
 631         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 632         undef($lo) if ($lo // '') eq '';
 633         my $re = qr/\A~?[0-9]+\z/;
 634         if (@extra || (($lo // '0') !~ $re) ||
 635                         (($hi // '0') !~ $re) ||
 636                         !(grep(defined, $lo, $hi))) {
 637                 die <<EOM;
 638 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 639 EOM
 640         }
 641         my @n = sort { $a <=> $b } keys %$v2_epochs;
 642         for (grep(defined, $lo, $hi)) {
 643                 if (/\A[0-9]+\z/) {
 644                         $_ > $n[-1] and die
 645 "`$_' exceeds maximum available epoch ($n[-1])\n";
 646                         $_ < $n[0] and die
 647 "`$_' is lower than minimum available epoch ($n[0])\n";
 648                 } elsif (/\A~([0-9]+)/) {
 649                         my $off = -$1 - 1;
 650                         $n[$off] // die "`$_' is out of range\n";
 651                         $_ = $n[$off];
 652                 } else { die "`$_' not understood\n" }
 653         }
 654         defined($lo) && defined($hi) && $lo > $hi and die
 655 "low value (`$lo') exceeds high (`$hi')\n";
 656         $lo //= $n[0] if $dotdot;
 657         $hi //= $n[-1] if $dotdot;
 658         $hi //= $lo;
 659         my $want = {};
 660         for ($lo..$hi) {
 661                 if (defined $v2_epochs->{$_}) {
 662                         $want->{$_} = 1;
 663                 } else {
 664                         warn
 665 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 666                 }
 667         }
 668         $want
 669 }
 670
 671 sub init_placeholder ($$$) {
 672         my ($src, $edst, $ent) = @_;
 673         PublicInbox::Import::init_bare($edst);
 674         my $f = "$edst/config";
 675         open my $fh, '>>', $f or die "open($f): $!";
 676         print $fh <<EOM or die "print($f): $!";
 677 [remote "origin"]
 678         url = $src
 679         fetch = +refs/*:refs/*
 680         mirror = true
 681
 682 ; This git epoch was created read-only and "public-inbox-fetch"
 683 ; will not fetch updates for it unless write permission is added.
 684 ; Hint: chmod +w $edst
 685 EOM
 686         if (defined($ent->{owner})) {
 687                 print $fh <<EOM or die "print($f): $!";
 688 [gitweb]
 689         owner = $ent->{owner}
 690 EOM
 691         }
 692         close $fh or die "close($f): $!";
 693         my %map = (head => 'HEAD', description => undef);
 694         while (my ($key, $fn) = each %map) {
 695                 my $val = $ent->{$key} // next;
 696                 $fn //= $key;
 697                 $fn = "$edst/$fn";
 698                 open $fh, '>', $fn or die "open($fn): $!";
 699                 print $fh $val, "\n" or die "print($fn): $!";
 700                 close $fh or die "close($fn): $!";
 701         }
 702 }
 703
 704 sub reap_cmd { # async, called via SIGCHLD
 705         my ($self, $cmd) = @_;
 706         my $cerr = $?;
 707         $? = 0; # don't let it influence normal exit
 708         $self->{lei}->child_error($cerr, "@$cmd failed (\$?=$cerr)") if $cerr;
 709 }
 710
 711 sub up_fp_done {
 712         my ($self) = @_;
 713         return if !keep_going($self);
 714         my $fh = delete $self->{-show_ref_up} // die 'BUG: no show-ref output';
 715         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 716         $self->{-ent} // die 'BUG: no -ent';
 717         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 718         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 719         return if $A eq $B;
 720         $self->{-ent}->{fingerprint} = $B;
 721         push @{$self->{chg}->{fp_mismatch}}, $self->{-key};
 722 }
 723
 724 sub atomic_write ($$$) {
 725         my ($dn, $bn, $raw) = @_;
 726         my $ft = File::Temp->new(DIR => $dn, TEMPLATE => "$bn-XXXX");
 727         print $ft $raw or die "print($ft): $!";
 728         $ft->flush or die "flush($ft): $!";
 729         ft_rename($ft, "$dn/$bn", 0666);
 730 }
 731
 732 sub run_next_puh {
 733         my ($self) = @_;
 734         my $puh = shift @{$self->{-puh_todo}} // return delete($self->{-fini});
 735         my $fini = PublicInbox::OnDestroy->new($$, \&run_next_puh, $self);
 736         my $cmd = [ @$puh, ($self->{cur_dst} // $self->{dst}) ];
 737         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 738         start_cmd($self, $cmd, undef, $opt, $fini);
 739 }
 740
 741 sub run_puh {
 742         my ($self, $fini) = @_;
 743         $self->{-fini} = $fini;
 744         @{$self->{-puh_todo}} = @PUH;
 745         run_next_puh($self);
 746 }
 747
 748 # modifies the to-be-written manifest entry, and sets values from it, too
 749 sub update_ent {
 750         my ($self) = @_;
 751         my $key = $self->{-key} // die 'BUG: no -key';
 752         my $new = $self->{-ent}->{fingerprint};
 753         my $cur = $self->{-local_manifest}->{$key}->{fingerprint} // "\0";
 754         my $dst = $self->{cur_dst} // $self->{dst};
 755         if (defined($new) && $new ne $cur) {
 756                 my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 757                 my $opt = { 2 => $self->{lei}->{2} };
 758                 open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 759                 $self->{-show_ref_up} = $opt->{1};
 760                 my $done = PublicInbox::OnDestroy->new($$, \&up_fp_done, $self);
 761                 start_cmd($self, $cmd, $opt, $done);
 762         }
 763         $new = $self->{-ent}->{head};
 764         $cur = $self->{-local_manifest}->{$key}->{head} // "\0";
 765         if (defined($new) && $new ne $cur) {
 766                 # n.b. grokmirror writes raw contents to $dst/HEAD w/o locking
 767                 my $cmd = [ 'git', "--git-dir=$dst" ];
 768                 if ($new =~ s/\Aref: //) {
 769                         push @$cmd, qw(symbolic-ref HEAD), $new;
 770                 } elsif ($new =~ /\A[a-f0-9]{40,}\z/) {
 771                         push @$cmd, qw(update-ref --no-deref HEAD), $new;
 772                 } else {
 773                         undef $cmd;
 774                         warn "W: $key: {head} => `$new' not understood\n";
 775                 }
 776                 start_cmd($self, $cmd, { 2 => $self->{lei}->{2} }) if $cmd;
 777         }
 778         if (my $symlinks = $self->{-ent}->{symlinks}) {
 779                 my $top = File::Spec->rel2abs($self->{dst});
 780                 push @{$self->{-new_symlinks}}, @$symlinks;
 781                 for my $p (@$symlinks) {
 782                         my $ln = "$top/$p";
 783                         $ln =~ tr!/!/!s;
 784                         my (undef, $dn, $bn) = File::Spec->splitpath($ln);
 785                         File::Path::mkpath($dn);
 786                         my $tgt = "$top/$key";
 787                         $tgt = File::Spec->abs2rel($tgt, $dn);
 788                         if (lstat($ln)) {
 789                                 if (-l _) {
 790                                         next if readlink($ln) eq $tgt;
 791                                         unlink($ln) or die "unlink($ln): $!";
 792                                 } else {
 793                                         push @{$self->{chg}->{badlink}}, $p;
 794                                 }
 795                         }
 796                         symlink($tgt, $ln) or die "symlink($tgt, $ln): $!";
 797                         ++$self->{chg}->{nr_chg};
 798                 }
 799         }
 800         if (defined(my $t = $self->{-ent}->{modified})) {
 801                 my ($dn, $bn) = ("$dst/info/web", 'last-modified');
 802                 my $orig = PublicInbox::Git::try_cat("$dn/$bn");
 803                 $t = strftime('%F %T', gmtime($t))." +0000\n";
 804                 File::Path::mkpath($dn);
 805                 atomic_write($dn, $bn, $t) if $orig ne $t;
 806         }
 807
 808         $new = $self->{-ent}->{owner} // return;
 809         $cur = $self->{-local_manifest}->{$key}->{owner} // "\0";
 810         return if $cur eq $new;
 811         my $cmd = [ qw(git config -f), "$dst/config", 'gitweb.owner', $new ];
 812         start_cmd($self, $cmd, { 2 => $self->{lei}->{2} });
 813 }
 814
 815 sub v1_done { # called via OnDestroy
 816         my ($self) = @_;
 817         return if $self->{dry_run} || !keep_going($self);
 818         _write_inbox_config($self);
 819         my $dst = $self->{cur_dst} // $self->{dst};
 820         update_ent($self) if $self->{-ent};
 821         my $o = "$dst/objects";
 822         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
 823                 my $base = File::Spec->rel2abs($o);
 824                 my @l = <$fh>;
 825                 my $ft;
 826                 for (@l) {
 827                         next unless m!\A/!;
 828                         $_ = File::Spec->abs2rel($_, $base);
 829                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
 830                                                 DIR => "$o/info");
 831                 }
 832                 if ($ft) {
 833                         print $ft @l or die "print($ft): $!";
 834                         $ft->flush or die "flush($ft): $!";
 835                         ft_rename($ft, $fn, 0666, $fh);
 836                 }
 837         }
 838         eval { set_description($self) };
 839         warn $@ if $@;
 840         return if ($self->{-is_epoch} ||
 841                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 842         write_makefile($dst, 1);
 843         index_cloned_inbox($self, 1);
 844 }
 845
 846 sub v2_done { # called via OnDestroy
 847         my ($self) = @_;
 848         return if $self->{dry_run} || !keep_going($self);
 849         my $dst = $self->{cur_dst} // $self->{dst};
 850         require PublicInbox::Lock;
 851         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 852         my $lck = $lk->lock_for_scope($$);
 853         _write_inbox_config($self);
 854         require PublicInbox::MultiGit;
 855         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 856         $mg->fill_alternates;
 857         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 858         for my $edst (@{delete($self->{-read_only}) // []}) {
 859                 my @st = stat($edst) or die "stat($edst): $!";
 860                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 861         }
 862         write_makefile($dst, 2);
 863         undef $lck; # unlock
 864         eval { set_description($self) };
 865         warn $@ if $@;
 866         index_cloned_inbox($self, 2);
 867 }
 868
 869 sub clone_v2_prep ($$;$) {
 870         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 871         my $lei = $self->{lei};
 872         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 873         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 874         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 875         my $dst = $self->{cur_dst} // $self->{dst};
 876         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 877         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 878         my (@skip, $desc);
 879         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 880         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 881                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 882                 my $src = $uri->as_string;
 883                 my $edst = $dst;
 884                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 885 failed to extract epoch number from $src
 886
 887                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 888                 $edst .= "/git/$nr.git";
 889                 my $ent;
 890                 if ($m) {
 891                         $ent = $m->{$key} //
 892                                 die("BUG: `$key' not in manifest.js.gz");
 893                         if (defined(my $d = $ent->{description})) {
 894                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 895                                 $desc = $d;
 896                         }
 897                 }
 898                 if (!$want || $want->{$nr}) {
 899                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 900                         $etask->{-ent} = $ent; # may have {reference}
 901                         $etask->{cur_src} = $src;
 902                         $etask->{cur_dst} = $edst;
 903                         $etask->{-is_epoch} = $fini;
 904                         my $ref = $ent->{reference} // '';
 905                         push @{$TODO->{$ref}}, $etask;
 906                         $self->{any_want}->{$key} = 1;
 907                 } else { # create a placeholder so users only need to chmod +w
 908                         init_placeholder($src, $edst, $ent);
 909                         push @{$task->{-read_only}}, $edst;
 910                         push @skip, $key;
 911                 }
 912         }
 913         # filter out the epochs we skipped
 914         $self->{chg}->{manifest} = 1 if $m && delete(@$m{@skip});
 915
 916         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 917
 918         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 919                 _get_txt_start($task, '_/text/config/raw', $fini);
 920
 921         defined($desc) ? ($task->{'txt.description'} = $desc) :
 922                 _get_txt_start($task, 'description', $fini);
 923 }
 924
 925 sub decode_manifest ($$$) {
 926         my ($fh, $fn, $uri) = @_;
 927         my $js;
 928         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 929         gunzip(\$gz => \$js, MultiStream => 1) or
 930                 die "gunzip($uri): $GunzipError\n";
 931         my $m = eval { PublicInbox::Config->json->decode($js) };
 932         die "$uri: error decoding `$js': $@\n" if $@;
 933         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 934         $m;
 935 }
 936
 937 sub load_current_manifest ($) {
 938         my ($self) = @_;
 939         my $fn = $self->{-manifest} // return;
 940         if (open(my $fh, '<', $fn)) {
 941                 decode_manifest($fh, $fn, $fn);
 942         } elsif ($!{ENOENT}) { # non-fatal, we can just do it slowly
 943                 warn "open($fn): $!\n" if !$self->{-initial_clone};
 944                 undef;
 945         } else {
 946                 die "open($fn): $!\n";
 947         }
 948 }
 949
 950 sub multi_inbox ($$$) {
 951         my ($self, $path, $m) = @_;
 952         my $incl = $self->{lei}->{opt}->{include};
 953         my $excl = $self->{lei}->{opt}->{exclude};
 954
 955         # assuming everything not v2 is v1, for now
 956         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 957         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 958         my $v2 = {};
 959
 960         for (@v2_epochs) {
 961                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 962                 push @{$v2->{$1}}, $_;
 963         }
 964         my $n = scalar(keys %$v2) + scalar(@v1);
 965         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 966         if (defined $incl) {
 967                 my $re = '(?:'.join('\\z|', map {
 968                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 969                         } @$incl).'\\z)';
 970                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 971                 delete @$m{map { @$_ } @gone} and $self->{chg}->{manifest} = 1;
 972                 delete @$m{grep(!/$re/, @v1)} and $self->{chg}->{manifest} = 1;
 973                 @v1 = grep(/$re/, @v1);
 974         }
 975         if (defined $excl) {
 976                 my $re = '(?:'.join('\\z|', map {
 977                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 978                         } @$excl).'\\z)';
 979                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 980                 delete @$m{map { @$_ } @gone} and $self->{chg}->{manifest} = 1;
 981                 delete @$m{grep(/$re/, @v1)} and $self->{chg}->{manifest} = 1;
 982                 @v1 = grep(!/$re/, @v1);
 983         }
 984         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 985         $ret->{v1} = \@v1 if @v1;
 986         $ret->{v2} = $v2 if keys %$v2;
 987         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 988                                 join("\n\t", sort @orig)
 989                         : "Nothing available to clone\n";
 990         my $path_pfx = '';
 991
 992         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 993         if (@v2_epochs) {
 994                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 995                                 @v2_epochs) == @v2_epochs) {
 996                         $$path =~ s!\A(/[^/]+)/!/! or last;
 997                         $path_pfx .= $1;
 998                 }
 999         } elsif (@v1) {
1000                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
1001                         $path_pfx .= $1;
1002                 }
1003         }
1004         ($path_pfx, $n, $ret);
1005 }
1006
1007 sub clone_all {
1008         my ($self, $m) = @_;
1009         my $todo = $TODO;
1010         $TODO = \'BUG on further use';
1011         my $end = PublicInbox::OnDestroy->new($$, \&fgrp_fetch_all, $self);
1012         {
1013                 my $nodep = delete $todo->{''};
1014
1015                 # do not download unwanted deps
1016                 my $any_want = delete $self->{any_want};
1017                 my @unwanted = grep { !$any_want->{$_} } keys %$todo;
1018                 my @nodep = delete(@$todo{@unwanted});
1019                 push(@$nodep, @$_) for @nodep;
1020
1021                 # handle no-dependency repos, first
1022                 for (@$nodep) {
1023                         clone_v1($_, $end);
1024                         return if !keep_going($self);
1025                 }
1026         }
1027         # resolve references, deepest, first:
1028         while (scalar keys %$todo) {
1029                 for my $x (keys %$todo) {
1030                         my ($nr, $nxt);
1031                         # resolve multi-level references
1032                         while ($m && defined($nxt = $m->{$x}->{reference})) {
1033                                 exists($todo->{$nxt}) or last;
1034                                 if (++$nr > 1000) {
1035                                         $m->{$x}->{reference} = undef;
1036                                         $m->{$nxt}->{reference} = undef;
1037                                         warn <<EOM
1038 E: dependency loop detected (`$x' => `$nxt'), breaking
1039 EOM
1040                                 }
1041                                 $x = $nxt;
1042                         }
1043                         my $y = delete $todo->{$x} // next; # already done
1044                         for (@$y) {
1045                                 clone_v1($_, $end);
1046                                 return if !keep_going($self);
1047                         }
1048                         last; # restart %$todo iteration
1049                 }
1050         }
1051
1052         # $end->DESTROY will call fgrp_fetch_all once all references
1053         # in $LIVE are gone, and do_reap will eventually drain $LIVE
1054         $end = undef;
1055         do_reap($self, 1);
1056 }
1057
1058 sub dump_manifest ($$) {
1059         my ($m, $ft) = @_;
1060         # write the smaller manifest if epochs were skipped so
1061         # users won't have to delete manifest if they +w an
1062         # epoch they no longer want to skip
1063         my $json = PublicInbox::Config->json->encode($m);
1064         my $mtime = (stat($ft))[9];
1065         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
1066         truncate($ft, 0) or die "truncate($ft): $!";
1067         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
1068         $ft->flush or die "flush($ft): $!";
1069         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
1070 }
1071
1072 sub dump_project_list ($$) {
1073         my ($self, $m) = @_;
1074         my $f = $self->{'-project-list'} // return;
1075         my $old = PublicInbox::Git::try_cat($f);
1076         my %new;
1077
1078         open my $dh, '<', '.' or die "open(.): $!";
1079         chdir($self->{dst}) or die "chdir($self->{dst}): $!";
1080         my @local = grep { -e $_ ? ($new{$_} = undef) : 1 } split(/\n/s, $old);
1081         chdir($dh) or die "chdir(restore): $!";
1082
1083         $new{substr($_, 1)} = 1 for keys %$m; # drop leading '/'
1084         my @list = sort keys %new;
1085         my @remote = grep { !defined($new{$_}) } @list;
1086         my %lnk = map { substr($_, 1) => undef } @{$self->{-new_symlinks}};
1087         @remote = grep { !exists($lnk{$_}) } @remote;
1088
1089         warn <<EOM if @remote;
1090 The following local repositories are ignored/gone from $self->{src}:
1091 EOM
1092         warn "\t", $_, "\n" for @remote;
1093         warn <<EOM if @local;
1094 The following repos in $f no longer exist on the filesystem:
1095 EOM
1096         warn "\t", $_, "\n" for @local;
1097
1098         my (undef, $dn, $bn) = File::Spec->splitpath($f);
1099         $self->{chg}->{nr_chg} += scalar(@remote) + scalar(@local);
1100         my $new = join("\n", @list, '');
1101         atomic_write($dn, $bn, $new) if $new ne $old;
1102 }
1103
1104 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
1105 sub try_manifest {
1106         my ($self) = @_;
1107         my $uri = URI->new($self->{src});
1108         my $lei = $self->{lei};
1109         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
1110         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
1111         my $path = $uri->path;
1112         chop($path) eq '/' or die "BUG: $uri not canonicalized";
1113         $uri->path($path . '/manifest.js.gz');
1114         my $manifest = $self->{-manifest} // "$self->{dst}/manifest.js.gz";
1115         my %opt = (UNLINK => 1, SUFFIX => '.tmp', TMPDIR => 1);
1116         if (!$self->{dry_run} && $manifest =~ m!\A(.+?)/[^/]+\z! and -d $1) {
1117                 $opt{DIR} = $1; # allows fast rename(2) w/o EXDEV
1118                 delete $opt{TMPDIR};
1119         }
1120         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX', %opt);
1121         my $cmd = $curl->for_uri($lei, $uri, qw(-R -o), $ft->filename);
1122         push(@$cmd, '-z', $manifest) if -f $manifest;
1123         my $mf_url = "$uri";
1124         %opt = map { $_ => $lei->{$_} } (0..2);
1125         my $cerr = run_reap($lei, $cmd, \%opt);
1126         if ($cerr) {
1127                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
1128                 return $lei->child_error($cerr, "@$cmd failed");
1129         }
1130
1131         # bail out if curl -z/--timecond hit 304 Not Modified, $ft will be empty
1132         if (-f $manifest && !-s $ft) {
1133                 $lei->child_error(127 << 8) if $lei->{opt}->{'exit-code'};
1134                 return $lei->qerr("# $manifest unchanged");
1135         }
1136
1137         my $m = eval { decode_manifest($ft, $ft, $uri) };
1138         if ($@) {
1139                 warn $@;
1140                 return try_scrape($self);
1141         }
1142         local $self->{chg} = {};
1143         local $self->{-local_manifest} = load_current_manifest($self);
1144         local $self->{-new_symlinks} = [];
1145         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
1146         return $lei->child_error(1, $multi) if !ref($multi);
1147         my $v2 = delete $multi->{v2};
1148         if ($v2) {
1149                 for my $name (sort keys %$v2) {
1150                         my $epochs = delete $v2->{$name};
1151                         my %v2_epochs = map {
1152                                 $uri->path($n > 1 ? $path_pfx.$path.$_
1153                                                 : $path_pfx.$_);
1154                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
1155                                 $e // die "no [0-9]+\.git in `$uri'";
1156                                 $e => [ $uri->clone, $_ ];
1157                         } @$epochs;
1158                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
1159                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
1160                         local $self->{cur_src} = $1;
1161                         local $self->{cur_dst} = $self->{dst};
1162                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
1163                                                         git/[0-9]+\.git\z!x) {
1164                                 $self->{cur_dst} .= "/$1";
1165                         }
1166                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
1167 E: `$self->{cur_dst}' must not contain newline
1168 EOM
1169                         clone_v2_prep($self, \%v2_epochs, $m);
1170                         return if !keep_going($self);
1171                 }
1172         }
1173         if (my $v1 = delete $multi->{v1}) {
1174                 my $p = $path_pfx.$path;
1175                 chop($p) if substr($p, -1, 1) eq '/';
1176                 $uri->path($p);
1177                 for my $name (@$v1) {
1178                         my $task = bless { %$self }, __PACKAGE__;
1179                         $task->{-ent} = $m->{$name} //
1180                                         die("BUG: no `$name' in manifest");
1181                         $task->{cur_src} = "$uri";
1182                         $task->{cur_dst} = $task->{dst};
1183                         $task->{-key} = $name;
1184                         if ($n > 1) {
1185                                 $task->{cur_dst} .= $name;
1186                                 $task->{cur_src} .= $name;
1187                         }
1188                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
1189 E: `$task->{cur_dst}' must not contain newline
1190 EOM
1191                         $task->{cur_src} .= '/';
1192                         my $dep = $task->{-ent}->{reference} // '';
1193                         push @{$TODO->{$dep}}, $task; # for clone_all
1194                         $self->{any_want}->{$name} = 1;
1195                 }
1196         }
1197         delete local $lei->{opt}->{epoch} if defined($v2);
1198         clone_all($self, $m);
1199         return if $self->{dry_run} || !keep_going($self);
1200
1201         # set by clone_v2_prep/-I/--exclude
1202         my $mis = delete $self->{chg}->{fp_mismatch};
1203         if ($mis) {
1204                 my $t = (stat($ft))[9];
1205                 $t = strftime('%F %k:%M:%S %z', localtime($t));
1206                 warn <<EOM;
1207 W: Fingerprints for the following repositories do not match
1208 W: $mf_url @ $t:
1209 W: These repositories may have updated since $t:
1210 EOM
1211                 warn "\t", $_, "\n" for @$mis;
1212                 warn <<EOM if !$self->{lei}->{opt}->{prune};
1213 W: The above fingerprints may never match without --prune
1214 EOM
1215         }
1216         dump_manifest($m => $ft) if delete($self->{chg}->{manifest}) || $mis;
1217         my $bad = delete $self->{chg}->{badlink};
1218         warn(<<EOM, map { ("\t", $_, "\n") } @$bad) if $bad;
1219 W: The following exist and have not been converted to symlinks
1220 EOM
1221         dump_project_list($self, $m);
1222         ft_rename($ft, $manifest, 0666);
1223         !$self->{chg}->{nr_chg} && $lei->{opt}->{'exit-code'} and
1224                 $lei->child_error(127 << 8);
1225 }
1226
1227 sub start_clone_url {
1228         my ($self) = @_;
1229         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
1230         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
1231 }
1232
1233 sub do_mirror { # via wq_io_do or public-inbox-clone
1234         my ($self) = @_;
1235         my $lei = $self->{lei};
1236         $self->{dry_run} = 1 if $lei->{opt}->{'dry-run'};
1237         umask($lei->{client_umask}) if defined $lei->{client_umask};
1238         $self->{-initial_clone} = 1 if !-d $self->{dst};
1239         local @PUH;
1240         if (defined(my $puh = $lei->{opt}->{'post-update-hook'})) {
1241                 require Text::ParseWords;
1242                 @PUH = map { [ Text::ParseWords::shellwords($_) ] } @$puh;
1243         }
1244         eval {
1245                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
1246                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
1247 --inbox-config must be one of `always', `v2', `v1', or `never'
1248
1249                 # we support these switches with '' (empty string).
1250                 # defaults match example conf distributed with grokmirror
1251                 my @pairs = qw(objstore objstore manifest manifest.js.gz
1252                                 project-list projects.list);
1253                 while (@pairs) {
1254                         my ($k, $default) = splice(@pairs, 0, 2);
1255                         my $v = $lei->{opt}->{$k} // next;
1256                         $v = $default if $v eq '';
1257                         $v = "$self->{dst}/$v" if $v !~ m!\A\.{0,2}/!;
1258                         $self->{"-$k"} = $v;
1259                 }
1260
1261                 local $LIVE = {};
1262                 local $TODO = {};
1263                 local $FGRP_TODO = {};
1264                 my $iv = $lei->{opt}->{'inbox-version'} //
1265                         return start_clone_url($self);
1266                 return clone_v1($self) if $iv == 1;
1267                 die "bad --inbox-version=$iv\n" if $iv != 2;
1268                 die <<EOM if $self->{src} !~ m!://!;
1269 cloning local v2 inboxes not supported
1270 EOM
1271                 try_scrape($self, 1);
1272         };
1273         $lei->fail($@) if $@;
1274 }
1275
1276 sub start {
1277         my ($cls, $lei, $src, $dst) = @_;
1278         my $self = bless { src => $src, dst => $dst }, $cls;
1279         $lei->request_umask;
1280         my ($op_c, $ops) = $lei->workers_start($self, 1);
1281         $lei->{wq1} = $self;
1282         $self->wq_io_do('do_mirror', []);
1283         $self->wq_close;
1284         $lei->wait_wq_events($op_c, $ops);
1285 }
1286
1287 sub ipc_atfork_child {
1288         my ($self) = @_;
1289         $self->{lei}->_lei_atfork_child;
1290         $self->SUPER::ipc_atfork_child;
1291 }
1292
1293 sub write_makefile {
1294         my ($dir, $ibx_ver) = @_;
1295         my $f = "$dir/Makefile";
1296         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
1297                 print $fh <<EOM or die "print($f) $!";
1298 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
1299 # manpage for more information on the format.  This Makefile is
1300 # intended as a familiar wrapper for users unfamiliar with
1301 # public-inbox-* commands.
1302 #
1303 # See the respective manpages for public-inbox-fetch(1),
1304 # public-inbox-index(1), etc for more information on
1305 # some of the commands used by this Makefile.
1306 #
1307 # This Makefile will not be modified nor read by public-inbox,
1308 # so you may edit it freely with your own convenience targets
1309 # and notes.  public-inbox-fetch will recreate it if removed.
1310 EOM
1311                 print $fh <<'EOM' or die "print($f): $!";
1312 # the default target:
1313 help :
1314         @echo Common targets:
1315         @echo '    make fetch        - fetch from remote git repostorie(s)'
1316         @echo '    make update       - fetch and update index '
1317         @echo
1318         @echo Rarely needed targets:
1319         @echo '    make reindex      - may be needed for new features/bugfixes'
1320         @echo '    make compact      - rewrite Xapian storage to save space'
1321         @echo '    make index        - initial index after clone
1322
1323 fetch :
1324         public-inbox-fetch
1325 update :
1326         @if ! public-inbox-fetch --exit-code; \
1327         then \
1328                 c=$$?; \
1329                 test $$c -eq 127 && exit 0; \
1330                 exit $$c; \
1331         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
1332         then \
1333                 public-inbox-index; \
1334         else \
1335                 echo 'public-inbox index not initialized'; \
1336                 echo 'see public-inbox-index(1) man page'; \
1337         fi
1338 index :
1339         public-inbox-index
1340 reindex :
1341         public-inbox-index --reindex
1342 compact :
1343         public-inbox-compact
1344
1345 .PHONY : help fetch update index reindex compact
1346 EOM
1347                 close $fh or die "close($f): $!";
1348         } else {
1349                 die "open($f): $!" unless $!{EEXIST};
1350         }
1351 }
1352
1353 1;