lib/PublicInbox/LeiOverview.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # per-mitem/smsg iterators for search results
   5 # "ovv" => "Overview viewer"
   6 package PublicInbox::LeiOverview;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::Lock);
  10 use POSIX qw(strftime);
  11 use Fcntl qw(F_GETFL O_APPEND);
  12 use File::Spec;
  13 use File::Temp ();
  14 use PublicInbox::MID qw($MID_EXTRACT);
  15 use PublicInbox::Address qw(pairs);
  16 use PublicInbox::Config;
  17 use PublicInbox::Search qw(get_pct);
  18 use PublicInbox::LeiDedupe;
  19 use PublicInbox::LeiToMail;
  20
  21 # cf. https://en.wikipedia.org/wiki/JSON_streaming
  22 my $JSONL = 'ldjson|ndjson|jsonl'; # 3 names for the same thing
  23
  24 sub _iso8601 ($) { strftime('%Y-%m-%dT%H:%M:%SZ', gmtime($_[0])) }
  25
  26 # we open this in the parent process before ->wq_do handoff
  27 sub ovv_out_lk_init ($) {
  28         my ($self) = @_;
  29         $self->{tmp_lk_id} = "$self.$$";
  30         my $tmp = File::Temp->new("lei-ovv.dst.$$.lock-XXXXXX",
  31                                         TMPDIR => 1, UNLINK => 0);
  32         $self->{lock_path} = $tmp->filename;
  33 }
  34
  35 sub ovv_out_lk_cancel ($) {
  36         my ($self) = @_;
  37         ($self->{tmp_lk_id}//'') eq "$self.$$" and
  38                 unlink(delete($self->{lock_path}));
  39 }
  40
  41 sub detect_fmt ($$) {
  42         my ($lei, $dst) = @_;
  43         if ($dst =~ m!\A([:/]+://)!) {
  44                 $lei->fail("$1 support not implemented, yet\n");
  45         } elsif (!-e $dst || -d _) {
  46                 'maildir'; # the default TODO: MH?
  47         } elsif (-f _ || -p _) {
  48                 $lei->fail("unable to determine mbox family of $dst\n");
  49         } else {
  50                 $lei->fail("unable to determine format of $dst\n");
  51         }
  52 }
  53
  54 sub new {
  55         my ($class, $lei) = @_;
  56         my $opt = $lei->{opt};
  57         my $dst = $opt->{output} // '-';
  58         $dst = '/dev/stdout' if $dst eq '-';
  59
  60         my $fmt = $opt->{'format'};
  61         $fmt = lc($fmt) if defined $fmt;
  62         if ($dst =~ s/\A([a-z0-9]+)://is) { # e.g. Maildir:/home/user/Mail/
  63                 my $ofmt = lc $1;
  64                 $fmt //= $ofmt;
  65                 return $lei->fail(<<"") if $fmt ne $ofmt;
  66 --format=$fmt and --output=$ofmt conflict
  67
  68         }
  69         $fmt //= 'json' if $dst eq '/dev/stdout';
  70         $fmt //= detect_fmt($lei, $dst) or return;
  71
  72         if (index($dst, '://') < 0) { # not a URL, so assume path
  73                  $dst = File::Spec->canonpath($dst);
  74         } # else URL
  75
  76         my $self = bless { fmt => $fmt, dst => $dst }, $class;
  77         $lei->{ovv} = $self;
  78         my $json;
  79         if ($fmt =~ /\A($JSONL|(?:concat)?json)\z/) {
  80                 $json = $self->{json} = ref(PublicInbox::Config->json);
  81         }
  82         my ($isatty, $seekable);
  83         if ($dst eq '/dev/stdout') {
  84                 $isatty = -t $lei->{1};
  85                 $lei->start_pager if $isatty;
  86                 $opt->{pretty} //= $isatty;
  87                 if (!$isatty && -f _) {
  88                         my $fl = fcntl($lei->{1}, F_GETFL, 0) //
  89                                 return $lei->fail("fcntl(stdout): $!");
  90                         ovv_out_lk_init($self) unless ($fl & O_APPEND);
  91                 } else {
  92                         ovv_out_lk_init($self);
  93                 }
  94         }
  95         if ($json) {
  96                 $lei->{dedupe} //= PublicInbox::LeiDedupe->new($lei);
  97         } else {
  98                 # default to the cheapest sort since MUA usually resorts
  99                 $lei->{opt}->{'sort'} //= 'docid' if $dst ne '/dev/stdout';
 100                 $lei->{l2m} = eval { PublicInbox::LeiToMail->new($lei) };
 101                 return $lei->fail($@) if $@;
 102         }
 103         $self;
 104 }
 105
 106 # called once by parent
 107 sub ovv_begin {
 108         my ($self, $lei) = @_;
 109         if ($self->{fmt} eq 'json') {
 110                 print { $lei->{1} } '[';
 111         } # TODO HTML/Atom/...
 112 }
 113
 114 # called once by parent (via PublicInbox::EOFpipe)
 115 sub ovv_end {
 116         my ($self, $lei) = @_;
 117         my $out = $lei->{1} or return;
 118         if ($self->{fmt} eq 'json') {
 119                 # JSON doesn't allow trailing commas, and preventing
 120                 # trailing commas is a PITA when parallelizing outputs
 121                 print $out "null]\n";
 122         } elsif ($self->{fmt} eq 'concatjson') {
 123                 print $out "\n";
 124         }
 125 }
 126
 127 sub ovv_atfork_child {
 128         my ($self) = @_;
 129         # reopen dedupe here
 130 }
 131
 132 # prepares an smsg for JSON
 133 sub _unbless_smsg {
 134         my ($smsg, $mitem) = @_;
 135
 136         delete @$smsg{qw(lines bytes num tid)};
 137         $smsg->{rt} = _iso8601(delete $smsg->{ts}); # JMAP receivedAt
 138         $smsg->{dt} = _iso8601(delete $smsg->{ds}); # JMAP UTCDate
 139         $smsg->{pct} = get_pct($mitem) if $mitem;
 140         if (my $r = delete $smsg->{references}) {
 141                 $smsg->{refs} = [ map { "<$_>" } ($r =~ m/$MID_EXTRACT/go) ];
 142         }
 143         if (my $m = delete($smsg->{mid})) {
 144                 $smsg->{'m'} = "<$m>";
 145         }
 146         for my $f (qw(from to cc)) {
 147                 my $v = delete $smsg->{$f} or next;
 148                 $smsg->{substr($f, 0, 1)} = pairs($v);
 149         }
 150         $smsg->{'s'} = delete $smsg->{subject};
 151         # can we be bothered to parse From/To/Cc into arrays?
 152         scalar { %$smsg }; # unbless
 153 }
 154
 155 sub ovv_atexit_child {
 156         my ($self, $lei) = @_;
 157         if (my $l2m = delete $lei->{l2m}) {
 158                 # gracefully stop lei2mail processes after all
 159                 # ->write_mail work is complete
 160                 delete $l2m->{-wq_s1};
 161                 if (my $rd = delete $l2m->{each_smsg_done}) {
 162                         read($rd, my $buf, 1); # wait for EOF
 163                 }
 164         }
 165         # order matters, git->{-tmp}->DESTROY must not fire until
 166         # {each_smsg_done} hits EOF above
 167         if (my $git = delete $self->{git}) {
 168                 $git->async_wait_all;
 169         }
 170         if (my $bref = delete $lei->{ovv_buf}) {
 171                 my $out = $lei->{1} or return;
 172                 my $lk = $self->lock_for_scope;
 173                 print $out $$bref;
 174         }
 175 }
 176
 177 # JSON module ->pretty output wastes too much vertical white space,
 178 # this (IMHO) provides better use of screen real-estate while not
 179 # being excessively compact:
 180 sub _json_pretty {
 181         my ($json, $k, $v) = @_;
 182         if (ref $v eq 'ARRAY') {
 183                 if (@$v) {
 184                         my $sep = ",\n" . (' ' x (length($k) + 7));
 185                         if (ref($v->[0])) { # f/t/c
 186                                 $v = '[' . join($sep, map {
 187                                         my $pair = $json->encode($_);
 188                                         $pair =~ s/(null|"),"/$1, "/g;
 189                                         $pair;
 190                                 } @$v) . ']';
 191                         } else { # references
 192                                 $v = '[' . join($sep, map {
 193                                         substr($json->encode([$_]), 1, -1);
 194                                 } @$v) . ']';
 195                         }
 196                 } else {
 197                         $v = '[]';
 198                 }
 199         }
 200         qq{  "$k": }.$v;
 201 }
 202
 203 sub ovv_each_smsg_cb { # runs in wq worker usually
 204         my ($self, $lei, $ibxish) = @_;
 205         my ($json, $dedupe);
 206         $lei->{1}->autoflush(1);
 207         if (my $pkg = $self->{json}) {
 208                 $json = $pkg->new;
 209                 $json->utf8->canonical;
 210                 $json->ascii(1) if $lei->{opt}->{ascii};
 211         }
 212         my $l2m = $lei->{l2m};
 213         if (!$l2m) {
 214                 $dedupe = $lei->{dedupe} // die 'BUG: {dedupe} missing';
 215                 $dedupe->prepare_dedupe;
 216         }
 217         $lei->{ovv_buf} = \(my $buf = '') if !$l2m;
 218         if ($l2m && !$ibxish) { # remote https?:// mboxrd
 219                 delete $l2m->{-wq_s1};
 220                 my $g2m = $l2m->can('git_to_mail');
 221                 my $wcb = $l2m->write_cb($lei);
 222                 sub {
 223                         my ($smsg, undef, $eml) = @_; # no mitem in $_[1]
 224                         $wcb->(undef, $smsg, $eml);
 225                 };
 226         } elsif ($l2m && $l2m->{-wq_s1}) {
 227                 my ($lei_ipc, @io) = $lei->atfork_parent_wq($l2m);
 228                 # $io[-1] becomes a notification pipe that triggers EOF
 229                 # in this wq worker when all outstanding ->write_mail
 230                 # calls are complete
 231                 pipe($l2m->{each_smsg_done}, $io[$#io + 1]) or die "pipe: $!";
 232                 fcntl($io[-1], 1031, 4096) if $^O eq 'linux'; # F_SETPIPE_SZ
 233                 delete @$lei_ipc{qw(l2m opt mset_opt cmd)};
 234                 $lei_ipc->{each_smsg_not_done} = $#io;
 235                 my $git = $ibxish->git; # (LeiXSearch|Inbox|ExtSearch)->git
 236                 $self->{git} = $git;
 237                 my $git_dir = $git->{git_dir};
 238                 sub {
 239                         my ($smsg, $mitem) = @_;
 240                         $smsg->{pct} = get_pct($mitem) if $mitem;
 241                         $l2m->wq_do('write_mail', \@io, $git_dir, $smsg,
 242                                         $lei_ipc);
 243                 }
 244         } elsif ($l2m) {
 245                 my $wcb = $l2m->write_cb($lei);
 246                 my $git = $ibxish->git; # (LeiXSearch|Inbox|ExtSearch)->git
 247                 $self->{git} = $git; # for ovv_atexit_child
 248                 my $g2m = $l2m->can('git_to_mail');
 249                 sub {
 250                         my ($smsg, $mitem) = @_;
 251                         $smsg->{pct} = get_pct($mitem) if $mitem;
 252                         $git->cat_async($smsg->{blob}, $g2m, [ $wcb, $smsg ]);
 253                 };
 254         } elsif ($self->{fmt} =~ /\A(concat)?json\z/ && $lei->{opt}->{pretty}) {
 255                 my $EOR = ($1//'') eq 'concat' ? "\n}" : "\n},";
 256                 sub { # DIY prettiness :P
 257                         my ($smsg, $mitem) = @_;
 258                         return if $dedupe->is_smsg_dup($smsg);
 259                         $smsg = _unbless_smsg($smsg, $mitem);
 260                         $buf .= "{\n";
 261                         $buf .= join(",\n", map {
 262                                 my $v = $smsg->{$_};
 263                                 if (ref($v)) {
 264                                         _json_pretty($json, $_, $v);
 265                                 } else {
 266                                         $v = $json->encode([$v]);
 267                                         qq{  "$_": }.substr($v, 1, -1);
 268                                 }
 269                         } sort keys %$smsg);
 270                         $buf .= $EOR;
 271                         if (length($buf) > 65536) {
 272                                 my $lk = $self->lock_for_scope;
 273                                 print { $lei->{1} } $buf;
 274                                 $buf = '';
 275                         }
 276                 }
 277         } elsif ($json) {
 278                 my $ORS = $self->{fmt} eq 'json' ? ",\n" : "\n"; # JSONL
 279                 sub {
 280                         my ($smsg, $mitem) = @_;
 281                         return if $dedupe->is_smsg_dup($smsg);
 282                         $buf .= $json->encode(_unbless_smsg(@_)) . $ORS;
 283                         if (length($buf) > 65536) {
 284                                 my $lk = $self->lock_for_scope;
 285                                 print { $lei->{1} } $buf;
 286                                 $buf = '';
 287                         }
 288                 }
 289         } # else { ...
 290 }
 291
 292 no warnings 'once';
 293 *DESTROY = \&ovv_out_lk_cancel;
 294
 295 1;