lib/PublicInbox/LeiOverview.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # per-mitem/smsg iterators for search results
   5 # "ovv" => "Overview viewer"
   6 package PublicInbox::LeiOverview;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::Lock);
  10 use POSIX qw(strftime);
  11 use Fcntl qw(F_GETFL O_APPEND);
  12 use File::Spec;
  13 use File::Temp ();
  14 use PublicInbox::MID qw($MID_EXTRACT);
  15 use PublicInbox::Address qw(pairs);
  16 use PublicInbox::Config;
  17 use PublicInbox::Search qw(get_pct);
  18 use PublicInbox::LeiDedupe;
  19 use PublicInbox::LeiToMail;
  20
  21 # cf. https://en.wikipedia.org/wiki/JSON_streaming
  22 my $JSONL = 'ldjson|ndjson|jsonl'; # 3 names for the same thing
  23
  24 sub _iso8601 ($) { strftime('%Y-%m-%dT%H:%M:%SZ', gmtime($_[0])) }
  25
  26 # we open this in the parent process before ->wq_do handoff
  27 sub ovv_out_lk_init ($) {
  28         my ($self) = @_;
  29         $self->{tmp_lk_id} = "$self.$$";
  30         my $tmp = File::Temp->new("lei-ovv.dst.$$.lock-XXXXXX",
  31                                         TMPDIR => 1, UNLINK => 0);
  32         $self->{lock_path} = $tmp->filename;
  33 }
  34
  35 sub ovv_out_lk_cancel ($) {
  36         my ($self) = @_;
  37         ($self->{tmp_lk_id}//'') eq "$self.$$" and
  38                 unlink(delete($self->{lock_path}));
  39 }
  40
  41 sub detect_fmt ($$) {
  42         my ($lei, $dst) = @_;
  43         if ($dst =~ m!\A([:/]+://)!) {
  44                 $lei->fail("$1 support not implemented, yet\n");
  45         } elsif (!-e $dst || -d _) {
  46                 'maildir'; # the default TODO: MH?
  47         } elsif (-f _ || -p _) {
  48                 $lei->fail("unable to determine mbox family of $dst\n");
  49         } else {
  50                 $lei->fail("unable to determine format of $dst\n");
  51         }
  52 }
  53
  54 sub new {
  55         my ($class, $lei) = @_;
  56         my $opt = $lei->{opt};
  57         my $dst = $opt->{output} // '-';
  58         $dst = '/dev/stdout' if $dst eq '-';
  59
  60         my $fmt = $opt->{'format'};
  61         $fmt = lc($fmt) if defined $fmt;
  62         if ($dst =~ s/\A([a-z0-9]+)://is) { # e.g. Maildir:/home/user/Mail/
  63                 my $ofmt = lc $1;
  64                 $fmt //= $ofmt;
  65                 return $lei->fail(<<"") if $fmt ne $ofmt;
  66 --format=$fmt and --output=$ofmt conflict
  67
  68         }
  69         $fmt //= 'json' if $dst eq '/dev/stdout';
  70         $fmt //= detect_fmt($lei, $dst) or return;
  71
  72         if (index($dst, '://') < 0) { # not a URL, so assume path
  73                  $dst = File::Spec->canonpath($dst);
  74         } # else URL
  75
  76         my $self = bless { fmt => $fmt, dst => $dst }, $class;
  77         $lei->{ovv} = $self;
  78         my $json;
  79         if ($fmt =~ /\A($JSONL|(?:concat)?json)\z/) {
  80                 $json = $self->{json} = ref(PublicInbox::Config->json);
  81         }
  82         my ($isatty, $seekable);
  83         if ($dst eq '/dev/stdout') {
  84                 $isatty = -t $lei->{1};
  85                 $lei->start_pager if $isatty;
  86                 $opt->{pretty} //= $isatty;
  87                 if (!$isatty && -f _) {
  88                         my $fl = fcntl($lei->{1}, F_GETFL, 0) //
  89                                 return $lei->fail("fcntl(stdout): $!");
  90                         ovv_out_lk_init($self) unless ($fl & O_APPEND);
  91                 } else {
  92                         ovv_out_lk_init($self);
  93                 }
  94         }
  95         if (!$json) {
  96                 # default to the cheapest sort since MUA usually resorts
  97                 $lei->{opt}->{'sort'} //= 'docid' if $dst ne '/dev/stdout';
  98                 $lei->{l2m} = eval { PublicInbox::LeiToMail->new($lei) };
  99                 return $lei->fail($@) if $@;
 100         }
 101         $lei->{dedupe} //= PublicInbox::LeiDedupe->new($lei);
 102         $self;
 103 }
 104
 105 # called once by parent
 106 sub ovv_begin {
 107         my ($self, $lei) = @_;
 108         if ($self->{fmt} eq 'json') {
 109                 print { $lei->{1} } '[';
 110         } # TODO HTML/Atom/...
 111 }
 112
 113 # called once by parent (via PublicInbox::EOFpipe)
 114 sub ovv_end {
 115         my ($self, $lei) = @_;
 116         my $out = $lei->{1} or return;
 117         if ($self->{fmt} eq 'json') {
 118                 # JSON doesn't allow trailing commas, and preventing
 119                 # trailing commas is a PITA when parallelizing outputs
 120                 print $out "null]\n";
 121         } elsif ($self->{fmt} eq 'concatjson') {
 122                 print $out "\n";
 123         }
 124 }
 125
 126 sub ovv_atfork_child {
 127         my ($self) = @_;
 128         # reopen dedupe here
 129 }
 130
 131 # prepares an smsg for JSON
 132 sub _unbless_smsg {
 133         my ($smsg, $mitem) = @_;
 134
 135         delete @$smsg{qw(lines bytes num tid)};
 136         $smsg->{rt} = _iso8601(delete $smsg->{ts}); # JMAP receivedAt
 137         $smsg->{dt} = _iso8601(delete $smsg->{ds}); # JMAP UTCDate
 138         $smsg->{relevance} = get_pct($mitem) if $mitem;
 139
 140         if (my $r = delete $smsg->{references}) {
 141                 $smsg->{refs} = [
 142                                 map { "<$_>" } ($r =~ m/$MID_EXTRACT/go) ];
 143         }
 144         if (my $m = delete($smsg->{mid})) {
 145                 $smsg->{'m'} = "<$m>";
 146         }
 147         for my $f (qw(from to cc)) {
 148                 my $v = delete $smsg->{$f} or next;
 149                 $smsg->{substr($f, 0, 1)} = pairs($v);
 150         }
 151         $smsg->{'s'} = delete $smsg->{subject};
 152         # can we be bothered to parse From/To/Cc into arrays?
 153         scalar { %$smsg }; # unbless
 154 }
 155
 156 sub ovv_atexit_child {
 157         my ($self, $lei) = @_;
 158         if (my $l2m = delete $lei->{l2m}) {
 159                 # gracefully stop lei2mail processes after all
 160                 # ->write_mail work is complete
 161                 delete $l2m->{-wq_s1};
 162                 if (my $rd = delete $l2m->{each_smsg_done}) {
 163                         read($rd, my $buf, 1); # wait for EOF
 164                 }
 165         }
 166         # order matters, git->{-tmp}->DESTROY must not fire until
 167         # {each_smsg_done} hits EOF above
 168         if (my $git = delete $self->{git}) {
 169                 $git->async_wait_all;
 170         }
 171         if (my $bref = delete $lei->{ovv_buf}) {
 172                 my $out = $lei->{1} or return;
 173                 my $lk = $self->lock_for_scope;
 174                 print $out $$bref;
 175         }
 176 }
 177
 178 # JSON module ->pretty output wastes too much vertical white space,
 179 # this (IMHO) provides better use of screen real-estate while not
 180 # being excessively compact:
 181 sub _json_pretty {
 182         my ($json, $k, $v) = @_;
 183         if (ref $v eq 'ARRAY') {
 184                 if (@$v) {
 185                         my $sep = ",\n" . (' ' x (length($k) + 7));
 186                         if (ref($v->[0])) { # f/t/c
 187                                 $v = '[' . join($sep, map {
 188                                         my $pair = $json->encode($_);
 189                                         $pair =~ s/(null|"),"/$1, "/g;
 190                                         $pair;
 191                                 } @$v) . ']';
 192                         } else { # references
 193                                 $v = '[' . join($sep, map {
 194                                         substr($json->encode([$_]), 1, -1);
 195                                 } @$v) . ']';
 196                         }
 197                 } else {
 198                         $v = '[]';
 199                 }
 200         }
 201         qq{  "$k": }.$v;
 202 }
 203
 204 sub ovv_each_smsg_cb { # runs in wq worker usually
 205         my ($self, $lei, $ibxish) = @_;
 206         my $json;
 207         $lei->{1}->autoflush(1);
 208         if (my $pkg = $self->{json}) {
 209                 $json = $pkg->new;
 210                 $json->utf8->canonical;
 211                 $json->ascii(1) if $lei->{opt}->{ascii};
 212         }
 213         my $l2m = $lei->{l2m};
 214         if ($l2m && $l2m->{-wq_s1}) {
 215                 my ($lei_ipc, @io) = $lei->atfork_parent_wq($l2m);
 216                 # n.b. $io[0] = qry_status_wr, $io[1] = mbox|stdout,
 217                 # $io[4] becomes a notification pipe that triggers EOF
 218                 # in this wq worker when all outstanding ->write_mail
 219                 # calls are complete
 220                 die "BUG: \$io[4] $io[4] unexpected" if $io[4];
 221                 pipe($l2m->{each_smsg_done}, $io[4]) or die "pipe: $!";
 222                 fcntl($io[4], 1031, 4096) if $^O eq 'linux';
 223                 delete @$lei_ipc{qw(l2m opt mset_opt cmd)};
 224                 my $git = $ibxish->git; # (LeiXSearch|Inbox|ExtSearch)->git
 225                 $self->{git} = $git;
 226                 my $git_dir = $git->{git_dir};
 227                 sub {
 228                         my ($smsg, $mitem) = @_;
 229                         my $kw = []; # TODO get from mitem
 230                         $l2m->wq_do('write_mail', \@io, $git_dir,
 231                                         $smsg->{blob}, $lei_ipc, $kw)
 232                 }
 233         } elsif ($l2m) {
 234                 my $wcb = $l2m->write_cb($lei);
 235                 my $git = $ibxish->git; # (LeiXSearch|Inbox|ExtSearch)->git
 236                 $self->{git} = $git; # for ovv_atexit_child
 237                 my $g2m = $l2m->can('git_to_mail');
 238                 sub {
 239                         my ($smsg, $mitem) = @_;
 240                         my $kw = []; # TODO get from mitem
 241                         $git->cat_async($smsg->{blob}, $g2m, [ $wcb, $kw ]);
 242                 };
 243         } elsif ($self->{fmt} =~ /\A(concat)?json\z/ && $lei->{opt}->{pretty}) {
 244                 my $EOR = ($1//'') eq 'concat' ? "\n}" : "\n},";
 245                 $lei->{ovv_buf} = \(my $buf = '');
 246                 sub { # DIY prettiness :P
 247                         my ($smsg, $mitem) = @_;
 248                         $smsg = _unbless_smsg($smsg, $mitem);
 249                         $buf .= "{\n";
 250                         $buf .= join(",\n", map {
 251                                 my $v = $smsg->{$_};
 252                                 if (ref($v)) {
 253                                         _json_pretty($json, $_, $v);
 254                                 } else {
 255                                         $v = $json->encode([$v]);
 256                                         qq{  "$_": }.substr($v, 1, -1);
 257                                 }
 258                         } sort keys %$smsg);
 259                         $buf .= $EOR;
 260                         if (length($buf) > 65536) {
 261                                 my $lk = $self->lock_for_scope;
 262                                 print { $lei->{1} } $buf;
 263                                 $buf = '';
 264                         }
 265                 }
 266         } elsif ($json) {
 267                 my $ORS = $self->{fmt} eq 'json' ? ",\n" : "\n"; # JSONL
 268                 $lei->{ovv_buf} = \(my $buf = '');
 269                 sub {
 270                         my ($smsg, $mitem) = @_;
 271                         delete @$smsg{qw(tid num)};
 272                         $buf .= $json->encode(_unbless_smsg(@_)) . $ORS;
 273                         if (length($buf) > 65536) {
 274                                 my $lk = $self->lock_for_scope;
 275                                 print { $lei->{1} } $buf;
 276                                 $buf = '';
 277                         }
 278                 }
 279         } elsif ($self->{fmt} eq 'oid') {
 280                 sub {
 281                         my ($smsg, $mitem) = @_;
 282                 }
 283         } # else { ...
 284 }
 285
 286 no warnings 'once';
 287 *DESTROY = \&ovv_out_lk_cancel;
 288
 289 1;