lib/PublicInbox/LeiOverview.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # per-mitem/smsg iterators for search results
   5 # "ovv" => "Overview viewer"
   6 package PublicInbox::LeiOverview;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::Lock);
  10 use POSIX qw(strftime);
  11 use Fcntl qw(F_GETFL O_APPEND);
  12 use File::Spec;
  13 use File::Temp ();
  14 use PublicInbox::MID qw($MID_EXTRACT);
  15 use PublicInbox::Address qw(pairs);
  16 use PublicInbox::Config;
  17 use PublicInbox::Search qw(get_pct);
  18 use PublicInbox::LeiDedupe;
  19 use PublicInbox::LeiToMail;
  20
  21 # cf. https://en.wikipedia.org/wiki/JSON_streaming
  22 my $JSONL = 'ldjson|ndjson|jsonl'; # 3 names for the same thing
  23
  24 sub _iso8601 ($) { strftime('%Y-%m-%dT%H:%M:%SZ', gmtime($_[0])) }
  25
  26 # we open this in the parent process before ->wq_io_do handoff
  27 sub ovv_out_lk_init ($) {
  28         my ($self) = @_;
  29         my $tmp = File::Temp->new("lei-ovv.dst.$$.lock-XXXXXX",
  30                                         TMPDIR => 1, UNLINK => 0);
  31         $self->{"lk_id.$self.$$"} = $self->{lock_path} = $tmp->filename;
  32 }
  33
  34 sub ovv_out_lk_cancel ($) {
  35         my ($self) = @_;
  36         my $lock_path = delete $self->{"lk_id.$self.$$"} or return;
  37         unlink($lock_path);
  38 }
  39
  40 sub detect_fmt ($$) {
  41         my ($lei, $dst) = @_;
  42         if ($dst =~ m!\A([:/]+://)!) {
  43                 $lei->fail("$1 support not implemented, yet\n");
  44         } elsif (!-e $dst || -d _) {
  45                 'maildir'; # the default TODO: MH?
  46         } elsif (-f _ || -p _) {
  47                 $lei->fail("unable to determine mbox family of $dst\n");
  48         } else {
  49                 $lei->fail("unable to determine format of $dst\n");
  50         }
  51 }
  52
  53 sub new {
  54         my ($class, $lei, $ofmt_key) = @_;
  55         my $opt = $lei->{opt};
  56         my $dst = $opt->{output} // '-';
  57         $dst = '/dev/stdout' if $dst eq '-';
  58         $ofmt_key //= 'format';
  59
  60         my $fmt = $opt->{$ofmt_key};
  61         $fmt = lc($fmt) if defined $fmt;
  62         if ($dst =~ m!\A([a-z0-9\+]+)://!is) {
  63                 defined($fmt) and return $lei->fail(<<"");
  64 --$ofmt_key=$fmt invalid with URL $dst
  65
  66                 $fmt = lc $1;
  67         } elsif ($dst =~ s/\A([a-z0-9]+)://is) { # e.g. Maildir:/home/user/Mail/
  68                 my $ofmt = lc $1;
  69                 $fmt //= $ofmt;
  70                 return $lei->fail(<<"") if $fmt ne $ofmt;
  71 --$ofmt_key=$fmt and --output=$ofmt conflict
  72
  73         }
  74         $fmt //= 'json' if $dst eq '/dev/stdout';
  75         $fmt //= detect_fmt($lei, $dst) or return;
  76
  77         if (index($dst, '://') < 0) { # not a URL, so assume path
  78                  $dst = File::Spec->canonpath($dst);
  79         } # else URL
  80
  81         my $self = bless { fmt => $fmt, dst => $dst }, $class;
  82         $lei->{ovv} = $self;
  83         my $json;
  84         if ($fmt =~ /\A($JSONL|(?:concat)?json)\z/) {
  85                 $json = $self->{json} = ref(PublicInbox::Config->json);
  86         }
  87         if ($dst eq '/dev/stdout') {
  88                 my $isatty = $lei->{need_pager} = -t $lei->{1};
  89                 $opt->{pretty} //= $isatty;
  90                 if (!$isatty && -f _) {
  91                         my $fl = fcntl($lei->{1}, F_GETFL, 0) //
  92                                 return $lei->fail("fcntl(stdout): $!");
  93                         ovv_out_lk_init($self) unless ($fl & O_APPEND);
  94                 } else {
  95                         ovv_out_lk_init($self);
  96                 }
  97         } elsif (!$opt->{quiet}) {
  98                 $lei->{-progress} = 1;
  99         }
 100         if ($json) {
 101                 $lei->{dedupe} //= PublicInbox::LeiDedupe->new($lei);
 102         } else {
 103                 # default to the cheapest sort since MUA usually resorts
 104                 $opt->{'sort'} //= 'docid' if $dst ne '/dev/stdout';
 105                 $lei->{l2m} = eval { PublicInbox::LeiToMail->new($lei) };
 106                 return $lei->fail($@) if $@;
 107                 if ($opt->{mua} && $lei->{l2m}->lock_free) {
 108                         $lei->{early_mua} = 1;
 109                         $opt->{alert} //= [ ':WINCH,:bell' ] if -t $lei->{1};
 110                 }
 111         }
 112         $self;
 113 }
 114
 115 # called once by parent
 116 sub ovv_begin {
 117         my ($self, $lei) = @_;
 118         if ($self->{fmt} eq 'json') {
 119                 $lei->out('[');
 120         } # TODO HTML/Atom/...
 121 }
 122
 123 # called once by parent (via PublicInbox::EOFpipe)
 124 sub ovv_end {
 125         my ($self, $lei) = @_;
 126         if ($self->{fmt} eq 'json') {
 127                 # JSON doesn't allow trailing commas, and preventing
 128                 # trailing commas is a PITA when parallelizing outputs
 129                 $lei->out("null]\n");
 130         } elsif ($self->{fmt} eq 'concatjson') {
 131                 $lei->out("\n");
 132         }
 133 }
 134
 135 # prepares an smsg for JSON
 136 sub _unbless_smsg {
 137         my ($smsg, $mitem) = @_;
 138
 139         delete @$smsg{qw(lines bytes num tid)};
 140         $smsg->{rt} = _iso8601(delete $smsg->{ts}); # JMAP receivedAt
 141         $smsg->{dt} = _iso8601(delete $smsg->{ds}); # JMAP UTCDate
 142         $smsg->{pct} = get_pct($mitem) if $mitem;
 143         if (my $r = delete $smsg->{references}) {
 144                 $smsg->{refs} = [ map { $_ } ($r =~ m/$MID_EXTRACT/go) ];
 145         }
 146         if (my $m = delete($smsg->{mid})) {
 147                 $smsg->{'m'} = $m;
 148         }
 149         for my $f (qw(from to cc)) {
 150                 my $v = delete $smsg->{$f} or next;
 151                 $smsg->{substr($f, 0, 1)} = pairs($v);
 152         }
 153         $smsg->{'s'} = delete $smsg->{subject};
 154         scalar { %$smsg }; # unbless
 155 }
 156
 157 sub ovv_atexit_child {
 158         my ($self, $lei) = @_;
 159         if (my $bref = delete $lei->{ovv_buf}) {
 160                 my $lk = $self->lock_for_scope;
 161                 $lei->out($$bref);
 162         }
 163 }
 164
 165 # JSON module ->pretty output wastes too much vertical white space,
 166 # this (IMHO) provides better use of screen real-estate while not
 167 # being excessively compact:
 168 sub _json_pretty {
 169         my ($json, $k, $v) = @_;
 170         if (ref $v eq 'ARRAY') {
 171                 if (@$v) {
 172                         my $sep = ",\n" . (' ' x (length($k) + 7));
 173                         if (ref($v->[0])) { # f/t/c
 174                                 $v = '[' . join($sep, map {
 175                                         my $pair = $json->encode($_);
 176                                         $pair =~ s/(null|"),"/$1, "/g;
 177                                         $pair;
 178                                 } @$v) . ']';
 179                         } else { # references
 180                                 $v = '[' . join($sep, map {
 181                                         substr($json->encode([$_]), 1, -1);
 182                                 } @$v) . ']';
 183                         }
 184                 } else {
 185                         $v = '[]';
 186                 }
 187         }
 188         qq{  "$k": }.$v;
 189 }
 190
 191 sub ovv_each_smsg_cb { # runs in wq worker usually
 192         my ($self, $lei, $ibxish) = @_;
 193         my ($json, $dedupe);
 194         if (my $pkg = $self->{json}) {
 195                 $json = $pkg->new;
 196                 $json->utf8->canonical;
 197                 $json->ascii(1) if $lei->{opt}->{ascii};
 198         }
 199         my $l2m = $lei->{l2m};
 200         if (!$l2m) {
 201                 $dedupe = $lei->{dedupe} // die 'BUG: {dedupe} missing';
 202                 $dedupe->prepare_dedupe;
 203         }
 204         $lei->{ovv_buf} = \(my $buf = '') if !$l2m;
 205         if ($l2m && !$ibxish) { # remote https?:// mboxrd
 206                 my $wcb = $l2m->write_cb($lei);
 207                 sub {
 208                         my ($smsg, undef, $eml) = @_; # no mitem in $_[1]
 209                         $wcb->(undef, $smsg, $eml);
 210                 };
 211         } elsif ($l2m && $l2m->{-wq_s1}) {
 212                 my $git_dir = $ibxish->git->{git_dir};
 213                 sub {
 214                         my ($smsg, $mitem) = @_;
 215                         $smsg->{pct} = get_pct($mitem) if $mitem;
 216                         $l2m->wq_io_do('write_mail', [], $git_dir, $smsg);
 217                 }
 218         } elsif ($self->{fmt} =~ /\A(concat)?json\z/ && $lei->{opt}->{pretty}) {
 219                 my $EOR = ($1//'') eq 'concat' ? "\n}" : "\n},";
 220                 sub { # DIY prettiness :P
 221                         my ($smsg, $mitem) = @_;
 222                         return if $dedupe->is_smsg_dup($smsg);
 223                         $smsg = _unbless_smsg($smsg, $mitem);
 224                         $buf .= "{\n";
 225                         $buf .= join(",\n", map {
 226                                 my $v = $smsg->{$_};
 227                                 if (ref($v)) {
 228                                         _json_pretty($json, $_, $v);
 229                                 } else {
 230                                         $v = $json->encode([$v]);
 231                                         qq{  "$_": }.substr($v, 1, -1);
 232                                 }
 233                         } sort keys %$smsg);
 234                         $buf .= $EOR;
 235                         return if length($buf) < 65536;
 236                         my $lk = $self->lock_for_scope;
 237                         $lei->out($buf);
 238                         $buf = '';
 239                 }
 240         } elsif ($json) {
 241                 my $ORS = $self->{fmt} eq 'json' ? ",\n" : "\n"; # JSONL
 242                 sub {
 243                         my ($smsg, $mitem) = @_;
 244                         return if $dedupe->is_smsg_dup($smsg);
 245                         $buf .= $json->encode(_unbless_smsg(@_)) . $ORS;
 246                         return if length($buf) < 65536;
 247                         my $lk = $self->lock_for_scope;
 248                         $lei->out($buf);
 249                         $buf = '';
 250                 }
 251         } else {
 252                 die "TODO: unhandled case $self->{fmt}"
 253         }
 254 }
 255
 256 no warnings 'once';
 257 *DESTROY = \&ovv_out_lk_cancel;
 258
 259 1;