]> Sergey Matveev's repositories - public-inbox.git/blob - lib/PublicInbox/LeiMirror.pm
829740bc456ae7403ed70f857d71a0852a46eba0
[public-inbox.git] / lib / PublicInbox / LeiMirror.pm
1 # Copyright (C) all contributors <meta@public-inbox.org>
2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
3
4 # "lei add-external --mirror" support (also "public-inbox-clone");
5 package PublicInbox::LeiMirror;
6 use v5.12;
7 use parent qw(PublicInbox::IPC);
8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
9 use IO::Compress::Gzip qw(gzip $GzipError);
10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
11 use File::Path ();
12 use File::Temp ();
13 use File::Spec ();
14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
15 use Carp qw(croak);
16 use URI;
17 use PublicInbox::Config;
18 use PublicInbox::Inbox;
19 use PublicInbox::LeiCurl;
20 use PublicInbox::OnDestroy;
21 use Digest::SHA qw(sha256_hex);
22
23 our $LIVE; # pid => callback
24 my $update_ref_stdin = $ENV{GIT_CAN_UPDATE_REF_STDIN} // 1;
25
26 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
27         my ($arg, $pid) = @_;
28         my ($mrr, $lei) = @$arg;
29         my $f = "$mrr->{dst}/mirror.done";
30         if ($?) {
31                 $lei->child_error($?);
32         } elsif (!$mrr->{dry_run} && !unlink($f)) {
33                 warn("unlink($f): $!\n") unless $!{ENOENT};
34         } else {
35                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
36                         require PublicInbox::LeiAddExternal;
37                         PublicInbox::LeiAddExternal::_finish_add_external(
38                                                         $lei, $mrr->{dst});
39                 }
40                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
41         }
42         $lei->dclose;
43 }
44
45 # for old installations without manifest.js.gz
46 sub try_scrape {
47         my ($self, $fallback_manifest) = @_;
48         my $uri = URI->new($self->{src});
49         my $lei = $self->{lei};
50         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
51         my $cmd = $curl->for_uri($lei, $uri, qw(-f --compressed));
52         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
53         my $fh = popen_rd($cmd, undef, $opt);
54         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
55         close($fh) or return $lei->child_error($?, "@$cmd failed");
56
57         # we grep with URL below, we don't want Subject/From headers
58         # making us clone random URLs.  This assumes remote instances
59         # prior to public-inbox 1.7.0
60         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
61         my @html = split(/<hr>/, $html);
62         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
63         if (!@urls && $fallback_manifest) {
64                 warn <<EOM;
65 W: failed to extract URLs from $uri, trying manifest.js.gz...
66 EOM
67                 return start_clone_url($self);
68         }
69         my $url = $uri->as_string;
70         chop($url) eq '/' or die "BUG: $uri not canonicalized";
71
72         # since this is for old instances w/o manifest.js.gz, try v1 first
73         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
74         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
75                 my %v2_epochs = map {
76                         my ($n) = (m!/([0-9]+)\z!);
77                         $n => [ URI->new($_), '' ]
78                 } @v2_urls; # uniq
79                 clone_v2_prep($self, \%v2_epochs);
80                 delete local $lei->{opt}->{epoch};
81                 clone_all($self);
82                 return;
83         }
84
85         # filter out common URLs served by WWW (e.g /$MSGID/T/)
86         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
87                         grep(m!\A\Q$url\E/*\z!, @urls)) {
88                 die <<"";
89 E: confused by scraping <$uri>, did you mean <$url>?
90
91         }
92         @urls and die <<"";
93 E: confused by scraping <$uri>, got ambiguous results:
94 @urls
95
96         die "E: scraping <$uri> revealed nothing\n";
97 }
98
99 sub clone_cmd {
100         my ($lei, $opt) = @_;
101         my @cmd = qw(git);
102         $opt->{$_} = $lei->{$_} for (0..2);
103         # we support "-c $key=$val" for arbitrary git config options
104         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
105         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
106         push @cmd, qw(clone --mirror);
107         push @cmd, '-q' if $lei->{opt}->{quiet} ||
108                         ($lei->{opt}->{jobs} // 1) > 1;
109         push @cmd, '-v' if $lei->{opt}->{verbose};
110         # XXX any other options to support?
111         # --reference is tricky with multiple epochs, but handled
112         # automatically if using manifest.js.gz
113         @cmd;
114 }
115
116 sub ft_rename ($$$;$) {
117         my ($ft, $dst, $open_mode, $fh) = @_;
118         my @st = stat($fh // $dst);
119         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
120         chmod($mode, $ft) or croak "E: chmod($ft): $!";
121         require File::Copy;
122         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
123         $ft->unlink_on_destroy(0);
124 }
125
126 sub do_reap ($;$) {
127         my ($self, $jobs) = @_;
128         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
129         $jobs = 1 if $jobs < 1;
130         while (keys(%$LIVE) >= $jobs) {
131                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
132                 if (my $x = delete $LIVE->{$pid}) {
133                         my $cb = shift @$x;
134                         $cb->(@$x) if $cb;
135                 } else {
136                         warn "reaped unknown PID=$pid ($?)\n";
137                 }
138         }
139 }
140
141 sub _get_txt_start { # non-fatal
142         my ($self, $endpoint, $fini) = @_;
143         my $uri = URI->new($self->{cur_src} // $self->{src});
144         my $lei = $self->{lei};
145         my $path = $uri->path;
146         chop($path) eq '/' or die "BUG: $uri not canonicalized";
147         $uri->path("$path/$endpoint");
148         my $f = (split(m!/!, $endpoint))[-1];
149         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
150         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
151         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(-f --compressed -R -o),
152                                         $ft->filename);
153         do_reap($self);
154         $lei->qerr("# @$cmd");
155         return if $self->{dry_run};
156         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
157         $LIVE->{spawn($cmd, undef, $opt)} =
158                         [ \&_get_txt_done, $self, $endpoint, $fini ];
159 }
160
161 sub _get_txt_done { # returns true on error (non-fatal), undef on success
162         my ($self, $endpoint) = @_;
163         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
164         my $cerr = $?;
165         $? = 0; # don't influence normal lei exit
166         return warn("$uri missing\n") if ($cerr >> 8) == 22;
167         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
168         seek($fh, SEEK_SET, 0) or die "seek: $!";
169         $self->{"mtime.$endpoint"} = (stat($fh))[9];
170         local $/;
171         $self->{"txt.$endpoint"} = <$fh>;
172         undef; # success
173 }
174
175 sub _write_inbox_config {
176         my ($self) = @_;
177         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
178         my $dst = $self->{cur_dst} // $self->{dst};
179         my $f = "$dst/inbox.config.example";
180         open my $fh, '>', $f or die "open($f): $!";
181         print $fh $buf or die "print: $!";
182         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
183         my $mtime = delete $self->{'mtime._/text/config/raw'};
184         $fh->flush or die "flush($f): $!";
185         if (defined $mtime) {
186                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
187         }
188         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
189         my $ibx = $self->{ibx} = {};
190         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
191                 for (qw(address newsgroup nntpmirror)) {
192                         $ibx->{$_} = $cfg->{"$sec.$_"};
193                 }
194         }
195 }
196
197 sub set_description ($) {
198         my ($self) = @_;
199         my $dst = $self->{cur_dst} // $self->{dst};
200         my $f = "$dst/description";
201         open my $fh, '+>>', $f or die "open($f): $!";
202         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
203         my $d = do { local $/; <$fh> } // die "read($f): $!";
204         chomp(my $orig = $d);
205         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
206                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
207                 $d = delete($self->{'txt.description'});
208         }
209         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
210         chomp $d;
211         return if $d eq $orig;
212         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
213         truncate($fh, 0) or die "truncate($f): $!";
214         print $fh $d, "\n" or die "print($f): $!";
215         close $fh or die "close($f): $!";
216 }
217
218 sub index_cloned_inbox {
219         my ($self, $iv) = @_;
220         my $lei = $self->{lei};
221
222         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
223         # lei is useless without Xapian + SQLite
224         if ($lei->{cmd} ne 'public-inbox-clone') {
225                 require PublicInbox::InboxWritable;
226                 require PublicInbox::Admin;
227                 my $ibx = delete($self->{ibx}) // {
228                         address => [ 'lei@example.com' ],
229                         version => $iv,
230                 };
231                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
232                 PublicInbox::Inbox->new($ibx);
233                 PublicInbox::InboxWritable->new($ibx);
234                 my $opt = {};
235                 for my $sw ($lei->index_opt) {
236                         my ($k) = ($sw =~ /\A([\w-]+)/);
237                         $opt->{$k} = $lei->{opt}->{$k};
238                 }
239                 # force synchronous dwaitpid for v2:
240                 local $PublicInbox::DS::in_loop = 0;
241                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
242                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
243                 local %ENV = (%ENV, %$env) if $env;
244                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
245                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
246         }
247         return if defined $self->{cur_dst}; # one of many repos to clone
248         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
249 }
250
251 sub run_reap {
252         my ($lei, $cmd, $opt) = @_;
253         $lei->qerr("# @$cmd");
254         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
255         my $ret = $?;
256         $? = 0; # don't let it influence normal exit
257         $ret;
258 }
259
260 sub start_clone {
261         my ($self, $cmd, $opt, $fini) = @_;
262         do_reap($self);
263         $self->{lei}->qerr("# @$cmd");
264         return if $self->{dry_run};
265         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
266 }
267
268 sub fetch_args ($$) {
269         my ($lei, $opt) = @_;
270         my @cmd; # (git --git-dir=...) to be added by caller
271         $opt->{$_} = $lei->{$_} for (0..2);
272         # we support "-c $key=$val" for arbitrary git config options
273         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
274         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
275         push @cmd, 'fetch';
276         push @cmd, '-q' if $lei->{opt}->{quiet} ||
277                         ($lei->{opt}->{jobs} // 1) > 1;
278         push @cmd, '-v' if $lei->{opt}->{verbose};
279         @cmd;
280 }
281
282 sub fgrp_update_old ($) { # for git <1.8.5
283         my ($fgrp) = @_;
284         my $cmd = [ @{$fgrp->{-torsocks}}, 'git', "--git-dir=$fgrp->{cur_dst}",
285                 fetch_args($fgrp->{lei}, my $opt = {}) ];
286         $fgrp->{lei}->qerr("# @$cmd");
287         do_reap($fgrp);
288         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $fgrp, $cmd ];
289 }
290
291 sub upr { # feed `git update-ref --stdin -z' verbosely
292         my ($fgrp, $w, $op, $ref, $oid) = @_;
293         $fgrp->{lei}->qerr("# $op $ref $oid");
294         print $w "$op $ref\0$oid\0" or die "print(w): $!";
295 }
296
297 sub fgrp_update {
298         my ($fgrp) = @_;
299         my $srcfh = delete $fgrp->{srcfh} or return;
300         my $dstfh = delete $fgrp->{dstfh} or return;
301         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
302         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
303         my %src = map { chomp; split(/\0/) } (<$srcfh>);
304         close $srcfh;
305         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
306         close $dstfh;
307         pipe(my ($r, $w)) or die "pipe: $!";
308         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
309                 qw(update-ref --stdin -z) ];
310         $fgrp->{lei}->qerr("# @$cmd");
311         my $opt = { 0 => $r, 1 => $fgrp->{lei}->{1}, 2 => $fgrp->{lei}->{2} };
312         my $pid = spawn($cmd, undef, $opt);
313         close $r or die "close(r): $!";
314         for my $ref (keys %dst) {
315                 my $new = delete $src{$ref};
316                 my $old = $dst{$ref};
317                 if (defined $new) {
318                         upr($fgrp, $w, 'update', $ref, $new) if $new ne $old;
319                 } else {
320                         upr($fgrp, $w, 'delete', $ref, $old);
321                 }
322         }
323         while (my ($ref, $oid) = each %src) {
324                 upr($fgrp, $w, 'create', $ref, $oid);
325         }
326         if (close($w)) { # git >= 1.8.5
327                 $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd ];
328                 do_reap($fgrp);
329         } else { # git <1.8.5 w/o update-ref --stdin
330                 warn "E: close(update-ref --stdin): $!\n";
331                 $update_ref_stdin = 0;
332                 waitpid($pid, 0) // die "waitpid(update-ref --stdin): $!";
333                 fgrp_update_old($fgrp);
334         }
335 }
336
337 sub pack_refs {
338         my ($self, $git_dir) = @_;
339         do_reap($self);
340         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
341         $self->{lei}->qerr("# @$cmd");
342         my $opt = { 1 => $self->{lei}->{1}, 2 => $self->{lei}->{2} };
343         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd ];
344 }
345
346 sub fgrp_fetched {
347         my ($fgrp) = @_;
348         return if $fgrp->{dry_run} || !$LIVE;
349         my $rn = $fgrp->{-remote};
350         my %opt = map { $_ => $fgrp->{lei}->{$_} } (0..2);
351         pack_refs($fgrp, $fgrp->{-osdir}); # objstore refs always packed
352
353         $update_ref_stdin or return fgrp_update_old($fgrp);
354
355         my $update_ref = PublicInbox::OnDestroy->new($$, \&fgrp_update, $fgrp);
356
357         my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
358                 "--format=refs/%(refname:lstrip=3)%00%(objectname)",
359                 "refs/remotes/$rn/" ];
360         do_reap($fgrp);
361         open($fgrp->{srcfh}, '+>', undef) or die "open(src): $!";
362         $fgrp->{lei}->qerr("# @$src >SRC");
363         my $pid = spawn($src, undef, { %opt, 1 => $fgrp->{srcfh} });
364         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $src, $update_ref ];
365
366         my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
367                 '--format=%(refname)%00%(objectname)' ];
368         do_reap($fgrp);
369         open($fgrp->{dstfh}, '+>', undef) or die "open(dst): $!";
370         $fgrp->{lei}->qerr("# @$dst >DST");
371         $pid = spawn($dst, undef, { %opt, 1 => $fgrp->{dstfh} });
372         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $dst, $update_ref ];
373 }
374
375 sub fgrp_fetch {
376         my ($fgrp, $fini) = @_;
377         my $cmd = [ @{$fgrp->{-torsocks}}, 'git', "--git-dir=$fgrp->{-osdir}",
378                         fetch_args($fgrp->{lei}, my $opt = {}), '--no-tags',
379                         $fgrp->{-remote} ];
380         $fgrp->{-fini} = $fini;
381         do_reap($fgrp);
382         $fgrp->{lei}->qerr("# @$cmd");
383         return if $fgrp->{dry_run};
384         my $fgrp_fini = PublicInbox::OnDestroy->new($$, \&fgrp_fetched, $fgrp);
385         my $pid = spawn($cmd, undef, $opt);
386         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd, $fgrp_fini ];
387 }
388
389 # keep this idempotent for future use by public-inbox-fetch
390 sub forkgroup_prep {
391         my ($self, $uri) = @_;
392         $self->{-ent} // return;
393         my $os = $self->{-objstore} // return;
394         my $fg = $self->{-ent}->{forkgroup} // return;
395         my $dir = "$os/$fg.git";
396         my @cmd = ('git', "--git-dir=$dir", 'config');
397         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
398         if (!-d $dir) {
399                 PublicInbox::Import::init_bare($dir);
400                 for ('repack.useDeltaIslands=true',
401                                 'pack.island=refs/remotes/([^/]+)/') {
402                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
403                 }
404         }
405         my $key = $self->{-key} // die 'BUG: no -key';
406         my ($bn) = ($key =~ m{/([a-z0-9_,;=!\+\{\}\|][^/]*)(?:\.git)?\z}i);
407         my $rn = "$bn-".substr(sha256_hex($key), 0, 16);
408         # --no-tags is required to avoid conflicts
409         for ("url=$uri", "fetch=+refs/*:refs/remotes/$rn/*",
410                         'tagopt=--no-tags') {
411                 my @kv = split(/=/, $_, 2);
412                 $kv[0] = "remote.$rn.$kv[0]";
413                 run_die([@cmd, @kv], undef, $opt);
414         }
415         $self->{-do_pack_refs} = 1; # likely coderepo
416         if (!-d $self->{cur_dst}) {
417                 my $alt = File::Spec->rel2abs("$dir/objects");
418                 PublicInbox::Import::init_bare($self->{cur_dst});
419                 my $o = "$self->{cur_dst}/objects";
420                 my $f = "$o/info/alternates";
421                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
422                 open my $fh, '+>>', $f or die "open($f): $!";
423                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
424                 chomp(my @cur = <$fh>);
425                 if (!grep(/\A\Q$l\E\z/, @cur)) {
426                         say $fh $l or die "say($f): $!";
427                 }
428                 close $fh or die "close($f): $!";
429                 @cmd = ('git', "--git-dir=$self->{cur_dst}",
430                         qw(remote add --mirror=fetch origin), "$uri");
431                 my $pid = spawn(\@cmd, undef, $opt);
432                 waitpid($pid, 0) // die "waitpid(@cmd): $!";
433                 die "E: @cmd: \$?=$?" if ($? && ($? >> 8) != 3);
434         }
435         bless { %$self, -osdir => $dir, -remote => $rn }, __PACKAGE__;
436 }
437
438 sub clone_v1 {
439         my ($self, $nohang) = @_;
440         my $lei = $self->{lei};
441         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
442         my $uri = URI->new($self->{cur_src} // $self->{src});
443         defined($lei->{opt}->{epoch}) and
444                 die "$uri is a v1 inbox, --epoch is not supported\n";
445         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
446         my $dst = $self->{cur_dst} // $self->{dst};
447         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
448         my $cmd = [ @{$self->{-torsocks}}, clone_cmd($lei, my $opt = {}),
449                 "$uri", $dst ];
450         my $fgrp = forkgroup_prep($self, $uri);
451         if (!defined($fgrp) && defined($self->{-ent})) {
452                 if (defined(my $ref = $self->{-ent}->{reference})) {
453                         -e "$self->{dst}$ref" and
454                                 push @$cmd, '--reference', "$self->{dst}$ref";
455                 }
456         }
457         $fgrp ? fgrp_fetch($fgrp, $fini) :
458                 start_clone($self, $cmd, $opt, $fini);
459
460         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
461                                 /\A(?:always|v1)\z/s) {
462                 _get_txt_start($self, '_/text/config/raw', $fini);
463         }
464
465         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
466         $self->{'txt.description'} = $d if defined $d;
467         (!defined($d) && !$nohang) and
468                 _get_txt_start($self, 'description', $fini);
469
470         $nohang or do_reap($self, 1); # for non-manifest clone
471 }
472
473 sub parse_epochs ($$) {
474         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
475         $opt_epochs // return; # undef => all epochs
476         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
477         undef($lo) if ($lo // '') eq '';
478         my $re = qr/\A~?[0-9]+\z/;
479         if (@extra || (($lo // '0') !~ $re) ||
480                         (($hi // '0') !~ $re) ||
481                         !(grep(defined, $lo, $hi))) {
482                 die <<EOM;
483 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
484 EOM
485         }
486         my @n = sort { $a <=> $b } keys %$v2_epochs;
487         for (grep(defined, $lo, $hi)) {
488                 if (/\A[0-9]+\z/) {
489                         $_ > $n[-1] and die
490 "`$_' exceeds maximum available epoch ($n[-1])\n";
491                         $_ < $n[0] and die
492 "`$_' is lower than minimum available epoch ($n[0])\n";
493                 } elsif (/\A~([0-9]+)/) {
494                         my $off = -$1 - 1;
495                         $n[$off] // die "`$_' is out of range\n";
496                         $_ = $n[$off];
497                 } else { die "`$_' not understood\n" }
498         }
499         defined($lo) && defined($hi) && $lo > $hi and die
500 "low value (`$lo') exceeds high (`$hi')\n";
501         $lo //= $n[0] if $dotdot;
502         $hi //= $n[-1] if $dotdot;
503         $hi //= $lo;
504         my $want = {};
505         for ($lo..$hi) {
506                 if (defined $v2_epochs->{$_}) {
507                         $want->{$_} = 1;
508                 } else {
509                         warn
510 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
511                 }
512         }
513         $want
514 }
515
516 sub init_placeholder ($$$) {
517         my ($src, $edst, $ent) = @_;
518         PublicInbox::Import::init_bare($edst);
519         my $f = "$edst/config";
520         open my $fh, '>>', $f or die "open($f): $!";
521         print $fh <<EOM or die "print($f): $!";
522 [remote "origin"]
523         url = $src
524         fetch = +refs/*:refs/*
525         mirror = true
526
527 ; This git epoch was created read-only and "public-inbox-fetch"
528 ; will not fetch updates for it unless write permission is added.
529 ; Hint: chmod +w $edst
530 EOM
531         if (defined($ent->{owner})) {
532                 print $fh <<EOM or die "print($f): $!";
533 [gitweb]
534         owner = $ent->{owner}
535 EOM
536         }
537         close $fh or die "close($f): $!";
538         my %map = (head => 'HEAD', description => undef);
539         while (my ($key, $fn) = each %map) {
540                 my $val = $ent->{$key} // next;
541                 $fn //= $key;
542                 $fn = "$edst/$fn";
543                 open $fh, '>', $fn or die "open($fn): $!";
544                 print $fh $val, "\n" or die "print($fn): $!";
545                 close $fh or die "close($fn): $!";
546         }
547 }
548
549 sub reap_cmd { # async, called via SIGCHLD
550         my ($self, $cmd) = @_;
551         my $cerr = $?;
552         $? = 0; # don't let it influence normal exit
553         if ($cerr) {
554                 kill('TERM', keys %$LIVE);
555                 $self->{lei}->child_error($cerr, "@$cmd failed");
556         }
557 }
558
559 sub v1_done { # called via OnDestroy
560         my ($self) = @_;
561         return if $self->{dry_run} || !$LIVE;
562         _write_inbox_config($self);
563         my $dst = $self->{cur_dst} // $self->{dst};
564         if (defined(my $o = $self->{-ent} ? $self->{-ent}->{owner} : undef)) {
565                 run_die([qw(git config -f), "$dst/config", 'gitweb.owner', $o]);
566         }
567         my $o = "$dst/objects";
568         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
569                 my $base = File::Spec->rel2abs($o);
570                 my @l = <$fh>;
571                 my $ft;
572                 for (@l) {
573                         next unless m!\A/!;
574                         $_ = File::Spec->abs2rel($_, $base);
575                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
576                                                 DIR => "$o/info");
577                 }
578                 if ($ft) {
579                         print $ft @l or die "print($ft): $!";
580                         $ft->flush or die "flush($ft): $!";
581                         ft_rename($ft, $fn, 0666, $fh);
582                 }
583         }
584         pack_refs($self, $dst) if delete $self->{-do_pack_refs};
585         eval { set_description($self) };
586         warn $@ if $@;
587         return if ($self->{-is_epoch} ||
588                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
589         write_makefile($dst, 1);
590         index_cloned_inbox($self, 1);
591 }
592
593 sub v2_done { # called via OnDestroy
594         my ($self) = @_;
595         return if $self->{dry_run} || !$LIVE;
596         my $dst = $self->{cur_dst} // $self->{dst};
597         require PublicInbox::Lock;
598         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
599         my $lck = $lk->lock_for_scope($$);
600         _write_inbox_config($self);
601         require PublicInbox::MultiGit;
602         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
603         $mg->fill_alternates;
604         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
605         for my $edst (@{delete($self->{-read_only}) // []}) {
606                 my @st = stat($edst) or die "stat($edst): $!";
607                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
608         }
609         write_makefile($dst, 2);
610         undef $lck; # unlock
611         eval { set_description($self) };
612         warn $@ if $@;
613         index_cloned_inbox($self, 2);
614 }
615
616 sub clone_v2_prep ($$;$) {
617         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
618         my $lei = $self->{lei};
619         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
620         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
621         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
622         my $dst = $self->{cur_dst} // $self->{dst};
623         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
624         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
625         delete $task->{todo}; # $self->{todo} still exists
626         my (@skip, $desc);
627         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
628         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
629                 my ($uri, $key) = @{$v2_epochs->{$nr}};
630                 my $src = $uri->as_string;
631                 my $edst = $dst;
632                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
633 failed to extract epoch number from $src
634
635                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
636                 $edst .= "/git/$nr.git";
637                 my $ent;
638                 if ($m) {
639                         $ent = $m->{$key} //
640                                 die("BUG: `$key' not in manifest.js.gz");
641                         if (defined(my $d = $ent->{description})) {
642                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
643                                 $desc = $d;
644                         }
645                 }
646                 if (!$want || $want->{$nr}) {
647                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
648                         $etask->{-ent} = $ent; # may have {reference}
649                         $etask->{cur_src} = $src;
650                         $etask->{cur_dst} = $edst;
651                         $etask->{-is_epoch} = $fini;
652                         my $ref = $ent->{reference} // '';
653                         push @{$self->{todo}->{$ref}}, $etask;
654                         $self->{any_want}->{$key} = 1;
655                 } else { # create a placeholder so users only need to chmod +w
656                         init_placeholder($src, $edst, $ent);
657                         push @{$task->{-read_only}}, $edst;
658                         push @skip, $key;
659                 }
660         }
661         # filter out the epochs we skipped
662         $self->{-culled_manifest} = 1 if $m && delete(@$m{@skip});
663
664         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
665
666         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
667                 _get_txt_start($task, '_/text/config/raw', $fini);
668
669         defined($desc) ? ($task->{'txt.description'} = $desc) :
670                 _get_txt_start($task, 'description', $fini);
671 }
672
673 sub decode_manifest ($$$) {
674         my ($fh, $fn, $uri) = @_;
675         my $js;
676         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
677         gunzip(\$gz => \$js, MultiStream => 1) or
678                 die "gunzip($uri): $GunzipError\n";
679         my $m = eval { PublicInbox::Config->json->decode($js) };
680         die "$uri: error decoding `$js': $@\n" if $@;
681         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
682         $m;
683 }
684
685 sub multi_inbox ($$$) {
686         my ($self, $path, $m) = @_;
687         my $incl = $self->{lei}->{opt}->{include};
688         my $excl = $self->{lei}->{opt}->{exclude};
689
690         # assuming everything not v2 is v1, for now
691         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
692         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
693         my $v2 = {};
694
695         for (@v2_epochs) {
696                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
697                 push @{$v2->{$1}}, $_;
698         }
699         my $n = scalar(keys %$v2) + scalar(@v1);
700         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
701         if (defined $incl) {
702                 my $re = '(?:'.join('\\z|', map {
703                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
704                         } @$incl).'\\z)';
705                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
706                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
707                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
708                 @v1 = grep(/$re/, @v1);
709         }
710         if (defined $excl) {
711                 my $re = '(?:'.join('\\z|', map {
712                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
713                         } @$excl).'\\z)';
714                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
715                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
716                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
717                 @v1 = grep(!/$re/, @v1);
718         }
719         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
720         $ret->{v1} = \@v1 if @v1;
721         $ret->{v2} = $v2 if keys %$v2;
722         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
723                                 join("\n\t", sort @orig)
724                         : "Nothing available to clone\n";
725         my $path_pfx = '';
726
727         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
728         if (@v2_epochs) {
729                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
730                                 @v2_epochs) == @v2_epochs) {
731                         $$path =~ s!\A(/[^/]+)/!/! or last;
732                         $path_pfx .= $1;
733                 }
734         } elsif (@v1) {
735                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
736                         $path_pfx .= $1;
737                 }
738         }
739         ($path_pfx, $n, $ret);
740 }
741
742 sub clone_all {
743         my ($self, $m) = @_;
744         my $todo = delete $self->{todo};
745         my $nodep = delete $todo->{''};
746
747         # do not download unwanted deps
748         my $any_want = delete $self->{any_want};
749         my @unwanted = grep { !$any_want->{$_} } keys %$todo;
750         my @nodep = delete(@$todo{@unwanted});
751         push(@$nodep, @$_) for @nodep;
752
753         # handle no-dependency repos, first
754         for (@$nodep) {
755                 clone_v1($_, 1);
756                 return if $self->{lei}->{child_error};
757         }
758         # resolve references, deepest, first:
759         while (scalar keys %$todo) {
760                 for my $x (keys %$todo) {
761                         my ($nr, $nxt);
762                         # resolve multi-level references
763                         while ($m && defined($nxt = $m->{$x}->{reference})) {
764                                 exists($todo->{$nxt}) or last;
765                                 die <<EOM if ++$nr > 1000;
766 E: dependency loop detected (`$x' => `$nxt')
767 EOM
768                                 $x = $nxt;
769                         }
770                         my $y = delete $todo->{$x} // next; # already done
771                         for (@$y) {
772                                 clone_v1($_, 1);
773                                 return if $self->{lei}->{child_error};
774                         }
775                         last; # restart %$todo iteration
776                 }
777         }
778         do_reap($self, 1);
779 }
780
781 sub dump_manifest ($$) {
782         my ($m, $ft) = @_;
783         # write the smaller manifest if epochs were skipped so
784         # users won't have to delete manifest if they +w an
785         # epoch they no longer want to skip
786         my $json = PublicInbox::Config->json->encode($m);
787         my $mtime = (stat($ft))[9];
788         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
789         truncate($ft, 0) or die "truncate($ft): $!";
790         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
791         $ft->flush or die "flush($ft): $!";
792         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
793 }
794
795 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
796 sub try_manifest {
797         my ($self) = @_;
798         my $uri = URI->new($self->{src});
799         my $lei = $self->{lei};
800         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
801         my $path = $uri->path;
802         chop($path) eq '/' or die "BUG: $uri not canonicalized";
803         $uri->path($path . '/manifest.js.gz');
804         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX',
805                                 UNLINK => 1, TMPDIR => 1, SUFFIX => '.tmp');
806         my $cmd = $curl->for_uri($lei, $uri, qw(-f -R -o), $ft->filename);
807         my %opt = map { $_ => $lei->{$_} } (0..2);
808         my $cerr = run_reap($lei, $cmd, \%opt);
809         if ($cerr) {
810                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
811                 return $lei->child_error($cerr, "@$cmd failed");
812         }
813         my $m = eval { decode_manifest($ft, $ft, $uri) };
814         if ($@) {
815                 warn $@;
816                 return try_scrape($self);
817         }
818         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
819         return $lei->child_error(1, $multi) if !ref($multi);
820         my $v2 = delete $multi->{v2};
821         local $self->{todo} = {};
822         if ($v2) {
823                 for my $name (sort keys %$v2) {
824                         my $epochs = delete $v2->{$name};
825                         my %v2_epochs = map {
826                                 $uri->path($n > 1 ? $path_pfx.$path.$_
827                                                 : $path_pfx.$_);
828                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
829                                 $e // die "no [0-9]+\.git in `$uri'";
830                                 $e => [ $uri->clone, $_ ];
831                         } @$epochs;
832                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
833                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
834                         local $self->{cur_src} = $1;
835                         local $self->{cur_dst} = $self->{dst};
836                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
837                                                         git/[0-9]+\.git\z!x) {
838                                 $self->{cur_dst} .= "/$1";
839                         }
840                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
841 E: `$self->{cur_dst}' must not contain newline
842 EOM
843                         clone_v2_prep($self, \%v2_epochs, $m);
844                         return if $self->{lei}->{child_error};
845                 }
846         }
847         if (my $v1 = delete $multi->{v1}) {
848                 my $p = $path_pfx.$path;
849                 chop($p) if substr($p, -1, 1) eq '/';
850                 $uri->path($p);
851                 for my $name (@$v1) {
852                         my $task = bless { %$self }, __PACKAGE__;
853                         $task->{-ent} = $m->{$name} //
854                                         die("BUG: no `$name' in manifest");
855                         $task->{cur_src} = "$uri";
856                         $task->{cur_dst} = $task->{dst};
857                         $task->{-key} = $name;
858                         if ($n > 1) {
859                                 $task->{cur_dst} .= $name;
860                                 $task->{cur_src} .= $name;
861                         }
862                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
863 E: `$task->{cur_dst}' must not contain newline
864 EOM
865                         $task->{cur_src} .= '/';
866                         my $dep = $task->{-ent}->{reference} // '';
867                         push @{$self->{todo}->{$dep}}, $task; # for clone_all
868                         $self->{any_want}->{$name} = 1;
869                 }
870         }
871         delete local $lei->{opt}->{epoch} if defined($v2);
872         clone_all($self, $m);
873         return if $self->{lei}->{child_error} || $self->{dry_run};
874
875         # set by clone_v2_prep/-I/--exclude
876         dump_manifest($m => $ft) if delete $self->{-culled_manifest};
877         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
878         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
879 }
880
881 sub start_clone_url {
882         my ($self) = @_;
883         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
884         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
885 }
886
887 sub do_mirror { # via wq_io_do or public-inbox-clone
888         my ($self) = @_;
889         my $lei = $self->{lei};
890         umask($lei->{client_umask}) if defined $lei->{client_umask};
891         eval {
892                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
893                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
894 --inbox-config must be one of `always', `v2', `v1', or `never'
895
896                 if (defined(my $os = $lei->{opt}->{objstore})) {
897                         $os = 'objstore' if $os eq ''; # --objstore w/o args
898                         $os = "$self->{dst}/$os" if $os !~ m!\A/!;
899                         $self->{-objstore} = $os;
900                 }
901                 local $LIVE;
902                 my $iv = $lei->{opt}->{'inbox-version'} //
903                         return start_clone_url($self);
904                 return clone_v1($self) if $iv == 1;
905                 die "bad --inbox-version=$iv\n" if $iv != 2;
906                 die <<EOM if $self->{src} !~ m!://!;
907 cloning local v2 inboxes not supported
908 EOM
909                 try_scrape($self, 1);
910         };
911         $lei->fail($@) if $@;
912 }
913
914 sub start {
915         my ($cls, $lei, $src, $dst) = @_;
916         my $self = bless { src => $src, dst => $dst }, $cls;
917         $lei->request_umask;
918         my ($op_c, $ops) = $lei->workers_start($self, 1);
919         $lei->{wq1} = $self;
920         $self->wq_io_do('do_mirror', []);
921         $self->wq_close;
922         $lei->wait_wq_events($op_c, $ops);
923 }
924
925 sub ipc_atfork_child {
926         my ($self) = @_;
927         $self->{lei}->_lei_atfork_child;
928         $self->SUPER::ipc_atfork_child;
929 }
930
931 sub write_makefile {
932         my ($dir, $ibx_ver) = @_;
933         my $f = "$dir/Makefile";
934         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
935                 print $fh <<EOM or die "print($f) $!";
936 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
937 # manpage for more information on the format.  This Makefile is
938 # intended as a familiar wrapper for users unfamiliar with
939 # public-inbox-* commands.
940 #
941 # See the respective manpages for public-inbox-fetch(1),
942 # public-inbox-index(1), etc for more information on
943 # some of the commands used by this Makefile.
944 #
945 # This Makefile will not be modified nor read by public-inbox,
946 # so you may edit it freely with your own convenience targets
947 # and notes.  public-inbox-fetch will recreate it if removed.
948 EOM
949                 print $fh <<'EOM' or die "print($f): $!";
950 # the default target:
951 help :
952         @echo Common targets:
953         @echo '    make fetch        - fetch from remote git repostorie(s)'
954         @echo '    make update       - fetch and update index '
955         @echo
956         @echo Rarely needed targets:
957         @echo '    make reindex      - may be needed for new features/bugfixes'
958         @echo '    make compact      - rewrite Xapian storage to save space'
959         @echo '    make index        - initial index after clone
960
961 fetch :
962         public-inbox-fetch
963 update :
964         @if ! public-inbox-fetch --exit-code; \
965         then \
966                 c=$$?; \
967                 test $$c -eq 127 && exit 0; \
968                 exit $$c; \
969         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
970         then \
971                 public-inbox-index; \
972         else \
973                 echo 'public-inbox index not initialized'; \
974                 echo 'see public-inbox-index(1) man page'; \
975         fi
976 index :
977         public-inbox-index
978 reindex :
979         public-inbox-index --reindex
980 compact :
981         public-inbox-compact
982
983 .PHONY : help fetch update index reindex compact
984 EOM
985                 close $fh or die "close($f): $!";
986         } else {
987                 die "open($f): $!" unless $!{EEXIST};
988         }
989 }
990
991 1;