lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::LeiCurl;
  20 use PublicInbox::OnDestroy;
  21 use Digest::SHA qw(sha256_hex sha1_hex);
  22 use POSIX qw(strftime);
  23
  24 our $LIVE; # pid => callback
  25 our $FGRP_TODO; # objstore -> [ fgrp mirror objects ]
  26 our $TODO; # reference => [ non-fgrp mirror objects ]
  27
  28 sub keep_going ($) {
  29         $LIVE && (!$_[0]->{lei}->{child_error} ||
  30                 $_[0]->{lei}->{opt}->{'keep-going'});
  31 }
  32
  33 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  34         my ($arg, $pid) = @_;
  35         my ($mrr, $lei) = @$arg;
  36         if ($?) {
  37                 $lei->child_error($?);
  38         } elsif (!$lei->{child_error}) {
  39                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  40                         require PublicInbox::LeiAddExternal;
  41                         PublicInbox::LeiAddExternal::_finish_add_external(
  42                                                         $lei, $mrr->{dst});
  43                 }
  44                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  45         }
  46         $lei->dclose;
  47 }
  48
  49 # for old installations without manifest.js.gz
  50 sub try_scrape {
  51         my ($self, $fallback_manifest) = @_;
  52         my $uri = URI->new($self->{src});
  53         my $lei = $self->{lei};
  54         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  55         my $cmd = $curl->for_uri($lei, $uri, '--compressed');
  56         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  57         my $fh = popen_rd($cmd, undef, $opt);
  58         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  59         close($fh) or return $lei->child_error($?, "@$cmd failed");
  60
  61         # we grep with URL below, we don't want Subject/From headers
  62         # making us clone random URLs.  This assumes remote instances
  63         # prior to public-inbox 1.7.0
  64         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  65         my @html = split(/<hr>/, $html);
  66         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  67         if (!@urls && $fallback_manifest) {
  68                 warn <<EOM;
  69 W: failed to extract URLs from $uri, trying manifest.js.gz...
  70 EOM
  71                 return start_clone_url($self);
  72         }
  73         my $url = $uri->as_string;
  74         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  75
  76         # since this is for old instances w/o manifest.js.gz, try v1 first
  77         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  78         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  79                 my %v2_epochs = map {
  80                         my ($n) = (m!/([0-9]+)\z!);
  81                         $n => [ URI->new($_), '' ]
  82                 } @v2_urls; # uniq
  83                 clone_v2_prep($self, \%v2_epochs);
  84                 delete local $lei->{opt}->{epoch};
  85                 clone_all($self);
  86                 return;
  87         }
  88
  89         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  90         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  91                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  92                 die <<"";
  93 E: confused by scraping <$uri>, did you mean <$url>?
  94
  95         }
  96         @urls and die <<"";
  97 E: confused by scraping <$uri>, got ambiguous results:
  98 @urls
  99
 100         die "E: scraping <$uri> revealed nothing\n";
 101 }
 102
 103 sub clone_cmd {
 104         my ($lei, $opt) = @_;
 105         my @cmd = qw(git);
 106         $opt->{$_} = $lei->{$_} for (0..2);
 107         # we support "-c $key=$val" for arbitrary git config options
 108         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 109         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 110         push @cmd, qw(clone --mirror);
 111         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 112                         ($lei->{opt}->{jobs} // 1) > 1;
 113         push @cmd, '-v' if $lei->{opt}->{verbose};
 114         # XXX any other options to support?
 115         # --reference is tricky with multiple epochs, but handled
 116         # automatically if using manifest.js.gz
 117         @cmd;
 118 }
 119
 120 sub ft_rename ($$$;$) {
 121         my ($ft, $dst, $open_mode, $fh) = @_;
 122         my @st = stat($fh // $dst);
 123         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 124         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 125         require File::Copy;
 126         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 127         $ft->unlink_on_destroy(0);
 128 }
 129
 130 sub do_reap ($;$) {
 131         my ($self, $jobs) = @_;
 132         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 133         $jobs = 1 if $jobs < 1;
 134         while (keys(%$LIVE) >= $jobs) {
 135                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 136                 if (my $x = delete $LIVE->{$pid}) {
 137                         my $cb = shift @$x;
 138                         $cb->(@$x) if $cb;
 139                 } else {
 140                         warn "reaped unknown PID=$pid ($?)\n";
 141                 }
 142         }
 143 }
 144
 145 sub _get_txt_start { # non-fatal
 146         my ($self, $endpoint, $fini) = @_;
 147         my $uri = URI->new($self->{cur_src} // $self->{src});
 148         my $lei = $self->{lei};
 149         my $path = $uri->path;
 150         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 151         $uri->path("$path/$endpoint");
 152         my $f = (split(m!/!, $endpoint))[-1];
 153         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 154         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 155         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(--compressed -R -o),
 156                                         $ft->filename);
 157         do_reap($self);
 158         $lei->qerr("# @$cmd");
 159         return if $self->{dry_run};
 160         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 161         $LIVE->{spawn($cmd, undef, $opt)} =
 162                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 163 }
 164
 165 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 166         my ($self, $endpoint) = @_;
 167         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 168         my $cerr = $?;
 169         $? = 0; # don't influence normal lei exit
 170         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 171         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 172         seek($fh, SEEK_SET, 0) or die "seek: $!";
 173         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 174         local $/;
 175         $self->{"txt.$endpoint"} = <$fh>;
 176         undef; # success
 177 }
 178
 179 sub _write_inbox_config {
 180         my ($self) = @_;
 181         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 182         my $dst = $self->{cur_dst} // $self->{dst};
 183         my $f = "$dst/inbox.config.example";
 184         my $mtime = delete $self->{'mtime._/text/config/raw'};
 185         if (sysopen(my $fh, $f, O_CREAT|O_EXCL|O_WRONLY)) {
 186                 print $fh $buf or die "print: $!";
 187                 chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 188                 $fh->flush or die "flush($f): $!";
 189                 if (defined $mtime) {
 190                         utime($mtime, $mtime, $fh) or die "utime($f): $!";
 191                 }
 192         } elsif (!$!{EEXIST}) {
 193                 die "open($f): $!";
 194         }
 195         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 196         my $ibx = $self->{ibx} = {};
 197         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 198                 for (qw(address newsgroup nntpmirror)) {
 199                         $ibx->{$_} = $cfg->{"$sec.$_"};
 200                 }
 201         }
 202 }
 203
 204 sub set_description ($) {
 205         my ($self) = @_;
 206         my $dst = $self->{cur_dst} // $self->{dst};
 207         chomp(my $orig = PublicInbox::Git::try_cat("$dst/description"));
 208         my $d = $orig;
 209         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 210                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 211                 $d = delete($self->{'txt.description'});
 212         }
 213         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 214         atomic_write($dst, 'description', $d."\n") if $d ne $orig;
 215 }
 216
 217 sub index_cloned_inbox {
 218         my ($self, $iv) = @_;
 219         my $lei = $self->{lei};
 220
 221         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 222         # lei is useless without Xapian + SQLite
 223         if ($lei->{cmd} ne 'public-inbox-clone') {
 224                 require PublicInbox::InboxWritable;
 225                 require PublicInbox::Admin;
 226                 my $ibx = delete($self->{ibx}) // {
 227                         address => [ 'lei@example.com' ],
 228                         version => $iv,
 229                 };
 230                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 231                 PublicInbox::Inbox->new($ibx);
 232                 PublicInbox::InboxWritable->new($ibx);
 233                 my $opt = {};
 234                 for my $sw ($lei->index_opt) {
 235                         my ($k) = ($sw =~ /\A([\w-]+)/);
 236                         $opt->{$k} = $lei->{opt}->{$k};
 237                 }
 238                 # force synchronous dwaitpid for v2:
 239                 local $PublicInbox::DS::in_loop = 0;
 240                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 241                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 242                 local %ENV = (%ENV, %$env) if $env;
 243                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 244                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 245         }
 246         return if defined $self->{cur_dst}; # one of many repos to clone
 247 }
 248
 249 sub run_reap {
 250         my ($lei, $cmd, $opt) = @_;
 251         $lei->qerr("# @$cmd");
 252         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 253         my $ret = $?;
 254         $? = 0; # don't let it influence normal exit
 255         $ret;
 256 }
 257
 258 sub start_cmd {
 259         my ($self, $cmd, $opt, $fini) = @_;
 260         do_reap($self);
 261         $self->{lei}->qerr("# @$cmd");
 262         return if $self->{dry_run};
 263         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 264 }
 265
 266 sub fetch_args ($$) {
 267         my ($lei, $opt) = @_;
 268         my @cmd; # (git --git-dir=...) to be added by caller
 269         $opt->{$_} = $lei->{$_} for (0..2);
 270         # we support "-c $key=$val" for arbitrary git config options
 271         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 272         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 273         push @cmd, 'fetch';
 274         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 275                         ($lei->{opt}->{jobs} // 1) > 1;
 276         push @cmd, '-v' if $lei->{opt}->{verbose};
 277         push(@cmd, '-p') if $lei->{opt}->{prune};
 278         @cmd;
 279 }
 280
 281 sub upr { # feed `git update-ref --stdin -z' verbosely
 282         my ($lei, $w, $op, @rest) = @_; # ($ref, $oid) = @rest
 283         $lei->qerr("# $op @rest") if $lei->{opt}->{verbose};
 284         print $w "$op ", join("\0", @rest, '') or die "print(w): $!";
 285 }
 286
 287 sub fgrp_update {
 288         my ($fgrp) = @_;
 289         return if !keep_going($fgrp);
 290         my $srcfh = delete $fgrp->{srcfh} or return;
 291         my $dstfh = delete $fgrp->{dstfh} or return;
 292         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 293         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 294         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 295         close $srcfh;
 296         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 297         close $dstfh;
 298         pipe(my ($r, $w)) or die "pipe: $!";
 299         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 300                 qw(update-ref --stdin -z) ];
 301         my $lei = $fgrp->{lei};
 302         my $pack = PublicInbox::OnDestroy->new($$, \&pack_dst, $fgrp);
 303         start_cmd($fgrp, $cmd, { 0 => $r, 2 => $lei->{2} }, $pack);
 304         close $r or die "close(r): $!";
 305         return if $fgrp->{dry_run};
 306         for my $ref (keys %dst) {
 307                 my $new = delete $src{$ref};
 308                 my $old = $dst{$ref};
 309                 if (defined $new) {
 310                         $new eq $old or
 311                                 upr($lei, $w, 'update', $ref, $new, $old);
 312                 } else {
 313                         upr($lei, $w, 'delete', $ref, $old);
 314                 }
 315         }
 316         while (my ($ref, $oid) = each %src) {
 317                 upr($lei, $w, 'create', $ref, $oid);
 318         }
 319         close($w) or warn "E: close(update-ref --stdin): $! (need git 1.8.5+)\n";
 320 }
 321
 322 sub pack_dst { # packs lightweight satellite repos
 323         my ($fgrp) = @_;
 324         pack_refs($fgrp, $fgrp->{cur_dst});
 325 }
 326
 327 sub pack_refs {
 328         my ($self, $git_dir) = @_;
 329         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 330         start_cmd($self, $cmd, { 2 => $self->{lei}->{2} });
 331 }
 332
 333 sub fgrpv_done {
 334         my ($fgrpv) = @_;
 335         return if !$LIVE;
 336         my $first = $fgrpv->[0] // die 'BUG: no fgrpv->[0]';
 337         return if !keep_going($first);
 338         pack_refs($first, $first->{-osdir}); # objstore refs always packed
 339         for my $fgrp (@$fgrpv) {
 340                 my $rn = $fgrp->{-remote};
 341                 my %opt = ( 2 => $fgrp->{lei}->{2} );
 342
 343                 my $update_ref = PublicInbox::OnDestroy->new($$,
 344                                                         \&fgrp_update, $fgrp);
 345
 346                 my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 347                         "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 348                         "refs/remotes/$rn/" ];
 349                 open(my $sfh, '+>', undef) or die "open(src): $!";
 350                 $fgrp->{srcfh} = $sfh;
 351                 start_cmd($fgrp, $src, { %opt, 1 => $sfh }, $update_ref);
 352                 my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 353                         '--format=%(refname)%00%(objectname)' ];
 354                 open(my $dfh, '+>', undef) or die "open(dst): $!";
 355                 $fgrp->{dstfh} = $dfh;
 356                 start_cmd($fgrp, $dst, { %opt, 1 => $dfh }, $update_ref);
 357         }
 358 }
 359
 360 sub fgrp_fetch_all {
 361         my ($self) = @_;
 362         my $todo = $FGRP_TODO;
 363         $FGRP_TODO = \'BUG on further use';
 364         keys(%$todo) or return;
 365
 366         # Rely on the fgrptmp remote groups in the config file rather
 367         # than listing all remotes since the remote name list may exceed
 368         # system argv limits:
 369         my $grp = 'fgrptmp';
 370
 371         my @git = (@{$self->{-torsocks}}, 'git');
 372         my $j = $self->{lei}->{opt}->{jobs};
 373         my $opt = {};
 374         my @fetch = do {
 375                 local $self->{lei}->{opt}->{jobs} = 1;
 376                 (fetch_args($self->{lei}, $opt),
 377                         qw(--no-tags --multiple));
 378         };
 379         push(@fetch, "-j$j") if $j;
 380         while (my ($osdir, $fgrpv) = each %$todo) {
 381                 my $f = "$osdir/config";
 382                 return if !keep_going($self);
 383
 384                 # clobber group from previous run atomically
 385                 my $cmd = ['git', "--git-dir=$osdir", qw(config -f),
 386                                 $f, '--unset-all', "remotes.$grp"];
 387                 $self->{lei}->qerr("# @$cmd");
 388                 if (!$self->{dry_run}) {
 389                         my $pid = spawn($cmd, undef, { 2 => $self->{lei}->{2} });
 390                         waitpid($pid, 0) // die "waitpid: $!";
 391                         die "E: @$cmd: \$?=$?" if ($? && ($? >> 8) != 5);
 392
 393                         # update the config atomically via O_APPEND while
 394                         # respecting git-config locking
 395                         sysopen(my $lk, "$f.lock", O_CREAT|O_EXCL|O_WRONLY)
 396                                 or die "open($f.lock): $!";
 397                         open my $fh, '>>', $f or die "open(>>$f): $!";
 398                         $fh->autoflush(1);
 399                         my $buf = join('', "[remotes]\n",
 400                                 map { "\t$grp = $_->{-remote}\n" } @$fgrpv);
 401                         print $fh $buf or die "print($f): $!";
 402                         close $fh or die "close($f): $!";
 403                         unlink("$f.lock") or die "unlink($f.lock): $!";
 404                 }
 405
 406                 $cmd = [ @git, "--git-dir=$osdir", @fetch, $grp ];
 407                 my $end = PublicInbox::OnDestroy->new($$, \&fgrpv_done, $fgrpv);
 408                 start_cmd($self, $cmd, $opt, $end);
 409         }
 410 }
 411
 412 # keep this idempotent for future use by public-inbox-fetch
 413 sub forkgroup_prep {
 414         my ($self, $uri) = @_;
 415         $self->{-ent} // return;
 416         my $os = $self->{-objstore} // return;
 417         my $fg = $self->{-ent}->{forkgroup} // return;
 418         my $dir = "$os/$fg.git";
 419         if (!-d $dir && !$self->{dry_run}) {
 420                 PublicInbox::Import::init_bare($dir);
 421                 my @cmd = ('git', "--git-dir=$dir", 'config');
 422                 my $opt = { 2 => $self->{lei}->{2} };
 423                 for ('repack.useDeltaIslands=true',
 424                                 'pack.island=refs/remotes/([^/]+)/') {
 425                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
 426                 }
 427         }
 428         my $key = $self->{-key} // die 'BUG: no -key';
 429         my $rn = substr(sha256_hex($key), 0, 16);
 430         if (!-d $self->{cur_dst} && !$self->{dry_run}) {
 431                 PublicInbox::Import::init_bare($self->{cur_dst});
 432                 my $f = "$self->{cur_dst}/config";
 433                 open my $fh, '+>>', $f or die "open:($f): $!";
 434                 print $fh <<EOM or die "print($f): $!";
 435 ; rely on the "$rn" remote in the
 436 ; $fg fork group for fetches
 437 ; only uncomment the following iff you detach from fork groups
 438 ; [remote "origin"]
 439 ;       url = $uri
 440 ;       fetch = +refs/*:refs/*
 441 ;       mirror = true
 442 EOM
 443                 close $fh or die "close($f): $!";
 444         }
 445         if (!$self->{dry_run}) {
 446                 my $alt = File::Spec->rel2abs("$dir/objects");
 447                 my $o = "$self->{cur_dst}/objects";
 448                 my $f = "$o/info/alternates";
 449                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 450                 open my $fh, '+>>', $f or die "open($f): $!";
 451                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 452                 chomp(my @cur = <$fh>);
 453                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 454                         say $fh $l or die "say($f): $!";
 455                 }
 456                 close $fh or die "close($f): $!";
 457         }
 458         bless {
 459                 %$self, -osdir => $dir, -remote => $rn, -uri => $uri
 460         }, __PACKAGE__;
 461 }
 462
 463 sub fp_done {
 464         my ($self, $cmd, $cb, @arg) = @_;
 465         if ($?) {
 466                 $self->{lei}->err("@$cmd failed (\$?=$?) (non-fatal)");
 467                 $? = 0; # don't let it influence normal exit
 468         }
 469         return if !keep_going($self);
 470         my $fh = delete $self->{-show_ref} // die 'BUG: no show-ref output';
 471         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 472         $self->{-ent} // die 'BUG: no -ent';
 473         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 474         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 475         return $cb->($self, @arg) if $A ne $B;
 476         $self->{lei}->qerr("# $self->{-key} up-to-date");
 477 }
 478
 479 sub cmp_fp_do {
 480         my ($self, $cb, @arg) = @_;
 481         # $cb is either resume_fetch or fgrp_enqueue
 482         $self->{-ent} // return $cb->($self, @arg);
 483         my $new = $self->{-ent}->{fingerprint} // return $cb->($self, @arg);
 484         my $key = $self->{-key} // die 'BUG: no -key';
 485         if (my $cur_ent = $self->{-local_manifest}->{$key}) {
 486                 # runs go_fetch->DESTROY run if eq
 487                 return if $cur_ent->{fingerprint} eq $new;
 488         }
 489         my $dst = $self->{cur_dst} // $self->{dst};
 490         my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 491         my $opt = { 2 => $self->{lei}->{2} };
 492         open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 493         $self->{-show_ref} = $opt->{1};
 494         do_reap($self);
 495         $self->{lei}->qerr("# @$cmd");
 496         $LIVE->{spawn($cmd, undef, $opt)} = [ \&fp_done, $self, $cmd,
 497                                                 $cb, @arg ];
 498 }
 499
 500 sub resume_fetch {
 501         my ($self, $uri, $fini) = @_;
 502         return if !keep_going($self);
 503         my $dst = $self->{cur_dst} // $self->{dst};
 504         my @git = ('git', "--git-dir=$dst");
 505         my $opt = { 2 => $self->{lei}->{2} };
 506         my $rn = 'origin'; # configurable?
 507         for ("url=$uri", "fetch=+refs/*:refs/*", 'mirror=true') {
 508                 my @kv = split(/=/, $_, 2);
 509                 $kv[0] = "remote.$rn.$kv[0]";
 510                 next if $self->{dry_run};
 511                 run_die([@git, 'config', @kv], undef, $opt);
 512         }
 513         my $cmd = [ @{$self->{-torsocks}}, @git,
 514                         fetch_args($self->{lei}, $opt), $rn ];
 515         push @$cmd, '-P' if $self->{lei}->{prune}; # --prune-tags implied
 516         start_cmd($self, $cmd, $opt, $fini);
 517 }
 518
 519 sub fgrp_enqueue {
 520         my ($fgrp, $end) = @_; # $end calls fgrp_fetch_all
 521         return if !keep_going($fgrp);
 522         my $opt = { 2 => $fgrp->{lei}->{2} };
 523         # --no-tags is required to avoid conflicts
 524         my $u = $fgrp->{-uri} // die 'BUG: no {-uri}';
 525         my $rn = $fgrp->{-remote} // die 'BUG: no {-remote}';
 526         my @cmd = ('git', "--git-dir=$fgrp->{-osdir}", 'config');
 527         for ("url=$u", "fetch=+refs/*:refs/remotes/$rn/*", 'tagopt=--no-tags') {
 528                 my @kv = split(/=/, $_, 2);
 529                 $kv[0] = "remote.$rn.$kv[0]";
 530                 $fgrp->{dry_run} ? $fgrp->{lei}->qerr("# @cmd @kv") :
 531                                 run_die([@cmd, @kv], undef, $opt);
 532         }
 533         push @{$FGRP_TODO->{$fgrp->{-osdir}}}, $fgrp;
 534 }
 535
 536 sub clone_v1 {
 537         my ($self, $end) = @_;
 538         my $lei = $self->{lei};
 539         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 540         my $uri = URI->new($self->{cur_src} // $self->{src});
 541         my $path = $uri->path;
 542         $path =~ s!/*\z!! and $uri->path($path);
 543         defined($lei->{opt}->{epoch}) and
 544                 die "$uri is a v1 inbox, --epoch is not supported\n";
 545         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 546         my $dst = $self->{cur_dst} // $self->{dst};
 547         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 548         my $resume = -d $dst;
 549         if (my $fgrp = forkgroup_prep($self, $uri)) {
 550                 $fgrp->{-fini} = $fini;
 551                 $resume ? cmp_fp_do($fgrp, \&fgrp_enqueue, $end)
 552                         : fgrp_enqueue($fgrp, $end);
 553         } elsif ($resume) {
 554                 cmp_fp_do($self, \&resume_fetch, $uri, $fini);
 555         } else { # normal clone
 556                 my $cmd = [ @{$self->{-torsocks}},
 557                                 clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 558                 if (defined($self->{-ent})) {
 559                         if (defined(my $ref = $self->{-ent}->{reference})) {
 560                                 -e "$self->{dst}$ref" and
 561                                         push @$cmd, '--reference',
 562                                                 "$self->{dst}$ref";
 563                         }
 564                 }
 565                 start_cmd($self, $cmd, $opt, $fini);
 566         }
 567         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 568                                 /\A(?:always|v1)\z/s) {
 569                 _get_txt_start($self, '_/text/config/raw', $fini);
 570         }
 571
 572         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 573         $self->{'txt.description'} = $d if defined $d;
 574         (!defined($d) && !$end) and
 575                 _get_txt_start($self, 'description', $fini);
 576
 577         $end or do_reap($self, 1); # for non-manifest clone
 578 }
 579
 580 sub parse_epochs ($$) {
 581         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 582         $opt_epochs // return; # undef => all epochs
 583         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 584         undef($lo) if ($lo // '') eq '';
 585         my $re = qr/\A~?[0-9]+\z/;
 586         if (@extra || (($lo // '0') !~ $re) ||
 587                         (($hi // '0') !~ $re) ||
 588                         !(grep(defined, $lo, $hi))) {
 589                 die <<EOM;
 590 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 591 EOM
 592         }
 593         my @n = sort { $a <=> $b } keys %$v2_epochs;
 594         for (grep(defined, $lo, $hi)) {
 595                 if (/\A[0-9]+\z/) {
 596                         $_ > $n[-1] and die
 597 "`$_' exceeds maximum available epoch ($n[-1])\n";
 598                         $_ < $n[0] and die
 599 "`$_' is lower than minimum available epoch ($n[0])\n";
 600                 } elsif (/\A~([0-9]+)/) {
 601                         my $off = -$1 - 1;
 602                         $n[$off] // die "`$_' is out of range\n";
 603                         $_ = $n[$off];
 604                 } else { die "`$_' not understood\n" }
 605         }
 606         defined($lo) && defined($hi) && $lo > $hi and die
 607 "low value (`$lo') exceeds high (`$hi')\n";
 608         $lo //= $n[0] if $dotdot;
 609         $hi //= $n[-1] if $dotdot;
 610         $hi //= $lo;
 611         my $want = {};
 612         for ($lo..$hi) {
 613                 if (defined $v2_epochs->{$_}) {
 614                         $want->{$_} = 1;
 615                 } else {
 616                         warn
 617 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 618                 }
 619         }
 620         $want
 621 }
 622
 623 sub init_placeholder ($$$) {
 624         my ($src, $edst, $ent) = @_;
 625         PublicInbox::Import::init_bare($edst);
 626         my $f = "$edst/config";
 627         open my $fh, '>>', $f or die "open($f): $!";
 628         print $fh <<EOM or die "print($f): $!";
 629 [remote "origin"]
 630         url = $src
 631         fetch = +refs/*:refs/*
 632         mirror = true
 633
 634 ; This git epoch was created read-only and "public-inbox-fetch"
 635 ; will not fetch updates for it unless write permission is added.
 636 ; Hint: chmod +w $edst
 637 EOM
 638         if (defined($ent->{owner})) {
 639                 print $fh <<EOM or die "print($f): $!";
 640 [gitweb]
 641         owner = $ent->{owner}
 642 EOM
 643         }
 644         close $fh or die "close($f): $!";
 645         my %map = (head => 'HEAD', description => undef);
 646         while (my ($key, $fn) = each %map) {
 647                 my $val = $ent->{$key} // next;
 648                 $fn //= $key;
 649                 $fn = "$edst/$fn";
 650                 open $fh, '>', $fn or die "open($fn): $!";
 651                 print $fh $val, "\n" or die "print($fn): $!";
 652                 close $fh or die "close($fn): $!";
 653         }
 654 }
 655
 656 sub reap_cmd { # async, called via SIGCHLD
 657         my ($self, $cmd) = @_;
 658         my $cerr = $?;
 659         $? = 0; # don't let it influence normal exit
 660         $self->{lei}->child_error($cerr, "@$cmd failed (\$?=$cerr)") if $cerr;
 661 }
 662
 663 sub up_fp_done {
 664         my ($self) = @_;
 665         return if !keep_going($self);
 666         my $fh = delete $self->{-show_ref_up} // die 'BUG: no show-ref output';
 667         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 668         $self->{-ent} // die 'BUG: no -ent';
 669         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 670         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 671         return if $A eq $B;
 672         $self->{-ent}->{fingerprint} = $B;
 673         push @{$self->{chg}->{fp_mismatch}}, $self->{-key};
 674 }
 675
 676 sub atomic_write ($$$) {
 677         my ($dn, $bn, $raw) = @_;
 678         my $ft = File::Temp->new(DIR => $dn, TEMPLATE => "$bn-XXXX");
 679         print $ft $raw or die "print($ft): $!";
 680         $ft->flush or die "flush($ft): $!";
 681         ft_rename($ft, "$dn/$bn", 0666);
 682 }
 683
 684 sub run_next_puh {
 685         my ($self) = @_;
 686         my $puh = shift @{$self->{-puh_todo}} // return;
 687         my $fini = PublicInbox::OnDestroy->new($$, \&run_next_puh, $self);
 688         my $cmd = [ @$puh, ($self->{cur_dst} // $self->{dst}) ];
 689         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 690         start_cmd($self, $cmd, undef, $opt, $fini);
 691 }
 692
 693 sub run_post_update_hooks {
 694         my ($self) = @_;
 695         my $puh = $self->{-puh} // return;
 696         @{$self->{-puh_todo}} = @$puh;
 697         run_next_puh($self);
 698 }
 699
 700 # modifies the to-be-written manifest entry, and sets values from it, too
 701 sub update_ent {
 702         my ($self) = @_;
 703         my $key = $self->{-key} // die 'BUG: no -key';
 704         my $new = $self->{-ent}->{fingerprint};
 705         my $cur = $self->{-local_manifest}->{$key}->{fingerprint} // "\0";
 706         my $dst = $self->{cur_dst} // $self->{dst};
 707         if (defined($new) && $new ne $cur) {
 708                 my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 709                 my $opt = { 2 => $self->{lei}->{2} };
 710                 open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 711                 $self->{-show_ref_up} = $opt->{1};
 712                 my $done = PublicInbox::OnDestroy->new($$, \&up_fp_done, $self);
 713                 start_cmd($self, $cmd, $opt, $done);
 714         }
 715         $new = $self->{-ent}->{head};
 716         $cur = $self->{-local_manifest}->{$key}->{head} // "\0";
 717         if (defined($new) && $new ne $cur) {
 718                 # n.b. grokmirror writes raw contents to $dst/HEAD w/o locking
 719                 my $cmd = [ 'git', "--git-dir=$dst" ];
 720                 if ($new =~ s/\Aref: //) {
 721                         push @$cmd, qw(symbolic-ref HEAD), $new;
 722                 } elsif ($new =~ /\A[a-f0-9]{40,}\z/) {
 723                         push @$cmd, qw(update-ref --no-deref HEAD), $new;
 724                 } else {
 725                         undef $cmd;
 726                         warn "W: $key: {head} => `$new' not understood\n";
 727                 }
 728                 start_cmd($self, $cmd, { 2 => $self->{lei}->{2} }) if $cmd;
 729         }
 730         if (my $symlinks = $self->{-ent}->{symlinks}) {
 731                 my $top = File::Spec->rel2abs($self->{dst});
 732                 push @{$self->{-new_symlinks}}, @$symlinks;
 733                 for my $p (@$symlinks) {
 734                         my $ln = "$top/$p";
 735                         $ln =~ tr!/!/!s;
 736                         my (undef, $dn, $bn) = File::Spec->splitpath($ln);
 737                         File::Path::mkpath($dn);
 738                         my $tgt = "$top/$key";
 739                         $tgt = File::Spec->abs2rel($tgt, $dn);
 740                         if (lstat($ln)) {
 741                                 if (-l _) {
 742                                         next if readlink($ln) eq $tgt;
 743                                         unlink($ln) or die "unlink($ln): $!";
 744                                 } else {
 745                                         push @{$self->{chg}->{badlink}}, $p;
 746                                 }
 747                         }
 748                         symlink($tgt, $ln) or die "symlink($tgt, $ln): $!";
 749                 }
 750         }
 751         if (defined(my $t = $self->{-ent}->{modified})) {
 752                 my ($dn, $bn) = ("$dst/info/web", 'last-modified');
 753                 my $orig = PublicInbox::Git::try_cat("$dn/$bn");
 754                 $t = strftime('%F %T', gmtime($t))." +0000\n";
 755                 File::Path::mkpath($dn);
 756                 atomic_write($dn, $bn, $t) if $orig ne $t;
 757         }
 758
 759         $new = $self->{-ent}->{owner} // return;
 760         $cur = $self->{-local_manifest}->{$key}->{owner} // "\0";
 761         return if $cur eq $new;
 762         my $cmd = [ qw(git config -f), "$dst/config", 'gitweb.owner', $new ];
 763         start_cmd($self, $cmd, { 2 => $self->{lei}->{2} });
 764 }
 765
 766 sub v1_done { # called via OnDestroy
 767         my ($self) = @_;
 768         return if $self->{dry_run} || !keep_going($self);
 769         _write_inbox_config($self);
 770         my $dst = $self->{cur_dst} // $self->{dst};
 771         update_ent($self) if $self->{-ent};
 772         my $o = "$dst/objects";
 773         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
 774                 my $base = File::Spec->rel2abs($o);
 775                 my @l = <$fh>;
 776                 my $ft;
 777                 for (@l) {
 778                         next unless m!\A/!;
 779                         $_ = File::Spec->abs2rel($_, $base);
 780                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
 781                                                 DIR => "$o/info");
 782                 }
 783                 if ($ft) {
 784                         print $ft @l or die "print($ft): $!";
 785                         $ft->flush or die "flush($ft): $!";
 786                         ft_rename($ft, $fn, 0666, $fh);
 787                 }
 788         }
 789         eval { set_description($self) };
 790         warn $@ if $@;
 791         run_post_update_hooks($self);
 792         return if ($self->{-is_epoch} ||
 793                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 794         write_makefile($dst, 1);
 795         index_cloned_inbox($self, 1);
 796 }
 797
 798 sub v2_done { # called via OnDestroy
 799         my ($self) = @_;
 800         return if $self->{dry_run} || !keep_going($self);
 801         my $dst = $self->{cur_dst} // $self->{dst};
 802         require PublicInbox::Lock;
 803         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 804         my $lck = $lk->lock_for_scope($$);
 805         _write_inbox_config($self);
 806         require PublicInbox::MultiGit;
 807         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 808         $mg->fill_alternates;
 809         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 810         for my $edst (@{delete($self->{-read_only}) // []}) {
 811                 my @st = stat($edst) or die "stat($edst): $!";
 812                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 813         }
 814         write_makefile($dst, 2);
 815         undef $lck; # unlock
 816         eval { set_description($self) };
 817         warn $@ if $@;
 818         index_cloned_inbox($self, 2);
 819 }
 820
 821 sub clone_v2_prep ($$;$) {
 822         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 823         my $lei = $self->{lei};
 824         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 825         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 826         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 827         my $dst = $self->{cur_dst} // $self->{dst};
 828         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 829         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 830         my (@skip, $desc);
 831         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 832         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 833                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 834                 my $src = $uri->as_string;
 835                 my $edst = $dst;
 836                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 837 failed to extract epoch number from $src
 838
 839                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 840                 $edst .= "/git/$nr.git";
 841                 my $ent;
 842                 if ($m) {
 843                         $ent = $m->{$key} //
 844                                 die("BUG: `$key' not in manifest.js.gz");
 845                         if (defined(my $d = $ent->{description})) {
 846                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 847                                 $desc = $d;
 848                         }
 849                 }
 850                 if (!$want || $want->{$nr}) {
 851                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 852                         $etask->{-ent} = $ent; # may have {reference}
 853                         $etask->{cur_src} = $src;
 854                         $etask->{cur_dst} = $edst;
 855                         $etask->{-is_epoch} = $fini;
 856                         my $ref = $ent->{reference} // '';
 857                         push @{$TODO->{$ref}}, $etask;
 858                         $self->{any_want}->{$key} = 1;
 859                 } else { # create a placeholder so users only need to chmod +w
 860                         init_placeholder($src, $edst, $ent);
 861                         push @{$task->{-read_only}}, $edst;
 862                         push @skip, $key;
 863                 }
 864         }
 865         # filter out the epochs we skipped
 866         $self->{chg}->{manifest} = 1 if $m && delete(@$m{@skip});
 867
 868         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 869
 870         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 871                 _get_txt_start($task, '_/text/config/raw', $fini);
 872
 873         defined($desc) ? ($task->{'txt.description'} = $desc) :
 874                 _get_txt_start($task, 'description', $fini);
 875 }
 876
 877 sub decode_manifest ($$$) {
 878         my ($fh, $fn, $uri) = @_;
 879         my $js;
 880         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 881         gunzip(\$gz => \$js, MultiStream => 1) or
 882                 die "gunzip($uri): $GunzipError\n";
 883         my $m = eval { PublicInbox::Config->json->decode($js) };
 884         die "$uri: error decoding `$js': $@\n" if $@;
 885         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 886         $m;
 887 }
 888
 889 sub load_current_manifest ($) {
 890         my ($self) = @_;
 891         my $fn = $self->{-manifest} // return;
 892         if (open(my $fh, '<', $fn)) {
 893                 decode_manifest($fh, $fn, $fn);
 894         } elsif ($!{ENOENT}) { # non-fatal, we can just do it slowly
 895                 warn "open($fn): $!\n" if !$self->{-initial_clone};
 896                 undef;
 897         } else {
 898                 die "open($fn): $!\n";
 899         }
 900 }
 901
 902 sub multi_inbox ($$$) {
 903         my ($self, $path, $m) = @_;
 904         my $incl = $self->{lei}->{opt}->{include};
 905         my $excl = $self->{lei}->{opt}->{exclude};
 906
 907         # assuming everything not v2 is v1, for now
 908         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 909         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 910         my $v2 = {};
 911
 912         for (@v2_epochs) {
 913                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 914                 push @{$v2->{$1}}, $_;
 915         }
 916         my $n = scalar(keys %$v2) + scalar(@v1);
 917         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 918         if (defined $incl) {
 919                 my $re = '(?:'.join('\\z|', map {
 920                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 921                         } @$incl).'\\z)';
 922                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 923                 delete @$m{map { @$_ } @gone} and $self->{chg}->{manifest} = 1;
 924                 delete @$m{grep(!/$re/, @v1)} and $self->{chg}->{manifest} = 1;
 925                 @v1 = grep(/$re/, @v1);
 926         }
 927         if (defined $excl) {
 928                 my $re = '(?:'.join('\\z|', map {
 929                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 930                         } @$excl).'\\z)';
 931                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 932                 delete @$m{map { @$_ } @gone} and $self->{chg}->{manifest} = 1;
 933                 delete @$m{grep(/$re/, @v1)} and $self->{chg}->{manifest} = 1;
 934                 @v1 = grep(!/$re/, @v1);
 935         }
 936         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 937         $ret->{v1} = \@v1 if @v1;
 938         $ret->{v2} = $v2 if keys %$v2;
 939         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 940                                 join("\n\t", sort @orig)
 941                         : "Nothing available to clone\n";
 942         my $path_pfx = '';
 943
 944         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 945         if (@v2_epochs) {
 946                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 947                                 @v2_epochs) == @v2_epochs) {
 948                         $$path =~ s!\A(/[^/]+)/!/! or last;
 949                         $path_pfx .= $1;
 950                 }
 951         } elsif (@v1) {
 952                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 953                         $path_pfx .= $1;
 954                 }
 955         }
 956         ($path_pfx, $n, $ret);
 957 }
 958
 959 sub clone_all {
 960         my ($self, $m) = @_;
 961         my $todo = $TODO;
 962         $TODO = \'BUG on further use';
 963         my $end = PublicInbox::OnDestroy->new($$, \&fgrp_fetch_all, $self);
 964         {
 965                 my $nodep = delete $todo->{''};
 966
 967                 # do not download unwanted deps
 968                 my $any_want = delete $self->{any_want};
 969                 my @unwanted = grep { !$any_want->{$_} } keys %$todo;
 970                 my @nodep = delete(@$todo{@unwanted});
 971                 push(@$nodep, @$_) for @nodep;
 972
 973                 # handle no-dependency repos, first
 974                 for (@$nodep) {
 975                         clone_v1($_, $end);
 976                         return if !keep_going($self);
 977                 }
 978         }
 979         # resolve references, deepest, first:
 980         while (scalar keys %$todo) {
 981                 for my $x (keys %$todo) {
 982                         my ($nr, $nxt);
 983                         # resolve multi-level references
 984                         while ($m && defined($nxt = $m->{$x}->{reference})) {
 985                                 exists($todo->{$nxt}) or last;
 986                                 if (++$nr > 1000) {
 987                                         $m->{$x}->{reference} = undef;
 988                                         $m->{$nxt}->{reference} = undef;
 989                                         warn <<EOM
 990 E: dependency loop detected (`$x' => `$nxt'), breaking
 991 EOM
 992                                 }
 993                                 $x = $nxt;
 994                         }
 995                         my $y = delete $todo->{$x} // next; # already done
 996                         for (@$y) {
 997                                 clone_v1($_, $end);
 998                                 return if !keep_going($self);
 999                         }
1000                         last; # restart %$todo iteration
1001                 }
1002         }
1003
1004         # $end->DESTROY will call fgrp_fetch_all once all references
1005         # in $LIVE are gone, and do_reap will eventually drain $LIVE
1006         $end = undef;
1007         do_reap($self, 1);
1008 }
1009
1010 sub dump_manifest ($$) {
1011         my ($m, $ft) = @_;
1012         # write the smaller manifest if epochs were skipped so
1013         # users won't have to delete manifest if they +w an
1014         # epoch they no longer want to skip
1015         my $json = PublicInbox::Config->json->encode($m);
1016         my $mtime = (stat($ft))[9];
1017         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
1018         truncate($ft, 0) or die "truncate($ft): $!";
1019         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
1020         $ft->flush or die "flush($ft): $!";
1021         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
1022 }
1023
1024 sub dump_project_list ($$) {
1025         my ($self, $m) = @_;
1026         my $f = $self->{'-project-list'} // return;
1027         my $old = PublicInbox::Git::try_cat($f);
1028         my %new;
1029
1030         open my $dh, '<', '.' or die "open(.): $!";
1031         chdir($self->{dst}) or die "chdir($self->{dst}): $!";
1032         my @local = grep { -e $_ ? ($new{$_} = undef) : 1 } split(/\n/s, $old);
1033         chdir($dh) or die "chdir(restore): $!";
1034
1035         $new{substr($_, 1)} = 1 for keys %$m; # drop leading '/'
1036         my @list = sort keys %new;
1037         my @remote = grep { !defined($new{$_}) } @list;
1038         my %lnk = map { substr($_, 1) => undef } @{$self->{-new_symlinks}};
1039         @remote = grep { !exists($lnk{$_}) } @remote;
1040
1041         warn <<EOM if @remote;
1042 The following local repositories are ignored/gone from $self->{src}:
1043 EOM
1044         warn "\t", $_, "\n" for @remote;
1045         warn <<EOM if @local;
1046 The following repos in $f no longer exist on the filesystem:
1047 EOM
1048         warn "\t", $_, "\n" for @local;
1049
1050         my (undef, $dn, $bn) = File::Spec->splitpath($f);
1051         atomic_write($dn, $bn, join("\n", @list, ''));
1052 }
1053
1054 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
1055 sub try_manifest {
1056         my ($self) = @_;
1057         my $uri = URI->new($self->{src});
1058         my $lei = $self->{lei};
1059         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
1060         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
1061         my $path = $uri->path;
1062         chop($path) eq '/' or die "BUG: $uri not canonicalized";
1063         $uri->path($path . '/manifest.js.gz');
1064         my $manifest = $self->{-manifest} // "$self->{dst}/manifest.js.gz";
1065         my %opt = (UNLINK => 1, SUFFIX => '.tmp', TMPDIR => 1);
1066         if (!$self->{dry_run} && $manifest =~ m!\A(.+?)/[^/]+\z! and -d $1) {
1067                 $opt{DIR} = $1; # allows fast rename(2) w/o EXDEV
1068                 delete $opt{TMPDIR};
1069         }
1070         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX', %opt);
1071         my $cmd = $curl->for_uri($lei, $uri, qw(-R -o), $ft->filename);
1072         push(@$cmd, '-z', $manifest) if -f $manifest;
1073         my $mf_url = "$uri";
1074         %opt = map { $_ => $lei->{$_} } (0..2);
1075         my $cerr = run_reap($lei, $cmd, \%opt);
1076         if ($cerr) {
1077                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
1078                 return $lei->child_error($cerr, "@$cmd failed");
1079         }
1080
1081         # bail out if curl -z/--timecond hit 304 Not Modified, $ft will be empty
1082         return $lei->qerr("# $manifest unchanged") if -f $manifest && !-s $ft;
1083
1084         my $m = eval { decode_manifest($ft, $ft, $uri) };
1085         if ($@) {
1086                 warn $@;
1087                 return try_scrape($self);
1088         }
1089         local $self->{chg} = {};
1090         local $self->{-local_manifest} = load_current_manifest($self);
1091         local $self->{-new_symlinks} = [];
1092         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
1093         return $lei->child_error(1, $multi) if !ref($multi);
1094         my $v2 = delete $multi->{v2};
1095         if ($v2) {
1096                 for my $name (sort keys %$v2) {
1097                         my $epochs = delete $v2->{$name};
1098                         my %v2_epochs = map {
1099                                 $uri->path($n > 1 ? $path_pfx.$path.$_
1100                                                 : $path_pfx.$_);
1101                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
1102                                 $e // die "no [0-9]+\.git in `$uri'";
1103                                 $e => [ $uri->clone, $_ ];
1104                         } @$epochs;
1105                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
1106                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
1107                         local $self->{cur_src} = $1;
1108                         local $self->{cur_dst} = $self->{dst};
1109                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
1110                                                         git/[0-9]+\.git\z!x) {
1111                                 $self->{cur_dst} .= "/$1";
1112                         }
1113                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
1114 E: `$self->{cur_dst}' must not contain newline
1115 EOM
1116                         clone_v2_prep($self, \%v2_epochs, $m);
1117                         return if !keep_going($self);
1118                 }
1119         }
1120         if (my $v1 = delete $multi->{v1}) {
1121                 my $p = $path_pfx.$path;
1122                 chop($p) if substr($p, -1, 1) eq '/';
1123                 $uri->path($p);
1124                 for my $name (@$v1) {
1125                         my $task = bless { %$self }, __PACKAGE__;
1126                         $task->{-ent} = $m->{$name} //
1127                                         die("BUG: no `$name' in manifest");
1128                         $task->{cur_src} = "$uri";
1129                         $task->{cur_dst} = $task->{dst};
1130                         $task->{-key} = $name;
1131                         if ($n > 1) {
1132                                 $task->{cur_dst} .= $name;
1133                                 $task->{cur_src} .= $name;
1134                         }
1135                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
1136 E: `$task->{cur_dst}' must not contain newline
1137 EOM
1138                         $task->{cur_src} .= '/';
1139                         my $dep = $task->{-ent}->{reference} // '';
1140                         push @{$TODO->{$dep}}, $task; # for clone_all
1141                         $self->{any_want}->{$name} = 1;
1142                 }
1143         }
1144         delete local $lei->{opt}->{epoch} if defined($v2);
1145         clone_all($self, $m);
1146         return if $self->{dry_run} || !keep_going($self);
1147
1148         # set by clone_v2_prep/-I/--exclude
1149         my $mis = delete $self->{chg}->{fp_mismatch};
1150         if ($mis) {
1151                 my $t = (stat($ft))[9];
1152                 $t = strftime('%F %k:%M:%S %z', localtime($t));
1153                 warn <<EOM;
1154 W: Fingerprints for the following repositories do not match
1155 W: $mf_url @ $t:
1156 W: These repositories may have updated since $t:
1157 EOM
1158                 warn "\t", $_, "\n" for @$mis;
1159                 warn <<EOM if !$self->{lei}->{opt}->{prune};
1160 W: The above fingerprints may never match without --prune
1161 EOM
1162         }
1163         dump_manifest($m => $ft) if delete($self->{chg}->{manifest}) || $mis;
1164         my $bad = delete $self->{chg}->{badlink};
1165         warn(<<EOM, map { ("\t", $_, "\n") } @$bad) if $bad;
1166 W: The following exist and have not been converted to symlinks
1167 EOM
1168         dump_project_list($self, $m);
1169         ft_rename($ft, $manifest, 0666);
1170 }
1171
1172 sub start_clone_url {
1173         my ($self) = @_;
1174         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
1175         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
1176 }
1177
1178 sub do_mirror { # via wq_io_do or public-inbox-clone
1179         my ($self) = @_;
1180         my $lei = $self->{lei};
1181         $self->{dry_run} = 1 if $lei->{opt}->{'dry-run'};
1182         umask($lei->{client_umask}) if defined $lei->{client_umask};
1183         $self->{-initial_clone} = 1 if !-d $self->{dst};
1184         if (defined(my $puh = $lei->{opt}->{'post-update-hook'})) {
1185                 require Text::ParseWords;
1186                 for (@$puh) {
1187                         my $pfx = [ Text::ParseWords::shellwords($_) ];
1188                         push @{$self->{-puh}}, $pfx;
1189                 }
1190         }
1191         eval {
1192                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
1193                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
1194 --inbox-config must be one of `always', `v2', `v1', or `never'
1195
1196                 # we support these switches with '' (empty string).
1197                 # defaults match example conf distributed with grokmirror
1198                 my @pairs = qw(objstore objstore manifest manifest.js.gz
1199                                 project-list projects.list);
1200                 while (@pairs) {
1201                         my ($k, $default) = splice(@pairs, 0, 2);
1202                         my $v = $lei->{opt}->{$k} // next;
1203                         $v = $default if $v eq '';
1204                         $v = "$self->{dst}/$v" if $v !~ m!\A\.{0,2}/!;
1205                         $self->{"-$k"} = $v;
1206                 }
1207
1208                 local $LIVE = {};
1209                 local $TODO = {};
1210                 local $FGRP_TODO = {};
1211                 my $iv = $lei->{opt}->{'inbox-version'} //
1212                         return start_clone_url($self);
1213                 return clone_v1($self) if $iv == 1;
1214                 die "bad --inbox-version=$iv\n" if $iv != 2;
1215                 die <<EOM if $self->{src} !~ m!://!;
1216 cloning local v2 inboxes not supported
1217 EOM
1218                 try_scrape($self, 1);
1219         };
1220         $lei->fail($@) if $@;
1221 }
1222
1223 sub start {
1224         my ($cls, $lei, $src, $dst) = @_;
1225         my $self = bless { src => $src, dst => $dst }, $cls;
1226         $lei->request_umask;
1227         my ($op_c, $ops) = $lei->workers_start($self, 1);
1228         $lei->{wq1} = $self;
1229         $self->wq_io_do('do_mirror', []);
1230         $self->wq_close;
1231         $lei->wait_wq_events($op_c, $ops);
1232 }
1233
1234 sub ipc_atfork_child {
1235         my ($self) = @_;
1236         $self->{lei}->_lei_atfork_child;
1237         $self->SUPER::ipc_atfork_child;
1238 }
1239
1240 sub write_makefile {
1241         my ($dir, $ibx_ver) = @_;
1242         my $f = "$dir/Makefile";
1243         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
1244                 print $fh <<EOM or die "print($f) $!";
1245 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
1246 # manpage for more information on the format.  This Makefile is
1247 # intended as a familiar wrapper for users unfamiliar with
1248 # public-inbox-* commands.
1249 #
1250 # See the respective manpages for public-inbox-fetch(1),
1251 # public-inbox-index(1), etc for more information on
1252 # some of the commands used by this Makefile.
1253 #
1254 # This Makefile will not be modified nor read by public-inbox,
1255 # so you may edit it freely with your own convenience targets
1256 # and notes.  public-inbox-fetch will recreate it if removed.
1257 EOM
1258                 print $fh <<'EOM' or die "print($f): $!";
1259 # the default target:
1260 help :
1261         @echo Common targets:
1262         @echo '    make fetch        - fetch from remote git repostorie(s)'
1263         @echo '    make update       - fetch and update index '
1264         @echo
1265         @echo Rarely needed targets:
1266         @echo '    make reindex      - may be needed for new features/bugfixes'
1267         @echo '    make compact      - rewrite Xapian storage to save space'
1268         @echo '    make index        - initial index after clone
1269
1270 fetch :
1271         public-inbox-fetch
1272 update :
1273         @if ! public-inbox-fetch --exit-code; \
1274         then \
1275                 c=$$?; \
1276                 test $$c -eq 127 && exit 0; \
1277                 exit $$c; \
1278         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
1279         then \
1280                 public-inbox-index; \
1281         else \
1282                 echo 'public-inbox index not initialized'; \
1283                 echo 'see public-inbox-index(1) man page'; \
1284         fi
1285 index :
1286         public-inbox-index
1287 reindex :
1288         public-inbox-index --reindex
1289 compact :
1290         public-inbox-compact
1291
1292 .PHONY : help fetch update index reindex compact
1293 EOM
1294                 close $fh or die "close($f): $!";
1295         } else {
1296                 die "open($f): $!" unless $!{EEXIST};
1297         }
1298 }
1299
1300 1;