lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::Git;
  20 use PublicInbox::LeiCurl;
  21 use PublicInbox::OnDestroy;
  22 use PublicInbox::SHA qw(sha256_hex sha1_hex);
  23 use POSIX qw(strftime);
  24
  25 our $LIVE; # pid => callback
  26 our $FGRP_TODO; # objstore -> [ fgrp mirror objects ]
  27 our $TODO; # reference => [ non-fgrp mirror objects ]
  28 our @PUH; # post-update hooks
  29
  30 sub keep_going ($) {
  31         $LIVE && (!$_[0]->{lei}->{child_error} ||
  32                 $_[0]->{lei}->{opt}->{'keep-going'});
  33 }
  34
  35 sub _wq_done_wait { # awaitpid cb (via wq_eof)
  36         my ($pid, $mrr, $lei) = @_;
  37         if ($?) {
  38                 $lei->child_error($?);
  39         } elsif (!$lei->{child_error}) {
  40                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  41                         require PublicInbox::LeiAddExternal;
  42                         PublicInbox::LeiAddExternal::_finish_add_external(
  43                                                         $lei, $mrr->{dst});
  44                 }
  45                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  46         }
  47         $lei->dclose;
  48 }
  49
  50 # for old installations without manifest.js.gz
  51 sub try_scrape {
  52         my ($self, $fallback_manifest) = @_;
  53         my $uri = URI->new($self->{src});
  54         my $lei = $self->{lei};
  55         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  56         my $cmd = $curl->for_uri($lei, $uri, '--compressed');
  57         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  58         my $fh = popen_rd($cmd, undef, $opt);
  59         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  60         close($fh) or return $lei->child_error($?, "@$cmd failed");
  61
  62         # we grep with URL below, we don't want Subject/From headers
  63         # making us clone random URLs.  This assumes remote instances
  64         # prior to public-inbox 1.7.0
  65         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  66         my @html = split(/<hr>/, $html);
  67         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  68         if (!@urls && $fallback_manifest) {
  69                 warn <<EOM;
  70 W: failed to extract URLs from $uri, trying manifest.js.gz...
  71 EOM
  72                 return start_clone_url($self);
  73         }
  74         my $url = $uri->as_string;
  75         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  76
  77         # since this is for old instances w/o manifest.js.gz, try v1 first
  78         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  79         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  80                 my %v2_epochs = map {
  81                         my ($n) = (m!/([0-9]+)\z!);
  82                         $n => [ URI->new($_), '' ]
  83                 } @v2_urls; # uniq
  84                 clone_v2_prep($self, \%v2_epochs);
  85                 delete local $lei->{opt}->{epoch};
  86                 clone_all($self);
  87                 return;
  88         }
  89
  90         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  91         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  92                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  93                 die <<"";
  94 E: confused by scraping <$uri>, did you mean <$url>?
  95
  96         }
  97         @urls and die <<"";
  98 E: confused by scraping <$uri>, got ambiguous results:
  99 @urls
 100
 101         die "E: scraping <$uri> revealed nothing\n";
 102 }
 103
 104 sub clone_cmd {
 105         my ($lei, $opt) = @_;
 106         my @cmd = qw(git);
 107         $opt->{$_} = $lei->{$_} for (0..2);
 108         # we support "-c $key=$val" for arbitrary git config options
 109         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 110         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 111         push @cmd, qw(clone --mirror);
 112         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 113                         ($lei->{opt}->{jobs} // 1) > 1;
 114         push @cmd, '-v' if $lei->{opt}->{verbose};
 115         # XXX any other options to support?
 116         # --reference is tricky with multiple epochs, but handled
 117         # automatically if using manifest.js.gz
 118         @cmd;
 119 }
 120
 121 sub ft_rename ($$$;$) {
 122         my ($ft, $dst, $open_mode, $fh) = @_;
 123         my @st = stat($fh // $dst);
 124         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 125         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 126         require File::Copy;
 127         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 128         $ft->unlink_on_destroy(0);
 129 }
 130
 131 sub do_reap ($;$) {
 132         my ($self, $jobs) = @_;
 133         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 134         $jobs = 1 if $jobs < 1;
 135         while (keys(%$LIVE) >= $jobs) {
 136                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 137                 if (my $x = delete $LIVE->{$pid}) {
 138                         my $cb = shift @$x;
 139                         $cb->(@$x) if $cb;
 140                 } else {
 141                         warn "reaped unknown PID=$pid ($?)\n";
 142                 }
 143         }
 144 }
 145
 146 sub _get_txt_start { # non-fatal
 147         my ($self, $endpoint, $fini) = @_;
 148         my $uri = URI->new($self->{cur_src} // $self->{src});
 149         my $lei = $self->{lei};
 150         my $path = $uri->path;
 151         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 152         $uri->path("$path/$endpoint");
 153         my $f = (split(m!/!, $endpoint))[-1];
 154         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 155         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 156         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(--compressed -R -o),
 157                                         $ft->filename);
 158         do_reap($self);
 159         $lei->qerr("# @$cmd");
 160         return if $self->{dry_run};
 161         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 162         $LIVE->{spawn($cmd, undef, $opt)} =
 163                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 164 }
 165
 166 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 167         my ($self, $endpoint) = @_;
 168         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 169         my $cerr = $?;
 170         $? = 0; # don't influence normal lei exit
 171         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 172         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 173         seek($fh, SEEK_SET, 0) or die "seek: $!";
 174         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 175         local $/;
 176         $self->{"txt.$endpoint"} = <$fh>;
 177         undef; # success
 178 }
 179
 180 sub _write_inbox_config {
 181         my ($self) = @_;
 182         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 183         my $dst = $self->{cur_dst} // $self->{dst};
 184         my $f = "$dst/inbox.config.example";
 185         my $mtime = delete $self->{'mtime._/text/config/raw'};
 186         if (sysopen(my $fh, $f, O_CREAT|O_EXCL|O_WRONLY)) {
 187                 print $fh $buf or die "print: $!";
 188                 chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 189                 $fh->flush or die "flush($f): $!";
 190                 if (defined $mtime) {
 191                         utime($mtime, $mtime, $fh) or die "utime($f): $!";
 192                 }
 193         } elsif (!$!{EEXIST}) {
 194                 die "open($f): $!";
 195         }
 196         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 197         my $ibx = $self->{ibx} = {};
 198         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 199                 for (qw(address newsgroup nntpmirror)) {
 200                         $ibx->{$_} = $cfg->{"$sec.$_"};
 201                 }
 202         }
 203 }
 204
 205 sub set_description ($) {
 206         my ($self) = @_;
 207         my $dst = $self->{cur_dst} // $self->{dst};
 208         chomp(my $orig = PublicInbox::Git::try_cat("$dst/description"));
 209         my $d = $orig;
 210         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 211                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 212                 $d = delete($self->{'txt.description'});
 213         }
 214         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 215         atomic_write($dst, 'description', $d."\n") if $d ne $orig;
 216 }
 217
 218 sub index_cloned_inbox {
 219         my ($self, $iv) = @_;
 220         my $lei = $self->{lei};
 221
 222         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 223         # lei is useless without Xapian + SQLite
 224         if ($lei->{cmd} ne 'public-inbox-clone') {
 225                 require PublicInbox::InboxWritable;
 226                 require PublicInbox::Admin;
 227                 my $ibx = delete($self->{ibx}) // {
 228                         address => [ 'lei@example.com' ],
 229                         version => $iv,
 230                 };
 231                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 232                 PublicInbox::Inbox->new($ibx);
 233                 PublicInbox::InboxWritable->new($ibx);
 234                 my $opt = {};
 235                 for my $sw ($lei->index_opt) {
 236                         my ($k) = ($sw =~ /\A([\w-]+)/);
 237                         $opt->{$k} = $lei->{opt}->{$k};
 238                 }
 239                 # force synchronous awaitpid for v2:
 240                 local $PublicInbox::DS::in_loop = 0;
 241                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 242                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 243                 local %ENV = (%ENV, %$env) if $env;
 244                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 245                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 246         }
 247         return if defined $self->{cur_dst}; # one of many repos to clone
 248 }
 249
 250 sub run_reap {
 251         my ($lei, $cmd, $opt) = @_;
 252         $lei->qerr("# @$cmd");
 253         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 254         my $ret = $?;
 255         $? = 0; # don't let it influence normal exit
 256         $ret;
 257 }
 258
 259 sub start_cmd {
 260         my ($self, $cmd, $opt, $fini) = @_;
 261         do_reap($self);
 262         utf8::decode(my $msg = "# @$cmd");
 263         $self->{lei}->qerr($msg);
 264         return if $self->{dry_run};
 265         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 266 }
 267
 268 sub fetch_args ($$) {
 269         my ($lei, $opt) = @_;
 270         my @cmd; # (git --git-dir=...) to be added by caller
 271         $opt->{$_} = $lei->{$_} for (0..2);
 272         # we support "-c $key=$val" for arbitrary git config options
 273         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 274         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 275         push @cmd, 'fetch';
 276         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 277                         ($lei->{opt}->{jobs} // 1) > 1;
 278         push @cmd, '-v' if $lei->{opt}->{verbose};
 279         push(@cmd, '-p') if $lei->{opt}->{prune};
 280         PublicInbox::Git::version() >= ((2 << 24) | (29 << 16)) and
 281                 push(@cmd, '--no-write-fetch-head');
 282         @cmd;
 283 }
 284
 285 sub upr { # feed `git update-ref --stdin -z' verbosely
 286         my ($lei, $w, $op, @rest) = @_; # ($ref, $oid) = @rest
 287         $lei->qerr("# $op @rest") if $lei->{opt}->{verbose};
 288         print $w "$op ", join("\0", @rest, '') or die "print(w): $!";
 289 }
 290
 291 sub start_update_ref {
 292         my ($fgrp) = @_;
 293         pipe(my ($r, $w)) or die "pipe: $!";
 294         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 295                 qw(update-ref --stdin -z) ];
 296         my $pack = PublicInbox::OnDestroy->new($$, \&satellite_done, $fgrp);
 297         start_cmd($fgrp, $cmd, { 0 => $r, 2 => $fgrp->{lei}->{2} }, $pack);
 298         close $r or die "close(r): $!";
 299         $fgrp->{dry_run} ? undef : $w;
 300 }
 301
 302 sub upref_warn { warn "E: close(update-ref --stdin): $! (need git 1.8.5+)\n" }
 303
 304 sub fgrp_update {
 305         my ($fgrp) = @_;
 306         return if !keep_going($fgrp);
 307         my $srcfh = delete $fgrp->{srcfh} or return;
 308         my $dstfh = delete $fgrp->{dstfh} or return;
 309         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 310         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 311         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 312         close $srcfh;
 313         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 314         close $dstfh;
 315         my $w = start_update_ref($fgrp) or return;
 316         my $lei = $fgrp->{lei};
 317         my $ndel;
 318         for my $ref (keys %dst) {
 319                 my $new = delete $src{$ref};
 320                 my $old = $dst{$ref};
 321                 if (defined $new) {
 322                         $new eq $old or
 323                                 upr($lei, $w, 'update', $ref, $new, $old);
 324                 } else {
 325                         upr($lei, $w, 'delete', $ref, $old);
 326                         ++$ndel;
 327                 }
 328         }
 329         # git's ref files backend doesn't allow directory/file conflicts
 330         # between `delete' and `create' ops:
 331         if ($ndel && scalar(keys %src)) {
 332                 $fgrp->{-create_refs} = \%src;
 333         } else {
 334                 while (my ($ref, $oid) = each %src) {
 335                         upr($lei, $w, 'create', $ref, $oid);
 336                 }
 337         }
 338         close($w) or upref_warn();
 339 }
 340
 341 sub satellite_done {
 342         my ($fgrp) = @_;
 343         if (my $create = delete $fgrp->{-create_refs}) {
 344                 my $w = start_update_ref($fgrp) or return;
 345                 while (my ($ref, $oid) = each %$create) {
 346                         upr($fgrp->{lei}, $w, 'create', $ref, $oid);
 347                 }
 348                 close($w) or upref_warn();
 349         } else {
 350                 pack_refs($fgrp, $fgrp->{cur_dst});
 351                 run_puh($fgrp);
 352         }
 353 }
 354
 355 sub pack_refs {
 356         my ($self, $git_dir) = @_;
 357         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 358         start_cmd($self, $cmd, { 2 => $self->{lei}->{2} });
 359 }
 360
 361 sub fgrpv_done {
 362         my ($fgrpv) = @_;
 363         return if !$LIVE;
 364         my $first = $fgrpv->[0] // die 'BUG: no fgrpv->[0]';
 365         return if !keep_going($first);
 366         pack_refs($first, $first->{-osdir}); # objstore refs always packed
 367         for my $fgrp (@$fgrpv) {
 368                 my $rn = $fgrp->{-remote};
 369                 my %opt = ( 2 => $fgrp->{lei}->{2} );
 370
 371                 my $update_ref = PublicInbox::OnDestroy->new($$,
 372                                                         \&fgrp_update, $fgrp);
 373
 374                 my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 375                         "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 376                         "refs/remotes/$rn/" ];
 377                 open(my $sfh, '+>', undef) or die "open(src): $!";
 378                 $fgrp->{srcfh} = $sfh;
 379                 start_cmd($fgrp, $src, { %opt, 1 => $sfh }, $update_ref);
 380                 my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 381                         '--format=%(refname)%00%(objectname)' ];
 382                 open(my $dfh, '+>', undef) or die "open(dst): $!";
 383                 $fgrp->{dstfh} = $dfh;
 384                 start_cmd($fgrp, $dst, { %opt, 1 => $dfh }, $update_ref);
 385         }
 386 }
 387
 388 sub fgrp_fetch_all {
 389         my ($self) = @_;
 390         my $todo = $FGRP_TODO;
 391         $FGRP_TODO = \'BUG on further use';
 392         keys(%$todo) or return;
 393
 394         # Rely on the fgrptmp remote groups in the config file rather
 395         # than listing all remotes since the remote name list may exceed
 396         # system argv limits:
 397         my $grp = 'fgrptmp';
 398
 399         my @git = (@{$self->{-torsocks}}, 'git');
 400         my $j = $self->{lei}->{opt}->{jobs};
 401         my $opt = {};
 402         my @fetch = do {
 403                 local $self->{lei}->{opt}->{jobs} = 1;
 404                 (fetch_args($self->{lei}, $opt),
 405                         qw(--no-tags --multiple));
 406         };
 407         push(@fetch, "-j$j") if $j;
 408         while (my ($osdir, $fgrpv) = each %$todo) {
 409                 my $f = "$osdir/config";
 410                 return if !keep_going($self);
 411
 412                 # clobber group from previous run atomically
 413                 my $cmd = ['git', "--git-dir=$osdir", qw(config -f),
 414                                 $f, '--unset-all', "remotes.$grp"];
 415                 $self->{lei}->qerr("# @$cmd");
 416                 if (!$self->{dry_run}) {
 417                         my $pid = spawn($cmd, undef, { 2 => $self->{lei}->{2} });
 418                         waitpid($pid, 0) // die "waitpid: $!";
 419                         die "E: @$cmd: \$?=$?" if ($? && ($? >> 8) != 5);
 420
 421                         # update the config atomically via O_APPEND while
 422                         # respecting git-config locking
 423                         sysopen(my $lk, "$f.lock", O_CREAT|O_EXCL|O_WRONLY)
 424                                 or die "open($f.lock): $!";
 425                         open my $fh, '>>', $f or die "open(>>$f): $!";
 426                         $fh->autoflush(1);
 427                         my $buf = join('', "[remotes]\n",
 428                                 map { "\t$grp = $_->{-remote}\n" } @$fgrpv);
 429                         print $fh $buf or die "print($f): $!";
 430                         close $fh or die "close($f): $!";
 431                         unlink("$f.lock") or die "unlink($f.lock): $!";
 432                 }
 433
 434                 $cmd = [ @git, "--git-dir=$osdir", @fetch, $grp ];
 435                 my $end = PublicInbox::OnDestroy->new($$, \&fgrpv_done, $fgrpv);
 436                 start_cmd($self, $cmd, $opt, $end);
 437         }
 438 }
 439
 440 # keep this idempotent for future use by public-inbox-fetch
 441 sub forkgroup_prep {
 442         my ($self, $uri) = @_;
 443         $self->{-ent} // return;
 444         my $os = $self->{-objstore} // return;
 445         my $fg = $self->{-ent}->{forkgroup} // return;
 446         my $dir = "$os/$fg.git";
 447         if (!-d $dir && !$self->{dry_run}) {
 448                 PublicInbox::Import::init_bare($dir);
 449                 my @cmd = ('git', "--git-dir=$dir", 'config');
 450                 my $opt = { 2 => $self->{lei}->{2} };
 451                 for ('repack.useDeltaIslands=true',
 452                                 'pack.island=refs/remotes/([^/]+)/') {
 453                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
 454                 }
 455         }
 456         my $key = $self->{-key} // die 'BUG: no -key';
 457         my $rn = substr(sha256_hex($key), 0, 16);
 458         if (!-d $self->{cur_dst} && !$self->{dry_run}) {
 459                 PublicInbox::Import::init_bare($self->{cur_dst});
 460                 my $f = "$self->{cur_dst}/config";
 461                 open my $fh, '+>>', $f or die "open:($f): $!";
 462                 print $fh <<EOM or die "print($f): $!";
 463 ; rely on the "$rn" remote in the
 464 ; $fg fork group for fetches
 465 ; only uncomment the following iff you detach from fork groups
 466 ; [remote "origin"]
 467 ;       url = $uri
 468 ;       fetch = +refs/*:refs/*
 469 ;       mirror = true
 470 EOM
 471                 close $fh or die "close($f): $!";
 472         }
 473         if (!$self->{dry_run}) {
 474                 my $alt = File::Spec->rel2abs("$dir/objects");
 475                 my $o = "$self->{cur_dst}/objects";
 476                 my $f = "$o/info/alternates";
 477                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 478                 open my $fh, '+>>', $f or die "open($f): $!";
 479                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 480                 chomp(my @cur = <$fh>);
 481                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 482                         say $fh $l or die "say($f): $!";
 483                 }
 484                 close $fh or die "close($f): $!";
 485         }
 486         bless {
 487                 %$self, -osdir => $dir, -remote => $rn, -uri => $uri
 488         }, __PACKAGE__;
 489 }
 490
 491 sub fp_done {
 492         my ($self, $cmd, $cb, @arg) = @_;
 493         if ($?) {
 494                 $self->{lei}->err("@$cmd failed (\$?=$?) (non-fatal)");
 495                 $? = 0; # don't let it influence normal exit
 496         }
 497         return if !keep_going($self);
 498         my $fh = delete $self->{-show_ref} // die 'BUG: no show-ref output';
 499         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 500         $self->{-ent} // die 'BUG: no -ent';
 501         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 502         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 503         return $cb->($self, @arg) if $A ne $B;
 504         $self->{lei}->qerr("# $self->{-key} up-to-date");
 505 }
 506
 507 sub cmp_fp_do {
 508         my ($self, $cb, @arg) = @_;
 509         # $cb is either resume_fetch or fgrp_enqueue
 510         $self->{-ent} // return $cb->($self, @arg);
 511         my $new = $self->{-ent}->{fingerprint} // return $cb->($self, @arg);
 512         my $key = $self->{-key} // die 'BUG: no -key';
 513         if (my $cur_ent = $self->{-local_manifest}->{$key}) {
 514                 # runs go_fetch->DESTROY run if eq
 515                 return if $cur_ent->{fingerprint} eq $new;
 516         }
 517         my $dst = $self->{cur_dst} // $self->{dst};
 518         my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 519         my $opt = { 2 => $self->{lei}->{2} };
 520         open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 521         $self->{-show_ref} = $opt->{1};
 522         do_reap($self);
 523         $self->{lei}->qerr("# @$cmd");
 524         $LIVE->{spawn($cmd, undef, $opt)} = [ \&fp_done, $self, $cmd,
 525                                                 $cb, @arg ];
 526 }
 527
 528 sub resume_fetch {
 529         my ($self, $uri, $fini) = @_;
 530         return if !keep_going($self);
 531         my $dst = $self->{cur_dst} // $self->{dst};
 532         my @git = ('git', "--git-dir=$dst");
 533         my $opt = { 2 => $self->{lei}->{2} };
 534         my $rn = 'random'.int(rand(1 << 30));
 535         for ("url=$uri", "fetch=+refs/*:refs/*", 'mirror=true') {
 536                 push @git, '-c', "remote.$rn.$_";
 537         }
 538         my $cmd = [ @{$self->{-torsocks}}, @git,
 539                         fetch_args($self->{lei}, $opt), $rn ];
 540         push @$cmd, '-P' if $self->{lei}->{prune}; # --prune-tags implied
 541         my $run_puh = PublicInbox::OnDestroy->new($$, \&run_puh, $self, $fini);
 542         ++$self->{chg}->{nr_chg};
 543         start_cmd($self, $cmd, $opt, $run_puh);
 544 }
 545
 546 sub fgrp_enqueue {
 547         my ($fgrp, $end) = @_; # $end calls fgrp_fetch_all
 548         return if !keep_going($fgrp);
 549         my $opt = { 2 => $fgrp->{lei}->{2} };
 550         # --no-tags is required to avoid conflicts
 551         my $u = $fgrp->{-uri} // die 'BUG: no {-uri}';
 552         my $rn = $fgrp->{-remote} // die 'BUG: no {-remote}';
 553         my @cmd = ('git', "--git-dir=$fgrp->{-osdir}", 'config');
 554         for ("url=$u", "fetch=+refs/*:refs/remotes/$rn/*", 'tagopt=--no-tags') {
 555                 my @kv = split(/=/, $_, 2);
 556                 $kv[0] = "remote.$rn.$kv[0]";
 557                 $fgrp->{dry_run} ? $fgrp->{lei}->qerr("# @cmd @kv") :
 558                                 run_die([@cmd, @kv], undef, $opt);
 559         }
 560         ++$fgrp->{chg}->{nr_chg};
 561         push @{$FGRP_TODO->{$fgrp->{-osdir}}}, $fgrp;
 562 }
 563
 564 sub clone_v1 {
 565         my ($self, $end) = @_;
 566         my $lei = $self->{lei};
 567         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 568         my $uri = URI->new($self->{cur_src} // $self->{src});
 569         my $path = $uri->path;
 570         $path =~ s!/*\z!! and $uri->path($path);
 571         defined($lei->{opt}->{epoch}) and
 572                 die "$uri is a v1 inbox, --epoch is not supported\n";
 573         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 574         my $dst = $self->{cur_dst} // $self->{dst};
 575         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 576         my $resume = -d $dst;
 577         if (my $fgrp = forkgroup_prep($self, $uri)) {
 578                 $fgrp->{-fini} = $fini;
 579                 $resume ? cmp_fp_do($fgrp, \&fgrp_enqueue, $end)
 580                         : fgrp_enqueue($fgrp, $end);
 581         } elsif ($resume) {
 582                 cmp_fp_do($self, \&resume_fetch, $uri, $fini);
 583         } else { # normal clone
 584                 my $cmd = [ @{$self->{-torsocks}},
 585                                 clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 586                 if (defined($self->{-ent})) {
 587                         if (defined(my $ref = $self->{-ent}->{reference})) {
 588                                 -e "$self->{dst}$ref" and
 589                                         push @$cmd, '--reference',
 590                                                 "$self->{dst}$ref";
 591                         }
 592                 }
 593                 ++$self->{chg}->{nr_chg};
 594                 start_cmd($self, $cmd, $opt, PublicInbox::OnDestroy->new($$,
 595                                                 \&run_puh, $self, $fini));
 596         }
 597         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 598                                 /\A(?:always|v1)\z/s) {
 599                 _get_txt_start($self, '_/text/config/raw', $fini);
 600         }
 601
 602         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 603         $self->{'txt.description'} = $d if defined $d;
 604         (!defined($d) && !$end) and
 605                 _get_txt_start($self, 'description', $fini);
 606
 607         $end or do_reap($self, 1); # for non-manifest clone
 608 }
 609
 610 sub parse_epochs ($$) {
 611         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 612         $opt_epochs // return; # undef => all epochs
 613         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 614         undef($lo) if ($lo // '') eq '';
 615         my $re = qr/\A~?[0-9]+\z/;
 616         if (@extra || (($lo // '0') !~ $re) ||
 617                         (($hi // '0') !~ $re) ||
 618                         !(grep(defined, $lo, $hi))) {
 619                 die <<EOM;
 620 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 621 EOM
 622         }
 623         my @n = sort { $a <=> $b } keys %$v2_epochs;
 624         for (grep(defined, $lo, $hi)) {
 625                 if (/\A[0-9]+\z/) {
 626                         $_ > $n[-1] and die
 627 "`$_' exceeds maximum available epoch ($n[-1])\n";
 628                         $_ < $n[0] and die
 629 "`$_' is lower than minimum available epoch ($n[0])\n";
 630                 } elsif (/\A~([0-9]+)/) {
 631                         my $off = -$1 - 1;
 632                         $n[$off] // die "`$_' is out of range\n";
 633                         $_ = $n[$off];
 634                 } else { die "`$_' not understood\n" }
 635         }
 636         defined($lo) && defined($hi) && $lo > $hi and die
 637 "low value (`$lo') exceeds high (`$hi')\n";
 638         $lo //= $n[0] if $dotdot;
 639         $hi //= $n[-1] if $dotdot;
 640         $hi //= $lo;
 641         my $want = {};
 642         for ($lo..$hi) {
 643                 if (defined $v2_epochs->{$_}) {
 644                         $want->{$_} = 1;
 645                 } else {
 646                         warn
 647 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 648                 }
 649         }
 650         $want
 651 }
 652
 653 sub init_placeholder ($$$) {
 654         my ($src, $edst, $ent) = @_;
 655         PublicInbox::Import::init_bare($edst);
 656         my $f = "$edst/config";
 657         open my $fh, '>>', $f or die "open($f): $!";
 658         print $fh <<EOM or die "print($f): $!";
 659 [remote "origin"]
 660         url = $src
 661         fetch = +refs/*:refs/*
 662         mirror = true
 663
 664 ; This git epoch was created read-only and "public-inbox-fetch"
 665 ; will not fetch updates for it unless write permission is added.
 666 ; Hint: chmod +w $edst
 667 EOM
 668         if (defined($ent->{owner})) {
 669                 print $fh <<EOM or die "print($f): $!";
 670 [gitweb]
 671         owner = $ent->{owner}
 672 EOM
 673         }
 674         close $fh or die "close($f): $!";
 675         my %map = (head => 'HEAD', description => undef);
 676         while (my ($key, $fn) = each %map) {
 677                 my $val = $ent->{$key} // next;
 678                 $fn //= $key;
 679                 $fn = "$edst/$fn";
 680                 open $fh, '>', $fn or die "open($fn): $!";
 681                 print $fh $val, "\n" or die "print($fn): $!";
 682                 close $fh or die "close($fn): $!";
 683         }
 684 }
 685
 686 sub reap_cmd { # async, called via SIGCHLD
 687         my ($self, $cmd) = @_;
 688         my $cerr = $?;
 689         $? = 0; # don't let it influence normal exit
 690         $self->{lei}->child_error($cerr, "@$cmd failed (\$?=$cerr)") if $cerr;
 691 }
 692
 693 sub up_fp_done {
 694         my ($self) = @_;
 695         return if !keep_going($self);
 696         my $fh = delete $self->{-show_ref_up} // die 'BUG: no show-ref output';
 697         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 698         $self->{-ent} // die 'BUG: no -ent';
 699         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 700         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 701         return if $A eq $B;
 702         $self->{-ent}->{fingerprint} = $B;
 703         push @{$self->{chg}->{fp_mismatch}}, $self->{-key};
 704 }
 705
 706 sub atomic_write ($$$) {
 707         my ($dn, $bn, $raw) = @_;
 708         my $ft = File::Temp->new(DIR => $dn, TEMPLATE => "$bn-XXXX");
 709         print $ft $raw or die "print($ft): $!";
 710         $ft->flush or die "flush($ft): $!";
 711         ft_rename($ft, "$dn/$bn", 0666);
 712 }
 713
 714 sub run_next_puh {
 715         my ($self) = @_;
 716         my $puh = shift @{$self->{-puh_todo}} // return delete($self->{-fini});
 717         my $fini = PublicInbox::OnDestroy->new($$, \&run_next_puh, $self);
 718         my $cmd = [ @$puh, ($self->{cur_dst} // $self->{dst}) ];
 719         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 720         start_cmd($self, $cmd, undef, $opt, $fini);
 721 }
 722
 723 sub run_puh {
 724         my ($self, $fini) = @_;
 725         $self->{-fini} = $fini;
 726         @{$self->{-puh_todo}} = @PUH;
 727         run_next_puh($self);
 728 }
 729
 730 # modifies the to-be-written manifest entry, and sets values from it, too
 731 sub update_ent {
 732         my ($self) = @_;
 733         my $key = $self->{-key} // die 'BUG: no -key';
 734         my $new = $self->{-ent}->{fingerprint};
 735         my $cur = $self->{-local_manifest}->{$key}->{fingerprint} // "\0";
 736         my $dst = $self->{cur_dst} // $self->{dst};
 737         if (defined($new) && $new ne $cur) {
 738                 my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 739                 my $opt = { 2 => $self->{lei}->{2} };
 740                 open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 741                 $self->{-show_ref_up} = $opt->{1};
 742                 my $done = PublicInbox::OnDestroy->new($$, \&up_fp_done, $self);
 743                 start_cmd($self, $cmd, $opt, $done);
 744         }
 745         $new = $self->{-ent}->{head};
 746         $cur = $self->{-local_manifest}->{$key}->{head} // "\0";
 747         if (defined($new) && $new ne $cur) {
 748                 # n.b. grokmirror writes raw contents to $dst/HEAD w/o locking
 749                 my $cmd = [ 'git', "--git-dir=$dst" ];
 750                 if ($new =~ s/\Aref: //) {
 751                         push @$cmd, qw(symbolic-ref HEAD), $new;
 752                 } elsif ($new =~ /\A[a-f0-9]{40,}\z/) {
 753                         push @$cmd, qw(update-ref --no-deref HEAD), $new;
 754                 } else {
 755                         undef $cmd;
 756                         warn "W: $key: {head} => `$new' not understood\n";
 757                 }
 758                 start_cmd($self, $cmd, { 2 => $self->{lei}->{2} }) if $cmd;
 759         }
 760         if (my $symlinks = $self->{-ent}->{symlinks}) {
 761                 my $top = File::Spec->rel2abs($self->{dst});
 762                 push @{$self->{-new_symlinks}}, @$symlinks;
 763                 for my $p (@$symlinks) {
 764                         my $ln = "$top/$p";
 765                         $ln =~ tr!/!/!s;
 766                         my (undef, $dn, $bn) = File::Spec->splitpath($ln);
 767                         File::Path::mkpath($dn);
 768                         my $tgt = "$top/$key";
 769                         $tgt = File::Spec->abs2rel($tgt, $dn);
 770                         if (lstat($ln)) {
 771                                 if (-l _) {
 772                                         next if readlink($ln) eq $tgt;
 773                                         unlink($ln) or die "unlink($ln): $!";
 774                                 } else {
 775                                         push @{$self->{chg}->{badlink}}, $p;
 776                                 }
 777                         }
 778                         symlink($tgt, $ln) or die "symlink($tgt, $ln): $!";
 779                         ++$self->{chg}->{nr_chg};
 780                 }
 781         }
 782         if (defined(my $t = $self->{-ent}->{modified})) {
 783                 my ($dn, $bn) = ("$dst/info/web", 'last-modified');
 784                 my $orig = PublicInbox::Git::try_cat("$dn/$bn");
 785                 $t = strftime('%F %T', gmtime($t))." +0000\n";
 786                 File::Path::mkpath($dn);
 787                 atomic_write($dn, $bn, $t) if $orig ne $t;
 788         }
 789
 790         $new = $self->{-ent}->{owner} // return;
 791         $cur = $self->{-local_manifest}->{$key}->{owner} // "\0";
 792         return if $cur eq $new;
 793         my $cmd = [ qw(git config -f), "$dst/config", 'gitweb.owner', $new ];
 794         start_cmd($self, $cmd, { 2 => $self->{lei}->{2} });
 795 }
 796
 797 sub v1_done { # called via OnDestroy
 798         my ($self) = @_;
 799         return if $self->{dry_run} || !keep_going($self);
 800         _write_inbox_config($self);
 801         my $dst = $self->{cur_dst} // $self->{dst};
 802         update_ent($self) if $self->{-ent};
 803         my $o = "$dst/objects";
 804         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
 805                 my $base = File::Spec->rel2abs($o);
 806                 my @l = <$fh>;
 807                 my $ft;
 808                 for (@l) {
 809                         next unless m!\A/!;
 810                         $_ = File::Spec->abs2rel($_, $base);
 811                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
 812                                                 DIR => "$o/info");
 813                 }
 814                 if ($ft) {
 815                         print $ft @l or die "print($ft): $!";
 816                         $ft->flush or die "flush($ft): $!";
 817                         ft_rename($ft, $fn, 0666, $fh);
 818                 }
 819         }
 820         eval { set_description($self) };
 821         warn $@ if $@;
 822         return if ($self->{-is_epoch} ||
 823                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 824         write_makefile($dst, 1);
 825         index_cloned_inbox($self, 1);
 826 }
 827
 828 sub v2_done { # called via OnDestroy
 829         my ($self) = @_;
 830         return if $self->{dry_run} || !keep_going($self);
 831         my $dst = $self->{cur_dst} // $self->{dst};
 832         require PublicInbox::Lock;
 833         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 834         my $lck = $lk->lock_for_scope($$);
 835         _write_inbox_config($self);
 836         require PublicInbox::MultiGit;
 837         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 838         $mg->fill_alternates;
 839         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 840         for my $edst (@{delete($self->{-read_only}) // []}) {
 841                 my @st = stat($edst) or die "stat($edst): $!";
 842                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 843         }
 844         write_makefile($dst, 2);
 845         undef $lck; # unlock
 846         eval { set_description($self) };
 847         warn $@ if $@;
 848         index_cloned_inbox($self, 2);
 849 }
 850
 851 sub clone_v2_prep ($$;$) {
 852         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 853         my $lei = $self->{lei};
 854         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 855         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 856         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 857         my $dst = $self->{cur_dst} // $self->{dst};
 858         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 859         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 860         my (@skip, $desc);
 861         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 862         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 863                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 864                 my $src = $uri->as_string;
 865                 my $edst = $dst;
 866                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 867 failed to extract epoch number from $src
 868
 869                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 870                 $edst .= "/git/$nr.git";
 871                 my $ent;
 872                 if ($m) {
 873                         $ent = $m->{$key} //
 874                                 die("BUG: `$key' not in manifest.js.gz");
 875                         if (defined(my $d = $ent->{description})) {
 876                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 877                                 $desc = $d;
 878                         }
 879                 }
 880                 if (!$want || $want->{$nr}) {
 881                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 882                         $etask->{-ent} = $ent; # may have {reference}
 883                         $etask->{cur_src} = $src;
 884                         $etask->{cur_dst} = $edst;
 885                         $etask->{-is_epoch} = $fini;
 886                         my $ref = $ent->{reference} // '';
 887                         push @{$TODO->{$ref}}, $etask;
 888                         $self->{any_want}->{$key} = 1;
 889                 } else { # create a placeholder so users only need to chmod +w
 890                         init_placeholder($src, $edst, $ent);
 891                         push @{$task->{-read_only}}, $edst;
 892                         push @skip, $key;
 893                 }
 894         }
 895         # filter out the epochs we skipped
 896         $self->{chg}->{manifest} = 1 if $m && delete(@$m{@skip});
 897
 898         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 899
 900         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 901                 _get_txt_start($task, '_/text/config/raw', $fini);
 902
 903         defined($desc) ? ($task->{'txt.description'} = $desc) :
 904                 _get_txt_start($task, 'description', $fini);
 905 }
 906
 907 sub decode_manifest ($$$) {
 908         my ($fh, $fn, $uri) = @_;
 909         my $js;
 910         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 911         gunzip(\$gz => \$js, MultiStream => 1) or
 912                 die "gunzip($uri): $GunzipError\n";
 913         my $m = eval { PublicInbox::Config->json->decode($js) };
 914         die "$uri: error decoding `$js': $@\n" if $@;
 915         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 916         $m;
 917 }
 918
 919 sub load_current_manifest ($) {
 920         my ($self) = @_;
 921         my $fn = $self->{-manifest} // return;
 922         if (open(my $fh, '<', $fn)) {
 923                 decode_manifest($fh, $fn, $fn);
 924         } elsif ($!{ENOENT}) { # non-fatal, we can just do it slowly
 925                 warn "open($fn): $!\n" if !$self->{-initial_clone};
 926                 undef;
 927         } else {
 928                 die "open($fn): $!\n";
 929         }
 930 }
 931
 932 sub multi_inbox ($$$) {
 933         my ($self, $path, $m) = @_;
 934         my $incl = $self->{lei}->{opt}->{include};
 935         my $excl = $self->{lei}->{opt}->{exclude};
 936
 937         # assuming everything not v2 is v1, for now
 938         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 939         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 940         my $v2 = {};
 941
 942         for (@v2_epochs) {
 943                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 944                 push @{$v2->{$1}}, $_;
 945         }
 946         my $n = scalar(keys %$v2) + scalar(@v1);
 947         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 948         if (defined $incl) {
 949                 my $re = '(?:'.join('\\z|', map {
 950                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 951                         } @$incl).'\\z)';
 952                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 953                 delete @$m{map { @$_ } @gone} and $self->{chg}->{manifest} = 1;
 954                 delete @$m{grep(!/$re/, @v1)} and $self->{chg}->{manifest} = 1;
 955                 @v1 = grep(/$re/, @v1);
 956         }
 957         if (defined $excl) {
 958                 my $re = '(?:'.join('\\z|', map {
 959                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 960                         } @$excl).'\\z)';
 961                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 962                 delete @$m{map { @$_ } @gone} and $self->{chg}->{manifest} = 1;
 963                 delete @$m{grep(/$re/, @v1)} and $self->{chg}->{manifest} = 1;
 964                 @v1 = grep(!/$re/, @v1);
 965         }
 966         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 967         $ret->{v1} = \@v1 if @v1;
 968         $ret->{v2} = $v2 if keys %$v2;
 969         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 970                                 join("\n\t", sort @orig)
 971                         : "Nothing available to clone\n";
 972         my $path_pfx = '';
 973
 974         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 975         if (@v2_epochs) {
 976                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 977                                 @v2_epochs) == @v2_epochs) {
 978                         $$path =~ s!\A(/[^/]+)/!/! or last;
 979                         $path_pfx .= $1;
 980                 }
 981         } elsif (@v1) {
 982                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 983                         $path_pfx .= $1;
 984                 }
 985         }
 986         ($path_pfx, $n, $ret);
 987 }
 988
 989 sub clone_all {
 990         my ($self, $m) = @_;
 991         my $todo = $TODO;
 992         $TODO = \'BUG on further use';
 993         my $end = PublicInbox::OnDestroy->new($$, \&fgrp_fetch_all, $self);
 994         {
 995                 my $nodep = delete $todo->{''};
 996
 997                 # do not download unwanted deps
 998                 my $any_want = delete $self->{any_want};
 999                 my @unwanted = grep { !$any_want->{$_} } keys %$todo;
1000                 my @nodep = delete(@$todo{@unwanted});
1001                 push(@$nodep, @$_) for @nodep;
1002
1003                 # handle no-dependency repos, first
1004                 for (@$nodep) {
1005                         clone_v1($_, $end);
1006                         return if !keep_going($self);
1007                 }
1008         }
1009         # resolve references, deepest, first:
1010         while (scalar keys %$todo) {
1011                 for my $x (keys %$todo) {
1012                         my ($nr, $nxt);
1013                         # resolve multi-level references
1014                         while ($m && defined($nxt = $m->{$x}->{reference})) {
1015                                 exists($todo->{$nxt}) or last;
1016                                 if (++$nr > 1000) {
1017                                         $m->{$x}->{reference} = undef;
1018                                         $m->{$nxt}->{reference} = undef;
1019                                         warn <<EOM
1020 E: dependency loop detected (`$x' => `$nxt'), breaking
1021 EOM
1022                                 }
1023                                 $x = $nxt;
1024                         }
1025                         my $y = delete $todo->{$x} // next; # already done
1026                         for (@$y) {
1027                                 clone_v1($_, $end);
1028                                 return if !keep_going($self);
1029                         }
1030                         last; # restart %$todo iteration
1031                 }
1032         }
1033
1034         # $end->DESTROY will call fgrp_fetch_all once all references
1035         # in $LIVE are gone, and do_reap will eventually drain $LIVE
1036         $end = undef;
1037         do_reap($self, 1);
1038 }
1039
1040 sub dump_manifest ($$) {
1041         my ($m, $ft) = @_;
1042         # write the smaller manifest if epochs were skipped so
1043         # users won't have to delete manifest if they +w an
1044         # epoch they no longer want to skip
1045         my $json = PublicInbox::Config->json->encode($m);
1046         my $mtime = (stat($ft))[9];
1047         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
1048         truncate($ft, 0) or die "truncate($ft): $!";
1049         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
1050         $ft->flush or die "flush($ft): $!";
1051         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
1052 }
1053
1054 sub dump_project_list ($$) {
1055         my ($self, $m) = @_;
1056         my $f = $self->{'-project-list'} // return;
1057         my $old = PublicInbox::Git::try_cat($f);
1058         my %new;
1059
1060         open my $dh, '<', '.' or die "open(.): $!";
1061         chdir($self->{dst}) or die "chdir($self->{dst}): $!";
1062         my @local = grep { -e $_ ? ($new{$_} = undef) : 1 } split(/\n/s, $old);
1063         chdir($dh) or die "chdir(restore): $!";
1064
1065         $new{substr($_, 1)} = 1 for keys %$m; # drop leading '/'
1066         my @list = sort keys %new;
1067         my @remote = grep { !defined($new{$_}) } @list;
1068         my %lnk = map { substr($_, 1) => undef } @{$self->{-new_symlinks}};
1069         @remote = grep { !exists($lnk{$_}) } @remote;
1070
1071         warn <<EOM if @remote;
1072 The following local repositories are ignored/gone from $self->{src}:
1073 EOM
1074         warn "\t", $_, "\n" for @remote;
1075         warn <<EOM if @local;
1076 The following repos in $f no longer exist on the filesystem:
1077 EOM
1078         warn "\t", $_, "\n" for @local;
1079
1080         my (undef, $dn, $bn) = File::Spec->splitpath($f);
1081         $self->{chg}->{nr_chg} += scalar(@remote) + scalar(@local);
1082         my $new = join("\n", @list, '');
1083         atomic_write($dn, $bn, $new) if $new ne $old;
1084 }
1085
1086 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
1087 sub try_manifest {
1088         my ($self) = @_;
1089         my $uri = URI->new($self->{src});
1090         my $lei = $self->{lei};
1091         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
1092         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
1093         my $path = $uri->path;
1094         chop($path) eq '/' or die "BUG: $uri not canonicalized";
1095         $uri->path($path . '/manifest.js.gz');
1096         my $manifest = $self->{-manifest} // "$self->{dst}/manifest.js.gz";
1097         my %opt = (UNLINK => 1, SUFFIX => '.tmp', TMPDIR => 1);
1098         if (!$self->{dry_run} && $manifest =~ m!\A(.+?)/[^/]+\z! and -d $1) {
1099                 $opt{DIR} = $1; # allows fast rename(2) w/o EXDEV
1100                 delete $opt{TMPDIR};
1101         }
1102         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX', %opt);
1103         my $cmd = $curl->for_uri($lei, $uri, qw(-R -o), $ft->filename);
1104         push(@$cmd, '-z', $manifest) if -f $manifest;
1105         my $mf_url = "$uri";
1106         %opt = map { $_ => $lei->{$_} } (0..2);
1107         my $cerr = run_reap($lei, $cmd, \%opt);
1108         if ($cerr) {
1109                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
1110                 return $lei->child_error($cerr, "@$cmd failed");
1111         }
1112
1113         # bail out if curl -z/--timecond hit 304 Not Modified, $ft will be empty
1114         if (-f $manifest && !-s $ft) {
1115                 $lei->child_error(127 << 8) if $lei->{opt}->{'exit-code'};
1116                 return $lei->qerr("# $manifest unchanged");
1117         }
1118
1119         my $m = eval { decode_manifest($ft, $ft, $uri) };
1120         if ($@) {
1121                 warn $@;
1122                 return try_scrape($self);
1123         }
1124         local $self->{chg} = {};
1125         local $self->{-local_manifest} = load_current_manifest($self);
1126         local $self->{-new_symlinks} = [];
1127         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
1128         return $lei->child_error(1, $multi) if !ref($multi);
1129         my $v2 = delete $multi->{v2};
1130         if ($v2) {
1131                 for my $name (sort keys %$v2) {
1132                         my $epochs = delete $v2->{$name};
1133                         my %v2_epochs = map {
1134                                 $uri->path($n > 1 ? $path_pfx.$path.$_
1135                                                 : $path_pfx.$_);
1136                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
1137                                 $e // die "no [0-9]+\.git in `$uri'";
1138                                 $e => [ $uri->clone, $_ ];
1139                         } @$epochs;
1140                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
1141                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
1142                         local $self->{cur_src} = $1;
1143                         local $self->{cur_dst} = $self->{dst};
1144                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
1145                                                         git/[0-9]+\.git\z!x) {
1146                                 $self->{cur_dst} .= "/$1";
1147                         }
1148                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
1149 E: `$self->{cur_dst}' must not contain newline
1150 EOM
1151                         clone_v2_prep($self, \%v2_epochs, $m);
1152                         return if !keep_going($self);
1153                 }
1154         }
1155         if (my $v1 = delete $multi->{v1}) {
1156                 my $p = $path_pfx.$path;
1157                 chop($p) if substr($p, -1, 1) eq '/';
1158                 $uri->path($p);
1159                 for my $name (@$v1) {
1160                         my $task = bless { %$self }, __PACKAGE__;
1161                         $task->{-ent} = $m->{$name} //
1162                                         die("BUG: no `$name' in manifest");
1163                         $task->{cur_src} = "$uri";
1164                         $task->{cur_dst} = $task->{dst};
1165                         $task->{-key} = $name;
1166                         if ($n > 1) {
1167                                 $task->{cur_dst} .= $name;
1168                                 $task->{cur_src} .= $name;
1169                         }
1170                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
1171 E: `$task->{cur_dst}' must not contain newline
1172 EOM
1173                         $task->{cur_src} .= '/';
1174                         my $dep = $task->{-ent}->{reference} // '';
1175                         push @{$TODO->{$dep}}, $task; # for clone_all
1176                         $self->{any_want}->{$name} = 1;
1177                 }
1178         }
1179         delete local $lei->{opt}->{epoch} if defined($v2);
1180         clone_all($self, $m);
1181         return if $self->{dry_run} || !keep_going($self);
1182
1183         # set by clone_v2_prep/-I/--exclude
1184         my $mis = delete $self->{chg}->{fp_mismatch};
1185         if ($mis) {
1186                 my $t = (stat($ft))[9];
1187                 $t = strftime('%F %k:%M:%S %z', localtime($t));
1188                 warn <<EOM;
1189 W: Fingerprints for the following repositories do not match
1190 W: $mf_url @ $t:
1191 W: These repositories may have updated since $t:
1192 EOM
1193                 warn "\t", $_, "\n" for @$mis;
1194                 warn <<EOM if !$self->{lei}->{opt}->{prune};
1195 W: The above fingerprints may never match without --prune
1196 EOM
1197         }
1198         dump_manifest($m => $ft) if delete($self->{chg}->{manifest}) || $mis;
1199         my $bad = delete $self->{chg}->{badlink};
1200         warn(<<EOM, map { ("\t", $_, "\n") } @$bad) if $bad;
1201 W: The following exist and have not been converted to symlinks
1202 EOM
1203         dump_project_list($self, $m);
1204         ft_rename($ft, $manifest, 0666);
1205         !$self->{chg}->{nr_chg} && $lei->{opt}->{'exit-code'} and
1206                 $lei->child_error(127 << 8);
1207 }
1208
1209 sub start_clone_url {
1210         my ($self) = @_;
1211         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
1212         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
1213 }
1214
1215 sub do_mirror { # via wq_io_do or public-inbox-clone
1216         my ($self) = @_;
1217         my $lei = $self->{lei};
1218         $self->{dry_run} = 1 if $lei->{opt}->{'dry-run'};
1219         umask($lei->{client_umask}) if defined $lei->{client_umask};
1220         $self->{-initial_clone} = 1 if !-d $self->{dst};
1221         local @PUH;
1222         if (defined(my $puh = $lei->{opt}->{'post-update-hook'})) {
1223                 require Text::ParseWords;
1224                 @PUH = map { [ Text::ParseWords::shellwords($_) ] } @$puh;
1225         }
1226         eval {
1227                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
1228                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
1229 --inbox-config must be one of `always', `v2', `v1', or `never'
1230
1231                 # we support these switches with '' (empty string).
1232                 # defaults match example conf distributed with grokmirror
1233                 my @pairs = qw(objstore objstore manifest manifest.js.gz
1234                                 project-list projects.list);
1235                 while (@pairs) {
1236                         my ($k, $default) = splice(@pairs, 0, 2);
1237                         my $v = $lei->{opt}->{$k} // next;
1238                         $v = $default if $v eq '';
1239                         $v = "$self->{dst}/$v" if $v !~ m!\A\.{0,2}/!;
1240                         $self->{"-$k"} = $v;
1241                 }
1242
1243                 local $LIVE = {};
1244                 local $TODO = {};
1245                 local $FGRP_TODO = {};
1246                 my $iv = $lei->{opt}->{'inbox-version'} //
1247                         return start_clone_url($self);
1248                 return clone_v1($self) if $iv == 1;
1249                 die "bad --inbox-version=$iv\n" if $iv != 2;
1250                 die <<EOM if $self->{src} !~ m!://!;
1251 cloning local v2 inboxes not supported
1252 EOM
1253                 try_scrape($self, 1);
1254         };
1255         $lei->fail($@) if $@;
1256 }
1257
1258 sub start {
1259         my ($cls, $lei, $src, $dst) = @_;
1260         my $self = bless { src => $src, dst => $dst }, $cls;
1261         $lei->request_umask;
1262         my ($op_c, $ops) = $lei->workers_start($self, 1);
1263         $lei->{wq1} = $self;
1264         $self->wq_io_do('do_mirror', []);
1265         $self->wq_close;
1266         $lei->wait_wq_events($op_c, $ops);
1267 }
1268
1269 sub ipc_atfork_child {
1270         my ($self) = @_;
1271         $self->{lei}->_lei_atfork_child;
1272         $self->SUPER::ipc_atfork_child;
1273 }
1274
1275 sub write_makefile {
1276         my ($dir, $ibx_ver) = @_;
1277         my $f = "$dir/Makefile";
1278         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
1279                 print $fh <<EOM or die "print($f) $!";
1280 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
1281 # manpage for more information on the format.  This Makefile is
1282 # intended as a familiar wrapper for users unfamiliar with
1283 # public-inbox-* commands.
1284 #
1285 # See the respective manpages for public-inbox-fetch(1),
1286 # public-inbox-index(1), etc for more information on
1287 # some of the commands used by this Makefile.
1288 #
1289 # This Makefile will not be modified nor read by public-inbox,
1290 # so you may edit it freely with your own convenience targets
1291 # and notes.  public-inbox-fetch will recreate it if removed.
1292 EOM
1293                 print $fh <<'EOM' or die "print($f): $!";
1294 # the default target:
1295 help :
1296         @echo Common targets:
1297         @echo '    make fetch        - fetch from remote git repostorie(s)'
1298         @echo '    make update       - fetch and update index '
1299         @echo
1300         @echo Rarely needed targets:
1301         @echo '    make reindex      - may be needed for new features/bugfixes'
1302         @echo '    make compact      - rewrite Xapian storage to save space'
1303         @echo '    make index        - initial index after clone
1304
1305 fetch :
1306         public-inbox-fetch
1307 update :
1308         @if ! public-inbox-fetch --exit-code; \
1309         then \
1310                 c=$$?; \
1311                 test $$c -eq 127 && exit 0; \
1312                 exit $$c; \
1313         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
1314         then \
1315                 public-inbox-index; \
1316         else \
1317                 echo 'public-inbox index not initialized'; \
1318                 echo 'see public-inbox-index(1) man page'; \
1319         fi
1320 index :
1321         public-inbox-index
1322 reindex :
1323         public-inbox-index --reindex
1324 compact :
1325         public-inbox-compact
1326
1327 .PHONY : help fetch update index reindex compact
1328 EOM
1329                 close $fh or die "close($f): $!";
1330         } else {
1331                 die "open($f): $!" unless $!{EEXIST};
1332         }
1333 }
1334
1335 1;