lib/PublicInbox/LeiOverview.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # per-mitem/smsg iterators for search results
   5 # "ovv" => "Overview viewer"
   6 package PublicInbox::LeiOverview;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::Lock);
  10 use POSIX qw(strftime);
  11 use Fcntl qw(F_GETFL O_APPEND);
  12 use File::Spec;
  13 use File::Temp ();
  14 use PublicInbox::MID qw($MID_EXTRACT);
  15 use PublicInbox::Address qw(pairs);
  16 use PublicInbox::Config;
  17 use PublicInbox::Search qw(get_pct);
  18 use PublicInbox::LeiDedupe;
  19 use PublicInbox::LeiToMail;
  20
  21 # cf. https://en.wikipedia.org/wiki/JSON_streaming
  22 my $JSONL = 'ldjson|ndjson|jsonl'; # 3 names for the same thing
  23
  24 sub _iso8601 ($) { strftime('%Y-%m-%dT%H:%M:%SZ', gmtime($_[0])) }
  25
  26 # we open this in the parent process before ->wq_do handoff
  27 sub ovv_out_lk_init ($) {
  28         my ($self) = @_;
  29         $self->{tmp_lk_id} = "$self.$$";
  30         my $tmp = File::Temp->new("lei-ovv.dst.$$.lock-XXXXXX",
  31                                         TMPDIR => 1, UNLINK => 0);
  32         $self->{lock_path} = $tmp->filename;
  33 }
  34
  35 sub ovv_out_lk_cancel ($) {
  36         my ($self) = @_;
  37         ($self->{tmp_lk_id}//'') eq "$self.$$" and
  38                 unlink(delete($self->{lock_path}));
  39 }
  40
  41 sub new {
  42         my ($class, $lei) = @_;
  43         my $opt = $lei->{opt};
  44         my $dst = $opt->{output} // '-';
  45         $dst = '/dev/stdout' if $dst eq '-';
  46
  47         my $fmt = $opt->{'format'};
  48         $fmt = lc($fmt) if defined $fmt;
  49         if ($dst =~ s/\A([a-z0-9]+)://is) { # e.g. Maildir:/home/user/Mail/
  50                 my $ofmt = lc $1;
  51                 $fmt //= $ofmt;
  52                 return $lei->fail(<<"") if $fmt ne $ofmt;
  53 --format=$fmt and --output=$ofmt conflict
  54
  55         }
  56         $fmt //= 'json' if $dst eq '/dev/stdout';
  57         $fmt //= 'maildir';
  58
  59         if (index($dst, '://') < 0) { # not a URL, so assume path
  60                  $dst = File::Spec->canonpath($dst);
  61         } # else URL
  62
  63         my $self = bless { fmt => $fmt, dst => $dst }, $class;
  64         $lei->{ovv} = $self;
  65         my $json;
  66         if ($fmt =~ /\A($JSONL|(?:concat)?json)\z/) {
  67                 $json = $self->{json} = ref(PublicInbox::Config->json);
  68         }
  69         my ($isatty, $seekable);
  70         if ($dst eq '/dev/stdout') {
  71                 $isatty = -t $lei->{1};
  72                 $lei->start_pager if $isatty;
  73                 $opt->{pretty} //= $isatty;
  74                 if (!$isatty && -f _) {
  75                         my $fl = fcntl($lei->{1}, F_GETFL, 0) //
  76                                 return $lei->fail("fcntl(stdout): $!");
  77                         ovv_out_lk_init($self) unless ($fl & O_APPEND);
  78                 } else {
  79                         ovv_out_lk_init($self);
  80                 }
  81         }
  82         if (!$json) {
  83                 # default to the cheapest sort since MUA usually resorts
  84                 $lei->{opt}->{'sort'} //= 'docid' if $dst ne '/dev/stdout';
  85                 $lei->{l2m} = PublicInbox::LeiToMail->new($lei);
  86         }
  87         $lei->{dedupe} //= PublicInbox::LeiDedupe->new($lei);
  88         $self;
  89 }
  90
  91 # called once by parent
  92 sub ovv_begin {
  93         my ($self, $lei) = @_;
  94         if ($self->{fmt} eq 'json') {
  95                 print { $lei->{1} } '[';
  96         } # TODO HTML/Atom/...
  97 }
  98
  99 # called once by parent (via PublicInbox::EOFpipe)
 100 sub ovv_end {
 101         my ($self, $lei) = @_;
 102         if ($self->{fmt} eq 'json') {
 103                 # JSON doesn't allow trailing commas, and preventing
 104                 # trailing commas is a PITA when parallelizing outputs
 105                 print { $lei->{1} } "null]\n";
 106         } elsif ($self->{fmt} eq 'concatjson') {
 107                 print { $lei->{1} } "\n";
 108         }
 109 }
 110
 111 sub ovv_atfork_child {
 112         my ($self) = @_;
 113         # reopen dedupe here
 114 }
 115
 116 # prepares an smsg for JSON
 117 sub _unbless_smsg {
 118         my ($smsg, $mitem) = @_;
 119
 120         delete @$smsg{qw(lines bytes num tid)};
 121         $smsg->{rt} = _iso8601(delete $smsg->{ts}); # JMAP receivedAt
 122         $smsg->{dt} = _iso8601(delete $smsg->{ds}); # JMAP UTCDate
 123         $smsg->{relevance} = get_pct($mitem) if $mitem;
 124
 125         if (my $r = delete $smsg->{references}) {
 126                 $smsg->{refs} = [
 127                                 map { "<$_>" } ($r =~ m/$MID_EXTRACT/go) ];
 128         }
 129         if (my $m = delete($smsg->{mid})) {
 130                 $smsg->{'m'} = "<$m>";
 131         }
 132         for my $f (qw(from to cc)) {
 133                 my $v = delete $smsg->{$f} or next;
 134                 $smsg->{substr($f, 0, 1)} = pairs($v);
 135         }
 136         $smsg->{'s'} = delete $smsg->{subject};
 137         # can we be bothered to parse From/To/Cc into arrays?
 138         scalar { %$smsg }; # unbless
 139 }
 140
 141 sub ovv_atexit_child {
 142         my ($self, $lei) = @_;
 143         if (my $l2m = delete $lei->{l2m}) {
 144                 # gracefully stop lei2mail processes after all
 145                 # ->write_mail work is complete
 146                 delete $l2m->{-wq_s1};
 147                 if (my $rd = delete $l2m->{each_smsg_done}) {
 148                         read($rd, my $buf, 1); # wait for EOF
 149                 }
 150         }
 151         # order matters, git->{-tmp}->DESTROY must not fire until
 152         # {each_smsg_done} hits EOF above
 153         if (my $git = delete $self->{git}) {
 154                 $git->async_wait_all;
 155         }
 156         if (my $bref = delete $lei->{ovv_buf}) {
 157                 my $out = $lei->{1} or return;
 158                 my $lk = $self->lock_for_scope;
 159                 print $out $$bref;
 160         }
 161 }
 162
 163 # JSON module ->pretty output wastes too much vertical white space,
 164 # this (IMHO) provides better use of screen real-estate while not
 165 # being excessively compact:
 166 sub _json_pretty {
 167         my ($json, $k, $v) = @_;
 168         if (ref $v eq 'ARRAY') {
 169                 if (@$v) {
 170                         my $sep = ",\n" . (' ' x (length($k) + 7));
 171                         if (ref($v->[0])) { # f/t/c
 172                                 $v = '[' . join($sep, map {
 173                                         my $pair = $json->encode($_);
 174                                         $pair =~ s/(null|"),"/$1, "/g;
 175                                         $pair;
 176                                 } @$v) . ']';
 177                         } else { # references
 178                                 $v = '[' . join($sep, map {
 179                                         substr($json->encode([$_]), 1, -1);
 180                                 } @$v) . ']';
 181                         }
 182                 } else {
 183                         $v = '[]';
 184                 }
 185         }
 186         qq{  "$k": }.$v;
 187 }
 188
 189 sub ovv_each_smsg_cb { # runs in wq worker usually
 190         my ($self, $lei, $ibxish) = @_;
 191         my $json;
 192         $lei->{1}->autoflush(1);
 193         if (my $pkg = $self->{json}) {
 194                 $json = $pkg->new;
 195                 $json->utf8->canonical;
 196                 $json->ascii(1) if $lei->{opt}->{ascii};
 197         }
 198         my $l2m = $lei->{l2m};
 199         if ($l2m && $l2m->{-wq_s1}) {
 200                 my ($lei_ipc, @io) = $lei->atfork_parent_wq($l2m);
 201                 # n.b. $io[0] = qry_status_wr, $io[1] = mbox|stdout,
 202                 # $io[4] becomes a notification pipe that triggers EOF
 203                 # in this wq worker when all outstanding ->write_mail
 204                 # calls are complete
 205                 die "BUG: \$io[4] $io[4] unexpected" if $io[4];
 206                 pipe($l2m->{each_smsg_done}, $io[4]) or die "pipe: $!";
 207                 fcntl($io[4], 1031, 4096) if $^O eq 'linux';
 208                 delete @$lei_ipc{qw(l2m opt mset_opt cmd)};
 209                 my $git = $ibxish->git; # (LeiXSearch|Inbox|ExtSearch)->git
 210                 $self->{git} = $git;
 211                 my $git_dir = $git->{git_dir};
 212                 sub {
 213                         my ($smsg, $mitem) = @_;
 214                         my $kw = []; # TODO get from mitem
 215                         $l2m->wq_do('write_mail', \@io, $git_dir,
 216                                         $smsg->{blob}, $lei_ipc, $kw)
 217                 }
 218         } elsif ($l2m) {
 219                 my $wcb = $l2m->write_cb($lei);
 220                 my $git = $ibxish->git; # (LeiXSearch|Inbox|ExtSearch)->git
 221                 $self->{git} = $git; # for ovv_atexit_child
 222                 my $g2m = $l2m->can('git_to_mail');
 223                 sub {
 224                         my ($smsg, $mitem) = @_;
 225                         my $kw = []; # TODO get from mitem
 226                         $git->cat_async($smsg->{blob}, $g2m, [ $wcb, $kw ]);
 227                 };
 228         } elsif ($self->{fmt} =~ /\A(concat)?json\z/ && $lei->{opt}->{pretty}) {
 229                 my $EOR = ($1//'') eq 'concat' ? "\n}" : "\n},";
 230                 $lei->{ovv_buf} = \(my $buf = '');
 231                 sub { # DIY prettiness :P
 232                         my ($smsg, $mitem) = @_;
 233                         $smsg = _unbless_smsg($smsg, $mitem);
 234                         $buf .= "{\n";
 235                         $buf .= join(",\n", map {
 236                                 my $v = $smsg->{$_};
 237                                 if (ref($v)) {
 238                                         _json_pretty($json, $_, $v);
 239                                 } else {
 240                                         $v = $json->encode([$v]);
 241                                         qq{  "$_": }.substr($v, 1, -1);
 242                                 }
 243                         } sort keys %$smsg);
 244                         $buf .= $EOR;
 245                         if (length($buf) > 65536) {
 246                                 my $lk = $self->lock_for_scope;
 247                                 print { $lei->{1} } $buf;
 248                                 $buf = '';
 249                         }
 250                 }
 251         } elsif ($json) {
 252                 my $ORS = $self->{fmt} eq 'json' ? ",\n" : "\n"; # JSONL
 253                 $lei->{ovv_buf} = \(my $buf = '');
 254                 sub {
 255                         my ($smsg, $mitem) = @_;
 256                         delete @$smsg{qw(tid num)};
 257                         $buf .= $json->encode(_unbless_smsg(@_)) . $ORS;
 258                         if (length($buf) > 65536) {
 259                                 my $lk = $self->lock_for_scope;
 260                                 print { $lei->{1} } $buf;
 261                                 $buf = '';
 262                         }
 263                 }
 264         } elsif ($self->{fmt} eq 'oid') {
 265                 sub {
 266                         my ($smsg, $mitem) = @_;
 267                 }
 268         } # else { ...
 269 }
 270
 271 no warnings 'once';
 272 *DESTROY = \&ovv_out_lk_cancel;
 273
 274 1;