lib/PublicInbox/LeiNoteEvent.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # internal command for dealing with inotify, kqueue vnodes, etc
   5 # it is a semi-persistent worker
   6 package PublicInbox::LeiNoteEvent;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::IPC);
  10 use PublicInbox::DS;
  11
  12 our $to_flush; # { cfgpath => $lei }
  13
  14 sub flush_lei ($) {
  15         my ($lei) = @_;
  16         my $lne = delete $lei->{cfg}->{-lei_note_event};
  17         $lne->wq_close(1, undef, $lei) if $lne; # runs _lei_wq_eof;
  18 }
  19
  20 # we batch up writes and flush every 5s (matching Linux default
  21 # writeback behavior) since MUAs can trigger a storm of inotify events
  22 sub flush_task { # PublicInbox::DS timer callback
  23         my $todo = $to_flush // return;
  24         $to_flush = undef;
  25         for my $lei (values %$todo) { flush_lei($lei) }
  26 }
  27
  28 # sets a timer to flush
  29 sub note_event_arm_done ($) {
  30         my ($lei) = @_;
  31         PublicInbox::DS::add_uniq_timer('flush_timer', 5, \&flush_task);
  32         $to_flush->{$lei->{cfg}->{'-f'}} //= $lei;
  33 }
  34
  35 sub eml_event ($$$$) {
  36         my ($self, $eml, $vmd, $state) = @_;
  37         my $sto = $self->{lei}->{sto};
  38         if ($state =~ /\Aimport-(?:rw|ro)\z/) {
  39                 $sto->wq_do('set_eml', $eml, $vmd);
  40         } elsif ($state =~ /\Aindex-(?:rw|ro)\z/) {
  41                 my $xoids = $self->{lei}->ale->xoids_for($eml);
  42                 $sto->wq_do('index_eml_only', $eml, $vmd, $xoids);
  43         } elsif ($state =~ /\Atag-(?:rw|ro)\z/) {
  44                 my $docids = [];
  45                 my $c = $self->{lse}->kw_changed($eml, $vmd->{kw}, $docids);
  46                 if (scalar @$docids) { # already in lei/store
  47                         $sto->wq_do('set_eml_vmd', undef, $vmd, $docids) if $c;
  48                 } elsif (my $xoids = $self->{lei}->ale->xoids_for($eml)) {
  49                         # it's in an external, only set kw, here
  50                         $sto->wq_do('set_xvmd', $xoids, $eml, $vmd);
  51                 } # else { totally unknown: ignore
  52         } else {
  53                 warn "unknown state: $state (in $self->{lei}->{cfg}->{'-f'})\n";
  54         }
  55 }
  56
  57 sub maildir_event { # via wq_io_do
  58         my ($self, $fn, $vmd, $state) = @_;
  59         my $eml = PublicInbox::InboxWritable::eml_from_path($fn) // return;
  60         eml_event($self, $eml, $vmd, $state);
  61 }
  62
  63 sub lei_note_event {
  64         my ($lei, $folder, $new_cur, $bn, $fn, @rest) = @_;
  65         die "BUG: unexpected: @rest" if @rest;
  66         my $cfg = $lei->_lei_cfg or return; # gone (race)
  67         my $sto = $lei->_lei_store or return; # gone
  68         return flush_lei($lei) if $folder eq 'done'; # special case
  69         my $lms = $lei->lms or return;
  70         $lms->lms_write_prepare if $new_cur eq ''; # for ->clear_src below
  71         my $err = $lms->arg2folder($lei, [ $folder ]);
  72         return if $err->{fail};
  73         my $state = $cfg->get_1("watch.$folder", 'state') // 'tag-rw';
  74         return if $state eq 'pause';
  75         return $lms->clear_src($folder, \$bn) if $new_cur eq '';
  76         $lms->lms_pause;
  77         $lei->ale; # prepare
  78         $sto->write_prepare($lei);
  79         require PublicInbox::MdirReader;
  80         my $self = $cfg->{-lei_note_event} //= do {
  81                 my $wq = bless { lms => $lms }, __PACKAGE__;
  82                 # MUAs such as mutt can trigger massive rename() storms so
  83                 # use all CPU power available:
  84                 my $jobs = $wq->detect_nproc // 1;
  85                 my ($op_c, $ops) = $lei->workers_start($wq, $jobs);
  86                 $lei->wait_wq_events($op_c, $ops);
  87                 note_event_arm_done($lei);
  88                 $lei->{lne} = $wq;
  89         };
  90         if ($folder =~ /\Amaildir:/i) {
  91                 my $fl = PublicInbox::MdirReader::maildir_basename_flags($bn)
  92                         // return;
  93                 return if index($fl, 'T') >= 0;
  94                 my $kw = PublicInbox::MdirReader::flags2kw($fl);
  95                 my $vmd = { kw => $kw, sync_info => [ $folder, \$bn ] };
  96                 $self->wq_io_do('maildir_event', [], $fn, $vmd, $state);
  97         } # else: TODO: imap
  98 }
  99
 100 sub ipc_atfork_child {
 101         my ($self) = @_;
 102         $self->{lei}->_lei_atfork_child(1); # persistent, for a while
 103         $self->{lms}->lms_write_prepare;
 104         $self->{lse} = $self->{lei}->{sto}->search;
 105         $self->SUPER::ipc_atfork_child;
 106 }
 107
 108 sub lne_done_wait {
 109         my ($arg, $pid) = @_;
 110         my ($self, $lei) = @$arg;
 111         $lei->can('wq_done_wait')->($arg, $pid);
 112 }
 113
 114 sub _lei_wq_eof { # EOF callback for main lei daemon
 115         my ($lei) = @_;
 116         my $lne = delete $lei->{lne} or return $lei->fail;
 117         $lei->sto_done_request;
 118         $lne->wq_wait_old(\&lne_done_wait, $lei);
 119 }
 120
 121 1;