lib/PublicInbox/LeiNoteEvent.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # internal command for dealing with inotify, kqueue vnodes, etc
   5 # it is a semi-persistent worker
   6 package PublicInbox::LeiNoteEvent;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::IPC);
  10
  11 my $flush_timer;
  12 our $to_flush; # { cfgpath => $lei }
  13
  14 sub flush_lei ($) {
  15         my ($lei) = @_;
  16         my $lne = delete $lei->{cfg}->{-lei_note_event};
  17         $lne->wq_close(1, undef, $lei) if $lne; # runs _lei_wq_eof;
  18 }
  19
  20 # we batch up writes and flush every 5s (matching Linux default
  21 # writeback behavior) since MUAs can trigger a storm of inotify events
  22 sub flush_task { # PublicInbox::DS timer callback
  23         undef $flush_timer;
  24         my $todo = $to_flush // return;
  25         $to_flush = undef;
  26         for my $lei (values %$todo) { flush_lei($lei) }
  27 }
  28
  29 # sets a timer to flush
  30 sub note_event_arm_done ($) {
  31         my ($lei) = @_;
  32         $flush_timer //= PublicInbox::DS::add_timer(5, \&flush_task);
  33         $to_flush->{$lei->{cfg}->{'-f'}} //= $lei;
  34 }
  35
  36 sub eml_event ($$$$) {
  37         my ($self, $eml, $vmd, $state) = @_;
  38         my $sto = $self->{lei}->{sto};
  39         if ($state =~ /\Aimport-(?:rw|ro)\z/) {
  40                 $sto->ipc_do('set_eml', $eml, $vmd);
  41         } elsif ($state =~ /\Aindex-(?:rw|ro)\z/) {
  42                 my $xoids = $self->{lei}->ale->xoids_for($eml);
  43                 $sto->ipc_do('index_eml_only', $eml, $vmd, $xoids);
  44         } elsif ($state =~ /\Atag-(?:rw|ro)\z/) {
  45                 my $docids = [];
  46                 my $c = $self->{lse}->kw_changed($eml, $vmd->{kw}, $docids);
  47                 if (scalar @$docids) { # already in lei/store
  48                         $sto->ipc_do('set_eml_vmd', undef, $vmd, $docids) if $c;
  49                 } elsif (my $xoids = $self->{lei}->ale->xoids_for($eml)) {
  50                         # it's in an external, only set kw, here
  51                         $sto->ipc_do('set_xvmd', $xoids, $eml, $vmd);
  52                 } # else { totally unknown: ignore
  53         } else {
  54                 warn "unknown state: $state (in $self->{lei}->{cfg}->{'-f'})\n";
  55         }
  56 }
  57
  58 sub maildir_event { # via wq_io_do
  59         my ($self, $fn, $vmd, $state) = @_;
  60         my $eml = PublicInbox::InboxWritable::eml_from_path($fn) // return;
  61         eml_event($self, $eml, $vmd, $state);
  62 }
  63
  64 sub lei_note_event {
  65         my ($lei, $folder, $new_cur, $bn, $fn, @rest) = @_;
  66         die "BUG: unexpected: @rest" if @rest;
  67         my $cfg = $lei->_lei_cfg or return; # gone (race)
  68         my $sto = $lei->_lei_store or return; # gone
  69         return flush_lei($lei) if $folder eq 'done'; # special case
  70         my $lms = $lei->lms or return;
  71         $lms->lms_write_prepare if $new_cur eq ''; # for ->clear_src below
  72         my $err = $lms->arg2folder($lei, [ $folder ]);
  73         return if $err->{fail};
  74         my $state = $cfg->get_1("watch.$folder", 'state') // 'tag-rw';
  75         return if $state eq 'pause';
  76         return $lms->clear_src($folder, \$bn) if $new_cur eq '';
  77         $lms->lms_pause;
  78         $lei->ale; # prepare
  79         $sto->write_prepare($lei);
  80         require PublicInbox::MdirReader;
  81         my $self = $cfg->{-lei_note_event} //= do {
  82                 my $wq = bless { lms => $lms }, __PACKAGE__;
  83                 # MUAs such as mutt can trigger massive rename() storms so
  84                 # use all CPU power available:
  85                 my $jobs = $wq->detect_nproc // 1;
  86                 my ($op_c, $ops) = $lei->workers_start($wq, $jobs);
  87                 $lei->wait_wq_events($op_c, $ops);
  88                 note_event_arm_done($lei);
  89                 $lei->{lne} = $wq;
  90         };
  91         if ($folder =~ /\Amaildir:/i) {
  92                 my $fl = PublicInbox::MdirReader::maildir_basename_flags($bn)
  93                         // return;
  94                 return if index($fl, 'T') >= 0;
  95                 my $kw = PublicInbox::MdirReader::flags2kw($fl);
  96                 my $vmd = { kw => $kw, sync_info => [ $folder, \$bn ] };
  97                 $self->wq_io_do('maildir_event', [], $fn, $vmd, $state);
  98         } # else: TODO: imap
  99 }
 100
 101 sub ipc_atfork_child {
 102         my ($self) = @_;
 103         $self->{lei}->_lei_atfork_child(1); # persistent, for a while
 104         $self->{lms}->lms_write_prepare;
 105         $self->{lse} = $self->{lei}->{sto}->search;
 106         $self->SUPER::ipc_atfork_child;
 107 }
 108
 109 sub lne_done_wait {
 110         my ($arg, $pid) = @_;
 111         my ($self, $lei) = @$arg;
 112         $lei->can('wq_done_wait')->($arg, $pid);
 113 }
 114
 115 sub _lei_wq_eof { # EOF callback for main lei daemon
 116         my ($lei) = @_;
 117         my $lne = delete $lei->{lne} or return $lei->fail;
 118         $lei->sto_done_request;
 119         $lne->wq_wait_old(\&lne_done_wait, $lei);
 120 }
 121
 122 1;