lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::LeiCurl;
  20 use PublicInbox::OnDestroy;
  21 use Digest::SHA qw(sha256_hex sha1_hex);
  22
  23 our $LIVE; # pid => callback
  24
  25 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  26         my ($arg, $pid) = @_;
  27         my ($mrr, $lei) = @$arg;
  28         my $f = "$mrr->{dst}/mirror.done";
  29         if ($?) {
  30                 $lei->child_error($?);
  31         } elsif (!$mrr->{dry_run} && !unlink($f)) {
  32                 warn("unlink($f): $!\n") unless $!{ENOENT};
  33         } else {
  34                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  35                         require PublicInbox::LeiAddExternal;
  36                         PublicInbox::LeiAddExternal::_finish_add_external(
  37                                                         $lei, $mrr->{dst});
  38                 }
  39                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  40         }
  41         $lei->dclose;
  42 }
  43
  44 # for old installations without manifest.js.gz
  45 sub try_scrape {
  46         my ($self, $fallback_manifest) = @_;
  47         my $uri = URI->new($self->{src});
  48         my $lei = $self->{lei};
  49         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  50         my $cmd = $curl->for_uri($lei, $uri, qw(-f --compressed));
  51         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  52         my $fh = popen_rd($cmd, undef, $opt);
  53         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  54         close($fh) or return $lei->child_error($?, "@$cmd failed");
  55
  56         # we grep with URL below, we don't want Subject/From headers
  57         # making us clone random URLs.  This assumes remote instances
  58         # prior to public-inbox 1.7.0
  59         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  60         my @html = split(/<hr>/, $html);
  61         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  62         if (!@urls && $fallback_manifest) {
  63                 warn <<EOM;
  64 W: failed to extract URLs from $uri, trying manifest.js.gz...
  65 EOM
  66                 return start_clone_url($self);
  67         }
  68         my $url = $uri->as_string;
  69         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  70
  71         # since this is for old instances w/o manifest.js.gz, try v1 first
  72         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  73         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  74                 my %v2_epochs = map {
  75                         my ($n) = (m!/([0-9]+)\z!);
  76                         $n => [ URI->new($_), '' ]
  77                 } @v2_urls; # uniq
  78                 clone_v2_prep($self, \%v2_epochs);
  79                 delete local $lei->{opt}->{epoch};
  80                 clone_all($self);
  81                 return;
  82         }
  83
  84         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  85         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  86                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  87                 die <<"";
  88 E: confused by scraping <$uri>, did you mean <$url>?
  89
  90         }
  91         @urls and die <<"";
  92 E: confused by scraping <$uri>, got ambiguous results:
  93 @urls
  94
  95         die "E: scraping <$uri> revealed nothing\n";
  96 }
  97
  98 sub clone_cmd {
  99         my ($lei, $opt) = @_;
 100         my @cmd = qw(git);
 101         $opt->{$_} = $lei->{$_} for (0..2);
 102         # we support "-c $key=$val" for arbitrary git config options
 103         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 104         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 105         push @cmd, qw(clone --mirror);
 106         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 107                         ($lei->{opt}->{jobs} // 1) > 1;
 108         push @cmd, '-v' if $lei->{opt}->{verbose};
 109         # XXX any other options to support?
 110         # --reference is tricky with multiple epochs, but handled
 111         # automatically if using manifest.js.gz
 112         @cmd;
 113 }
 114
 115 sub ft_rename ($$$;$) {
 116         my ($ft, $dst, $open_mode, $fh) = @_;
 117         my @st = stat($fh // $dst);
 118         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 119         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 120         require File::Copy;
 121         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 122         $ft->unlink_on_destroy(0);
 123 }
 124
 125 sub do_reap ($;$) {
 126         my ($self, $jobs) = @_;
 127         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 128         $jobs = 1 if $jobs < 1;
 129         while (keys(%$LIVE) >= $jobs) {
 130                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 131                 if (my $x = delete $LIVE->{$pid}) {
 132                         my $cb = shift @$x;
 133                         $cb->(@$x) if $cb;
 134                 } else {
 135                         warn "reaped unknown PID=$pid ($?)\n";
 136                 }
 137         }
 138 }
 139
 140 sub _get_txt_start { # non-fatal
 141         my ($self, $endpoint, $fini) = @_;
 142         my $uri = URI->new($self->{cur_src} // $self->{src});
 143         my $lei = $self->{lei};
 144         my $path = $uri->path;
 145         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 146         $uri->path("$path/$endpoint");
 147         my $f = (split(m!/!, $endpoint))[-1];
 148         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 149         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 150         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(-f --compressed -R -o),
 151                                         $ft->filename);
 152         do_reap($self);
 153         $lei->qerr("# @$cmd");
 154         return if $self->{dry_run};
 155         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 156         $LIVE->{spawn($cmd, undef, $opt)} =
 157                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 158 }
 159
 160 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 161         my ($self, $endpoint) = @_;
 162         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 163         my $cerr = $?;
 164         $? = 0; # don't influence normal lei exit
 165         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 166         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 167         seek($fh, SEEK_SET, 0) or die "seek: $!";
 168         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 169         local $/;
 170         $self->{"txt.$endpoint"} = <$fh>;
 171         undef; # success
 172 }
 173
 174 sub _write_inbox_config {
 175         my ($self) = @_;
 176         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 177         my $dst = $self->{cur_dst} // $self->{dst};
 178         my $f = "$dst/inbox.config.example";
 179         open my $fh, '>', $f or die "open($f): $!";
 180         print $fh $buf or die "print: $!";
 181         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 182         my $mtime = delete $self->{'mtime._/text/config/raw'};
 183         $fh->flush or die "flush($f): $!";
 184         if (defined $mtime) {
 185                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
 186         }
 187         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 188         my $ibx = $self->{ibx} = {};
 189         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 190                 for (qw(address newsgroup nntpmirror)) {
 191                         $ibx->{$_} = $cfg->{"$sec.$_"};
 192                 }
 193         }
 194 }
 195
 196 sub set_description ($) {
 197         my ($self) = @_;
 198         my $dst = $self->{cur_dst} // $self->{dst};
 199         my $f = "$dst/description";
 200         open my $fh, '+>>', $f or die "open($f): $!";
 201         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 202         my $d = do { local $/; <$fh> } // die "read($f): $!";
 203         chomp(my $orig = $d);
 204         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 205                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 206                 $d = delete($self->{'txt.description'});
 207         }
 208         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 209         chomp $d;
 210         return if $d eq $orig;
 211         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 212         truncate($fh, 0) or die "truncate($f): $!";
 213         print $fh $d, "\n" or die "print($f): $!";
 214         close $fh or die "close($f): $!";
 215 }
 216
 217 sub index_cloned_inbox {
 218         my ($self, $iv) = @_;
 219         my $lei = $self->{lei};
 220
 221         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 222         # lei is useless without Xapian + SQLite
 223         if ($lei->{cmd} ne 'public-inbox-clone') {
 224                 require PublicInbox::InboxWritable;
 225                 require PublicInbox::Admin;
 226                 my $ibx = delete($self->{ibx}) // {
 227                         address => [ 'lei@example.com' ],
 228                         version => $iv,
 229                 };
 230                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 231                 PublicInbox::Inbox->new($ibx);
 232                 PublicInbox::InboxWritable->new($ibx);
 233                 my $opt = {};
 234                 for my $sw ($lei->index_opt) {
 235                         my ($k) = ($sw =~ /\A([\w-]+)/);
 236                         $opt->{$k} = $lei->{opt}->{$k};
 237                 }
 238                 # force synchronous dwaitpid for v2:
 239                 local $PublicInbox::DS::in_loop = 0;
 240                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 241                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 242                 local %ENV = (%ENV, %$env) if $env;
 243                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 244                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 245         }
 246         return if defined $self->{cur_dst}; # one of many repos to clone
 247         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 248 }
 249
 250 sub run_reap {
 251         my ($lei, $cmd, $opt) = @_;
 252         $lei->qerr("# @$cmd");
 253         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 254         my $ret = $?;
 255         $? = 0; # don't let it influence normal exit
 256         $ret;
 257 }
 258
 259 sub start_cmd {
 260         my ($self, $cmd, $opt, $fini) = @_;
 261         do_reap($self);
 262         $self->{lei}->qerr("# @$cmd");
 263         return if $self->{dry_run};
 264         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 265 }
 266
 267 sub fetch_args ($$) {
 268         my ($lei, $opt) = @_;
 269         my @cmd; # (git --git-dir=...) to be added by caller
 270         $opt->{$_} = $lei->{$_} for (0..2);
 271         # we support "-c $key=$val" for arbitrary git config options
 272         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 273         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 274         push @cmd, 'fetch';
 275         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 276                         ($lei->{opt}->{jobs} // 1) > 1;
 277         push @cmd, '-v' if $lei->{opt}->{verbose};
 278         @cmd;
 279 }
 280
 281 sub upr { # feed `git update-ref --stdin -z' verbosely
 282         my ($lei, $w, $op, @rest) = @_; # ($ref, $oid) = @rest
 283         $lei->qerr("# $op @rest") if $lei->{opt}->{verbose};
 284         print $w "$op ", join("\0", @rest, '') or die "print(w): $!";
 285 }
 286
 287 sub fgrp_update {
 288         my ($fgrp) = @_;
 289         my $srcfh = delete $fgrp->{srcfh} or return;
 290         my $dstfh = delete $fgrp->{dstfh} or return;
 291         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 292         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 293         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 294         close $srcfh;
 295         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 296         close $dstfh;
 297         pipe(my ($r, $w)) or die "pipe: $!";
 298         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 299                 qw(update-ref --stdin -z) ];
 300         my $lei = $fgrp->{lei};
 301         $lei->qerr("# @$cmd");
 302         my $opt = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 303         my $pid = spawn($cmd, undef, $opt);
 304         close $r or die "close(r): $!";
 305         for my $ref (keys %dst) {
 306                 my $new = delete $src{$ref};
 307                 my $old = $dst{$ref};
 308                 if (defined $new) {
 309                         $new eq $old or
 310                                 upr($lei, $w, 'update', $ref, $new, $old);
 311                 } else {
 312                         upr($lei, $w, 'delete', $ref, $old);
 313                 }
 314         }
 315         while (my ($ref, $oid) = each %src) {
 316                 upr($lei, $w, 'create', $ref, $oid);
 317         }
 318         close($w) or warn "E: close(update-ref --stdin): $! (need git 1.8.5+)\n";
 319         my $pack = PublicInbox::OnDestroy->new($$, \&pack_dst, $fgrp);
 320         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd, $pack ];
 321 }
 322
 323 sub pack_dst { # packs lightweight satellite repos
 324         my ($fgrp) = @_;
 325         pack_refs($fgrp, $fgrp->{cur_dst});
 326 }
 327
 328 sub pack_refs {
 329         my ($self, $git_dir) = @_;
 330         do_reap($self);
 331         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 332         $self->{lei}->qerr("# @$cmd");
 333         return if $self->{dry_run};
 334         my $opt = { 1 => $self->{lei}->{1}, 2 => $self->{lei}->{2} };
 335         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd ];
 336 }
 337
 338 sub fgrpv_done {
 339         my ($fgrpv) = @_;
 340         return if !$LIVE;
 341         my $pid;
 342         my $first = $fgrpv->[0] // die 'BUG: no fgrpv->[0]';
 343         pack_refs($first, $first->{-osdir}); # objstore refs always packed
 344         for my $fgrp (@$fgrpv) {
 345                 my $rn = $fgrp->{-remote};
 346                 my %opt = map { $_ => $fgrp->{lei}->{$_} } (0..2);
 347
 348                 my $update_ref = $fgrp->{dry_run} ? undef :
 349                         PublicInbox::OnDestroy->new($$, \&fgrp_update, $fgrp);
 350
 351                 my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 352                         "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 353                         "refs/remotes/$rn/" ];
 354                 do_reap($fgrp);
 355                 $fgrp->{lei}->qerr("# @$src >SRC");
 356                 if ($update_ref) {
 357                         open(my $fh, '+>', undef) or die "open(src): $!";
 358                         $pid = spawn($src, undef, { %opt, 1 => $fh });
 359                         $fgrp->{srcfh} = $fh;
 360                         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $src, $update_ref ]
 361                 }
 362                 my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 363                         '--format=%(refname)%00%(objectname)' ];
 364                 do_reap($fgrp);
 365                 $fgrp->{lei}->qerr("# @$dst >DST");
 366                 if ($update_ref) {
 367                         open(my $fh, '+>', undef) or die "open(dst): $!";
 368                         $pid = spawn($dst, undef, { %opt, 1 => $fh });
 369                         $fgrp->{dstfh} = $fh;
 370                         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $dst, $update_ref ]
 371                 }
 372         }
 373 }
 374
 375 sub fgrp_fetch_all {
 376         my ($self) = @_;
 377         my $todo = delete $self->{fgrp_todo} or return;
 378         keys(%$todo) or return;
 379
 380         # Rely on the fgrptmp remote groups in the config file rather
 381         # than listing all remotes since the remote name list may exceed
 382         # system argv limits:
 383         my $grp = 'fgrptmp';
 384
 385         my @git = (@{$self->{-torsocks}}, 'git');
 386         my $j = $self->{lei}->{opt}->{jobs};
 387         my $opt = {};
 388         my @fetch = do {
 389                 local $self->{lei}->{opt}->{jobs} = 1;
 390                 (fetch_args($self->{lei}, $opt),
 391                         qw(--no-tags --multiple));
 392         };
 393         push(@fetch, "-j$j") if $j;
 394         my $pid;
 395         while (my ($osdir, $fgrpv) = each %$todo) {
 396                 my $f = "$osdir/config";
 397
 398                 # clobber group from previous run atomically
 399                 my $cmd = ['git', "--git-dir=$osdir", qw(config -f),
 400                                 $f, '--unset-all', "remotes.$grp"];
 401                 $self->{lei}->qerr("# @$cmd");
 402                 if (!$self->{dry_run}) {
 403                         $pid = spawn($cmd);
 404                         waitpid($pid, 0) // die "waitpid: $!";
 405                         die "E: @$cmd: \$?=$?" if ($? && ($? >> 8) != 5);
 406
 407                         # update the config atomically via O_APPEND while
 408                         # respecting git-config locking
 409                         sysopen(my $lk, "$f.lock", O_CREAT|O_EXCL|O_WRONLY)
 410                                 or die "open($f.lock): $!";
 411                         open my $fh, '>>', $f or die "open(>>$f): $!";
 412                         $fh->autoflush(1);
 413                         my $buf = join('', "[remotes]\n",
 414                                 map { "\t$grp = $_->{-remote}\n" } @$fgrpv);
 415                         print $fh $buf or die "print($f): $!";
 416                         close $fh or die "close($f): $!";
 417                         unlink("$f.lock") or die "unlink($f.lock): $!";
 418                 }
 419
 420                 $cmd = [ @git, "--git-dir=$osdir", @fetch, $grp ];
 421                 do_reap($self);
 422                 $self->{lei}->qerr("# @$cmd");
 423                 my $end = PublicInbox::OnDestroy->new($$, \&fgrpv_done, $fgrpv);
 424                 return if $self->{dry_run};
 425                 $pid = spawn($cmd, undef, $opt);
 426                 $LIVE->{$pid} = [ \&reap_cmd, $self, $cmd, $end ];
 427         }
 428 }
 429
 430 # keep this idempotent for future use by public-inbox-fetch
 431 sub forkgroup_prep {
 432         my ($self, $uri) = @_;
 433         $self->{-ent} // return;
 434         my $os = $self->{-objstore} // return;
 435         my $fg = $self->{-ent}->{forkgroup} // return;
 436         my $dir = "$os/$fg.git";
 437         my @cmd = ('git', "--git-dir=$dir", 'config');
 438         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 439         if (!-d $dir && !$self->{dry_run}) {
 440                 PublicInbox::Import::init_bare($dir);
 441                 for ('repack.useDeltaIslands=true',
 442                                 'pack.island=refs/remotes/([^/]+)/') {
 443                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
 444                 }
 445         }
 446         my $key = $self->{-key} // die 'BUG: no -key';
 447         my $rn = substr(sha256_hex($key), 0, 16);
 448         unless ($self->{dry_run}) {
 449                 # --no-tags is required to avoid conflicts
 450                 for ("url=$uri", "fetch=+refs/*:refs/remotes/$rn/*",
 451                                 'tagopt=--no-tags') {
 452                         my @kv = split(/=/, $_, 2);
 453                         $kv[0] = "remote.$rn.$kv[0]";
 454                         run_die([@cmd, @kv], undef, $opt);
 455                 }
 456         }
 457         if (!-d $self->{cur_dst} && !$self->{dry_run}) {
 458                 my $alt = File::Spec->rel2abs("$dir/objects");
 459                 PublicInbox::Import::init_bare($self->{cur_dst});
 460                 my $o = "$self->{cur_dst}/objects";
 461                 my $f = "$o/info/alternates";
 462                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 463                 open my $fh, '+>>', $f or die "open($f): $!";
 464                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 465                 chomp(my @cur = <$fh>);
 466                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 467                         say $fh $l or die "say($f): $!";
 468                 }
 469                 close $fh or die "close($f): $!";
 470                 $f = "$self->{cur_dst}/config";
 471                 open $fh, '+>>', $f or die "open:($f): $!";
 472                 print $fh <<EOM or die "print($f): $!";
 473 ; rely on the "$rn" remote in the
 474 ; $fg fork group for fetches
 475 ; only uncomment the following iff you detach from fork groups
 476 ; [remote "origin"]
 477 ;       url = $uri
 478 ;       fetch = +refs/*:refs/*
 479 ;       mirror = true
 480 EOM
 481                 close $fh or die "close($f): $!";
 482         }
 483         bless { %$self, -osdir => $dir, -remote => $rn }, __PACKAGE__;
 484 }
 485
 486 sub fp_done {
 487         my ($self, $go_fetch) = @_;
 488         my $fh = delete $self->{-show_ref} // die 'BUG: no show-ref output';
 489         seek($fh, SEEK_SET, 0) or die "seek(show_ref): $!";
 490         $self->{-ent} // die 'BUG: no -ent';
 491         my $A = $self->{-ent}->{fingerprint} // die 'BUG: no fingerprint';
 492         my $B = sha1_hex(do { local $/; <$fh> } // die("read(show_ref): $!"));
 493         return if $A ne $B; # $go_fetch->DESTROY fires
 494         $go_fetch->cancel;
 495         $self->{lei}->qerr("# $self->{-key} up-to-date");
 496 }
 497
 498 sub cmp_fp_fetch {
 499         my ($self, $go_fetch) = @_;
 500         my $dst = $self->{cur_dst} // $self->{dst};
 501         my $cmd = ['git', "--git-dir=$dst", 'show-ref'];
 502         my $opt = { 2 => $self->{lei}->{2} };
 503         open($opt->{1}, '+>', undef) or die "open(tmp): $!";
 504         $self->{-show_ref} = $opt->{1};
 505         my $done = PublicInbox::OnDestroy->new($$, \&fp_done, $self, $go_fetch);
 506         start_cmd($self, $cmd, $opt, $done);
 507 }
 508
 509 sub resume_fetch_maybe {
 510         my ($self, $uri, $fini) = @_;
 511         my $go_fetch = PublicInbox::OnDestroy->new($$, \&resume_fetch, @_);
 512         cmp_fp_fetch($self, $go_fetch) if $self->{-ent} &&
 513                                 defined($self->{-ent}->{fingerprint});
 514 }
 515
 516 sub resume_fetch {
 517         my ($self, $uri, $fini) = @_;
 518         my $dst = $self->{cur_dst} // $self->{dst};
 519         my @git = ('git', "--git-dir=$dst");
 520         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 521         my $rn = 'origin'; # configurable?
 522         for ("url=$uri", "fetch=+refs/*:refs/*", 'mirror=true') {
 523                 my @kv = split(/=/, $_, 2);
 524                 $kv[0] = "remote.$rn.$kv[0]";
 525                 next if $self->{dry_run};
 526                 run_die([@git, 'config', @kv], undef, $opt);
 527         }
 528         my $cmd = [ @{$self->{-torsocks}}, @git,
 529                         fetch_args($self->{lei}, $opt), $rn ];
 530         start_cmd($self, $cmd, $opt, $fini);
 531 }
 532
 533 sub fgrp_enqueue_maybe {
 534         my ($self, $fgrp) = @_;
 535         my $enq = PublicInbox::OnDestroy->new($$, \&fgrp_enqueue, $self, $fgrp);
 536         cmp_fp_fetch($self, $enq) if $self->{-ent} &&
 537                                         defined($self->{-ent}->{fingerprint});
 538         # $enq->DESTROY calls fgrp_enqueue otherwise
 539 }
 540
 541 sub fgrp_enqueue {
 542         my ($self, $fgrp) = @_;
 543         push @{$self->{fgrp_todo}->{$fgrp->{-osdir}}}, $fgrp;
 544 }
 545
 546 sub clone_v1 {
 547         my ($self, $nohang) = @_;
 548         my $lei = $self->{lei};
 549         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 550         my $uri = URI->new($self->{cur_src} // $self->{src});
 551         defined($lei->{opt}->{epoch}) and
 552                 die "$uri is a v1 inbox, --epoch is not supported\n";
 553         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 554         my $dst = $self->{cur_dst} // $self->{dst};
 555         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 556         my $resume = -d $dst;
 557         if (my $fgrp = forkgroup_prep($self, $uri)) {
 558                 $fgrp->{-fini} = $fini;
 559                 $resume ? fgrp_enqueue_maybe($self, $fgrp) :
 560                                 fgrp_enqueue($self, $fgrp);
 561         } elsif ($resume) {
 562                 resume_fetch_maybe($self, $uri, $fini);
 563         } else { # normal clone
 564                 my $cmd = [ @{$self->{-torsocks}},
 565                                 clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 566                 if (defined($self->{-ent})) {
 567                         if (defined(my $ref = $self->{-ent}->{reference})) {
 568                                 -e "$self->{dst}$ref" and
 569                                         push @$cmd, '--reference',
 570                                                 "$self->{dst}$ref";
 571                         }
 572                 }
 573                 start_cmd($self, $cmd, $opt, $fini);
 574         }
 575         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 576                                 /\A(?:always|v1)\z/s) {
 577                 _get_txt_start($self, '_/text/config/raw', $fini);
 578         }
 579
 580         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 581         $self->{'txt.description'} = $d if defined $d;
 582         (!defined($d) && !$nohang) and
 583                 _get_txt_start($self, 'description', $fini);
 584
 585         $nohang or do_reap($self, 1); # for non-manifest clone
 586 }
 587
 588 sub parse_epochs ($$) {
 589         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 590         $opt_epochs // return; # undef => all epochs
 591         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 592         undef($lo) if ($lo // '') eq '';
 593         my $re = qr/\A~?[0-9]+\z/;
 594         if (@extra || (($lo // '0') !~ $re) ||
 595                         (($hi // '0') !~ $re) ||
 596                         !(grep(defined, $lo, $hi))) {
 597                 die <<EOM;
 598 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 599 EOM
 600         }
 601         my @n = sort { $a <=> $b } keys %$v2_epochs;
 602         for (grep(defined, $lo, $hi)) {
 603                 if (/\A[0-9]+\z/) {
 604                         $_ > $n[-1] and die
 605 "`$_' exceeds maximum available epoch ($n[-1])\n";
 606                         $_ < $n[0] and die
 607 "`$_' is lower than minimum available epoch ($n[0])\n";
 608                 } elsif (/\A~([0-9]+)/) {
 609                         my $off = -$1 - 1;
 610                         $n[$off] // die "`$_' is out of range\n";
 611                         $_ = $n[$off];
 612                 } else { die "`$_' not understood\n" }
 613         }
 614         defined($lo) && defined($hi) && $lo > $hi and die
 615 "low value (`$lo') exceeds high (`$hi')\n";
 616         $lo //= $n[0] if $dotdot;
 617         $hi //= $n[-1] if $dotdot;
 618         $hi //= $lo;
 619         my $want = {};
 620         for ($lo..$hi) {
 621                 if (defined $v2_epochs->{$_}) {
 622                         $want->{$_} = 1;
 623                 } else {
 624                         warn
 625 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 626                 }
 627         }
 628         $want
 629 }
 630
 631 sub init_placeholder ($$$) {
 632         my ($src, $edst, $ent) = @_;
 633         PublicInbox::Import::init_bare($edst);
 634         my $f = "$edst/config";
 635         open my $fh, '>>', $f or die "open($f): $!";
 636         print $fh <<EOM or die "print($f): $!";
 637 [remote "origin"]
 638         url = $src
 639         fetch = +refs/*:refs/*
 640         mirror = true
 641
 642 ; This git epoch was created read-only and "public-inbox-fetch"
 643 ; will not fetch updates for it unless write permission is added.
 644 ; Hint: chmod +w $edst
 645 EOM
 646         if (defined($ent->{owner})) {
 647                 print $fh <<EOM or die "print($f): $!";
 648 [gitweb]
 649         owner = $ent->{owner}
 650 EOM
 651         }
 652         close $fh or die "close($f): $!";
 653         my %map = (head => 'HEAD', description => undef);
 654         while (my ($key, $fn) = each %map) {
 655                 my $val = $ent->{$key} // next;
 656                 $fn //= $key;
 657                 $fn = "$edst/$fn";
 658                 open $fh, '>', $fn or die "open($fn): $!";
 659                 print $fh $val, "\n" or die "print($fn): $!";
 660                 close $fh or die "close($fn): $!";
 661         }
 662 }
 663
 664 sub reap_cmd { # async, called via SIGCHLD
 665         my ($self, $cmd) = @_;
 666         my $cerr = $?;
 667         $? = 0; # don't let it influence normal exit
 668         if ($cerr) {
 669                 kill('TERM', keys %$LIVE);
 670                 $self->{lei}->child_error($cerr, "@$cmd failed (\$?=$cerr)");
 671         }
 672 }
 673
 674 sub v1_done { # called via OnDestroy
 675         my ($self) = @_;
 676         return if $self->{dry_run} || !$LIVE;
 677         _write_inbox_config($self);
 678         my $dst = $self->{cur_dst} // $self->{dst};
 679         if (defined(my $o = $self->{-ent} ? $self->{-ent}->{owner} : undef)) {
 680                 run_die([qw(git config -f), "$dst/config", 'gitweb.owner', $o]);
 681         }
 682         my $o = "$dst/objects";
 683         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
 684                 my $base = File::Spec->rel2abs($o);
 685                 my @l = <$fh>;
 686                 my $ft;
 687                 for (@l) {
 688                         next unless m!\A/!;
 689                         $_ = File::Spec->abs2rel($_, $base);
 690                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
 691                                                 DIR => "$o/info");
 692                 }
 693                 if ($ft) {
 694                         print $ft @l or die "print($ft): $!";
 695                         $ft->flush or die "flush($ft): $!";
 696                         ft_rename($ft, $fn, 0666, $fh);
 697                 }
 698         }
 699         eval { set_description($self) };
 700         warn $@ if $@;
 701         return if ($self->{-is_epoch} ||
 702                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 703         write_makefile($dst, 1);
 704         index_cloned_inbox($self, 1);
 705 }
 706
 707 sub v2_done { # called via OnDestroy
 708         my ($self) = @_;
 709         return if $self->{dry_run} || !$LIVE;
 710         my $dst = $self->{cur_dst} // $self->{dst};
 711         require PublicInbox::Lock;
 712         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 713         my $lck = $lk->lock_for_scope($$);
 714         _write_inbox_config($self);
 715         require PublicInbox::MultiGit;
 716         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 717         $mg->fill_alternates;
 718         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 719         for my $edst (@{delete($self->{-read_only}) // []}) {
 720                 my @st = stat($edst) or die "stat($edst): $!";
 721                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 722         }
 723         write_makefile($dst, 2);
 724         undef $lck; # unlock
 725         eval { set_description($self) };
 726         warn $@ if $@;
 727         index_cloned_inbox($self, 2);
 728 }
 729
 730 sub clone_v2_prep ($$;$) {
 731         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 732         my $lei = $self->{lei};
 733         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 734         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 735         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 736         my $dst = $self->{cur_dst} // $self->{dst};
 737         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 738         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 739         delete $task->{todo}; # $self->{todo} still exists
 740         my (@skip, $desc);
 741         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 742         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 743                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 744                 my $src = $uri->as_string;
 745                 my $edst = $dst;
 746                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 747 failed to extract epoch number from $src
 748
 749                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 750                 $edst .= "/git/$nr.git";
 751                 my $ent;
 752                 if ($m) {
 753                         $ent = $m->{$key} //
 754                                 die("BUG: `$key' not in manifest.js.gz");
 755                         if (defined(my $d = $ent->{description})) {
 756                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 757                                 $desc = $d;
 758                         }
 759                 }
 760                 if (!$want || $want->{$nr}) {
 761                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 762                         $etask->{-ent} = $ent; # may have {reference}
 763                         $etask->{cur_src} = $src;
 764                         $etask->{cur_dst} = $edst;
 765                         $etask->{-is_epoch} = $fini;
 766                         my $ref = $ent->{reference} // '';
 767                         push @{$self->{todo}->{$ref}}, $etask;
 768                         $self->{any_want}->{$key} = 1;
 769                 } else { # create a placeholder so users only need to chmod +w
 770                         init_placeholder($src, $edst, $ent);
 771                         push @{$task->{-read_only}}, $edst;
 772                         push @skip, $key;
 773                 }
 774         }
 775         # filter out the epochs we skipped
 776         $self->{-culled_manifest} = 1 if $m && delete(@$m{@skip});
 777
 778         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 779
 780         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 781                 _get_txt_start($task, '_/text/config/raw', $fini);
 782
 783         defined($desc) ? ($task->{'txt.description'} = $desc) :
 784                 _get_txt_start($task, 'description', $fini);
 785 }
 786
 787 sub decode_manifest ($$$) {
 788         my ($fh, $fn, $uri) = @_;
 789         my $js;
 790         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 791         gunzip(\$gz => \$js, MultiStream => 1) or
 792                 die "gunzip($uri): $GunzipError\n";
 793         my $m = eval { PublicInbox::Config->json->decode($js) };
 794         die "$uri: error decoding `$js': $@\n" if $@;
 795         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 796         $m;
 797 }
 798
 799 sub multi_inbox ($$$) {
 800         my ($self, $path, $m) = @_;
 801         my $incl = $self->{lei}->{opt}->{include};
 802         my $excl = $self->{lei}->{opt}->{exclude};
 803
 804         # assuming everything not v2 is v1, for now
 805         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 806         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 807         my $v2 = {};
 808
 809         for (@v2_epochs) {
 810                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 811                 push @{$v2->{$1}}, $_;
 812         }
 813         my $n = scalar(keys %$v2) + scalar(@v1);
 814         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 815         if (defined $incl) {
 816                 my $re = '(?:'.join('\\z|', map {
 817                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 818                         } @$incl).'\\z)';
 819                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 820                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 821                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
 822                 @v1 = grep(/$re/, @v1);
 823         }
 824         if (defined $excl) {
 825                 my $re = '(?:'.join('\\z|', map {
 826                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 827                         } @$excl).'\\z)';
 828                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 829                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 830                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
 831                 @v1 = grep(!/$re/, @v1);
 832         }
 833         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 834         $ret->{v1} = \@v1 if @v1;
 835         $ret->{v2} = $v2 if keys %$v2;
 836         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 837                                 join("\n\t", sort @orig)
 838                         : "Nothing available to clone\n";
 839         my $path_pfx = '';
 840
 841         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 842         if (@v2_epochs) {
 843                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 844                                 @v2_epochs) == @v2_epochs) {
 845                         $$path =~ s!\A(/[^/]+)/!/! or last;
 846                         $path_pfx .= $1;
 847                 }
 848         } elsif (@v1) {
 849                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 850                         $path_pfx .= $1;
 851                 }
 852         }
 853         ($path_pfx, $n, $ret);
 854 }
 855
 856 sub clone_all {
 857         my ($self, $m) = @_;
 858         my $todo = delete $self->{todo};
 859         my $nodep = delete $todo->{''};
 860
 861         # do not download unwanted deps
 862         my $any_want = delete $self->{any_want};
 863         my @unwanted = grep { !$any_want->{$_} } keys %$todo;
 864         my @nodep = delete(@$todo{@unwanted});
 865         push(@$nodep, @$_) for @nodep;
 866
 867         # handle no-dependency repos, first
 868         for (@$nodep) {
 869                 clone_v1($_, 1);
 870                 return if $self->{lei}->{child_error};
 871         }
 872         # resolve references, deepest, first:
 873         while (scalar keys %$todo) {
 874                 for my $x (keys %$todo) {
 875                         my ($nr, $nxt);
 876                         # resolve multi-level references
 877                         while ($m && defined($nxt = $m->{$x}->{reference})) {
 878                                 exists($todo->{$nxt}) or last;
 879                                 die <<EOM if ++$nr > 1000;
 880 E: dependency loop detected (`$x' => `$nxt')
 881 EOM
 882                                 $x = $nxt;
 883                         }
 884                         my $y = delete $todo->{$x} // next; # already done
 885                         for (@$y) {
 886                                 clone_v1($_, 1);
 887                                 return if $self->{lei}->{child_error};
 888                         }
 889                         last; # restart %$todo iteration
 890                 }
 891         }
 892         do_reap($self, 1); # finish all fingerprint checks
 893         fgrp_fetch_all($self);
 894         do_reap($self, 1);
 895 }
 896
 897 sub dump_manifest ($$) {
 898         my ($m, $ft) = @_;
 899         # write the smaller manifest if epochs were skipped so
 900         # users won't have to delete manifest if they +w an
 901         # epoch they no longer want to skip
 902         my $json = PublicInbox::Config->json->encode($m);
 903         my $mtime = (stat($ft))[9];
 904         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
 905         truncate($ft, 0) or die "truncate($ft): $!";
 906         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
 907         $ft->flush or die "flush($ft): $!";
 908         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
 909 }
 910
 911 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
 912 sub try_manifest {
 913         my ($self) = @_;
 914         my $uri = URI->new($self->{src});
 915         my $lei = $self->{lei};
 916         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 917         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 918         my $path = $uri->path;
 919         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 920         $uri->path($path . '/manifest.js.gz');
 921         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX',
 922                                 UNLINK => 1, TMPDIR => 1, SUFFIX => '.tmp');
 923         my $cmd = $curl->for_uri($lei, $uri, qw(-f -R -o), $ft->filename);
 924         my %opt = map { $_ => $lei->{$_} } (0..2);
 925         my $cerr = run_reap($lei, $cmd, \%opt);
 926         if ($cerr) {
 927                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
 928                 return $lei->child_error($cerr, "@$cmd failed");
 929         }
 930         my $m = eval { decode_manifest($ft, $ft, $uri) };
 931         if ($@) {
 932                 warn $@;
 933                 return try_scrape($self);
 934         }
 935         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
 936         return $lei->child_error(1, $multi) if !ref($multi);
 937         my $v2 = delete $multi->{v2};
 938         local $self->{todo} = {};
 939         local $self->{fgrp_todo} = {}; # { objstore_dir => [fgrp, ...] }
 940         if ($v2) {
 941                 for my $name (sort keys %$v2) {
 942                         my $epochs = delete $v2->{$name};
 943                         my %v2_epochs = map {
 944                                 $uri->path($n > 1 ? $path_pfx.$path.$_
 945                                                 : $path_pfx.$_);
 946                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
 947                                 $e // die "no [0-9]+\.git in `$uri'";
 948                                 $e => [ $uri->clone, $_ ];
 949                         } @$epochs;
 950                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
 951                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
 952                         local $self->{cur_src} = $1;
 953                         local $self->{cur_dst} = $self->{dst};
 954                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
 955                                                         git/[0-9]+\.git\z!x) {
 956                                 $self->{cur_dst} .= "/$1";
 957                         }
 958                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
 959 E: `$self->{cur_dst}' must not contain newline
 960 EOM
 961                         clone_v2_prep($self, \%v2_epochs, $m);
 962                         return if $self->{lei}->{child_error};
 963                 }
 964         }
 965         if (my $v1 = delete $multi->{v1}) {
 966                 my $p = $path_pfx.$path;
 967                 chop($p) if substr($p, -1, 1) eq '/';
 968                 $uri->path($p);
 969                 for my $name (@$v1) {
 970                         my $task = bless { %$self }, __PACKAGE__;
 971                         $task->{-ent} = $m->{$name} //
 972                                         die("BUG: no `$name' in manifest");
 973                         $task->{cur_src} = "$uri";
 974                         $task->{cur_dst} = $task->{dst};
 975                         $task->{-key} = $name;
 976                         if ($n > 1) {
 977                                 $task->{cur_dst} .= $name;
 978                                 $task->{cur_src} .= $name;
 979                         }
 980                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
 981 E: `$task->{cur_dst}' must not contain newline
 982 EOM
 983                         $task->{cur_src} .= '/';
 984                         my $dep = $task->{-ent}->{reference} // '';
 985                         push @{$self->{todo}->{$dep}}, $task; # for clone_all
 986                         $self->{any_want}->{$name} = 1;
 987                 }
 988         }
 989         delete local $lei->{opt}->{epoch} if defined($v2);
 990         clone_all($self, $m);
 991         return if $self->{lei}->{child_error} || $self->{dry_run};
 992
 993         # set by clone_v2_prep/-I/--exclude
 994         dump_manifest($m => $ft) if delete $self->{-culled_manifest};
 995         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
 996         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 997 }
 998
 999 sub start_clone_url {
1000         my ($self) = @_;
1001         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
1002         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
1003 }
1004
1005 sub do_mirror { # via wq_io_do or public-inbox-clone
1006         my ($self) = @_;
1007         my $lei = $self->{lei};
1008         $self->{dry_run} = 1 if $lei->{opt}->{'dry-run'};
1009         umask($lei->{client_umask}) if defined $lei->{client_umask};
1010         eval {
1011                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
1012                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
1013 --inbox-config must be one of `always', `v2', `v1', or `never'
1014
1015                 if (defined(my $os = $lei->{opt}->{objstore})) {
1016                         $os = 'objstore' if $os eq ''; # --objstore w/o args
1017                         $os = "$self->{dst}/$os" if $os !~ m!\A/!;
1018                         $self->{-objstore} = $os;
1019                 }
1020                 local $LIVE;
1021                 my $iv = $lei->{opt}->{'inbox-version'} //
1022                         return start_clone_url($self);
1023                 return clone_v1($self) if $iv == 1;
1024                 die "bad --inbox-version=$iv\n" if $iv != 2;
1025                 die <<EOM if $self->{src} !~ m!://!;
1026 cloning local v2 inboxes not supported
1027 EOM
1028                 try_scrape($self, 1);
1029         };
1030         $lei->fail($@) if $@;
1031 }
1032
1033 sub start {
1034         my ($cls, $lei, $src, $dst) = @_;
1035         my $self = bless { src => $src, dst => $dst }, $cls;
1036         $lei->request_umask;
1037         my ($op_c, $ops) = $lei->workers_start($self, 1);
1038         $lei->{wq1} = $self;
1039         $self->wq_io_do('do_mirror', []);
1040         $self->wq_close;
1041         $lei->wait_wq_events($op_c, $ops);
1042 }
1043
1044 sub ipc_atfork_child {
1045         my ($self) = @_;
1046         $self->{lei}->_lei_atfork_child;
1047         $self->SUPER::ipc_atfork_child;
1048 }
1049
1050 sub write_makefile {
1051         my ($dir, $ibx_ver) = @_;
1052         my $f = "$dir/Makefile";
1053         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
1054                 print $fh <<EOM or die "print($f) $!";
1055 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
1056 # manpage for more information on the format.  This Makefile is
1057 # intended as a familiar wrapper for users unfamiliar with
1058 # public-inbox-* commands.
1059 #
1060 # See the respective manpages for public-inbox-fetch(1),
1061 # public-inbox-index(1), etc for more information on
1062 # some of the commands used by this Makefile.
1063 #
1064 # This Makefile will not be modified nor read by public-inbox,
1065 # so you may edit it freely with your own convenience targets
1066 # and notes.  public-inbox-fetch will recreate it if removed.
1067 EOM
1068                 print $fh <<'EOM' or die "print($f): $!";
1069 # the default target:
1070 help :
1071         @echo Common targets:
1072         @echo '    make fetch        - fetch from remote git repostorie(s)'
1073         @echo '    make update       - fetch and update index '
1074         @echo
1075         @echo Rarely needed targets:
1076         @echo '    make reindex      - may be needed for new features/bugfixes'
1077         @echo '    make compact      - rewrite Xapian storage to save space'
1078         @echo '    make index        - initial index after clone
1079
1080 fetch :
1081         public-inbox-fetch
1082 update :
1083         @if ! public-inbox-fetch --exit-code; \
1084         then \
1085                 c=$$?; \
1086                 test $$c -eq 127 && exit 0; \
1087                 exit $$c; \
1088         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
1089         then \
1090                 public-inbox-index; \
1091         else \
1092                 echo 'public-inbox index not initialized'; \
1093                 echo 'see public-inbox-index(1) man page'; \
1094         fi
1095 index :
1096         public-inbox-index
1097 reindex :
1098         public-inbox-index --reindex
1099 compact :
1100         public-inbox-compact
1101
1102 .PHONY : help fetch update index reindex compact
1103 EOM
1104                 close $fh or die "close($f): $!";
1105         } else {
1106                 die "open($f): $!" unless $!{EEXIST};
1107         }
1108 }
1109
1110 1;