lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support
   5 package PublicInbox::LeiMirror;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn);
  11 use PublicInbox::PktOp;
  12
  13 sub mirror_done { # EOF callback for main daemon
  14         my ($lei) = @_;
  15         my $mrr = delete $lei->{mrr};
  16         $mrr->wq_wait_old($lei) if $mrr;
  17         # FIXME: check $? before finish
  18         $lei->add_external_finish($mrr->{dst});
  19         $lei->dclose;
  20 }
  21
  22 # for old installations without manifest.js.gz
  23 sub try_scrape {
  24         my ($self) = @_;
  25         my $uri = URI->new($self->{src});
  26         my $lei = $self->{lei};
  27         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  28         my $cmd = $curl->for_uri($lei, $uri);
  29         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  30         my $fh = popen_rd($cmd, $lei->{env}, $opt);
  31         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  32         close($fh) or return $lei->child_error($?, "@$cmd failed");
  33
  34         # we grep with URL below, we don't want Subject/From headers
  35         # making us clone random URLs
  36         my @urls = ($html =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  37         my $url = $uri->as_string;
  38         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  39
  40         # since this is for old instances w/o manifest.js.gz, try v1 first
  41         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  42         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  43                 my %v2_uris = map { $_ => URI->new($_) } @v2_urls; # uniq
  44                 return clone_v2($self, [ values %v2_uris ]);
  45         }
  46
  47         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  48         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  49                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  50                 die <<"";
  51 E: confused by scraping <$uri>, did you mean <$url>?
  52
  53         }
  54         @urls and die <<"";
  55 E: confused by scraping <$uri>, got ambiguous results:
  56 @urls
  57
  58         die "E: scraping <$uri> revealed nothing\n";
  59 }
  60
  61 sub clone_cmd {
  62         my ($lei) = @_;
  63         my @cmd = qw(git);
  64         # we support "-c $key=$val" for arbitrary git config options
  65         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
  66         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
  67         push @cmd, qw(clone --mirror);
  68         push @cmd, '-q' if $lei->{opt}->{quiet};
  69         push @cmd, '-v' if $lei->{opt}->{verbose};
  70         # XXX any other options to support?
  71         # --reference is tricky with multiple epochs...
  72         @cmd;
  73 }
  74
  75 # tries the relatively new /$INBOX/_/text/config/raw endpoint
  76 sub _try_config {
  77         my ($self) = @_;
  78         my $dst = $self->{dst};
  79         if (!-d $dst || !mkdir($dst)) {
  80                 require File::Path;
  81                 File::Path::mkpath($dst);
  82                 -d $dst or die "mkpath($dst): $!\n";
  83         }
  84         my $uri = URI->new($self->{src});
  85         my $lei = $self->{lei};
  86         my $path = $uri->path;
  87         chop($path) eq '/' or die "BUG: $uri not canonicalized";
  88         $uri->path($path . '/_/text/config/raw');
  89         my $cmd = $self->{curl}->for_uri($lei, $uri);
  90         push @$cmd, '--compressed'; # curl decompresses for us
  91         my $ce = "$dst/inbox.config.example";
  92         my $f = "$ce-$$.tmp";
  93         open(my $fh, '+>', $f) or return $lei->err("open $f: $! (non-fatal)");
  94         my $opt = { 0 => $lei->{0}, 1 => $fh, 2 => $lei->{2} };
  95         $lei->qerr("# @$cmd");
  96         my $pid = spawn($cmd, $lei->{env}, $opt);
  97         waitpid($pid, 0) == $pid or return $lei->err("waitpid @$cmd: $!");
  98         if (($? >> 8) == 22) { # 404 missing
  99                 unlink($f) if -s $fh == 0;
 100                 return;
 101         }
 102         return $lei->err("# @$cmd failed (non-fatal)") if $?;
 103         rename($f, $ce) or return $lei->err("link($f, $ce): $! (non-fatal)");
 104         my $cfg = PublicInbox::Config::git_config_dump($f);
 105         my $ibx = $self->{ibx} = {};
 106         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 107                 for (qw(address newsgroup nntpmirror)) {
 108                         $ibx->{$_} = $cfg->{"$sec.$_"};
 109                 }
 110         }
 111 }
 112
 113 sub index_cloned_inbox {
 114         my ($self, $iv) = @_;
 115         my $ibx = delete($self->{ibx}) // {
 116                 address => [ 'lei@example.com' ],
 117                 version => $iv,
 118         };
 119         $ibx->{inboxdir} = $self->{dst};
 120         PublicInbox::Inbox->new($ibx);
 121         PublicInbox::InboxWritable->new($ibx);
 122         my $opt = {};
 123         my $lei = $self->{lei};
 124         for my $sw ($lei->index_opt) {
 125                 my ($k) = ($sw =~ /\A([\w-]+)/);
 126                 $opt->{$k} = $lei->{opt}->{$k};
 127         }
 128         # force synchronous dwaitpid for v2:
 129         local $PublicInbox::DS::in_loop = 0;
 130         my $cfg = PublicInbox::Config->new;
 131         my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 132         local %ENV = (%ENV, %$env) if $env;
 133         PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 134         PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 135 }
 136
 137 sub clone_v1 {
 138         my ($self) = @_;
 139         my $lei = $self->{lei};
 140         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 141         my $uri = URI->new($self->{src});
 142         my $pfx = $curl->torsocks($lei, $uri) or return;
 143         my $cmd = [ @$pfx, clone_cmd($lei), $uri->as_string, $self->{dst} ];
 144         $lei->qerr("# @$cmd");
 145         my $pid = spawn($cmd, $lei->{env}, $lei);
 146         waitpid($pid, 0) == $pid or die "BUG: waitpid @$cmd: $!";
 147         $? == 0 or return $lei->child_error($?, "@$cmd failed");
 148         _try_config($self);
 149         index_cloned_inbox($self, 1);
 150 }
 151
 152 sub clone_v2 {
 153         my ($self, $v2_uris) = @_;
 154         my $lei = $self->{lei};
 155         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 156         my $pfx //= $curl->torsocks($lei, $v2_uris->[0]) or return;
 157         my @epochs;
 158         my $dst = $self->{dst};
 159         my @src_edst;
 160         for my $uri (@$v2_uris) {
 161                 my $src = $uri->as_string;
 162                 my $edst = $dst;
 163                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 164 failed to extract epoch number from $src
 165
 166                 my $nr = $1 + 0;
 167                 $edst .= "/git/$nr.git";
 168                 push @src_edst, [ $src, $edst ];
 169         }
 170         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 171         _try_config($self);
 172         my $on_destroy = $lk->lock_for_scope($$);
 173         my @cmd = clone_cmd($lei);
 174         while (my $pair = shift(@src_edst)) {
 175                 my $cmd = [ @$pfx, @cmd, @$pair ];
 176                 $lei->qerr("# @$cmd");
 177                 my $pid = spawn($cmd, $lei->{env}, $lei);
 178                 waitpid($pid, 0) == $pid or die "BUG: waitpid @$cmd: $!";
 179                 $? == 0 or return $lei->child_error($?, "@$cmd failed");
 180         }
 181         undef $on_destroy; # unlock
 182         index_cloned_inbox($self, 2);
 183 }
 184
 185 sub try_manifest {
 186         my ($self) = @_;
 187         my $uri = URI->new($self->{src});
 188         my $lei = $self->{lei};
 189         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 190         my $path = $uri->path;
 191         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 192         $uri->path($path . '/manifest.js.gz');
 193         my $cmd = $curl->for_uri($lei, $uri);
 194         $lei->qerr("# @$cmd");
 195         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
 196         my $fh = popen_rd($cmd, $lei->{env}, $opt);
 197         my $gz = do { local $/; <$fh> } // die "read(curl $uri): $!";
 198         unless (close $fh) {
 199                 return try_scrape($self) if ($? >> 8) == 22; # 404 missing
 200                 return $lei->child_error($?, "@$cmd failed");
 201         }
 202         my $js;
 203         gunzip(\$gz => \$js, MultiStream => 1) or
 204                 die "gunzip($uri): $GunzipError";
 205         my $m = eval { PublicInbox::Config->json->decode($js) };
 206         die "$uri: error decoding `$js': $@" if $@;
 207         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 208
 209         my $v1_bare = $m->{$path};
 210         my @v2_epochs = grep(m!\A\Q$path\E/git/[0-9]+\.git\z!, keys %$m);
 211         if (@v2_epochs) {
 212                 # It may be possible to have v1 + v2 in parallel someday:
 213                 $lei->err(<<EOM) if defined $v1_bare;
 214 # `$v1_bare' appears to be a v1 inbox while v2 epochs exist:
 215 # @v2_epochs
 216 # ignoring $v1_bare (use --inbox-version=1 to force v1 instead)
 217 EOM
 218                 @v2_epochs = map { $uri->path($_); $uri->clone } @v2_epochs;
 219                 clone_v2($self, \@v2_epochs);
 220         } elsif ($v1_bare) {
 221                 clone_v1($self);
 222         } elsif (my @maybe = grep(m!\Q$path\E!, keys %$m)) {
 223                 die "E: confused by <$uri>, possible matches:\n@maybe";
 224         } else {
 225                 die "E: confused by <$uri>";
 226         }
 227 }
 228
 229 sub start_clone_url {
 230         my ($self) = @_;
 231         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 232         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 233 }
 234
 235 sub do_mirror { # via wq_do
 236         my ($self) = @_;
 237         my $lei = $self->{lei};
 238         eval {
 239                 my $iv = $lei->{opt}->{'inbox-version'};
 240                 if (defined $iv) {
 241                         return clone_v1($self) if $iv == 1;
 242                         return try_scrape($self) if $iv == 2;
 243                         die "bad --inbox-version=$iv\n";
 244                 }
 245                 return start_clone_url($self) if $self->{src} =~ m!://!;
 246                 die "TODO: cloning local directories not supported, yet";
 247         };
 248         return $lei->fail($@) if $@;
 249         $lei->qerr("# mirrored $self->{src} => $self->{dst}");
 250 }
 251
 252 sub start {
 253         my ($cls, $lei, $src, $dst) = @_;
 254         my $self = bless { lei => $lei, src => $src, dst => $dst }, $cls;
 255         $lei->{mrr} = $self;
 256         if ($src =~ m!https?://!) {
 257                 require URI;
 258                 require PublicInbox::LeiCurl;
 259         }
 260         require PublicInbox::Lock;
 261         require PublicInbox::Inbox;
 262         require PublicInbox::Admin;
 263         require PublicInbox::InboxWritable;
 264         my $ops = {
 265                 '!' => [ $lei->can('fail_handler'), $lei ],
 266                 'x_it' => [ $lei->can('x_it'), $lei ],
 267                 'child_error' => [ $lei->can('child_error'), $lei ],
 268                 '' => [ \&mirror_done, $lei ],
 269         };
 270         ($lei->{pkt_op_c}, $lei->{pkt_op_p}) = PublicInbox::PktOp->pair($ops);
 271         $self->wq_workers_start('lei_mirror', 1, $lei->oldset, {lei => $lei});
 272         my $op = delete $lei->{pkt_op_c};
 273         delete $lei->{pkt_op_p};
 274         $self->wq_do('do_mirror', []);
 275         $self->wq_close(1);
 276         $lei->event_step_init; # wait for shutdowns
 277         if ($lei->{oneshot}) {
 278                 while ($op->{sock}) { $op->event_step }
 279         }
 280 }
 281
 282 sub ipc_atfork_child {
 283         my ($self) = @_;
 284         $self->{lei}->lei_atfork_child;
 285         $self->SUPER::ipc_atfork_child;
 286 }
 287
 288 1;