lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::LeiCurl;
  20 use PublicInbox::OnDestroy;
  21 use Digest::SHA qw(sha256_hex);
  22
  23 our $LIVE; # pid => callback
  24
  25 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  26         my ($arg, $pid) = @_;
  27         my ($mrr, $lei) = @$arg;
  28         my $f = "$mrr->{dst}/mirror.done";
  29         if ($?) {
  30                 $lei->child_error($?);
  31         } elsif (!$mrr->{dry_run} && !unlink($f)) {
  32                 warn("unlink($f): $!\n") unless $!{ENOENT};
  33         } else {
  34                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  35                         require PublicInbox::LeiAddExternal;
  36                         PublicInbox::LeiAddExternal::_finish_add_external(
  37                                                         $lei, $mrr->{dst});
  38                 }
  39                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  40         }
  41         $lei->dclose;
  42 }
  43
  44 # for old installations without manifest.js.gz
  45 sub try_scrape {
  46         my ($self, $fallback_manifest) = @_;
  47         my $uri = URI->new($self->{src});
  48         my $lei = $self->{lei};
  49         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  50         my $cmd = $curl->for_uri($lei, $uri, qw(-f --compressed));
  51         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  52         my $fh = popen_rd($cmd, undef, $opt);
  53         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  54         close($fh) or return $lei->child_error($?, "@$cmd failed");
  55
  56         # we grep with URL below, we don't want Subject/From headers
  57         # making us clone random URLs.  This assumes remote instances
  58         # prior to public-inbox 1.7.0
  59         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  60         my @html = split(/<hr>/, $html);
  61         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  62         if (!@urls && $fallback_manifest) {
  63                 warn <<EOM;
  64 W: failed to extract URLs from $uri, trying manifest.js.gz...
  65 EOM
  66                 return start_clone_url($self);
  67         }
  68         my $url = $uri->as_string;
  69         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  70
  71         # since this is for old instances w/o manifest.js.gz, try v1 first
  72         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  73         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  74                 my %v2_epochs = map {
  75                         my ($n) = (m!/([0-9]+)\z!);
  76                         $n => [ URI->new($_), '' ]
  77                 } @v2_urls; # uniq
  78                 clone_v2_prep($self, \%v2_epochs);
  79                 delete local $lei->{opt}->{epoch};
  80                 clone_all($self);
  81                 return;
  82         }
  83
  84         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  85         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  86                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  87                 die <<"";
  88 E: confused by scraping <$uri>, did you mean <$url>?
  89
  90         }
  91         @urls and die <<"";
  92 E: confused by scraping <$uri>, got ambiguous results:
  93 @urls
  94
  95         die "E: scraping <$uri> revealed nothing\n";
  96 }
  97
  98 sub clone_cmd {
  99         my ($lei, $opt) = @_;
 100         my @cmd = qw(git);
 101         $opt->{$_} = $lei->{$_} for (0..2);
 102         # we support "-c $key=$val" for arbitrary git config options
 103         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 104         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 105         push @cmd, qw(clone --mirror);
 106         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 107                         ($lei->{opt}->{jobs} // 1) > 1;
 108         push @cmd, '-v' if $lei->{opt}->{verbose};
 109         # XXX any other options to support?
 110         # --reference is tricky with multiple epochs, but handled
 111         # automatically if using manifest.js.gz
 112         @cmd;
 113 }
 114
 115 sub ft_rename ($$$;$) {
 116         my ($ft, $dst, $open_mode, $fh) = @_;
 117         my @st = stat($fh // $dst);
 118         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 119         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 120         require File::Copy;
 121         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 122         $ft->unlink_on_destroy(0);
 123 }
 124
 125 sub do_reap ($;$) {
 126         my ($self, $jobs) = @_;
 127         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 128         $jobs = 1 if $jobs < 1;
 129         while (keys(%$LIVE) >= $jobs) {
 130                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 131                 if (my $x = delete $LIVE->{$pid}) {
 132                         my $cb = shift @$x;
 133                         $cb->(@$x) if $cb;
 134                 } else {
 135                         warn "reaped unknown PID=$pid ($?)\n";
 136                 }
 137         }
 138 }
 139
 140 sub _get_txt_start { # non-fatal
 141         my ($self, $endpoint, $fini) = @_;
 142         my $uri = URI->new($self->{cur_src} // $self->{src});
 143         my $lei = $self->{lei};
 144         my $path = $uri->path;
 145         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 146         $uri->path("$path/$endpoint");
 147         my $f = (split(m!/!, $endpoint))[-1];
 148         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 149         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 150         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(-f --compressed -R -o),
 151                                         $ft->filename);
 152         do_reap($self);
 153         $lei->qerr("# @$cmd");
 154         return if $self->{dry_run};
 155         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 156         $LIVE->{spawn($cmd, undef, $opt)} =
 157                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 158 }
 159
 160 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 161         my ($self, $endpoint) = @_;
 162         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 163         my $cerr = $?;
 164         $? = 0; # don't influence normal lei exit
 165         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 166         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 167         seek($fh, SEEK_SET, 0) or die "seek: $!";
 168         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 169         local $/;
 170         $self->{"txt.$endpoint"} = <$fh>;
 171         undef; # success
 172 }
 173
 174 sub _write_inbox_config {
 175         my ($self) = @_;
 176         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 177         my $dst = $self->{cur_dst} // $self->{dst};
 178         my $f = "$dst/inbox.config.example";
 179         open my $fh, '>', $f or die "open($f): $!";
 180         print $fh $buf or die "print: $!";
 181         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 182         my $mtime = delete $self->{'mtime._/text/config/raw'};
 183         $fh->flush or die "flush($f): $!";
 184         if (defined $mtime) {
 185                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
 186         }
 187         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 188         my $ibx = $self->{ibx} = {};
 189         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 190                 for (qw(address newsgroup nntpmirror)) {
 191                         $ibx->{$_} = $cfg->{"$sec.$_"};
 192                 }
 193         }
 194 }
 195
 196 sub set_description ($) {
 197         my ($self) = @_;
 198         my $dst = $self->{cur_dst} // $self->{dst};
 199         my $f = "$dst/description";
 200         open my $fh, '+>>', $f or die "open($f): $!";
 201         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 202         my $d = do { local $/; <$fh> } // die "read($f): $!";
 203         chomp(my $orig = $d);
 204         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 205                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 206                 $d = delete($self->{'txt.description'});
 207         }
 208         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 209         chomp $d;
 210         return if $d eq $orig;
 211         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 212         truncate($fh, 0) or die "truncate($f): $!";
 213         print $fh $d, "\n" or die "print($f): $!";
 214         close $fh or die "close($f): $!";
 215 }
 216
 217 sub index_cloned_inbox {
 218         my ($self, $iv) = @_;
 219         my $lei = $self->{lei};
 220
 221         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 222         # lei is useless without Xapian + SQLite
 223         if ($lei->{cmd} ne 'public-inbox-clone') {
 224                 require PublicInbox::InboxWritable;
 225                 require PublicInbox::Admin;
 226                 my $ibx = delete($self->{ibx}) // {
 227                         address => [ 'lei@example.com' ],
 228                         version => $iv,
 229                 };
 230                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 231                 PublicInbox::Inbox->new($ibx);
 232                 PublicInbox::InboxWritable->new($ibx);
 233                 my $opt = {};
 234                 for my $sw ($lei->index_opt) {
 235                         my ($k) = ($sw =~ /\A([\w-]+)/);
 236                         $opt->{$k} = $lei->{opt}->{$k};
 237                 }
 238                 # force synchronous dwaitpid for v2:
 239                 local $PublicInbox::DS::in_loop = 0;
 240                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 241                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 242                 local %ENV = (%ENV, %$env) if $env;
 243                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 244                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 245         }
 246         return if defined $self->{cur_dst}; # one of many repos to clone
 247         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 248 }
 249
 250 sub run_reap {
 251         my ($lei, $cmd, $opt) = @_;
 252         $lei->qerr("# @$cmd");
 253         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 254         my $ret = $?;
 255         $? = 0; # don't let it influence normal exit
 256         $ret;
 257 }
 258
 259 sub start_clone {
 260         my ($self, $cmd, $opt, $fini) = @_;
 261         do_reap($self);
 262         $self->{lei}->qerr("# @$cmd");
 263         return if $self->{dry_run};
 264         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 265 }
 266
 267 sub fetch_args ($$) {
 268         my ($lei, $opt) = @_;
 269         my @cmd; # (git --git-dir=...) to be added by caller
 270         $opt->{$_} = $lei->{$_} for (0..2);
 271         # we support "-c $key=$val" for arbitrary git config options
 272         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 273         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 274         push @cmd, 'fetch';
 275         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 276                         ($lei->{opt}->{jobs} // 1) > 1;
 277         push @cmd, '-v' if $lei->{opt}->{verbose};
 278         @cmd;
 279 }
 280
 281 sub upr { # feed `git update-ref --stdin -z' verbosely
 282         my ($lei, $w, $op, $ref, $oid) = @_;
 283         $lei->qerr("# $op $ref $oid") if $lei->{opt}->{verbose};
 284         print $w "$op $ref\0$oid\0" or die "print(w): $!";
 285 }
 286
 287 sub fgrp_update {
 288         my ($fgrp) = @_;
 289         my $srcfh = delete $fgrp->{srcfh} or return;
 290         my $dstfh = delete $fgrp->{dstfh} or return;
 291         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 292         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 293         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 294         close $srcfh;
 295         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 296         close $dstfh;
 297         pipe(my ($r, $w)) or die "pipe: $!";
 298         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 299                 qw(update-ref --stdin -z) ];
 300         my $lei = $fgrp->{lei};
 301         $lei->qerr("# @$cmd");
 302         my $opt = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 303         my $pid = spawn($cmd, undef, $opt);
 304         close $r or die "close(r): $!";
 305         for my $ref (keys %dst) {
 306                 my $new = delete $src{$ref};
 307                 my $old = $dst{$ref};
 308                 if (defined $new) {
 309                         upr($lei, $w, 'update', $ref, $new) if $new ne $old;
 310                 } else {
 311                         upr($lei, $w, 'delete', $ref, $old);
 312                 }
 313         }
 314         while (my ($ref, $oid) = each %src) {
 315                 upr($lei, $w, 'create', $ref, $oid);
 316         }
 317         close($w) or warn "E: close(update-ref --stdin): $! (need git 1.8.5+)\n";
 318         my $pack = PublicInbox::OnDestroy->new($$, \&pack_dst, $fgrp);
 319         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd, $pack ];
 320 }
 321
 322 sub pack_dst { # packs lightweight satellite repos
 323         my ($fgrp) = @_;
 324         pack_refs($fgrp, $fgrp->{cur_dst});
 325 }
 326
 327 sub pack_refs {
 328         my ($self, $git_dir) = @_;
 329         do_reap($self);
 330         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 331         $self->{lei}->qerr("# @$cmd");
 332         return if $self->{dry_run};
 333         my $opt = { 1 => $self->{lei}->{1}, 2 => $self->{lei}->{2} };
 334         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd ];
 335 }
 336
 337 sub fgrpv_done {
 338         my ($fgrpv) = @_;
 339         return if !$LIVE;
 340         my $pid;
 341         my $first = $fgrpv->[0] // die 'BUG: no fgrpv->[0]';
 342         pack_refs($first, $first->{-osdir}); # objstore refs always packed
 343         for my $fgrp (@$fgrpv) {
 344                 my $rn = $fgrp->{-remote};
 345                 my %opt = map { $_ => $fgrp->{lei}->{$_} } (0..2);
 346
 347                 my $update_ref = $fgrp->{dry_run} ? undef :
 348                         PublicInbox::OnDestroy->new($$, \&fgrp_update, $fgrp);
 349
 350                 my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 351                         "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 352                         "refs/remotes/$rn/" ];
 353                 do_reap($fgrp);
 354                 $fgrp->{lei}->qerr("# @$src >SRC");
 355                 if ($update_ref) {
 356                         open(my $fh, '+>', undef) or die "open(src): $!";
 357                         $pid = spawn($src, undef, { %opt, 1 => $fh });
 358                         $fgrp->{srcfh} = $fh;
 359                         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $src, $update_ref ]
 360                 }
 361                 my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 362                         '--format=%(refname)%00%(objectname)' ];
 363                 do_reap($fgrp);
 364                 $fgrp->{lei}->qerr("# @$dst >DST");
 365                 if ($update_ref) {
 366                         open(my $fh, '+>', undef) or die "open(dst): $!";
 367                         $pid = spawn($dst, undef, { %opt, 1 => $fh });
 368                         $fgrp->{dstfh} = $fh;
 369                         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $dst, $update_ref ]
 370                 }
 371         }
 372 }
 373
 374 sub fgrp_fetch_all {
 375         my ($self) = @_;
 376         my $todo = delete $self->{fgrp_todo} or return;
 377         keys(%$todo) or return;
 378
 379         # Rely on the fgrptmp remote groups in the config file rather
 380         # than listing all remotes since the remote name list may exceed
 381         # system argv limits:
 382         my $grp = 'fgrptmp';
 383
 384         my @git = (@{$self->{-torsocks}}, 'git');
 385         my $j = $self->{lei}->{opt}->{jobs};
 386         my $opt = {};
 387         my @fetch = do {
 388                 local $self->{lei}->{opt}->{jobs} = 1;
 389                 (fetch_args($self->{lei}, $opt),
 390                         qw(--no-tags --multiple));
 391         };
 392         push(@fetch, "-j$j") if $j;
 393         my $pid;
 394         while (my ($osdir, $fgrpv) = each %$todo) {
 395                 my $f = "$osdir/config";
 396
 397                 # clobber group from previous run atomically
 398                 my $cmd = ['git', "--git-dir=$osdir", qw(config -f),
 399                                 $f, '--unset-all', "remotes.$grp"];
 400                 $self->{lei}->qerr("# @$cmd");
 401                 if (!$self->{dry_run}) {
 402                         $pid = spawn($cmd);
 403                         waitpid($pid, 0) // die "waitpid: $!";
 404                         die "E: @$cmd: \$?=$?" if ($? && ($? >> 8) != 5);
 405
 406                         # update the config atomically via O_APPEND while
 407                         # respecting git-config locking
 408                         sysopen(my $lk, "$f.lock", O_CREAT|O_EXCL|O_WRONLY)
 409                                 or die "open($f.lock): $!";
 410                         open my $fh, '>>', $f or die "open(>>$f): $!";
 411                         $fh->autoflush(1);
 412                         my $buf = join('', "[remotes]\n",
 413                                 map { "\t$grp = $_->{-remote}\n" } @$fgrpv);
 414                         print $fh $buf or die "print($f): $!";
 415                         close $fh or die "close($f): $!";
 416                         unlink("$f.lock") or die "unlink($f.lock): $!";
 417                 }
 418
 419                 $cmd = [ @git, "--git-dir=$osdir", @fetch, $grp ];
 420                 do_reap($self);
 421                 $self->{lei}->qerr("# @$cmd");
 422                 my $end = PublicInbox::OnDestroy->new($$, \&fgrpv_done, $fgrpv);
 423                 return if $self->{dry_run};
 424                 $pid = spawn($cmd, undef, $opt);
 425                 $LIVE->{$pid} = [ \&reap_cmd, $self, $cmd, $end ];
 426         }
 427 }
 428
 429 # keep this idempotent for future use by public-inbox-fetch
 430 sub forkgroup_prep {
 431         my ($self, $uri) = @_;
 432         $self->{-ent} // return;
 433         my $os = $self->{-objstore} // return;
 434         my $fg = $self->{-ent}->{forkgroup} // return;
 435         my $dir = "$os/$fg.git";
 436         my @cmd = ('git', "--git-dir=$dir", 'config');
 437         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 438         if (!-d $dir && !$self->{dry_run}) {
 439                 PublicInbox::Import::init_bare($dir);
 440                 for ('repack.useDeltaIslands=true',
 441                                 'pack.island=refs/remotes/([^/]+)/') {
 442                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
 443                 }
 444         }
 445         my $key = $self->{-key} // die 'BUG: no -key';
 446         my $rn = substr(sha256_hex($key), 0, 16);
 447         unless ($self->{dry_run}) {
 448                 # --no-tags is required to avoid conflicts
 449                 for ("url=$uri", "fetch=+refs/*:refs/remotes/$rn/*",
 450                                 'tagopt=--no-tags') {
 451                         my @kv = split(/=/, $_, 2);
 452                         $kv[0] = "remote.$rn.$kv[0]";
 453                         run_die([@cmd, @kv], undef, $opt);
 454                 }
 455         }
 456         if (!-d $self->{cur_dst} && !$self->{dry_run}) {
 457                 my $alt = File::Spec->rel2abs("$dir/objects");
 458                 PublicInbox::Import::init_bare($self->{cur_dst});
 459                 my $o = "$self->{cur_dst}/objects";
 460                 my $f = "$o/info/alternates";
 461                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 462                 open my $fh, '+>>', $f or die "open($f): $!";
 463                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 464                 chomp(my @cur = <$fh>);
 465                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 466                         say $fh $l or die "say($f): $!";
 467                 }
 468                 close $fh or die "close($f): $!";
 469                 $f = "$self->{cur_dst}/config";
 470                 open $fh, '+>>', $f or die "open:($f): $!";
 471                 print $fh <<EOM or die "print($f): $!";
 472 ; rely on the "$rn" remote in the
 473 ; $fg fork group for fetches
 474 ; only uncomment the following iff you detach from fork groups
 475 ; [remote "origin"]
 476 ;       url = $uri
 477 ;       fetch = +refs/*:refs/*
 478 ;       mirror = true
 479 EOM
 480                 close $fh or die "close($f): $!";
 481         }
 482         bless { %$self, -osdir => $dir, -remote => $rn }, __PACKAGE__;
 483 }
 484
 485 sub clone_v1 {
 486         my ($self, $nohang) = @_;
 487         my $lei = $self->{lei};
 488         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 489         my $uri = URI->new($self->{cur_src} // $self->{src});
 490         defined($lei->{opt}->{epoch}) and
 491                 die "$uri is a v1 inbox, --epoch is not supported\n";
 492         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 493         my $dst = $self->{cur_dst} // $self->{dst};
 494         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 495         if (my $fgrp = forkgroup_prep($self, $uri)) {
 496                 $fgrp->{-fini} = $fini;
 497                 push @{$self->{fgrp_todo}->{$fgrp->{-osdir}}}, $fgrp;
 498         } else { # normal fetch
 499                 my $cmd = [ @{$self->{-torsocks}},
 500                                 clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 501                 if (defined($self->{-ent})) {
 502                         if (defined(my $ref = $self->{-ent}->{reference})) {
 503                                 -e "$self->{dst}$ref" and
 504                                         push @$cmd, '--reference',
 505                                                 "$self->{dst}$ref";
 506                         }
 507                 }
 508                 start_clone($self, $cmd, $opt, $fini);
 509         }
 510         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 511                                 /\A(?:always|v1)\z/s) {
 512                 _get_txt_start($self, '_/text/config/raw', $fini);
 513         }
 514
 515         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 516         $self->{'txt.description'} = $d if defined $d;
 517         (!defined($d) && !$nohang) and
 518                 _get_txt_start($self, 'description', $fini);
 519
 520         $nohang or do_reap($self, 1); # for non-manifest clone
 521 }
 522
 523 sub parse_epochs ($$) {
 524         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 525         $opt_epochs // return; # undef => all epochs
 526         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 527         undef($lo) if ($lo // '') eq '';
 528         my $re = qr/\A~?[0-9]+\z/;
 529         if (@extra || (($lo // '0') !~ $re) ||
 530                         (($hi // '0') !~ $re) ||
 531                         !(grep(defined, $lo, $hi))) {
 532                 die <<EOM;
 533 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 534 EOM
 535         }
 536         my @n = sort { $a <=> $b } keys %$v2_epochs;
 537         for (grep(defined, $lo, $hi)) {
 538                 if (/\A[0-9]+\z/) {
 539                         $_ > $n[-1] and die
 540 "`$_' exceeds maximum available epoch ($n[-1])\n";
 541                         $_ < $n[0] and die
 542 "`$_' is lower than minimum available epoch ($n[0])\n";
 543                 } elsif (/\A~([0-9]+)/) {
 544                         my $off = -$1 - 1;
 545                         $n[$off] // die "`$_' is out of range\n";
 546                         $_ = $n[$off];
 547                 } else { die "`$_' not understood\n" }
 548         }
 549         defined($lo) && defined($hi) && $lo > $hi and die
 550 "low value (`$lo') exceeds high (`$hi')\n";
 551         $lo //= $n[0] if $dotdot;
 552         $hi //= $n[-1] if $dotdot;
 553         $hi //= $lo;
 554         my $want = {};
 555         for ($lo..$hi) {
 556                 if (defined $v2_epochs->{$_}) {
 557                         $want->{$_} = 1;
 558                 } else {
 559                         warn
 560 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 561                 }
 562         }
 563         $want
 564 }
 565
 566 sub init_placeholder ($$$) {
 567         my ($src, $edst, $ent) = @_;
 568         PublicInbox::Import::init_bare($edst);
 569         my $f = "$edst/config";
 570         open my $fh, '>>', $f or die "open($f): $!";
 571         print $fh <<EOM or die "print($f): $!";
 572 [remote "origin"]
 573         url = $src
 574         fetch = +refs/*:refs/*
 575         mirror = true
 576
 577 ; This git epoch was created read-only and "public-inbox-fetch"
 578 ; will not fetch updates for it unless write permission is added.
 579 ; Hint: chmod +w $edst
 580 EOM
 581         if (defined($ent->{owner})) {
 582                 print $fh <<EOM or die "print($f): $!";
 583 [gitweb]
 584         owner = $ent->{owner}
 585 EOM
 586         }
 587         close $fh or die "close($f): $!";
 588         my %map = (head => 'HEAD', description => undef);
 589         while (my ($key, $fn) = each %map) {
 590                 my $val = $ent->{$key} // next;
 591                 $fn //= $key;
 592                 $fn = "$edst/$fn";
 593                 open $fh, '>', $fn or die "open($fn): $!";
 594                 print $fh $val, "\n" or die "print($fn): $!";
 595                 close $fh or die "close($fn): $!";
 596         }
 597 }
 598
 599 sub reap_cmd { # async, called via SIGCHLD
 600         my ($self, $cmd) = @_;
 601         my $cerr = $?;
 602         $? = 0; # don't let it influence normal exit
 603         if ($cerr) {
 604                 kill('TERM', keys %$LIVE);
 605                 $self->{lei}->child_error($cerr, "@$cmd failed (\$?=$cerr)");
 606         }
 607 }
 608
 609 sub v1_done { # called via OnDestroy
 610         my ($self) = @_;
 611         return if $self->{dry_run} || !$LIVE;
 612         _write_inbox_config($self);
 613         my $dst = $self->{cur_dst} // $self->{dst};
 614         if (defined(my $o = $self->{-ent} ? $self->{-ent}->{owner} : undef)) {
 615                 run_die([qw(git config -f), "$dst/config", 'gitweb.owner', $o]);
 616         }
 617         my $o = "$dst/objects";
 618         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
 619                 my $base = File::Spec->rel2abs($o);
 620                 my @l = <$fh>;
 621                 my $ft;
 622                 for (@l) {
 623                         next unless m!\A/!;
 624                         $_ = File::Spec->abs2rel($_, $base);
 625                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
 626                                                 DIR => "$o/info");
 627                 }
 628                 if ($ft) {
 629                         print $ft @l or die "print($ft): $!";
 630                         $ft->flush or die "flush($ft): $!";
 631                         ft_rename($ft, $fn, 0666, $fh);
 632                 }
 633         }
 634         eval { set_description($self) };
 635         warn $@ if $@;
 636         return if ($self->{-is_epoch} ||
 637                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 638         write_makefile($dst, 1);
 639         index_cloned_inbox($self, 1);
 640 }
 641
 642 sub v2_done { # called via OnDestroy
 643         my ($self) = @_;
 644         return if $self->{dry_run} || !$LIVE;
 645         my $dst = $self->{cur_dst} // $self->{dst};
 646         require PublicInbox::Lock;
 647         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 648         my $lck = $lk->lock_for_scope($$);
 649         _write_inbox_config($self);
 650         require PublicInbox::MultiGit;
 651         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 652         $mg->fill_alternates;
 653         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 654         for my $edst (@{delete($self->{-read_only}) // []}) {
 655                 my @st = stat($edst) or die "stat($edst): $!";
 656                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 657         }
 658         write_makefile($dst, 2);
 659         undef $lck; # unlock
 660         eval { set_description($self) };
 661         warn $@ if $@;
 662         index_cloned_inbox($self, 2);
 663 }
 664
 665 sub clone_v2_prep ($$;$) {
 666         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 667         my $lei = $self->{lei};
 668         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 669         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 670         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 671         my $dst = $self->{cur_dst} // $self->{dst};
 672         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 673         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 674         delete $task->{todo}; # $self->{todo} still exists
 675         my (@skip, $desc);
 676         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 677         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 678                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 679                 my $src = $uri->as_string;
 680                 my $edst = $dst;
 681                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 682 failed to extract epoch number from $src
 683
 684                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 685                 $edst .= "/git/$nr.git";
 686                 my $ent;
 687                 if ($m) {
 688                         $ent = $m->{$key} //
 689                                 die("BUG: `$key' not in manifest.js.gz");
 690                         if (defined(my $d = $ent->{description})) {
 691                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 692                                 $desc = $d;
 693                         }
 694                 }
 695                 if (!$want || $want->{$nr}) {
 696                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 697                         $etask->{-ent} = $ent; # may have {reference}
 698                         $etask->{cur_src} = $src;
 699                         $etask->{cur_dst} = $edst;
 700                         $etask->{-is_epoch} = $fini;
 701                         my $ref = $ent->{reference} // '';
 702                         push @{$self->{todo}->{$ref}}, $etask;
 703                         $self->{any_want}->{$key} = 1;
 704                 } else { # create a placeholder so users only need to chmod +w
 705                         init_placeholder($src, $edst, $ent);
 706                         push @{$task->{-read_only}}, $edst;
 707                         push @skip, $key;
 708                 }
 709         }
 710         # filter out the epochs we skipped
 711         $self->{-culled_manifest} = 1 if $m && delete(@$m{@skip});
 712
 713         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 714
 715         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 716                 _get_txt_start($task, '_/text/config/raw', $fini);
 717
 718         defined($desc) ? ($task->{'txt.description'} = $desc) :
 719                 _get_txt_start($task, 'description', $fini);
 720 }
 721
 722 sub decode_manifest ($$$) {
 723         my ($fh, $fn, $uri) = @_;
 724         my $js;
 725         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 726         gunzip(\$gz => \$js, MultiStream => 1) or
 727                 die "gunzip($uri): $GunzipError\n";
 728         my $m = eval { PublicInbox::Config->json->decode($js) };
 729         die "$uri: error decoding `$js': $@\n" if $@;
 730         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 731         $m;
 732 }
 733
 734 sub multi_inbox ($$$) {
 735         my ($self, $path, $m) = @_;
 736         my $incl = $self->{lei}->{opt}->{include};
 737         my $excl = $self->{lei}->{opt}->{exclude};
 738
 739         # assuming everything not v2 is v1, for now
 740         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 741         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 742         my $v2 = {};
 743
 744         for (@v2_epochs) {
 745                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 746                 push @{$v2->{$1}}, $_;
 747         }
 748         my $n = scalar(keys %$v2) + scalar(@v1);
 749         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 750         if (defined $incl) {
 751                 my $re = '(?:'.join('\\z|', map {
 752                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 753                         } @$incl).'\\z)';
 754                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 755                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 756                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
 757                 @v1 = grep(/$re/, @v1);
 758         }
 759         if (defined $excl) {
 760                 my $re = '(?:'.join('\\z|', map {
 761                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 762                         } @$excl).'\\z)';
 763                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 764                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 765                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
 766                 @v1 = grep(!/$re/, @v1);
 767         }
 768         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 769         $ret->{v1} = \@v1 if @v1;
 770         $ret->{v2} = $v2 if keys %$v2;
 771         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 772                                 join("\n\t", sort @orig)
 773                         : "Nothing available to clone\n";
 774         my $path_pfx = '';
 775
 776         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 777         if (@v2_epochs) {
 778                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 779                                 @v2_epochs) == @v2_epochs) {
 780                         $$path =~ s!\A(/[^/]+)/!/! or last;
 781                         $path_pfx .= $1;
 782                 }
 783         } elsif (@v1) {
 784                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 785                         $path_pfx .= $1;
 786                 }
 787         }
 788         ($path_pfx, $n, $ret);
 789 }
 790
 791 sub clone_all {
 792         my ($self, $m) = @_;
 793         my $todo = delete $self->{todo};
 794         my $nodep = delete $todo->{''};
 795
 796         # do not download unwanted deps
 797         my $any_want = delete $self->{any_want};
 798         my @unwanted = grep { !$any_want->{$_} } keys %$todo;
 799         my @nodep = delete(@$todo{@unwanted});
 800         push(@$nodep, @$_) for @nodep;
 801
 802         # handle no-dependency repos, first
 803         for (@$nodep) {
 804                 clone_v1($_, 1);
 805                 return if $self->{lei}->{child_error};
 806         }
 807         # resolve references, deepest, first:
 808         while (scalar keys %$todo) {
 809                 for my $x (keys %$todo) {
 810                         my ($nr, $nxt);
 811                         # resolve multi-level references
 812                         while ($m && defined($nxt = $m->{$x}->{reference})) {
 813                                 exists($todo->{$nxt}) or last;
 814                                 die <<EOM if ++$nr > 1000;
 815 E: dependency loop detected (`$x' => `$nxt')
 816 EOM
 817                                 $x = $nxt;
 818                         }
 819                         my $y = delete $todo->{$x} // next; # already done
 820                         for (@$y) {
 821                                 clone_v1($_, 1);
 822                                 return if $self->{lei}->{child_error};
 823                         }
 824                         last; # restart %$todo iteration
 825                 }
 826         }
 827         fgrp_fetch_all($self);
 828         do_reap($self, 1);
 829 }
 830
 831 sub dump_manifest ($$) {
 832         my ($m, $ft) = @_;
 833         # write the smaller manifest if epochs were skipped so
 834         # users won't have to delete manifest if they +w an
 835         # epoch they no longer want to skip
 836         my $json = PublicInbox::Config->json->encode($m);
 837         my $mtime = (stat($ft))[9];
 838         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
 839         truncate($ft, 0) or die "truncate($ft): $!";
 840         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
 841         $ft->flush or die "flush($ft): $!";
 842         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
 843 }
 844
 845 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
 846 sub try_manifest {
 847         my ($self) = @_;
 848         my $uri = URI->new($self->{src});
 849         my $lei = $self->{lei};
 850         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 851         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 852         my $path = $uri->path;
 853         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 854         $uri->path($path . '/manifest.js.gz');
 855         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX',
 856                                 UNLINK => 1, TMPDIR => 1, SUFFIX => '.tmp');
 857         my $cmd = $curl->for_uri($lei, $uri, qw(-f -R -o), $ft->filename);
 858         my %opt = map { $_ => $lei->{$_} } (0..2);
 859         my $cerr = run_reap($lei, $cmd, \%opt);
 860         if ($cerr) {
 861                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
 862                 return $lei->child_error($cerr, "@$cmd failed");
 863         }
 864         my $m = eval { decode_manifest($ft, $ft, $uri) };
 865         if ($@) {
 866                 warn $@;
 867                 return try_scrape($self);
 868         }
 869         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
 870         return $lei->child_error(1, $multi) if !ref($multi);
 871         my $v2 = delete $multi->{v2};
 872         local $self->{todo} = {};
 873         local $self->{fgrp_todo} = {}; # { objstore_dir => [fgrp, ...] }
 874         if ($v2) {
 875                 for my $name (sort keys %$v2) {
 876                         my $epochs = delete $v2->{$name};
 877                         my %v2_epochs = map {
 878                                 $uri->path($n > 1 ? $path_pfx.$path.$_
 879                                                 : $path_pfx.$_);
 880                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
 881                                 $e // die "no [0-9]+\.git in `$uri'";
 882                                 $e => [ $uri->clone, $_ ];
 883                         } @$epochs;
 884                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
 885                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
 886                         local $self->{cur_src} = $1;
 887                         local $self->{cur_dst} = $self->{dst};
 888                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
 889                                                         git/[0-9]+\.git\z!x) {
 890                                 $self->{cur_dst} .= "/$1";
 891                         }
 892                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
 893 E: `$self->{cur_dst}' must not contain newline
 894 EOM
 895                         clone_v2_prep($self, \%v2_epochs, $m);
 896                         return if $self->{lei}->{child_error};
 897                 }
 898         }
 899         if (my $v1 = delete $multi->{v1}) {
 900                 my $p = $path_pfx.$path;
 901                 chop($p) if substr($p, -1, 1) eq '/';
 902                 $uri->path($p);
 903                 for my $name (@$v1) {
 904                         my $task = bless { %$self }, __PACKAGE__;
 905                         $task->{-ent} = $m->{$name} //
 906                                         die("BUG: no `$name' in manifest");
 907                         $task->{cur_src} = "$uri";
 908                         $task->{cur_dst} = $task->{dst};
 909                         $task->{-key} = $name;
 910                         if ($n > 1) {
 911                                 $task->{cur_dst} .= $name;
 912                                 $task->{cur_src} .= $name;
 913                         }
 914                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
 915 E: `$task->{cur_dst}' must not contain newline
 916 EOM
 917                         $task->{cur_src} .= '/';
 918                         my $dep = $task->{-ent}->{reference} // '';
 919                         push @{$self->{todo}->{$dep}}, $task; # for clone_all
 920                         $self->{any_want}->{$name} = 1;
 921                 }
 922         }
 923         delete local $lei->{opt}->{epoch} if defined($v2);
 924         clone_all($self, $m);
 925         return if $self->{lei}->{child_error} || $self->{dry_run};
 926
 927         # set by clone_v2_prep/-I/--exclude
 928         dump_manifest($m => $ft) if delete $self->{-culled_manifest};
 929         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
 930         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 931 }
 932
 933 sub start_clone_url {
 934         my ($self) = @_;
 935         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 936         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 937 }
 938
 939 sub do_mirror { # via wq_io_do or public-inbox-clone
 940         my ($self) = @_;
 941         my $lei = $self->{lei};
 942         $self->{dry_run} = 1 if $lei->{opt}->{'dry-run'};
 943         umask($lei->{client_umask}) if defined $lei->{client_umask};
 944         eval {
 945                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
 946                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
 947 --inbox-config must be one of `always', `v2', `v1', or `never'
 948
 949                 if (defined(my $os = $lei->{opt}->{objstore})) {
 950                         $os = 'objstore' if $os eq ''; # --objstore w/o args
 951                         $os = "$self->{dst}/$os" if $os !~ m!\A/!;
 952                         $self->{-objstore} = $os;
 953                 }
 954                 local $LIVE;
 955                 my $iv = $lei->{opt}->{'inbox-version'} //
 956                         return start_clone_url($self);
 957                 return clone_v1($self) if $iv == 1;
 958                 die "bad --inbox-version=$iv\n" if $iv != 2;
 959                 die <<EOM if $self->{src} !~ m!://!;
 960 cloning local v2 inboxes not supported
 961 EOM
 962                 try_scrape($self, 1);
 963         };
 964         $lei->fail($@) if $@;
 965 }
 966
 967 sub start {
 968         my ($cls, $lei, $src, $dst) = @_;
 969         my $self = bless { src => $src, dst => $dst }, $cls;
 970         $lei->request_umask;
 971         my ($op_c, $ops) = $lei->workers_start($self, 1);
 972         $lei->{wq1} = $self;
 973         $self->wq_io_do('do_mirror', []);
 974         $self->wq_close;
 975         $lei->wait_wq_events($op_c, $ops);
 976 }
 977
 978 sub ipc_atfork_child {
 979         my ($self) = @_;
 980         $self->{lei}->_lei_atfork_child;
 981         $self->SUPER::ipc_atfork_child;
 982 }
 983
 984 sub write_makefile {
 985         my ($dir, $ibx_ver) = @_;
 986         my $f = "$dir/Makefile";
 987         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
 988                 print $fh <<EOM or die "print($f) $!";
 989 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
 990 # manpage for more information on the format.  This Makefile is
 991 # intended as a familiar wrapper for users unfamiliar with
 992 # public-inbox-* commands.
 993 #
 994 # See the respective manpages for public-inbox-fetch(1),
 995 # public-inbox-index(1), etc for more information on
 996 # some of the commands used by this Makefile.
 997 #
 998 # This Makefile will not be modified nor read by public-inbox,
 999 # so you may edit it freely with your own convenience targets
1000 # and notes.  public-inbox-fetch will recreate it if removed.
1001 EOM
1002                 print $fh <<'EOM' or die "print($f): $!";
1003 # the default target:
1004 help :
1005         @echo Common targets:
1006         @echo '    make fetch        - fetch from remote git repostorie(s)'
1007         @echo '    make update       - fetch and update index '
1008         @echo
1009         @echo Rarely needed targets:
1010         @echo '    make reindex      - may be needed for new features/bugfixes'
1011         @echo '    make compact      - rewrite Xapian storage to save space'
1012         @echo '    make index        - initial index after clone
1013
1014 fetch :
1015         public-inbox-fetch
1016 update :
1017         @if ! public-inbox-fetch --exit-code; \
1018         then \
1019                 c=$$?; \
1020                 test $$c -eq 127 && exit 0; \
1021                 exit $$c; \
1022         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
1023         then \
1024                 public-inbox-index; \
1025         else \
1026                 echo 'public-inbox index not initialized'; \
1027                 echo 'see public-inbox-index(1) man page'; \
1028         fi
1029 index :
1030         public-inbox-index
1031 reindex :
1032         public-inbox-index --reindex
1033 compact :
1034         public-inbox-compact
1035
1036 .PHONY : help fetch update index reindex compact
1037 EOM
1038                 close $fh or die "close($f): $!";
1039         } else {
1040                 die "open($f): $!" unless $!{EEXIST};
1041         }
1042 }
1043
1044 1;