lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::LeiCurl;
  20 use PublicInbox::OnDestroy;
  21 use Digest::SHA qw(sha256_hex sha1_hex);
  22 use POSIX qw(strftime);
  23
  24 our $LIVE; # pid => callback
  25 our $FGRP_TODO; # objstore -> [ fgrp mirror objects ]
  26 our $TODO; # reference => [ non-fgrp mirror objects ]
  27
  28 sub keep_going ($) {
  29         $LIVE && (!$_[0]->{lei}->{child_error} ||
  30                 $_[0]->{lei}->{opt}->{'keep-going'});
  31 }
  32
  33 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  34         my ($arg, $pid) = @_;
  35         my ($mrr, $lei) = @$arg;
  36         if ($?) {
  37                 $lei->child_error($?);
  38         } elsif (!$lei->{child_error}) {
  39                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  40                         require PublicInbox::LeiAddExternal;
  41                         PublicInbox::LeiAddExternal::_finish_add_external(
  42                                                         $lei, $mrr->{dst});
  43                 }
  44                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  45         }
  46         $lei->dclose;
  47 }
  48
  49 # for old installations without manifest.js.gz
  50 sub try_scrape {
  51         my ($self, $fallback_manifest) = @_;
  52         my $uri = URI->new($self->{src});
  53         my $lei = $self->{lei};
  54         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  55         my $cmd = $curl->for_uri($lei, $uri, '--compressed');
  56         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  57         my $fh = popen_rd($cmd, undef, $opt);
  58         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  59         close($fh) or return $lei->child_error($?, "@$cmd failed");
  60
  61         # we grep with URL below, we don't want Subject/From headers
  62         # making us clone random URLs.  This assumes remote instances
  63         # prior to public-inbox 1.7.0
  64         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  65         my @html = split(/<hr>/, $html);
  66         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  67         if (!@urls && $fallback_manifest) {
  68                 warn <<EOM;
  69 W: failed to extract URLs from $uri, trying manifest.js.gz...
  70 EOM
  71                 return start_clone_url($self);
  72         }
  73         my $url = $uri->as_string;
  74         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  75
  76         # since this is for old instances w/o manifest.js.gz, try v1 first
  77         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  78         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  79                 my %v2_epochs = map {
  80                         my ($n) = (m!/([0-9]+)\z!);
  81                         $n => [ URI->new($_), '' ]
  82                 } @v2_urls; # uniq
  83                 clone_v2_prep($self, \%v2_epochs);
  84                 delete local $lei->{opt}->{epoch};
  85                 clone_all($self);
  86                 return;
  87         }
  88
  89         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  90         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  91                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  92                 die <<"";
  93 E: confused by scraping <$uri>, did you mean <$url>?
  94
  95         }
  96         @urls and die <<"";
  97 E: confused by scraping <$uri>, got ambiguous results:
  98 @urls
  99
 100         die "E: scraping <$uri> revealed nothing\n";
 101 }
 102
 103 sub clone_cmd {
 104         my ($lei, $opt) = @_;
 105         my @cmd = qw(git);
 106         $opt->{$_} = $lei->{$_} for (0..2);
 107         # we support "-c $key=$val" for arbitrary git config options
 108         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 109         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 110         push @cmd, qw(clone --mirror);
 111         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 112                         ($lei->{opt}->{jobs} // 1) > 1;
 113         push @cmd, '-v' if $lei->{opt}->{verbose};
 114         # XXX any other options to support?
 115         # --reference is tricky with multiple epochs, but handled
 116         # automatically if using manifest.js.gz
 117         @cmd;
 118 }
 119
 120 sub ft_rename ($$$;$) {
 121         my ($ft, $dst, $open_mode, $fh) = @_;
 122         my @st = stat($fh // $dst);
 123         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 124         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 125         require File::Copy;
 126         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 127         $ft->unlink_on_destroy(0);
 128 }
 129
 130 sub do_reap ($;$) {
 131         my ($self, $jobs) = @_;
 132         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 133         $jobs = 1 if $jobs < 1;
 134         while (keys(%$LIVE) >= $jobs) {
 135                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 136                 if (my $x = delete $LIVE->{$pid}) {
 137                         my $cb = shift @$x;
 138                         $cb->(@$x) if $cb;
 139                 } else {
 140                         warn "reaped unknown PID=$pid ($?)\n";
 141                 }
 142         }
 143 }
 144
 145 sub _get_txt_start { # non-fatal
 146         my ($self, $endpoint, $fini) = @_;
 147         my $uri = URI->new($self->{cur_src} // $self->{src});
 148         my $lei = $self->{lei};
 149         my $path = $uri->path;
 150         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 151         $uri->path("$path/$endpoint");
 152         my $f = (split(m!/!, $endpoint))[-1];
 153         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 154         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 155         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(--compressed -R -o),
 156                                         $ft->filename);
 157         do_reap($self);
 158         $lei->qerr("# @$cmd");
 159         return if $self->{dry_run};
 160         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 161         $LIVE->{spawn($cmd, undef, $opt)} =
 162                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 163 }
 164
 165 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 166         my ($self, $endpoint) = @_;
 167         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 168         my $cerr = $?;
 169         $? = 0; # don't influence normal lei exit
 170         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 171         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 172         seek($fh, SEEK_SET, 0) or die "seek: $!";
 173         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 174         local $/;
 175         $self->{"txt.$endpoint"} = <$fh>;
 176         undef; # success
 177 }
 178
 179 sub _write_inbox_config {
 180         my ($self) = @_;
 181         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 182         my $dst = $self->{cur_dst} // $self->{dst};
 183         my $f = "$dst/inbox.config.example";
 184         my $mtime = delete $self->{'mtime._/text/config/raw'};
 185         if (sysopen(my $fh, $f, O_CREAT|O_EXCL|O_WRONLY)) {
 186                 print $fh $buf or die "print: $!";
 187                 chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 188                 $fh->flush or die "flush($f): $!";
 189                 if (defined $mtime) {
 190                         utime($mtime, $mtime, $fh) or die "utime($f): $!";
 191                 }
 192         } elsif (!$!{EEXIST}) {
 193                 die "open($f): $!";
 194         }
 195         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 196         my $ibx = $self->{ibx} = {};
 197         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 198                 for (qw(address newsgroup nntpmirror)) {
 199                         $ibx->{$_} = $cfg->{"$sec.$_"};
 200                 }
 201         }
 202 }
 203
 204 sub set_description ($) {
 205         my ($self) = @_;
 206         my $dst = $self->{cur_dst} // $self->{dst};
 207         chomp(my $orig = PublicInbox::Git::try_cat("$dst/description"));
 208         my $d = $orig;
 209         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 210                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 211                 $d = delete($self->{'txt.description'});
 212         }
 213         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 214         atomic_write($dst, 'description', $d."\n") if $d ne $orig;
 215 }
 216
 217 sub index_cloned_inbox {
 218         my ($self, $iv) = @_;
 219         my $lei = $self->{lei};
 220
 221         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 222         # lei is useless without Xapian + SQLite
 223         if ($lei->{cmd} ne 'public-inbox-clone') {
 224                 require PublicInbox::InboxWritable;
 225                 require PublicInbox::Admin;
 226                 my $ibx = delete($self->{ibx}) // {
 227                         address => [ 'lei@example.com' ],
 228                         version => $iv,
 229                 };
 230                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 231                 PublicInbox::Inbox->new($ibx);
 232                 PublicInbox::InboxWritable->new($ibx);
 233                 my $opt = {};
 234                 for my $sw ($lei->index_opt) {
 235                         my ($k) = ($sw =~ /\A([\w-]+)/);
 236                         $opt->{$k} = $lei->{opt}->{$k};
 237                 }
 238                 # force synchronous dwaitpid for v2:
 239                 local $PublicInbox::DS::in_loop = 0;
 240                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 241                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 242                 local %ENV = (%ENV, %$env) if $env;
 243                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 244                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 245         }
 246         return if defined $self->{cur_dst}; # one of many repos to clone
 247 }
 248
 249 sub run_reap {
 250         my ($lei, $cmd, $opt) = @_;
 251         $lei->qerr("# @$cmd");
 252         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 253         my $ret = $?;
 254         $? = 0; # don't let it influence normal exit
 255         $ret;
 256 }
 257
 258 sub start_cmd {
 259         my ($self, $cmd, $opt, $fini) = @_;
 260         do_reap($self);
 261         $self->{lei}->qerr("# @$cmd");
 262         return if $self->{dry_run};
 263         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 264 }
 265
 266 sub fetch_args ($$) {
 267         my ($lei, $opt) = @_;
 268         my @cmd; # (git --git-dir=...) to be added by caller
 269         $opt->{$_} = $lei->{$_} for (0..2);
 270         # we support "-c $key=$val" for arbitrary git config options
 271         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 272         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 273         push @cmd, 'fetch';
 274         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 275                         ($lei->{opt}->{jobs} // 1) > 1;
 276         push @cmd, '-v' if $lei->{opt}->{verbose};
 277         push(@cmd, '-p') if $lei->{opt}->{prune};
 278         @cmd;
 279 }
 280
 281 sub upr { # feed `git update-ref --stdin -z' verbosely
 282         my ($lei, $w, $op, @rest) = @_; # ($ref, $oid) = @rest
 283         $lei->qerr("# $op @rest") if $lei->{opt}->{verbose};
 284         print $w "$op ", join("\0", @rest, '') or die "print(w): $!";
 285 }
 286
 287 sub fgrp_update {
 288         my ($fgrp) = @_;
 289         return if !keep_going($fgrp);
 290         my $srcfh = delete $fgrp->{srcfh} or return;
 291         my $dstfh = delete $fgrp->{dstfh} or return;
 292         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 293         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 294         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 295         close $srcfh;
 296         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 297         close $dstfh;
 298         pipe(my ($r, $w)) or die "pipe: $!";
 299         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 300                 qw(update-ref --stdin -z) ];
 301         my $lei = $fgrp->{lei};
 302         my $pack = PublicInbox::OnDestroy->new($$, \&pack_dst, $fgrp);
 303         start_cmd($fgrp, $cmd, { 0 => $r, 2 => $lei->{2} }, $pack);
 304         close $r or die "close(r): $!";
 305         return if $fgrp->{dry_run};
 306         for my $ref (keys %dst) {
 307                 my $new = delete $src{$ref};
 308                 my $old = $dst{$ref};
 309                 if (defined $new) {
 310                         $new eq $old or
 311                                 upr($lei, $w, 'update', $ref, $new, $old);
 312                 } else {
 313                         upr($lei, $w, 'delete', $ref, $old);
 314                 }
 315         }
 316         while (my ($ref, $oid) = each %src) {
 317                 upr($lei, $w, 'create', $ref, $oid);
 318         }
 319         close($w) or warn "E: close(update-ref --stdin): $! (need git 1.8.5+)\n";
 320 }
 321
 322 sub pack_dst { # packs lightweight satellite repos
 323         my ($fgrp) = @_;
 324         pack_refs($fgrp, $fgrp->{cur_dst});
 325 }
 326
 327 sub pack_refs {
 328         my ($self, $git_dir) = @_;
 329         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 330         start_cmd($self, $cmd, { 2 => $self->{lei}->{2} });
 331 }
 332
 333 sub fgrpv_done {
 334         my ($fgrpv) = @_;
 335         return if !$LIVE;
 336         my $first = $fgrpv->[0] // die 'BUG: no fgrpv->[0]';
 337         return if !keep_going($first);
 338         pack_refs($first, $first->{-osdir}); # objstore refs always packed
 339         for my $fgrp (@$fgrpv) {
 340                 my $rn = $fgrp->{-remote};
 341                 my %opt = ( 2 => $fgrp->{lei}->{2} );
 342
 343                 my $update_ref = PublicInbox::OnDestroy->new($$,
 344                                                         \&fgrp_update, $fgrp);
 345
 346                 my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 347                         "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 348                         "refs/remotes/$rn/" ];
 349                 open(my $sfh, '+>', undef) or die "open(src): $!";
 350                 $fgrp->{srcfh} = $sfh;
 351                 start_cmd($fgrp, $src, { %opt, 1 => $sfh }, $update_ref);
 352                 my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 353                         '--format=%(refname)%00%(objectname)' ];
 354                 open(my $dfh, '+>', undef) or die "open(dst): $!";
 355                 $fgrp->{dstfh} = $dfh;
 356                 start_cmd($fgrp, $dst, { %opt, 1 => $dfh }, $update_ref);
 357         }
 358 }
 359
 360 sub fgrp_fetch_all {
 361         my ($self) = @_;
 362         my $todo = $FGRP_TODO;
 363         $FGRP_TODO = \'BUG on further use';
 364         keys(%$todo) or return;
 365
 366         # Rely on the fgrptmp remote groups in the config file rather
 367         # than listing all remotes since the remote name list may exceed
 368         # system argv limits:
 369         my $grp = 'fgrptmp';
 370
 371         my @git = (@{$self->{-torsocks}}, 'git');
 372         my $j = $self->{lei}->{opt}->{jobs};
 373         my $opt = {};
 374         my @fetch = do {
 375                 local $self->{lei}->{opt}->{jobs} = 1;
 376                 (fetch_args($self->{lei}, $opt),
 377                         qw(--no-tags --multiple));
 378         };
 379         push(@fetch, "-j$j") if $j;
 380         while (my ($osdir, $fgrpv) = each %$todo) {
 381                 my $f = "$osdir/config";
 382                 return if !keep_going($self);
 383
 384                 # clobber group from previous run atomically
 385                 my $cmd = ['git', "--git-dir=$osdir", qw(config -f),
 386                                 $f, '--unset-all', "remotes.$grp"];
 387                 $self->{lei}->qerr("# @$cmd");
 388                 if (!$self->{dry_run}) {
 389                         my $pid = spawn($cmd, undef, { 2 => $self->{lei}->{2} });
 390                         waitpid($pid, 0) // die "waitpid: $!";
 391                         die "E: @$cmd: \$?=$?" if ($? && ($? >> 8) != 5);
 392
 393                         # update the config atomically via O_APPEND while
 394                         # respecting git-config locking
 395                         sysopen(my $lk, "$f.lock", O_CREAT|O_EXCL|O_WRONLY)
 396                                 or die "open($f.lock): $!";
 397                         open my $fh, '>>', $f or die "open(>>$f): $!";
 398                         $fh->autoflush(1);
 399                         my $buf = join('', "[remotes]\n",
 400                                 map { "\t$grp = $_->{-remote}\n" } @$fgrpv);
 401                         print $fh $buf or die "print($f): $!";
 402                         close $fh or die "close($f): $!";
 403                         unlink("$f.lock") or die "unlink($f.lock): $!";
 404                 }
 405
 406                 $cmd = [ @git, "--git-dir=$osdir", @fetch, $grp ];
 407                 my $end = PublicInbox::OnDestroy->new($$, \&fgrpv_done, $fgrpv);
 408                 start_cmd($self, $cmd, $opt, $end);
 409         }
 410 }
 411
 412 # keep this idempotent for future use by public-inbox-fetch
 413 sub forkgroup_prep {
 414         my ($self, $uri) = @_;
 415         $self->{-ent} // return;
 416         my $os = $self->{-objstore} // return;
 417         my $fg = $self->{-ent}->{forkgroup} // return;
 418         my $dir = "$os/$fg.git";
 419         if (!-d $dir && !$self->{dry_run}) {
 420                 PublicInbox::Import::init_bare($dir);
 421                 my @cmd = ('git', "--git-dir=$dir", 'config');
 422                 my $opt = { 2 => $self->{lei}->{2} };
 423                 for ('repack.useDeltaIslands=true',
 424                                 'pack.island=refs/remotes/([^/]+)/') {
 425                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
 426                 }
 427         }
 428         my $key = $self->{-key} // die 'BUG: no -key';
 429         my $rn = substr(sha256_hex($key), 0, 16);
 430         if (!-d $self->{cur_dst} && !$self->{dry_run}) {
 431                 PublicInbox::Import::init_bare($self->{cur_dst});
 432                 my $f = "$self->{cur_dst}/config";
 433                 open my $fh, '+>>', $f or die "open:($f): $!";
 434                 print $fh <<EOM or die "print($f): $!";
 435 ; rely on the "$rn" remote in the
 436 ; $fg fork group for fetches
 437 ; only uncomment the following iff you detach from fork groups
 438 ; [remote "origin"]
 439 ;       url = $uri
 440 ;       fetch = +refs/*:refs/*
 441 ;       mirror = true
 442 EOM
 443                 close $fh or die "close($f): $!";
 444         }
 445         if (!$self->{dry_run}) {
 446                 my $alt = File::Spec->rel2abs("$dir/objects");
 447                 my $o = "$self->{cur_dst}/objects";
 448                 my $f = "$o/info/alternates";
 449                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 450                 open my $fh, '+>>', $f or die "open($f): $!";
 451                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 452                 chomp(my @cur = <$fh>);
 453                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 454                         say $fh $l or die "say($f): $!";
 455                 }
 456                 close $fh or die "close($f): $!";
 457         }
 458         bless {
 459                 %$self, -osdir => $dir, -remote => $rn, -uri => $uri
 460         }, __PACKAGE__;
 461 }
 462
 463 sub fp_done {
 464         my ($self, $cb, @arg) = @_;
 465         return if !keep_going($self);
 466         my $fh = delete $self->{-show_ref} // die 'BUG: no show-ref output';
 467         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 468         $self->{-ent} // die 'BUG: no -ent';
 469         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 470         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 471         return $cb->($self, @arg) if $A ne $B;
 472         $self->{lei}->qerr("# $self->{-key} up-to-date");
 473 }
 474
 475 sub cmp_fp_do {
 476         my ($self, $cb, @arg) = @_;
 477         # $cb is either resume_fetch or fgrp_enqueue
 478         $self->{-ent} // return $cb->($self, @arg);
 479         my $new = $self->{-ent}->{fingerprint} // return $cb->($self, @arg);
 480         my $key = $self->{-key} // die 'BUG: no -key';
 481         if (my $cur_ent = $self->{-local_manifest}->{$key}) {
 482                 # runs go_fetch->DESTROY run if eq
 483                 return if $cur_ent->{fingerprint} eq $new;
 484         }
 485         my $dst = $self->{cur_dst} // $self->{dst};
 486         my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 487         my $opt = { 2 => $self->{lei}->{2} };
 488         open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 489         $self->{-show_ref} = $opt->{1};
 490         my $done = PublicInbox::OnDestroy->new($$, \&fp_done, $self, $cb, @arg);
 491         start_cmd($self, $cmd, $opt, $done);
 492 }
 493
 494 sub resume_fetch {
 495         my ($self, $uri, $fini) = @_;
 496         return if !keep_going($self);
 497         my $dst = $self->{cur_dst} // $self->{dst};
 498         my @git = ('git', "--git-dir=$dst");
 499         my $opt = { 2 => $self->{lei}->{2} };
 500         my $rn = 'origin'; # configurable?
 501         for ("url=$uri", "fetch=+refs/*:refs/*", 'mirror=true') {
 502                 my @kv = split(/=/, $_, 2);
 503                 $kv[0] = "remote.$rn.$kv[0]";
 504                 next if $self->{dry_run};
 505                 run_die([@git, 'config', @kv], undef, $opt);
 506         }
 507         my $cmd = [ @{$self->{-torsocks}}, @git,
 508                         fetch_args($self->{lei}, $opt), $rn ];
 509         push @$cmd, '-P' if $self->{lei}->{prune}; # --prune-tags implied
 510         start_cmd($self, $cmd, $opt, $fini);
 511 }
 512
 513 sub fgrp_enqueue {
 514         my ($fgrp, $end) = @_; # $end calls fgrp_fetch_all
 515         return if !keep_going($fgrp);
 516         my $opt = { 2 => $fgrp->{lei}->{2} };
 517         # --no-tags is required to avoid conflicts
 518         my $u = $fgrp->{-uri} // die 'BUG: no {-uri}';
 519         my $rn = $fgrp->{-remote} // die 'BUG: no {-remote}';
 520         my @cmd = ('git', "--git-dir=$fgrp->{-osdir}", 'config');
 521         for ("url=$u", "fetch=+refs/*:refs/remotes/$rn/*", 'tagopt=--no-tags') {
 522                 my @kv = split(/=/, $_, 2);
 523                 $kv[0] = "remote.$rn.$kv[0]";
 524                 $fgrp->{dry_run} ? $fgrp->{lei}->qerr("# @cmd @kv") :
 525                                 run_die([@cmd, @kv], undef, $opt);
 526         }
 527         push @{$FGRP_TODO->{$fgrp->{-osdir}}}, $fgrp;
 528 }
 529
 530 sub clone_v1 {
 531         my ($self, $end) = @_;
 532         my $lei = $self->{lei};
 533         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 534         my $uri = URI->new($self->{cur_src} // $self->{src});
 535         my $path = $uri->path;
 536         $path =~ s!/*\z!! and $uri->path($path);
 537         defined($lei->{opt}->{epoch}) and
 538                 die "$uri is a v1 inbox, --epoch is not supported\n";
 539         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 540         my $dst = $self->{cur_dst} // $self->{dst};
 541         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 542         my $resume = -d $dst;
 543         if (my $fgrp = forkgroup_prep($self, $uri)) {
 544                 $fgrp->{-fini} = $fini;
 545                 $resume ? cmp_fp_do($fgrp, \&fgrp_enqueue, $end)
 546                         : fgrp_enqueue($fgrp, $end);
 547         } elsif ($resume) {
 548                 cmp_fp_do($self, \&resume_fetch, $uri, $fini);
 549         } else { # normal clone
 550                 my $cmd = [ @{$self->{-torsocks}},
 551                                 clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 552                 if (defined($self->{-ent})) {
 553                         if (defined(my $ref = $self->{-ent}->{reference})) {
 554                                 -e "$self->{dst}$ref" and
 555                                         push @$cmd, '--reference',
 556                                                 "$self->{dst}$ref";
 557                         }
 558                 }
 559                 start_cmd($self, $cmd, $opt, $fini);
 560         }
 561         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 562                                 /\A(?:always|v1)\z/s) {
 563                 _get_txt_start($self, '_/text/config/raw', $fini);
 564         }
 565
 566         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 567         $self->{'txt.description'} = $d if defined $d;
 568         (!defined($d) && !$end) and
 569                 _get_txt_start($self, 'description', $fini);
 570
 571         $end or do_reap($self, 1); # for non-manifest clone
 572 }
 573
 574 sub parse_epochs ($$) {
 575         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 576         $opt_epochs // return; # undef => all epochs
 577         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 578         undef($lo) if ($lo // '') eq '';
 579         my $re = qr/\A~?[0-9]+\z/;
 580         if (@extra || (($lo // '0') !~ $re) ||
 581                         (($hi // '0') !~ $re) ||
 582                         !(grep(defined, $lo, $hi))) {
 583                 die <<EOM;
 584 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 585 EOM
 586         }
 587         my @n = sort { $a <=> $b } keys %$v2_epochs;
 588         for (grep(defined, $lo, $hi)) {
 589                 if (/\A[0-9]+\z/) {
 590                         $_ > $n[-1] and die
 591 "`$_' exceeds maximum available epoch ($n[-1])\n";
 592                         $_ < $n[0] and die
 593 "`$_' is lower than minimum available epoch ($n[0])\n";
 594                 } elsif (/\A~([0-9]+)/) {
 595                         my $off = -$1 - 1;
 596                         $n[$off] // die "`$_' is out of range\n";
 597                         $_ = $n[$off];
 598                 } else { die "`$_' not understood\n" }
 599         }
 600         defined($lo) && defined($hi) && $lo > $hi and die
 601 "low value (`$lo') exceeds high (`$hi')\n";
 602         $lo //= $n[0] if $dotdot;
 603         $hi //= $n[-1] if $dotdot;
 604         $hi //= $lo;
 605         my $want = {};
 606         for ($lo..$hi) {
 607                 if (defined $v2_epochs->{$_}) {
 608                         $want->{$_} = 1;
 609                 } else {
 610                         warn
 611 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 612                 }
 613         }
 614         $want
 615 }
 616
 617 sub init_placeholder ($$$) {
 618         my ($src, $edst, $ent) = @_;
 619         PublicInbox::Import::init_bare($edst);
 620         my $f = "$edst/config";
 621         open my $fh, '>>', $f or die "open($f): $!";
 622         print $fh <<EOM or die "print($f): $!";
 623 [remote "origin"]
 624         url = $src
 625         fetch = +refs/*:refs/*
 626         mirror = true
 627
 628 ; This git epoch was created read-only and "public-inbox-fetch"
 629 ; will not fetch updates for it unless write permission is added.
 630 ; Hint: chmod +w $edst
 631 EOM
 632         if (defined($ent->{owner})) {
 633                 print $fh <<EOM or die "print($f): $!";
 634 [gitweb]
 635         owner = $ent->{owner}
 636 EOM
 637         }
 638         close $fh or die "close($f): $!";
 639         my %map = (head => 'HEAD', description => undef);
 640         while (my ($key, $fn) = each %map) {
 641                 my $val = $ent->{$key} // next;
 642                 $fn //= $key;
 643                 $fn = "$edst/$fn";
 644                 open $fh, '>', $fn or die "open($fn): $!";
 645                 print $fh $val, "\n" or die "print($fn): $!";
 646                 close $fh or die "close($fn): $!";
 647         }
 648 }
 649
 650 sub reap_cmd { # async, called via SIGCHLD
 651         my ($self, $cmd) = @_;
 652         my $cerr = $?;
 653         $? = 0; # don't let it influence normal exit
 654         $self->{lei}->child_error($cerr, "@$cmd failed (\$?=$cerr)") if $cerr;
 655 }
 656
 657 sub up_fp_done {
 658         my ($self) = @_;
 659         return if !keep_going($self);
 660         my $fh = delete $self->{-show_ref_up} // die 'BUG: no show-ref output';
 661         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 662         $self->{-ent} // die 'BUG: no -ent';
 663         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 664         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 665         return if $A eq $B;
 666         $self->{-ent}->{fingerprint} = $B;
 667         push @{$self->{chg}->{fp_mismatch}}, $self->{-key};
 668 }
 669
 670 sub atomic_write ($$$) {
 671         my ($dn, $bn, $raw) = @_;
 672         my $ft = File::Temp->new(DIR => $dn, TEMPLATE => "$bn-XXXX");
 673         print $ft $raw or die "print($ft): $!";
 674         $ft->flush or die "flush($ft): $!";
 675         ft_rename($ft, "$dn/$bn", 0666);
 676 }
 677
 678 # modifies the to-be-written manifest entry, and sets values from it, too
 679 sub update_ent {
 680         my ($self) = @_;
 681         my $key = $self->{-key} // die 'BUG: no -key';
 682         my $new = $self->{-ent}->{fingerprint};
 683         my $cur = $self->{-local_manifest}->{$key}->{fingerprint} // "\0";
 684         my $dst = $self->{cur_dst} // $self->{dst};
 685         if (defined($new) && $new ne $cur) {
 686                 my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 687                 my $opt = { 2 => $self->{lei}->{2} };
 688                 open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 689                 $self->{-show_ref_up} = $opt->{1};
 690                 my $done = PublicInbox::OnDestroy->new($$, \&up_fp_done, $self);
 691                 start_cmd($self, $cmd, $opt, $done);
 692         }
 693         $new = $self->{-ent}->{head};
 694         $cur = $self->{-local_manifest}->{$key}->{head} // "\0";
 695         if (defined($new) && $new ne $cur) {
 696                 # n.b. grokmirror writes raw contents to $dst/HEAD w/o locking
 697                 my $cmd = [ 'git', "--git-dir=$dst" ];
 698                 if ($new =~ s/\Aref: //) {
 699                         push @$cmd, qw(symbolic-ref HEAD), $new;
 700                 } elsif ($new =~ /\A[a-f0-9]{40,}\z/) {
 701                         push @$cmd, qw(update-ref --no-deref HEAD), $new;
 702                 } else {
 703                         undef $cmd;
 704                         warn "W: $key: {head} => `$new' not understood\n";
 705                 }
 706                 start_cmd($self, $cmd, { 2 => $self->{lei}->{2} }) if $cmd;
 707         }
 708         if (my $symlinks = $self->{-ent}->{symlinks}) {
 709                 my $top = File::Spec->rel2abs($self->{dst});
 710                 push @{$self->{-new_symlinks}}, @$symlinks;
 711                 for my $p (@$symlinks) {
 712                         my $ln = "$top/$p";
 713                         $ln =~ tr!/!/!s;
 714                         my (undef, $dn, $bn) = File::Spec->splitpath($ln);
 715                         File::Path::mkpath($dn);
 716                         my $tgt = "$top/$key";
 717                         $tgt = File::Spec->abs2rel($tgt, $dn);
 718                         if (lstat($ln)) {
 719                                 if (-l _) {
 720                                         next if readlink($ln) eq $tgt;
 721                                         unlink($ln) or die "unlink($ln): $!";
 722                                 } else {
 723                                         push @{$self->{chg}->{badlink}}, $p;
 724                                 }
 725                         }
 726                         symlink($tgt, $ln) or die "symlink($tgt, $ln): $!";
 727                 }
 728         }
 729         if (defined(my $t = $self->{-ent}->{modified})) {
 730                 my ($dn, $bn) = ("$dst/info/web", 'last-modified');
 731                 my $orig = PublicInbox::Git::try_cat("$dn/$bn");
 732                 $t = strftime('%F %T', gmtime($t))." +0000\n";
 733                 File::Path::mkpath($dn);
 734                 atomic_write($dn, $bn, $t) if $orig ne $t;
 735         }
 736
 737         $new = $self->{-ent}->{owner} // return;
 738         $cur = $self->{-local_manifest}->{$key}->{owner} // "\0";
 739         return if $cur eq $new;
 740         my $cmd = [ qw(git config -f), "$dst/config", 'gitweb.owner', $new ];
 741         start_cmd($self, $cmd, { 2 => $self->{lei}->{2} });
 742 }
 743
 744 sub v1_done { # called via OnDestroy
 745         my ($self) = @_;
 746         return if $self->{dry_run} || !keep_going($self);
 747         _write_inbox_config($self);
 748         my $dst = $self->{cur_dst} // $self->{dst};
 749         update_ent($self) if $self->{-ent};
 750         my $o = "$dst/objects";
 751         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
 752                 my $base = File::Spec->rel2abs($o);
 753                 my @l = <$fh>;
 754                 my $ft;
 755                 for (@l) {
 756                         next unless m!\A/!;
 757                         $_ = File::Spec->abs2rel($_, $base);
 758                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
 759                                                 DIR => "$o/info");
 760                 }
 761                 if ($ft) {
 762                         print $ft @l or die "print($ft): $!";
 763                         $ft->flush or die "flush($ft): $!";
 764                         ft_rename($ft, $fn, 0666, $fh);
 765                 }
 766         }
 767         eval { set_description($self) };
 768         warn $@ if $@;
 769         return if ($self->{-is_epoch} ||
 770                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 771         write_makefile($dst, 1);
 772         index_cloned_inbox($self, 1);
 773 }
 774
 775 sub v2_done { # called via OnDestroy
 776         my ($self) = @_;
 777         return if $self->{dry_run} || !keep_going($self);
 778         my $dst = $self->{cur_dst} // $self->{dst};
 779         require PublicInbox::Lock;
 780         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 781         my $lck = $lk->lock_for_scope($$);
 782         _write_inbox_config($self);
 783         require PublicInbox::MultiGit;
 784         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 785         $mg->fill_alternates;
 786         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 787         for my $edst (@{delete($self->{-read_only}) // []}) {
 788                 my @st = stat($edst) or die "stat($edst): $!";
 789                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 790         }
 791         write_makefile($dst, 2);
 792         undef $lck; # unlock
 793         eval { set_description($self) };
 794         warn $@ if $@;
 795         index_cloned_inbox($self, 2);
 796 }
 797
 798 sub clone_v2_prep ($$;$) {
 799         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 800         my $lei = $self->{lei};
 801         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 802         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 803         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 804         my $dst = $self->{cur_dst} // $self->{dst};
 805         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 806         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 807         my (@skip, $desc);
 808         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 809         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 810                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 811                 my $src = $uri->as_string;
 812                 my $edst = $dst;
 813                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 814 failed to extract epoch number from $src
 815
 816                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 817                 $edst .= "/git/$nr.git";
 818                 my $ent;
 819                 if ($m) {
 820                         $ent = $m->{$key} //
 821                                 die("BUG: `$key' not in manifest.js.gz");
 822                         if (defined(my $d = $ent->{description})) {
 823                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 824                                 $desc = $d;
 825                         }
 826                 }
 827                 if (!$want || $want->{$nr}) {
 828                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 829                         $etask->{-ent} = $ent; # may have {reference}
 830                         $etask->{cur_src} = $src;
 831                         $etask->{cur_dst} = $edst;
 832                         $etask->{-is_epoch} = $fini;
 833                         my $ref = $ent->{reference} // '';
 834                         push @{$TODO->{$ref}}, $etask;
 835                         $self->{any_want}->{$key} = 1;
 836                 } else { # create a placeholder so users only need to chmod +w
 837                         init_placeholder($src, $edst, $ent);
 838                         push @{$task->{-read_only}}, $edst;
 839                         push @skip, $key;
 840                 }
 841         }
 842         # filter out the epochs we skipped
 843         $self->{chg}->{manifest} = 1 if $m && delete(@$m{@skip});
 844
 845         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 846
 847         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 848                 _get_txt_start($task, '_/text/config/raw', $fini);
 849
 850         defined($desc) ? ($task->{'txt.description'} = $desc) :
 851                 _get_txt_start($task, 'description', $fini);
 852 }
 853
 854 sub decode_manifest ($$$) {
 855         my ($fh, $fn, $uri) = @_;
 856         my $js;
 857         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 858         gunzip(\$gz => \$js, MultiStream => 1) or
 859                 die "gunzip($uri): $GunzipError\n";
 860         my $m = eval { PublicInbox::Config->json->decode($js) };
 861         die "$uri: error decoding `$js': $@\n" if $@;
 862         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 863         $m;
 864 }
 865
 866 sub load_current_manifest ($) {
 867         my ($self) = @_;
 868         my $fn = $self->{-manifest} // return;
 869         if (open(my $fh, '<', $fn)) {
 870                 decode_manifest($fh, $fn, $fn);
 871         } elsif ($!{ENOENT}) { # non-fatal, we can just do it slowly
 872                 warn "open($fn): $!\n" if !$self->{-initial_clone};
 873                 undef;
 874         } else {
 875                 die "open($fn): $!\n";
 876         }
 877 }
 878
 879 sub multi_inbox ($$$) {
 880         my ($self, $path, $m) = @_;
 881         my $incl = $self->{lei}->{opt}->{include};
 882         my $excl = $self->{lei}->{opt}->{exclude};
 883
 884         # assuming everything not v2 is v1, for now
 885         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 886         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 887         my $v2 = {};
 888
 889         for (@v2_epochs) {
 890                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 891                 push @{$v2->{$1}}, $_;
 892         }
 893         my $n = scalar(keys %$v2) + scalar(@v1);
 894         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 895         if (defined $incl) {
 896                 my $re = '(?:'.join('\\z|', map {
 897                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 898                         } @$incl).'\\z)';
 899                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 900                 delete @$m{map { @$_ } @gone} and $self->{chg}->{manifest} = 1;
 901                 delete @$m{grep(!/$re/, @v1)} and $self->{chg}->{manifest} = 1;
 902                 @v1 = grep(/$re/, @v1);
 903         }
 904         if (defined $excl) {
 905                 my $re = '(?:'.join('\\z|', map {
 906                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 907                         } @$excl).'\\z)';
 908                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 909                 delete @$m{map { @$_ } @gone} and $self->{chg}->{manifest} = 1;
 910                 delete @$m{grep(/$re/, @v1)} and $self->{chg}->{manifest} = 1;
 911                 @v1 = grep(!/$re/, @v1);
 912         }
 913         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 914         $ret->{v1} = \@v1 if @v1;
 915         $ret->{v2} = $v2 if keys %$v2;
 916         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 917                                 join("\n\t", sort @orig)
 918                         : "Nothing available to clone\n";
 919         my $path_pfx = '';
 920
 921         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 922         if (@v2_epochs) {
 923                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 924                                 @v2_epochs) == @v2_epochs) {
 925                         $$path =~ s!\A(/[^/]+)/!/! or last;
 926                         $path_pfx .= $1;
 927                 }
 928         } elsif (@v1) {
 929                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 930                         $path_pfx .= $1;
 931                 }
 932         }
 933         ($path_pfx, $n, $ret);
 934 }
 935
 936 sub clone_all {
 937         my ($self, $m) = @_;
 938         my $todo = $TODO;
 939         $TODO = \'BUG on further use';
 940         my $end = PublicInbox::OnDestroy->new($$, \&fgrp_fetch_all, $self);
 941         {
 942                 my $nodep = delete $todo->{''};
 943
 944                 # do not download unwanted deps
 945                 my $any_want = delete $self->{any_want};
 946                 my @unwanted = grep { !$any_want->{$_} } keys %$todo;
 947                 my @nodep = delete(@$todo{@unwanted});
 948                 push(@$nodep, @$_) for @nodep;
 949
 950                 # handle no-dependency repos, first
 951                 for (@$nodep) {
 952                         clone_v1($_, $end);
 953                         return if !keep_going($self);
 954                 }
 955         }
 956         # resolve references, deepest, first:
 957         while (scalar keys %$todo) {
 958                 for my $x (keys %$todo) {
 959                         my ($nr, $nxt);
 960                         # resolve multi-level references
 961                         while ($m && defined($nxt = $m->{$x}->{reference})) {
 962                                 exists($todo->{$nxt}) or last;
 963                                 die <<EOM if ++$nr > 1000;
 964 E: dependency loop detected (`$x' => `$nxt')
 965 EOM
 966                                 $x = $nxt;
 967                         }
 968                         my $y = delete $todo->{$x} // next; # already done
 969                         for (@$y) {
 970                                 clone_v1($_, $end);
 971                                 return if !keep_going($self);
 972                         }
 973                         last; # restart %$todo iteration
 974                 }
 975         }
 976
 977         # $end->DESTROY will call fgrp_fetch_all once all references
 978         # in $LIVE are gone, and do_reap will eventually drain $LIVE
 979         $end = undef;
 980         do_reap($self, 1);
 981 }
 982
 983 sub dump_manifest ($$) {
 984         my ($m, $ft) = @_;
 985         # write the smaller manifest if epochs were skipped so
 986         # users won't have to delete manifest if they +w an
 987         # epoch they no longer want to skip
 988         my $json = PublicInbox::Config->json->encode($m);
 989         my $mtime = (stat($ft))[9];
 990         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
 991         truncate($ft, 0) or die "truncate($ft): $!";
 992         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
 993         $ft->flush or die "flush($ft): $!";
 994         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
 995 }
 996
 997 sub dump_project_list ($$) {
 998         my ($self, $m) = @_;
 999         my $f = $self->{'-project-list'} // return;
1000         my $old = PublicInbox::Git::try_cat($f);
1001         my %new;
1002
1003         open my $dh, '<', '.' or die "open(.): $!";
1004         chdir($self->{dst}) or die "chdir($self->{dst}): $!";
1005         my @local = grep { -e $_ ? ($new{$_} = undef) : 1 } split(/\n/s, $old);
1006         chdir($dh) or die "chdir(restore): $!";
1007
1008         $new{substr($_, 1)} = 1 for keys %$m; # drop leading '/'
1009         my @list = sort keys %new;
1010         my @remote = grep { !defined($new{$_}) } @list;
1011         my %lnk = map { substr($_, 1) => undef } @{$self->{-new_symlinks}};
1012         @remote = grep { !exists($lnk{$_}) } @remote;
1013
1014         warn <<EOM if @remote;
1015 The following local repositories are ignored/gone from $self->{src}:
1016 EOM
1017         warn "\t", $_, "\n" for @remote;
1018         warn <<EOM if @local;
1019 The following repos in $f no longer exist on the filesystem:
1020 EOM
1021         warn "\t", $_, "\n" for @local;
1022
1023         my (undef, $dn, $bn) = File::Spec->splitpath($f);
1024         atomic_write($dn, $bn, join("\n", @list, ''));
1025 }
1026
1027 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
1028 sub try_manifest {
1029         my ($self) = @_;
1030         my $uri = URI->new($self->{src});
1031         my $lei = $self->{lei};
1032         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
1033         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
1034         my $path = $uri->path;
1035         chop($path) eq '/' or die "BUG: $uri not canonicalized";
1036         $uri->path($path . '/manifest.js.gz');
1037         my $manifest = $self->{-manifest} // "$self->{dst}/manifest.js.gz";
1038         my %opt = (UNLINK => 1, SUFFIX => '.tmp', TMPDIR => 1);
1039         if (!$self->{dry_run} && $manifest =~ m!\A(.+?)/[^/]+\z! and -d $1) {
1040                 $opt{DIR} = $1; # allows fast rename(2) w/o EXDEV
1041                 delete $opt{TMPDIR};
1042         }
1043         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX', %opt);
1044         my $cmd = $curl->for_uri($lei, $uri, qw(-R -o), $ft->filename);
1045         push(@$cmd, '-z', $manifest) if -f $manifest;
1046         my $mf_url = "$uri";
1047         %opt = map { $_ => $lei->{$_} } (0..2);
1048         my $cerr = run_reap($lei, $cmd, \%opt);
1049         if ($cerr) {
1050                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
1051                 return $lei->child_error($cerr, "@$cmd failed");
1052         }
1053
1054         # bail out if curl -z/--timecond hit 304 Not Modified, $ft will be empty
1055         return $lei->qerr("# $manifest unchanged") if -f $manifest && !-s $ft;
1056
1057         my $m = eval { decode_manifest($ft, $ft, $uri) };
1058         if ($@) {
1059                 warn $@;
1060                 return try_scrape($self);
1061         }
1062         local $self->{chg} = {};
1063         local $self->{-local_manifest} = load_current_manifest($self);
1064         local $self->{-new_symlinks} = [];
1065         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
1066         return $lei->child_error(1, $multi) if !ref($multi);
1067         my $v2 = delete $multi->{v2};
1068         if ($v2) {
1069                 for my $name (sort keys %$v2) {
1070                         my $epochs = delete $v2->{$name};
1071                         my %v2_epochs = map {
1072                                 $uri->path($n > 1 ? $path_pfx.$path.$_
1073                                                 : $path_pfx.$_);
1074                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
1075                                 $e // die "no [0-9]+\.git in `$uri'";
1076                                 $e => [ $uri->clone, $_ ];
1077                         } @$epochs;
1078                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
1079                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
1080                         local $self->{cur_src} = $1;
1081                         local $self->{cur_dst} = $self->{dst};
1082                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
1083                                                         git/[0-9]+\.git\z!x) {
1084                                 $self->{cur_dst} .= "/$1";
1085                         }
1086                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
1087 E: `$self->{cur_dst}' must not contain newline
1088 EOM
1089                         clone_v2_prep($self, \%v2_epochs, $m);
1090                         return if !keep_going($self);
1091                 }
1092         }
1093         if (my $v1 = delete $multi->{v1}) {
1094                 my $p = $path_pfx.$path;
1095                 chop($p) if substr($p, -1, 1) eq '/';
1096                 $uri->path($p);
1097                 for my $name (@$v1) {
1098                         my $task = bless { %$self }, __PACKAGE__;
1099                         $task->{-ent} = $m->{$name} //
1100                                         die("BUG: no `$name' in manifest");
1101                         $task->{cur_src} = "$uri";
1102                         $task->{cur_dst} = $task->{dst};
1103                         $task->{-key} = $name;
1104                         if ($n > 1) {
1105                                 $task->{cur_dst} .= $name;
1106                                 $task->{cur_src} .= $name;
1107                         }
1108                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
1109 E: `$task->{cur_dst}' must not contain newline
1110 EOM
1111                         $task->{cur_src} .= '/';
1112                         my $dep = $task->{-ent}->{reference} // '';
1113                         push @{$TODO->{$dep}}, $task; # for clone_all
1114                         $self->{any_want}->{$name} = 1;
1115                 }
1116         }
1117         delete local $lei->{opt}->{epoch} if defined($v2);
1118         clone_all($self, $m);
1119         return if $self->{dry_run} || !keep_going($self);
1120
1121         # set by clone_v2_prep/-I/--exclude
1122         my $mis = delete $self->{chg}->{fp_mismatch};
1123         if ($mis) {
1124                 my $t = (stat($ft))[9];
1125                 $t = strftime('%F %k:%M:%S %z', localtime($t));
1126                 warn <<EOM;
1127 W: Fingerprints for the following repositories do not match
1128 W: $mf_url @ $t:
1129 W: These repositories may have updated since $t:
1130 EOM
1131                 warn "\t", $_, "\n" for @$mis;
1132                 warn <<EOM if !$self->{lei}->{opt}->{prune};
1133 W: The above fingerprints may never match without --prune
1134 EOM
1135         }
1136         dump_manifest($m => $ft) if delete($self->{chg}->{manifest}) || $mis;
1137         my $bad = delete $self->{chg}->{badlink};
1138         warn(<<EOM, map { ("\t", $_, "\n") } @$bad) if $bad;
1139 W: The following exist and have not been converted to symlinks
1140 EOM
1141         dump_project_list($self, $m);
1142         ft_rename($ft, $manifest, 0666);
1143 }
1144
1145 sub start_clone_url {
1146         my ($self) = @_;
1147         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
1148         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
1149 }
1150
1151 sub do_mirror { # via wq_io_do or public-inbox-clone
1152         my ($self) = @_;
1153         my $lei = $self->{lei};
1154         $self->{dry_run} = 1 if $lei->{opt}->{'dry-run'};
1155         umask($lei->{client_umask}) if defined $lei->{client_umask};
1156         $self->{-initial_clone} = 1 if !-d $self->{dst};
1157         eval {
1158                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
1159                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
1160 --inbox-config must be one of `always', `v2', `v1', or `never'
1161
1162                 # we support these switches with '' (empty string).
1163                 # defaults match example conf distributed with grokmirror
1164                 my @pairs = qw(objstore objstore manifest manifest.js.gz
1165                                 project-list projects.list);
1166                 while (@pairs) {
1167                         my ($k, $default) = splice(@pairs, 0, 2);
1168                         my $v = $lei->{opt}->{$k} // next;
1169                         $v = $default if $v eq '';
1170                         $v = "$self->{dst}/$v" if $v !~ m!\A\.{0,2}/!;
1171                         $self->{"-$k"} = $v;
1172                 }
1173
1174                 local $LIVE = {};
1175                 local $TODO = {};
1176                 local $FGRP_TODO = {};
1177                 my $iv = $lei->{opt}->{'inbox-version'} //
1178                         return start_clone_url($self);
1179                 return clone_v1($self) if $iv == 1;
1180                 die "bad --inbox-version=$iv\n" if $iv != 2;
1181                 die <<EOM if $self->{src} !~ m!://!;
1182 cloning local v2 inboxes not supported
1183 EOM
1184                 try_scrape($self, 1);
1185         };
1186         $lei->fail($@) if $@;
1187 }
1188
1189 sub start {
1190         my ($cls, $lei, $src, $dst) = @_;
1191         my $self = bless { src => $src, dst => $dst }, $cls;
1192         $lei->request_umask;
1193         my ($op_c, $ops) = $lei->workers_start($self, 1);
1194         $lei->{wq1} = $self;
1195         $self->wq_io_do('do_mirror', []);
1196         $self->wq_close;
1197         $lei->wait_wq_events($op_c, $ops);
1198 }
1199
1200 sub ipc_atfork_child {
1201         my ($self) = @_;
1202         $self->{lei}->_lei_atfork_child;
1203         $self->SUPER::ipc_atfork_child;
1204 }
1205
1206 sub write_makefile {
1207         my ($dir, $ibx_ver) = @_;
1208         my $f = "$dir/Makefile";
1209         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
1210                 print $fh <<EOM or die "print($f) $!";
1211 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
1212 # manpage for more information on the format.  This Makefile is
1213 # intended as a familiar wrapper for users unfamiliar with
1214 # public-inbox-* commands.
1215 #
1216 # See the respective manpages for public-inbox-fetch(1),
1217 # public-inbox-index(1), etc for more information on
1218 # some of the commands used by this Makefile.
1219 #
1220 # This Makefile will not be modified nor read by public-inbox,
1221 # so you may edit it freely with your own convenience targets
1222 # and notes.  public-inbox-fetch will recreate it if removed.
1223 EOM
1224                 print $fh <<'EOM' or die "print($f): $!";
1225 # the default target:
1226 help :
1227         @echo Common targets:
1228         @echo '    make fetch        - fetch from remote git repostorie(s)'
1229         @echo '    make update       - fetch and update index '
1230         @echo
1231         @echo Rarely needed targets:
1232         @echo '    make reindex      - may be needed for new features/bugfixes'
1233         @echo '    make compact      - rewrite Xapian storage to save space'
1234         @echo '    make index        - initial index after clone
1235
1236 fetch :
1237         public-inbox-fetch
1238 update :
1239         @if ! public-inbox-fetch --exit-code; \
1240         then \
1241                 c=$$?; \
1242                 test $$c -eq 127 && exit 0; \
1243                 exit $$c; \
1244         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
1245         then \
1246                 public-inbox-index; \
1247         else \
1248                 echo 'public-inbox index not initialized'; \
1249                 echo 'see public-inbox-index(1) man page'; \
1250         fi
1251 index :
1252         public-inbox-index
1253 reindex :
1254         public-inbox-index --reindex
1255 compact :
1256         public-inbox-compact
1257
1258 .PHONY : help fetch update index reindex compact
1259 EOM
1260                 close $fh or die "close($f): $!";
1261         } else {
1262                 die "open($f): $!" unless $!{EEXIST};
1263         }
1264 }
1265
1266 1;