lib/PublicInbox/LeiNoteEvent.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # internal command for dealing with inotify, kqueue vnodes, etc
   5 # it is a semi-persistent worker
   6 package PublicInbox::LeiNoteEvent;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::IPC);
  10 use PublicInbox::DS;
  11
  12 our $to_flush; # { cfgpath => $lei }
  13
  14 sub flush_lei ($;$) {
  15         my ($lei, $manual) = @_;
  16         my $lne = delete $lei->{cfg}->{-lei_note_event} // return;
  17         $lne->{lei_sock} = $lei->{sock} if $manual;
  18         $lne->wq_close; # runs _lei_wq_eof;
  19 }
  20
  21 # we batch up writes and flush every 5s (matching Linux default
  22 # writeback behavior) since MUAs can trigger a storm of inotify events
  23 sub flush_task { # PublicInbox::DS timer callback
  24         my $todo = $to_flush // return;
  25         $to_flush = undef;
  26         for my $lei (values %$todo) { flush_lei($lei) }
  27 }
  28
  29 # sets a timer to flush
  30 sub note_event_arm_done ($) {
  31         my ($lei) = @_;
  32         PublicInbox::DS::add_uniq_timer('flush_timer', 5, \&flush_task);
  33         $to_flush->{$lei->{cfg}->{'-f'}} //= $lei;
  34 }
  35
  36 sub eml_event ($$$$) {
  37         my ($self, $eml, $vmd, $state) = @_;
  38         my $sto = $self->{lei}->{sto};
  39         if ($state =~ /\Aimport-(?:rw|ro)\z/) {
  40                 $sto->wq_do('set_eml', $eml, $vmd);
  41         } elsif ($state =~ /\Aindex-(?:rw|ro)\z/) {
  42                 my $xoids = $self->{lei}->ale->xoids_for($eml);
  43                 $sto->wq_do('index_eml_only', $eml, $vmd, $xoids);
  44         } elsif ($state =~ /\Atag-(?:rw|ro)\z/) {
  45                 my $docids = [];
  46                 my $c = eval {
  47                         $self->{lse}->kw_changed($eml, $vmd->{kw}, $docids);
  48                 } // 1; # too new, assume changed since still to-be-committed.
  49                 if (scalar @$docids) { # already in lei/store
  50                         $sto->wq_do('set_eml_vmd', undef, $vmd, $docids) if $c;
  51                 } elsif (my $xoids = $self->{lei}->ale->xoids_for($eml)) {
  52                         # it's in an external, only set kw, here
  53                         $sto->wq_do('set_xvmd', $xoids, $eml, $vmd);
  54                 } # else { totally unknown: ignore
  55         } else {
  56                 warn "unknown state: $state (in $self->{lei}->{cfg}->{'-f'})\n";
  57         }
  58 }
  59
  60 sub maildir_event { # via wq_io_do
  61         my ($self, $fn, $vmd, $state) = @_;
  62         my $eml = PublicInbox::InboxWritable::eml_from_path($fn) // return;
  63         eml_event($self, $eml, $vmd, $state);
  64 }
  65
  66 sub lei_note_event {
  67         my ($lei, $folder, $new_cur, $bn, $fn, @rest) = @_;
  68         die "BUG: unexpected: @rest" if @rest;
  69         my $cfg = $lei->_lei_cfg or return; # gone (race)
  70         my $sto = $lei->_lei_store or return; # gone
  71         return flush_lei($lei, 1) if $folder eq 'done'; # special case
  72         my $lms = $lei->lms or return;
  73         $lms->lms_write_prepare if $new_cur eq ''; # for ->clear_src below
  74         $lei->{opt}->{quiet} = 1;
  75         $lms->arg2folder($lei, [ $folder ]);
  76         my $state = $cfg->get_1("watch.$folder.state") // 'tag-rw';
  77         return if $state eq 'pause';
  78         return $lms->clear_src($folder, \$bn) if $new_cur eq '';
  79         $lms->lms_pause;
  80         $lei->ale; # prepare
  81         $sto->write_prepare($lei);
  82         require PublicInbox::MdirReader;
  83         my $self = $cfg->{-lei_note_event} //= do {
  84                 my $wq = bless { lms => $lms }, __PACKAGE__;
  85                 # MUAs such as mutt can trigger massive rename() storms so
  86                 # use some CPU, but don't overwhelm slower storage, either
  87                 my $jobs = $wq->detect_nproc // 1;
  88                 $jobs = 4 if $jobs > 4; # same default as V2Writable
  89                 my ($op_c, $ops) = $lei->workers_start($wq, $jobs);
  90                 $lei->wait_wq_events($op_c, $ops);
  91                 note_event_arm_done($lei);
  92                 $lei->{lne} = $wq;
  93         };
  94         if ($folder =~ /\Amaildir:/i) {
  95                 my $fl = PublicInbox::MdirReader::maildir_basename_flags($bn)
  96                         // return;
  97                 return if index($fl, 'T') >= 0;
  98                 my $kw = PublicInbox::MdirReader::flags2kw($fl);
  99                 my $vmd = { kw => $kw, sync_info => [ $folder, \$bn ] };
 100                 $self->wq_do('maildir_event', $fn, $vmd, $state);
 101         } # else: TODO: imap
 102 }
 103
 104 sub ipc_atfork_child {
 105         my ($self) = @_;
 106         $self->{lei}->_lei_atfork_child(1); # persistent, for a while
 107         $self->{lms}->lms_write_prepare;
 108         $self->{lse} = $self->{lei}->{sto}->search;
 109         $self->SUPER::ipc_atfork_child;
 110 }
 111
 112 sub _lei_wq_eof { # EOF callback for main lei daemon
 113         my ($lei) = @_;
 114         my $lne = delete $lei->{lne} or return $lei->fail;
 115         $lei->sto_done_request($lne->{lei_sock});
 116 }
 117
 118 1;