lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support
   5 package PublicInbox::LeiMirror;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
  10 use PublicInbox::Spawn qw(popen_rd spawn);
  11
  12 sub do_finish_mirror { # dwaitpid callback
  13         my ($arg, $pid) = @_;
  14         my ($mrr, $lei) = @$arg;
  15         if ($? == 0 && unlink("$mrr->{dst}/mirror.done")) {
  16                 $lei->add_external_finish($mrr->{dst});
  17         }
  18         $lei->dclose;
  19 }
  20
  21 sub mirror_done { # EOF callback for main daemon
  22         my ($lei) = @_;
  23         my $mrr = delete $lei->{mrr} or return;
  24         $mrr->wq_wait_old(\&do_finish_mirror, $lei);
  25 }
  26
  27 # for old installations without manifest.js.gz
  28 sub try_scrape {
  29         my ($self) = @_;
  30         my $uri = URI->new($self->{src});
  31         my $lei = $self->{lei};
  32         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  33         my $cmd = $curl->for_uri($lei, $uri, '--compressed');
  34         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  35         my $fh = popen_rd($cmd, $lei->{env}, $opt);
  36         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  37         close($fh) or return $lei->child_error($?, "@$cmd failed");
  38
  39         # we grep with URL below, we don't want Subject/From headers
  40         # making us clone random URLs
  41         my @urls = ($html =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  42         my $url = $uri->as_string;
  43         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  44
  45         # since this is for old instances w/o manifest.js.gz, try v1 first
  46         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  47         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  48                 my %v2_uris = map { $_ => URI->new($_) } @v2_urls; # uniq
  49                 return clone_v2($self, [ values %v2_uris ]);
  50         }
  51
  52         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  53         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  54                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  55                 die <<"";
  56 E: confused by scraping <$uri>, did you mean <$url>?
  57
  58         }
  59         @urls and die <<"";
  60 E: confused by scraping <$uri>, got ambiguous results:
  61 @urls
  62
  63         die "E: scraping <$uri> revealed nothing\n";
  64 }
  65
  66 sub clone_cmd {
  67         my ($lei, $opt) = @_;
  68         my @cmd = qw(git);
  69         $opt->{$_} = $lei->{$_} for (0..2);
  70         # we support "-c $key=$val" for arbitrary git config options
  71         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
  72         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
  73         push @cmd, qw(clone --mirror);
  74         push @cmd, '-q' if $lei->{opt}->{quiet};
  75         push @cmd, '-v' if $lei->{opt}->{verbose};
  76         # XXX any other options to support?
  77         # --reference is tricky with multiple epochs...
  78         @cmd;
  79 }
  80
  81 # tries the relatively new /$INBOX/_/text/config/raw endpoint
  82 sub _try_config {
  83         my ($self) = @_;
  84         my $dst = $self->{dst};
  85         if (!-d $dst || !mkdir($dst)) {
  86                 require File::Path;
  87                 File::Path::mkpath($dst);
  88                 -d $dst or die "mkpath($dst): $!\n";
  89         }
  90         my $uri = URI->new($self->{src});
  91         my $lei = $self->{lei};
  92         my $path = $uri->path;
  93         chop($path) eq '/' or die "BUG: $uri not canonicalized";
  94         $uri->path($path . '/_/text/config/raw');
  95         my $cmd = $self->{curl}->for_uri($lei, $uri, '--compressed');
  96         my $ce = "$dst/inbox.config.example";
  97         my $f = "$ce-$$.tmp";
  98         open(my $fh, '+>', $f) or return $lei->err("open $f: $! (non-fatal)");
  99         my $opt = { 0 => $lei->{0}, 1 => $fh, 2 => $lei->{2} };
 100         my $cerr = run_reap($lei, $cmd, $opt) // return;
 101         if (($cerr >> 8) == 22) { # 404 missing
 102                 unlink($f) if -s $fh == 0;
 103                 return;
 104         }
 105         return $lei->err("# @$cmd failed (non-fatal)") if $cerr;
 106         rename($f, $ce) or return $lei->err("link($f, $ce): $! (non-fatal)");
 107         my $cfg = PublicInbox::Config::git_config_dump($f);
 108         my $ibx = $self->{ibx} = {};
 109         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 110                 for (qw(address newsgroup nntpmirror)) {
 111                         $ibx->{$_} = $cfg->{"$sec.$_"};
 112                 }
 113         }
 114 }
 115
 116 sub index_cloned_inbox {
 117         my ($self, $iv) = @_;
 118         my $ibx = delete($self->{ibx}) // {
 119                 address => [ 'lei@example.com' ],
 120                 version => $iv,
 121         };
 122         $ibx->{inboxdir} = $self->{dst};
 123         PublicInbox::Inbox->new($ibx);
 124         PublicInbox::InboxWritable->new($ibx);
 125         my $opt = {};
 126         my $lei = $self->{lei};
 127         for my $sw ($lei->index_opt) {
 128                 my ($k) = ($sw =~ /\A([\w-]+)/);
 129                 $opt->{$k} = $lei->{opt}->{$k};
 130         }
 131         # force synchronous dwaitpid for v2:
 132         local $PublicInbox::DS::in_loop = 0;
 133         my $cfg = PublicInbox::Config->new;
 134         my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 135         local %ENV = (%ENV, %$env) if $env;
 136         PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 137         PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 138         open my $x, '>', "$self->{dst}/mirror.done"; # for do_finish_mirror
 139 }
 140
 141 sub run_reap {
 142         my ($lei, $cmd, $opt) = @_;
 143         $lei->qerr("# @$cmd");
 144         $opt->{pgid} = 0;
 145         my $pid = spawn($cmd, $lei->{env}, $opt);
 146         my $reap = PublicInbox::OnDestroy->new($lei->can('sigint_reap'), $pid);
 147         my $err = waitpid($pid, 0) == $pid ? undef : "waitpid @$cmd: $!";
 148         @$reap = (); # cancel reap
 149         $err ? $lei->err($err) : $?
 150 }
 151
 152 sub clone_v1 {
 153         my ($self) = @_;
 154         my $lei = $self->{lei};
 155         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 156         my $uri = URI->new($self->{src});
 157         my $pfx = $curl->torsocks($lei, $uri) or return;
 158         my $cmd = [ @$pfx, clone_cmd($lei, my $opt = {}),
 159                         $uri->as_string, $self->{dst} ];
 160         my $cerr = run_reap($lei, $cmd, $opt) // return;
 161         return $lei->child_error($cerr, "@$cmd failed") if $cerr;
 162         _try_config($self);
 163         index_cloned_inbox($self, 1);
 164 }
 165
 166 sub clone_v2 {
 167         my ($self, $v2_uris) = @_;
 168         my $lei = $self->{lei};
 169         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 170         my $pfx //= $curl->torsocks($lei, $v2_uris->[0]) or return;
 171         my @epochs;
 172         my $dst = $self->{dst};
 173         my @src_edst;
 174         for my $uri (@$v2_uris) {
 175                 my $src = $uri->as_string;
 176                 my $edst = $dst;
 177                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 178 failed to extract epoch number from $src
 179
 180                 my $nr = $1 + 0;
 181                 $edst .= "/git/$nr.git";
 182                 push @src_edst, [ $src, $edst ];
 183         }
 184         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 185         _try_config($self);
 186         my $on_destroy = $lk->lock_for_scope($$);
 187         my @cmd = clone_cmd($lei, my $opt = {});
 188         while (my $pair = shift(@src_edst)) {
 189                 my $cmd = [ @$pfx, @cmd, @$pair ];
 190                 my $cerr = run_reap($lei, $cmd, $opt) // return;
 191                 return $lei->child_error($cerr, "@$cmd failed") if $cerr;
 192         }
 193         undef $on_destroy; # unlock
 194         index_cloned_inbox($self, 2);
 195 }
 196
 197 sub try_manifest {
 198         my ($self) = @_;
 199         my $uri = URI->new($self->{src});
 200         my $lei = $self->{lei};
 201         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 202         my $path = $uri->path;
 203         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 204         $uri->path($path . '/manifest.js.gz');
 205         my $cmd = $curl->for_uri($lei, $uri);
 206         $lei->qerr("# @$cmd");
 207         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
 208         my ($fh, $pid) = popen_rd($cmd, $lei->{env}, $opt);
 209         my $reap = PublicInbox::OnDestroy->new($lei->can('sigint_reap'), $pid);
 210         my $gz = do { local $/; <$fh> } // die "read(curl $uri): $!";
 211         close $fh;
 212         my $err = waitpid($pid, 0) == $pid ? undef : "waitpid @$cmd: $!";
 213         @$reap = ();
 214         return $lei->err($err) if $err;
 215         if ($?) {
 216                 return try_scrape($self) if ($? >> 8) == 22; # 404 missing
 217                 return $lei->child_error($?, "@$cmd failed");
 218         }
 219         my $js;
 220         gunzip(\$gz => \$js, MultiStream => 1) or
 221                 die "gunzip($uri): $GunzipError";
 222         my $m = eval { PublicInbox::Config->json->decode($js) };
 223         die "$uri: error decoding `$js': $@" if $@;
 224         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 225
 226         my $v1_bare = $m->{$path};
 227         my @v2_epochs = grep(m!\A\Q$path\E/git/[0-9]+\.git\z!, keys %$m);
 228         if (@v2_epochs) {
 229                 # It may be possible to have v1 + v2 in parallel someday:
 230                 $lei->err(<<EOM) if defined $v1_bare;
 231 # `$v1_bare' appears to be a v1 inbox while v2 epochs exist:
 232 # @v2_epochs
 233 # ignoring $v1_bare (use --inbox-version=1 to force v1 instead)
 234 EOM
 235                 @v2_epochs = map { $uri->path($_); $uri->clone } @v2_epochs;
 236                 clone_v2($self, \@v2_epochs);
 237         } elsif ($v1_bare) {
 238                 clone_v1($self);
 239         } elsif (my @maybe = grep(m!\Q$path\E!, keys %$m)) {
 240                 die "E: confused by <$uri>, possible matches:\n@maybe";
 241         } else {
 242                 die "E: confused by <$uri>";
 243         }
 244 }
 245
 246 sub start_clone_url {
 247         my ($self) = @_;
 248         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 249         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 250 }
 251
 252 sub do_mirror { # via wq_io_do
 253         my ($self) = @_;
 254         my $lei = $self->{lei};
 255         eval {
 256                 my $iv = $lei->{opt}->{'inbox-version'};
 257                 if (defined $iv) {
 258                         return clone_v1($self) if $iv == 1;
 259                         return try_scrape($self) if $iv == 2;
 260                         die "bad --inbox-version=$iv\n";
 261                 }
 262                 return start_clone_url($self) if $self->{src} =~ m!://!;
 263                 die "TODO: cloning local directories not supported, yet";
 264         };
 265         return $lei->fail($@) if $@;
 266         $lei->qerr("# mirrored $self->{src} => $self->{dst}");
 267 }
 268
 269 sub start {
 270         my ($cls, $lei, $src, $dst) = @_;
 271         my $self = bless { lei => $lei, src => $src, dst => $dst }, $cls;
 272         $lei->{mrr} = $self;
 273         if ($src =~ m!https?://!) {
 274                 require URI;
 275                 require PublicInbox::LeiCurl;
 276         }
 277         require PublicInbox::Lock;
 278         require PublicInbox::Inbox;
 279         require PublicInbox::Admin;
 280         require PublicInbox::InboxWritable;
 281         my $op = $lei->workers_start($self, 'lei_mirror', 1, {
 282                 '' => [ \&mirror_done, $lei ]
 283         });
 284         $self->wq_io_do('do_mirror', []);
 285         $self->wq_close(1);
 286         while ($op && $op->{sock}) { $op->event_step }
 287 }
 288
 289 sub ipc_atfork_child {
 290         my ($self) = @_;
 291         $self->{lei}->lei_atfork_child;
 292         $SIG{TERM} = sub { exit(128 + 15) }; # trigger OnDestroy $reap
 293         $self->SUPER::ipc_atfork_child;
 294 }
 295
 296 1;