lib/PublicInbox/LeiNoteEvent.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # internal command for dealing with inotify, kqueue vnodes, etc
   5 # it is a semi-persistent worker
   6 package PublicInbox::LeiNoteEvent;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::IPC);
  10 use PublicInbox::DS;
  11 use Errno qw(ENOENT);
  12
  13 our $to_flush; # { cfgpath => $lei }
  14
  15 sub flush_lei ($;$) {
  16         my ($lei, $manual) = @_;
  17         my $lne = delete $lei->{cfg}->{-lei_note_event} // return;
  18         $lne->{lei_sock} = $lei->{sock} if $manual;
  19         $lne->wq_close; # runs _lei_wq_eof;
  20 }
  21
  22 # we batch up writes and flush every 5s (matching Linux default
  23 # writeback behavior) since MUAs can trigger a storm of inotify events
  24 sub flush_task { # PublicInbox::DS timer callback
  25         my $todo = $to_flush // return;
  26         $to_flush = undef;
  27         for my $lei (values %$todo) { flush_lei($lei) }
  28 }
  29
  30 sub eml_event ($$$$) {
  31         my ($self, $eml, $vmd, $state) = @_;
  32         my $sto = $self->{lei}->{sto};
  33         if ($state =~ /\Aimport-(?:rw|ro)\z/) {
  34                 $sto->wq_do('set_eml', $eml, $vmd);
  35         } elsif ($state =~ /\Aindex-(?:rw|ro)\z/) {
  36                 my $xoids = $self->{lei}->ale->xoids_for($eml);
  37                 $sto->wq_do('index_eml_only', $eml, $vmd, $xoids);
  38         } elsif ($state =~ /\Atag-(?:rw|ro)\z/) {
  39                 my $docids = [];
  40                 my $c = eval {
  41                         $self->{lse}->kw_changed($eml, $vmd->{kw}, $docids);
  42                 } // 1; # too new, assume changed since still to-be-committed.
  43                 if (scalar @$docids) { # already in lei/store
  44                         $sto->wq_do('set_eml_vmd', undef, $vmd, $docids) if $c;
  45                 } elsif (my $xoids = $self->{lei}->ale->xoids_for($eml)) {
  46                         # it's in an external, only set kw, here
  47                         $sto->wq_do('set_xvmd', $xoids, $eml, $vmd);
  48                 } # else { totally unknown: ignore
  49         } else {
  50                 warn "unknown state: $state (in $self->{lei}->{cfg}->{'-f'})\n";
  51         }
  52 }
  53
  54 sub maildir_event { # via wq_nonblock_do
  55         my ($self, $fn, $vmd, $state) = @_;
  56         if (my $eml = PublicInbox::InboxWritable::eml_from_path($fn)) {
  57                 eml_event($self, $eml, $vmd, $state);
  58         } elsif ($! == ENOENT) {
  59                 $self->{lms}->clear_src(@{$vmd->{sync_info}});
  60         } # else: eml_from_path already warns
  61 }
  62
  63 sub lei_note_event {
  64         my ($lei, $folder, $new_cur, $bn, $fn, @rest) = @_;
  65         die "BUG: unexpected: @rest" if @rest;
  66         my $cfg = $lei->_lei_cfg or return; # gone (race)
  67         my $sto = $lei->_lei_store or return; # gone
  68         return flush_lei($lei, 1) if $folder eq 'done'; # special case
  69         my $lms = $lei->lms or return;
  70         $lms->lms_write_prepare if $new_cur eq ''; # for ->clear_src below
  71         $lei->{opt}->{quiet} = 1;
  72         $lms->arg2folder($lei, [ $folder ]);
  73         my $state = $cfg->get_1("watch.$folder.state") // 'tag-rw';
  74         return if $state eq 'pause';
  75         return $lms->clear_src($folder, \$bn) if $new_cur eq '';
  76         $lms->lms_pause;
  77         $lei->ale; # prepare
  78         $sto->write_prepare($lei);
  79         require PublicInbox::MdirReader;
  80         my $self = $cfg->{-lei_note_event} //= do {
  81                 my $wq = bless { lms => $lms }, __PACKAGE__;
  82                 # MUAs such as mutt can trigger massive rename() storms so
  83                 # use some CPU, but don't overwhelm slower storage, either
  84                 my $jobs = $wq->detect_nproc // 1;
  85                 $jobs = 4 if $jobs > 4; # same default as V2Writable
  86                 my ($op_c, $ops) = $lei->workers_start($wq, $jobs);
  87                 $lei->wait_wq_events($op_c, $ops);
  88                 PublicInbox::DS::add_uniq_timer('flush_timer', 5, \&flush_task);
  89                 $to_flush->{$lei->{cfg}->{'-f'}} //= $lei;
  90                 $wq->prepare_nonblock;
  91                 $lei->{lne} = $wq;
  92         };
  93         if ($folder =~ /\Amaildir:/i) {
  94                 my $fl = PublicInbox::MdirReader::maildir_basename_flags($bn)
  95                         // return;
  96                 return if index($fl, 'T') >= 0;
  97                 my $kw = PublicInbox::MdirReader::flags2kw($fl);
  98                 my $vmd = { kw => $kw, sync_info => [ $folder, \$bn ] };
  99                 $self->wq_nonblock_do('maildir_event', $fn, $vmd, $state);
 100         } # else: TODO: imap
 101 }
 102
 103 sub ipc_atfork_child {
 104         my ($self) = @_;
 105         $self->{lei}->_lei_atfork_child(1); # persistent, for a while
 106         $self->{lms}->lms_write_prepare;
 107         $self->{lse} = $self->{lei}->{sto}->search;
 108         $self->SUPER::ipc_atfork_child;
 109 }
 110
 111 sub _lei_wq_eof { # EOF callback for main lei daemon
 112         $_[0]->wq_eof('lne');
 113 }
 114
 115 1;