lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use v5.12;
   7 use parent qw(PublicInbox::IPC);
   8 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
   9 use IO::Compress::Gzip qw(gzip $GzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  11 use File::Path ();
  12 use File::Temp ();
  13 use File::Spec ();
  14 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  15 use Carp qw(croak);
  16 use URI;
  17 use PublicInbox::Config;
  18 use PublicInbox::Inbox;
  19 use PublicInbox::LeiCurl;
  20 use PublicInbox::OnDestroy;
  21 use Digest::SHA qw(sha256_hex);
  22
  23 our $LIVE; # pid => callback
  24
  25 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  26         my ($arg, $pid) = @_;
  27         my ($mrr, $lei) = @$arg;
  28         my $f = "$mrr->{dst}/mirror.done";
  29         if ($?) {
  30                 $lei->child_error($?);
  31         } elsif (!$mrr->{dry_run} && !unlink($f)) {
  32                 warn("unlink($f): $!\n") unless $!{ENOENT};
  33         } else {
  34                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  35                         require PublicInbox::LeiAddExternal;
  36                         PublicInbox::LeiAddExternal::_finish_add_external(
  37                                                         $lei, $mrr->{dst});
  38                 }
  39                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  40         }
  41         $lei->dclose;
  42 }
  43
  44 # for old installations without manifest.js.gz
  45 sub try_scrape {
  46         my ($self, $fallback_manifest) = @_;
  47         my $uri = URI->new($self->{src});
  48         my $lei = $self->{lei};
  49         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  50         my $cmd = $curl->for_uri($lei, $uri, qw(-f --compressed));
  51         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  52         my $fh = popen_rd($cmd, undef, $opt);
  53         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  54         close($fh) or return $lei->child_error($?, "@$cmd failed");
  55
  56         # we grep with URL below, we don't want Subject/From headers
  57         # making us clone random URLs.  This assumes remote instances
  58         # prior to public-inbox 1.7.0
  59         # 5b96edcb1e0d8252 (www: move mirror instructions to /text/, 2021-08-28)
  60         my @html = split(/<hr>/, $html);
  61         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  62         if (!@urls && $fallback_manifest) {
  63                 warn <<EOM;
  64 W: failed to extract URLs from $uri, trying manifest.js.gz...
  65 EOM
  66                 return start_clone_url($self);
  67         }
  68         my $url = $uri->as_string;
  69         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  70
  71         # since this is for old instances w/o manifest.js.gz, try v1 first
  72         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  73         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  74                 my %v2_epochs = map {
  75                         my ($n) = (m!/([0-9]+)\z!);
  76                         $n => [ URI->new($_), '' ]
  77                 } @v2_urls; # uniq
  78                 clone_v2_prep($self, \%v2_epochs);
  79                 delete local $lei->{opt}->{epoch};
  80                 clone_all($self);
  81                 return;
  82         }
  83
  84         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  85         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  86                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  87                 die <<"";
  88 E: confused by scraping <$uri>, did you mean <$url>?
  89
  90         }
  91         @urls and die <<"";
  92 E: confused by scraping <$uri>, got ambiguous results:
  93 @urls
  94
  95         die "E: scraping <$uri> revealed nothing\n";
  96 }
  97
  98 sub clone_cmd {
  99         my ($lei, $opt) = @_;
 100         my @cmd = qw(git);
 101         $opt->{$_} = $lei->{$_} for (0..2);
 102         # we support "-c $key=$val" for arbitrary git config options
 103         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 104         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 105         push @cmd, qw(clone --mirror);
 106         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 107                         ($lei->{opt}->{jobs} // 1) > 1;
 108         push @cmd, '-v' if $lei->{opt}->{verbose};
 109         # XXX any other options to support?
 110         # --reference is tricky with multiple epochs, but handled
 111         # automatically if using manifest.js.gz
 112         @cmd;
 113 }
 114
 115 sub ft_rename ($$$;$) {
 116         my ($ft, $dst, $open_mode, $fh) = @_;
 117         my @st = stat($fh // $dst);
 118         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 119         chmod($mode, $ft) or croak "E: chmod($ft): $!";
 120         require File::Copy;
 121         File::Copy::mv($ft->filename, $dst) or croak "E: mv($ft => $dst): $!";
 122         $ft->unlink_on_destroy(0);
 123 }
 124
 125 sub do_reap ($;$) {
 126         my ($self, $jobs) = @_;
 127         $jobs //= $self->{-jobs} //= $self->{lei}->{opt}->{jobs} // 1;
 128         $jobs = 1 if $jobs < 1;
 129         while (keys(%$LIVE) >= $jobs) {
 130                 my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 131                 if (my $x = delete $LIVE->{$pid}) {
 132                         my $cb = shift @$x;
 133                         $cb->(@$x) if $cb;
 134                 } else {
 135                         warn "reaped unknown PID=$pid ($?)\n";
 136                 }
 137         }
 138 }
 139
 140 sub _get_txt_start { # non-fatal
 141         my ($self, $endpoint, $fini) = @_;
 142         my $uri = URI->new($self->{cur_src} // $self->{src});
 143         my $lei = $self->{lei};
 144         my $path = $uri->path;
 145         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 146         $uri->path("$path/$endpoint");
 147         my $f = (split(m!/!, $endpoint))[-1];
 148         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 149         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 150         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(-f --compressed -R -o),
 151                                         $ft->filename);
 152         do_reap($self);
 153         $lei->qerr("# @$cmd");
 154         return if $self->{dry_run};
 155         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 156         $LIVE->{spawn($cmd, undef, $opt)} =
 157                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 158 }
 159
 160 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 161         my ($self, $endpoint) = @_;
 162         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 163         my $cerr = $?;
 164         $? = 0; # don't influence normal lei exit
 165         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 166         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 167         seek($fh, SEEK_SET, 0) or die "seek: $!";
 168         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 169         local $/;
 170         $self->{"txt.$endpoint"} = <$fh>;
 171         undef; # success
 172 }
 173
 174 sub _write_inbox_config {
 175         my ($self) = @_;
 176         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 177         my $dst = $self->{cur_dst} // $self->{dst};
 178         my $f = "$dst/inbox.config.example";
 179         open my $fh, '>', $f or die "open($f): $!";
 180         print $fh $buf or die "print: $!";
 181         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 182         my $mtime = delete $self->{'mtime._/text/config/raw'};
 183         $fh->flush or die "flush($f): $!";
 184         if (defined $mtime) {
 185                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
 186         }
 187         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 188         my $ibx = $self->{ibx} = {};
 189         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 190                 for (qw(address newsgroup nntpmirror)) {
 191                         $ibx->{$_} = $cfg->{"$sec.$_"};
 192                 }
 193         }
 194 }
 195
 196 sub set_description ($) {
 197         my ($self) = @_;
 198         my $dst = $self->{cur_dst} // $self->{dst};
 199         my $f = "$dst/description";
 200         open my $fh, '+>>', $f or die "open($f): $!";
 201         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 202         my $d = do { local $/; <$fh> } // die "read($f): $!";
 203         chomp(my $orig = $d);
 204         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 205                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 206                 $d = delete($self->{'txt.description'});
 207         }
 208         $d //= 'mirror of '.($self->{cur_src} // $self->{src});
 209         chomp $d;
 210         return if $d eq $orig;
 211         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 212         truncate($fh, 0) or die "truncate($f): $!";
 213         print $fh $d, "\n" or die "print($f): $!";
 214         close $fh or die "close($f): $!";
 215 }
 216
 217 sub index_cloned_inbox {
 218         my ($self, $iv) = @_;
 219         my $lei = $self->{lei};
 220
 221         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 222         # lei is useless without Xapian + SQLite
 223         if ($lei->{cmd} ne 'public-inbox-clone') {
 224                 require PublicInbox::InboxWritable;
 225                 require PublicInbox::Admin;
 226                 my $ibx = delete($self->{ibx}) // {
 227                         address => [ 'lei@example.com' ],
 228                         version => $iv,
 229                 };
 230                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 231                 PublicInbox::Inbox->new($ibx);
 232                 PublicInbox::InboxWritable->new($ibx);
 233                 my $opt = {};
 234                 for my $sw ($lei->index_opt) {
 235                         my ($k) = ($sw =~ /\A([\w-]+)/);
 236                         $opt->{$k} = $lei->{opt}->{$k};
 237                 }
 238                 # force synchronous dwaitpid for v2:
 239                 local $PublicInbox::DS::in_loop = 0;
 240                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 241                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 242                 local %ENV = (%ENV, %$env) if $env;
 243                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 244                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 245         }
 246         return if defined $self->{cur_dst}; # one of many repos to clone
 247         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 248 }
 249
 250 sub run_reap {
 251         my ($lei, $cmd, $opt) = @_;
 252         $lei->qerr("# @$cmd");
 253         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 254         my $ret = $?;
 255         $? = 0; # don't let it influence normal exit
 256         $ret;
 257 }
 258
 259 sub start_clone {
 260         my ($self, $cmd, $opt, $fini) = @_;
 261         do_reap($self);
 262         $self->{lei}->qerr("# @$cmd");
 263         return if $self->{dry_run};
 264         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd, $fini ]
 265 }
 266
 267 sub fetch_args ($$) {
 268         my ($lei, $opt) = @_;
 269         my @cmd; # (git --git-dir=...) to be added by caller
 270         $opt->{$_} = $lei->{$_} for (0..2);
 271         # we support "-c $key=$val" for arbitrary git config options
 272         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
 273         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
 274         push @cmd, 'fetch';
 275         push @cmd, '-q' if $lei->{opt}->{quiet} ||
 276                         ($lei->{opt}->{jobs} // 1) > 1;
 277         push @cmd, '-v' if $lei->{opt}->{verbose};
 278         @cmd;
 279 }
 280
 281 sub upr { # feed `git update-ref --stdin -z' verbosely
 282         my ($lei, $w, $op, $ref, $oid) = @_;
 283         $lei->qerr("# $op $ref $oid") if $lei->{opt}->{verbose};
 284         print $w "$op $ref\0$oid\0" or die "print(w): $!";
 285 }
 286
 287 sub fgrp_update {
 288         my ($fgrp) = @_;
 289         my $srcfh = delete $fgrp->{srcfh} or return;
 290         my $dstfh = delete $fgrp->{dstfh} or return;
 291         seek($srcfh, SEEK_SET, 0) or die "seek(src): $!";
 292         seek($dstfh, SEEK_SET, 0) or die "seek(dst): $!";
 293         my %src = map { chomp; split(/\0/) } (<$srcfh>);
 294         close $srcfh;
 295         my %dst = map { chomp; split(/\0/) } (<$dstfh>);
 296         close $dstfh;
 297         pipe(my ($r, $w)) or die "pipe: $!";
 298         my $cmd = [ 'git', "--git-dir=$fgrp->{cur_dst}",
 299                 qw(update-ref --stdin -z) ];
 300         my $lei = $fgrp->{lei};
 301         $lei->qerr("# @$cmd");
 302         my $opt = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 303         my $pid = spawn($cmd, undef, $opt);
 304         close $r or die "close(r): $!";
 305         for my $ref (keys %dst) {
 306                 my $new = delete $src{$ref};
 307                 my $old = $dst{$ref};
 308                 if (defined $new) {
 309                         upr($lei, $w, 'update', $ref, $new) if $new ne $old;
 310                 } else {
 311                         upr($lei, $w, 'delete', $ref, $old);
 312                 }
 313         }
 314         while (my ($ref, $oid) = each %src) {
 315                 upr($lei, $w, 'create', $ref, $oid);
 316         }
 317         close($w) or warn "E: close(update-ref --stdin): $! (need git 1.8.5+)\n";
 318         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd ];
 319         do_reap($fgrp);
 320 }
 321
 322 sub pack_refs {
 323         my ($self, $git_dir) = @_;
 324         do_reap($self);
 325         my $cmd = [ 'git', "--git-dir=$git_dir", qw(pack-refs --all --prune) ];
 326         $self->{lei}->qerr("# @$cmd");
 327         my $opt = { 1 => $self->{lei}->{1}, 2 => $self->{lei}->{2} };
 328         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_cmd, $self, $cmd ];
 329 }
 330
 331 sub fgrp_fetched {
 332         my ($fgrp) = @_;
 333         return if $fgrp->{dry_run} || !$LIVE;
 334         my $rn = $fgrp->{-remote};
 335         my %opt = map { $_ => $fgrp->{lei}->{$_} } (0..2);
 336         pack_refs($fgrp, $fgrp->{-osdir}); # objstore refs always packed
 337
 338         my $update_ref = PublicInbox::OnDestroy->new($$, \&fgrp_update, $fgrp);
 339
 340         my $src = [ 'git', "--git-dir=$fgrp->{-osdir}", 'for-each-ref',
 341                 "--format=refs/%(refname:lstrip=3)%00%(objectname)",
 342                 "refs/remotes/$rn/" ];
 343         do_reap($fgrp);
 344         open($fgrp->{srcfh}, '+>', undef) or die "open(src): $!";
 345         $fgrp->{lei}->qerr("# @$src >SRC");
 346         my $pid = spawn($src, undef, { %opt, 1 => $fgrp->{srcfh} });
 347         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $src, $update_ref ];
 348
 349         my $dst = [ 'git', "--git-dir=$fgrp->{cur_dst}", 'for-each-ref',
 350                 '--format=%(refname)%00%(objectname)' ];
 351         do_reap($fgrp);
 352         open($fgrp->{dstfh}, '+>', undef) or die "open(dst): $!";
 353         $fgrp->{lei}->qerr("# @$dst >DST");
 354         $pid = spawn($dst, undef, { %opt, 1 => $fgrp->{dstfh} });
 355         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $dst, $update_ref ];
 356 }
 357
 358 sub fgrp_fetch {
 359         my ($fgrp, $fini) = @_;
 360         my $cmd = [ @{$fgrp->{-torsocks}}, 'git', "--git-dir=$fgrp->{-osdir}",
 361                         fetch_args($fgrp->{lei}, my $opt = {}), '--no-tags',
 362                         $fgrp->{-remote} ];
 363         $fgrp->{-fini} = $fini;
 364         do_reap($fgrp);
 365         $fgrp->{lei}->qerr("# @$cmd");
 366         return if $fgrp->{dry_run};
 367         my $fgrp_fini = PublicInbox::OnDestroy->new($$, \&fgrp_fetched, $fgrp);
 368         my $pid = spawn($cmd, undef, $opt);
 369         $LIVE->{$pid} = [ \&reap_cmd, $fgrp, $cmd, $fgrp_fini ];
 370 }
 371
 372 # keep this idempotent for future use by public-inbox-fetch
 373 sub forkgroup_prep {
 374         my ($self, $uri) = @_;
 375         $self->{-ent} // return;
 376         my $os = $self->{-objstore} // return;
 377         my $fg = $self->{-ent}->{forkgroup} // return;
 378         my $dir = "$os/$fg.git";
 379         my @cmd = ('git', "--git-dir=$dir", 'config');
 380         my $opt = +{ map { $_ => $self->{lei}->{$_} } (0..2) };
 381         if (!-d $dir && !$self->{dry_run}) {
 382                 PublicInbox::Import::init_bare($dir);
 383                 for ('repack.useDeltaIslands=true',
 384                                 'pack.island=refs/remotes/([^/]+)/') {
 385                         run_die([@cmd, split(/=/, $_, 2)], undef, $opt);
 386                 }
 387         }
 388         my $key = $self->{-key} // die 'BUG: no -key';
 389         my $rn = $key;
 390         $rn =~ s!\A[\./]+!!s;
 391         $rn =~ s/\.*?(?:\.git)?\.*?\z//s;
 392         $rn =~ s![\@\{\}/:\?\[\]\^~\s\f[:cntrl:]\*]!_!isg;
 393         $rn .= '-'.substr(sha256_hex($key), 0, 16);
 394         unless ($self->{dry_run}) {
 395                 # --no-tags is required to avoid conflicts
 396                 for ("url=$uri", "fetch=+refs/*:refs/remotes/$rn/*",
 397                                 'tagopt=--no-tags') {
 398                         my @kv = split(/=/, $_, 2);
 399                         $kv[0] = "remote.$rn.$kv[0]";
 400                         run_die([@cmd, @kv], undef, $opt);
 401                 }
 402         }
 403         $self->{-do_pack_refs} = 1; # likely coderepo
 404         if (!-d $self->{cur_dst} && !$self->{dry_run}) {
 405                 my $alt = File::Spec->rel2abs("$dir/objects");
 406                 PublicInbox::Import::init_bare($self->{cur_dst});
 407                 my $o = "$self->{cur_dst}/objects";
 408                 my $f = "$o/info/alternates";
 409                 my $l = File::Spec->abs2rel($alt, File::Spec->rel2abs($o));
 410                 open my $fh, '+>>', $f or die "open($f): $!";
 411                 seek($fh, SEEK_SET, 0) or die "seek($f): $!";
 412                 chomp(my @cur = <$fh>);
 413                 if (!grep(/\A\Q$l\E\z/, @cur)) {
 414                         say $fh $l or die "say($f): $!";
 415                 }
 416                 close $fh or die "close($f): $!";
 417                 $f = "$self->{cur_dst}/config";
 418                 open $fh, '+>>', $f or die "open:($f): $!";
 419                 print $fh <<EOM or die "print($f): $!";
 420 ; rely on the "$rn" remote in the
 421 ; $fg fork group for fetches
 422 ; only uncomment the following iff you detach from fork groups
 423 ; [remote "origin"]
 424 ;       url = $uri
 425 ;       fetch = +refs/*:refs/*
 426 ;       mirror = true
 427 EOM
 428                 close $fh or die "close($f): $!";
 429         }
 430         bless { %$self, -osdir => $dir, -remote => $rn }, __PACKAGE__;
 431 }
 432
 433 sub clone_v1 {
 434         my ($self, $nohang) = @_;
 435         my $lei = $self->{lei};
 436         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 437         my $uri = URI->new($self->{cur_src} // $self->{src});
 438         defined($lei->{opt}->{epoch}) and
 439                 die "$uri is a v1 inbox, --epoch is not supported\n";
 440         $self->{-torsocks} //= $curl->torsocks($lei, $uri) or return;
 441         my $dst = $self->{cur_dst} // $self->{dst};
 442         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 443         my $cmd = [ @{$self->{-torsocks}}, clone_cmd($lei, my $opt = {}),
 444                 "$uri", $dst ];
 445         my $fgrp = forkgroup_prep($self, $uri);
 446         if (!defined($fgrp) && defined($self->{-ent})) {
 447                 if (defined(my $ref = $self->{-ent}->{reference})) {
 448                         -e "$self->{dst}$ref" and
 449                                 push @$cmd, '--reference', "$self->{dst}$ref";
 450                 }
 451         }
 452         $fgrp ? fgrp_fetch($fgrp, $fini) :
 453                 start_clone($self, $cmd, $opt, $fini);
 454
 455         if (!$self->{-is_epoch} && $lei->{opt}->{'inbox-config'} =~
 456                                 /\A(?:always|v1)\z/s) {
 457                 _get_txt_start($self, '_/text/config/raw', $fini);
 458         }
 459
 460         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 461         $self->{'txt.description'} = $d if defined $d;
 462         (!defined($d) && !$nohang) and
 463                 _get_txt_start($self, 'description', $fini);
 464
 465         $nohang or do_reap($self, 1); # for non-manifest clone
 466 }
 467
 468 sub parse_epochs ($$) {
 469         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 470         $opt_epochs // return; # undef => all epochs
 471         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 472         undef($lo) if ($lo // '') eq '';
 473         my $re = qr/\A~?[0-9]+\z/;
 474         if (@extra || (($lo // '0') !~ $re) ||
 475                         (($hi // '0') !~ $re) ||
 476                         !(grep(defined, $lo, $hi))) {
 477                 die <<EOM;
 478 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 479 EOM
 480         }
 481         my @n = sort { $a <=> $b } keys %$v2_epochs;
 482         for (grep(defined, $lo, $hi)) {
 483                 if (/\A[0-9]+\z/) {
 484                         $_ > $n[-1] and die
 485 "`$_' exceeds maximum available epoch ($n[-1])\n";
 486                         $_ < $n[0] and die
 487 "`$_' is lower than minimum available epoch ($n[0])\n";
 488                 } elsif (/\A~([0-9]+)/) {
 489                         my $off = -$1 - 1;
 490                         $n[$off] // die "`$_' is out of range\n";
 491                         $_ = $n[$off];
 492                 } else { die "`$_' not understood\n" }
 493         }
 494         defined($lo) && defined($hi) && $lo > $hi and die
 495 "low value (`$lo') exceeds high (`$hi')\n";
 496         $lo //= $n[0] if $dotdot;
 497         $hi //= $n[-1] if $dotdot;
 498         $hi //= $lo;
 499         my $want = {};
 500         for ($lo..$hi) {
 501                 if (defined $v2_epochs->{$_}) {
 502                         $want->{$_} = 1;
 503                 } else {
 504                         warn
 505 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 506                 }
 507         }
 508         $want
 509 }
 510
 511 sub init_placeholder ($$$) {
 512         my ($src, $edst, $ent) = @_;
 513         PublicInbox::Import::init_bare($edst);
 514         my $f = "$edst/config";
 515         open my $fh, '>>', $f or die "open($f): $!";
 516         print $fh <<EOM or die "print($f): $!";
 517 [remote "origin"]
 518         url = $src
 519         fetch = +refs/*:refs/*
 520         mirror = true
 521
 522 ; This git epoch was created read-only and "public-inbox-fetch"
 523 ; will not fetch updates for it unless write permission is added.
 524 ; Hint: chmod +w $edst
 525 EOM
 526         if (defined($ent->{owner})) {
 527                 print $fh <<EOM or die "print($f): $!";
 528 [gitweb]
 529         owner = $ent->{owner}
 530 EOM
 531         }
 532         close $fh or die "close($f): $!";
 533         my %map = (head => 'HEAD', description => undef);
 534         while (my ($key, $fn) = each %map) {
 535                 my $val = $ent->{$key} // next;
 536                 $fn //= $key;
 537                 $fn = "$edst/$fn";
 538                 open $fh, '>', $fn or die "open($fn): $!";
 539                 print $fh $val, "\n" or die "print($fn): $!";
 540                 close $fh or die "close($fn): $!";
 541         }
 542 }
 543
 544 sub reap_cmd { # async, called via SIGCHLD
 545         my ($self, $cmd) = @_;
 546         my $cerr = $?;
 547         $? = 0; # don't let it influence normal exit
 548         if ($cerr) {
 549                 kill('TERM', keys %$LIVE);
 550                 $self->{lei}->child_error($cerr, "@$cmd failed");
 551         }
 552 }
 553
 554 sub v1_done { # called via OnDestroy
 555         my ($self) = @_;
 556         return if $self->{dry_run} || !$LIVE;
 557         _write_inbox_config($self);
 558         my $dst = $self->{cur_dst} // $self->{dst};
 559         if (defined(my $o = $self->{-ent} ? $self->{-ent}->{owner} : undef)) {
 560                 run_die([qw(git config -f), "$dst/config", 'gitweb.owner', $o]);
 561         }
 562         my $o = "$dst/objects";
 563         if (open(my $fh, '<', my $fn = "$o/info/alternates")) {;
 564                 my $base = File::Spec->rel2abs($o);
 565                 my @l = <$fh>;
 566                 my $ft;
 567                 for (@l) {
 568                         next unless m!\A/!;
 569                         $_ = File::Spec->abs2rel($_, $base);
 570                         $ft //= File::Temp->new(TEMPLATE => '.XXXX',
 571                                                 DIR => "$o/info");
 572                 }
 573                 if ($ft) {
 574                         print $ft @l or die "print($ft): $!";
 575                         $ft->flush or die "flush($ft): $!";
 576                         ft_rename($ft, $fn, 0666, $fh);
 577                 }
 578         }
 579         pack_refs($self, $dst) if delete $self->{-do_pack_refs};
 580         eval { set_description($self) };
 581         warn $@ if $@;
 582         return if ($self->{-is_epoch} ||
 583                 $self->{lei}->{opt}->{'inbox-config'} ne 'always');
 584         write_makefile($dst, 1);
 585         index_cloned_inbox($self, 1);
 586 }
 587
 588 sub v2_done { # called via OnDestroy
 589         my ($self) = @_;
 590         return if $self->{dry_run} || !$LIVE;
 591         my $dst = $self->{cur_dst} // $self->{dst};
 592         require PublicInbox::Lock;
 593         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 594         my $lck = $lk->lock_for_scope($$);
 595         _write_inbox_config($self);
 596         require PublicInbox::MultiGit;
 597         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 598         $mg->fill_alternates;
 599         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 600         for my $edst (@{delete($self->{-read_only}) // []}) {
 601                 my @st = stat($edst) or die "stat($edst): $!";
 602                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 603         }
 604         write_makefile($dst, 2);
 605         undef $lck; # unlock
 606         eval { set_description($self) };
 607         warn $@ if $@;
 608         index_cloned_inbox($self, 2);
 609 }
 610
 611 sub clone_v2_prep ($$;$) {
 612         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 613         my $lei = $self->{lei};
 614         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 615         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 616         $self->{-torsocks} //= $curl->torsocks($lei, $first_uri) or return;
 617         my $dst = $self->{cur_dst} // $self->{dst};
 618         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 619         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 620         delete $task->{todo}; # $self->{todo} still exists
 621         my (@skip, $desc);
 622         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 623         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 624                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 625                 my $src = $uri->as_string;
 626                 my $edst = $dst;
 627                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 628 failed to extract epoch number from $src
 629
 630                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 631                 $edst .= "/git/$nr.git";
 632                 my $ent;
 633                 if ($m) {
 634                         $ent = $m->{$key} //
 635                                 die("BUG: `$key' not in manifest.js.gz");
 636                         if (defined(my $d = $ent->{description})) {
 637                                 $d =~ s/ \[epoch [0-9]+\]\z//s;
 638                                 $desc = $d;
 639                         }
 640                 }
 641                 if (!$want || $want->{$nr}) {
 642                         my $etask = bless { %$task, -key => $key }, __PACKAGE__;
 643                         $etask->{-ent} = $ent; # may have {reference}
 644                         $etask->{cur_src} = $src;
 645                         $etask->{cur_dst} = $edst;
 646                         $etask->{-is_epoch} = $fini;
 647                         my $ref = $ent->{reference} // '';
 648                         push @{$self->{todo}->{$ref}}, $etask;
 649                         $self->{any_want}->{$key} = 1;
 650                 } else { # create a placeholder so users only need to chmod +w
 651                         init_placeholder($src, $edst, $ent);
 652                         push @{$task->{-read_only}}, $edst;
 653                         push @skip, $key;
 654                 }
 655         }
 656         # filter out the epochs we skipped
 657         $self->{-culled_manifest} = 1 if $m && delete(@$m{@skip});
 658
 659         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 660
 661         $lei->{opt}->{'inbox-config'} =~ /\A(?:always|v2)\z/s and
 662                 _get_txt_start($task, '_/text/config/raw', $fini);
 663
 664         defined($desc) ? ($task->{'txt.description'} = $desc) :
 665                 _get_txt_start($task, 'description', $fini);
 666 }
 667
 668 sub decode_manifest ($$$) {
 669         my ($fh, $fn, $uri) = @_;
 670         my $js;
 671         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 672         gunzip(\$gz => \$js, MultiStream => 1) or
 673                 die "gunzip($uri): $GunzipError\n";
 674         my $m = eval { PublicInbox::Config->json->decode($js) };
 675         die "$uri: error decoding `$js': $@\n" if $@;
 676         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 677         $m;
 678 }
 679
 680 sub multi_inbox ($$$) {
 681         my ($self, $path, $m) = @_;
 682         my $incl = $self->{lei}->{opt}->{include};
 683         my $excl = $self->{lei}->{opt}->{exclude};
 684
 685         # assuming everything not v2 is v1, for now
 686         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 687         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 688         my $v2 = {};
 689
 690         for (@v2_epochs) {
 691                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 692                 push @{$v2->{$1}}, $_;
 693         }
 694         my $n = scalar(keys %$v2) + scalar(@v1);
 695         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 696         if (defined $incl) {
 697                 my $re = '(?:'.join('\\z|', map {
 698                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 699                         } @$incl).'\\z)';
 700                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 701                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 702                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
 703                 @v1 = grep(/$re/, @v1);
 704         }
 705         if (defined $excl) {
 706                 my $re = '(?:'.join('\\z|', map {
 707                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E/
 708                         } @$excl).'\\z)';
 709                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 710                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 711                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
 712                 @v1 = grep(!/$re/, @v1);
 713         }
 714         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 715         $ret->{v1} = \@v1 if @v1;
 716         $ret->{v2} = $v2 if keys %$v2;
 717         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 718                                 join("\n\t", sort @orig)
 719                         : "Nothing available to clone\n";
 720         my $path_pfx = '';
 721
 722         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 723         if (@v2_epochs) {
 724                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 725                                 @v2_epochs) == @v2_epochs) {
 726                         $$path =~ s!\A(/[^/]+)/!/! or last;
 727                         $path_pfx .= $1;
 728                 }
 729         } elsif (@v1) {
 730                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 731                         $path_pfx .= $1;
 732                 }
 733         }
 734         ($path_pfx, $n, $ret);
 735 }
 736
 737 sub clone_all {
 738         my ($self, $m) = @_;
 739         my $todo = delete $self->{todo};
 740         my $nodep = delete $todo->{''};
 741
 742         # do not download unwanted deps
 743         my $any_want = delete $self->{any_want};
 744         my @unwanted = grep { !$any_want->{$_} } keys %$todo;
 745         my @nodep = delete(@$todo{@unwanted});
 746         push(@$nodep, @$_) for @nodep;
 747
 748         # handle no-dependency repos, first
 749         for (@$nodep) {
 750                 clone_v1($_, 1);
 751                 return if $self->{lei}->{child_error};
 752         }
 753         # resolve references, deepest, first:
 754         while (scalar keys %$todo) {
 755                 for my $x (keys %$todo) {
 756                         my ($nr, $nxt);
 757                         # resolve multi-level references
 758                         while ($m && defined($nxt = $m->{$x}->{reference})) {
 759                                 exists($todo->{$nxt}) or last;
 760                                 die <<EOM if ++$nr > 1000;
 761 E: dependency loop detected (`$x' => `$nxt')
 762 EOM
 763                                 $x = $nxt;
 764                         }
 765                         my $y = delete $todo->{$x} // next; # already done
 766                         for (@$y) {
 767                                 clone_v1($_, 1);
 768                                 return if $self->{lei}->{child_error};
 769                         }
 770                         last; # restart %$todo iteration
 771                 }
 772         }
 773         do_reap($self, 1);
 774 }
 775
 776 sub dump_manifest ($$) {
 777         my ($m, $ft) = @_;
 778         # write the smaller manifest if epochs were skipped so
 779         # users won't have to delete manifest if they +w an
 780         # epoch they no longer want to skip
 781         my $json = PublicInbox::Config->json->encode($m);
 782         my $mtime = (stat($ft))[9];
 783         seek($ft, SEEK_SET, 0) or die "seek($ft): $!";
 784         truncate($ft, 0) or die "truncate($ft): $!";
 785         gzip(\$json => $ft) or die "gzip($ft): $GzipError";
 786         $ft->flush or die "flush($ft): $!";
 787         utime($mtime, $mtime, "$ft") or die "utime(..., $ft): $!";
 788 }
 789
 790 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
 791 sub try_manifest {
 792         my ($self) = @_;
 793         my $uri = URI->new($self->{src});
 794         my $lei = $self->{lei};
 795         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 796         my $path = $uri->path;
 797         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 798         $uri->path($path . '/manifest.js.gz');
 799         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX',
 800                                 UNLINK => 1, TMPDIR => 1, SUFFIX => '.tmp');
 801         my $cmd = $curl->for_uri($lei, $uri, qw(-f -R -o), $ft->filename);
 802         my %opt = map { $_ => $lei->{$_} } (0..2);
 803         my $cerr = run_reap($lei, $cmd, \%opt);
 804         if ($cerr) {
 805                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
 806                 return $lei->child_error($cerr, "@$cmd failed");
 807         }
 808         my $m = eval { decode_manifest($ft, $ft, $uri) };
 809         if ($@) {
 810                 warn $@;
 811                 return try_scrape($self);
 812         }
 813         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
 814         return $lei->child_error(1, $multi) if !ref($multi);
 815         my $v2 = delete $multi->{v2};
 816         local $self->{todo} = {};
 817         if ($v2) {
 818                 for my $name (sort keys %$v2) {
 819                         my $epochs = delete $v2->{$name};
 820                         my %v2_epochs = map {
 821                                 $uri->path($n > 1 ? $path_pfx.$path.$_
 822                                                 : $path_pfx.$_);
 823                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
 824                                 $e // die "no [0-9]+\.git in `$uri'";
 825                                 $e => [ $uri->clone, $_ ];
 826                         } @$epochs;
 827                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
 828                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
 829                         local $self->{cur_src} = $1;
 830                         local $self->{cur_dst} = $self->{dst};
 831                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
 832                                                         git/[0-9]+\.git\z!x) {
 833                                 $self->{cur_dst} .= "/$1";
 834                         }
 835                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
 836 E: `$self->{cur_dst}' must not contain newline
 837 EOM
 838                         clone_v2_prep($self, \%v2_epochs, $m);
 839                         return if $self->{lei}->{child_error};
 840                 }
 841         }
 842         if (my $v1 = delete $multi->{v1}) {
 843                 my $p = $path_pfx.$path;
 844                 chop($p) if substr($p, -1, 1) eq '/';
 845                 $uri->path($p);
 846                 for my $name (@$v1) {
 847                         my $task = bless { %$self }, __PACKAGE__;
 848                         $task->{-ent} = $m->{$name} //
 849                                         die("BUG: no `$name' in manifest");
 850                         $task->{cur_src} = "$uri";
 851                         $task->{cur_dst} = $task->{dst};
 852                         $task->{-key} = $name;
 853                         if ($n > 1) {
 854                                 $task->{cur_dst} .= $name;
 855                                 $task->{cur_src} .= $name;
 856                         }
 857                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
 858 E: `$task->{cur_dst}' must not contain newline
 859 EOM
 860                         $task->{cur_src} .= '/';
 861                         my $dep = $task->{-ent}->{reference} // '';
 862                         push @{$self->{todo}->{$dep}}, $task; # for clone_all
 863                         $self->{any_want}->{$name} = 1;
 864                 }
 865         }
 866         delete local $lei->{opt}->{epoch} if defined($v2);
 867         clone_all($self, $m);
 868         return if $self->{lei}->{child_error} || $self->{dry_run};
 869
 870         # set by clone_v2_prep/-I/--exclude
 871         dump_manifest($m => $ft) if delete $self->{-culled_manifest};
 872         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
 873         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 874 }
 875
 876 sub start_clone_url {
 877         my ($self) = @_;
 878         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 879         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 880 }
 881
 882 sub do_mirror { # via wq_io_do or public-inbox-clone
 883         my ($self) = @_;
 884         my $lei = $self->{lei};
 885         umask($lei->{client_umask}) if defined $lei->{client_umask};
 886         eval {
 887                 my $ic = $lei->{opt}->{'inbox-config'} //= 'always';
 888                 $ic =~ /\A(?:v1|v2|always|never)\z/s or die <<"";
 889 --inbox-config must be one of `always', `v2', `v1', or `never'
 890
 891                 if (defined(my $os = $lei->{opt}->{objstore})) {
 892                         $os = 'objstore' if $os eq ''; # --objstore w/o args
 893                         $os = "$self->{dst}/$os" if $os !~ m!\A/!;
 894                         $self->{-objstore} = $os;
 895                 }
 896                 local $LIVE;
 897                 my $iv = $lei->{opt}->{'inbox-version'} //
 898                         return start_clone_url($self);
 899                 return clone_v1($self) if $iv == 1;
 900                 die "bad --inbox-version=$iv\n" if $iv != 2;
 901                 die <<EOM if $self->{src} !~ m!://!;
 902 cloning local v2 inboxes not supported
 903 EOM
 904                 try_scrape($self, 1);
 905         };
 906         $lei->fail($@) if $@;
 907 }
 908
 909 sub start {
 910         my ($cls, $lei, $src, $dst) = @_;
 911         my $self = bless { src => $src, dst => $dst }, $cls;
 912         $lei->request_umask;
 913         my ($op_c, $ops) = $lei->workers_start($self, 1);
 914         $lei->{wq1} = $self;
 915         $self->wq_io_do('do_mirror', []);
 916         $self->wq_close;
 917         $lei->wait_wq_events($op_c, $ops);
 918 }
 919
 920 sub ipc_atfork_child {
 921         my ($self) = @_;
 922         $self->{lei}->_lei_atfork_child;
 923         $self->SUPER::ipc_atfork_child;
 924 }
 925
 926 sub write_makefile {
 927         my ($dir, $ibx_ver) = @_;
 928         my $f = "$dir/Makefile";
 929         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
 930                 print $fh <<EOM or die "print($f) $!";
 931 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
 932 # manpage for more information on the format.  This Makefile is
 933 # intended as a familiar wrapper for users unfamiliar with
 934 # public-inbox-* commands.
 935 #
 936 # See the respective manpages for public-inbox-fetch(1),
 937 # public-inbox-index(1), etc for more information on
 938 # some of the commands used by this Makefile.
 939 #
 940 # This Makefile will not be modified nor read by public-inbox,
 941 # so you may edit it freely with your own convenience targets
 942 # and notes.  public-inbox-fetch will recreate it if removed.
 943 EOM
 944                 print $fh <<'EOM' or die "print($f): $!";
 945 # the default target:
 946 help :
 947         @echo Common targets:
 948         @echo '    make fetch        - fetch from remote git repostorie(s)'
 949         @echo '    make update       - fetch and update index '
 950         @echo
 951         @echo Rarely needed targets:
 952         @echo '    make reindex      - may be needed for new features/bugfixes'
 953         @echo '    make compact      - rewrite Xapian storage to save space'
 954         @echo '    make index        - initial index after clone
 955
 956 fetch :
 957         public-inbox-fetch
 958 update :
 959         @if ! public-inbox-fetch --exit-code; \
 960         then \
 961                 c=$$?; \
 962                 test $$c -eq 127 && exit 0; \
 963                 exit $$c; \
 964         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
 965         then \
 966                 public-inbox-index; \
 967         else \
 968                 echo 'public-inbox index not initialized'; \
 969                 echo 'see public-inbox-index(1) man page'; \
 970         fi
 971 index :
 972         public-inbox-index
 973 reindex :
 974         public-inbox-index --reindex
 975 compact :
 976         public-inbox-compact
 977
 978 .PHONY : help fetch update index reindex compact
 979 EOM
 980                 close $fh or die "close($f): $!";
 981         } else {
 982                 die "open($f): $!" unless $!{EEXIST};
 983         }
 984 }
 985
 986 1;