lib/PublicInbox/LeiQuery.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # handles "lei q" command and provides internals for
   5 # several other sub-commands (up, lcat, ...)
   6 package PublicInbox::LeiQuery;
   7 use strict;
   8 use v5.10.1;
   9 use PublicInbox::OverIdx;
  10
  11 sub prep_ext { # externals_each callback
  12         my ($lxs, $exclude, $loc) = @_;
  13         $lxs->prepare_external($loc) unless $exclude->{$loc};
  14 }
  15
  16 sub _start_query { # used by "lei q" and "lei up"
  17         my ($self) = @_;
  18         require PublicInbox::LeiOverview;
  19         PublicInbox::LeiOverview->new($self) or return;
  20         my $opt = $self->{opt};
  21         PublicInbox::OverIdx::fork_ok($opt);
  22         my ($xj, $mj) = split(/,/, $opt->{jobs} // '');
  23         (defined($xj) && $xj ne '' && $xj !~ /\A[1-9][0-9]*\z/) and
  24                 die "`$xj' search jobs must be >= 1\n";
  25         my $lxs = $self->{lxs};
  26         $xj ||= $lxs->concurrency($opt); # allow: "--jobs ,$WRITER_ONLY"
  27         my $nproc = $lxs->detect_nproc || 1; # don't memoize, schedtool(1) exists
  28         $xj = $nproc if $xj > $nproc;
  29         $lxs->{-wq_nr_workers} = $xj;
  30         (defined($mj) && $mj !~ /\A[1-9][0-9]*\z/) and
  31                 die "`$mj' writer jobs must be >= 1\n";
  32         my $l2m = $self->{l2m};
  33         # we use \1 (a ref) to distinguish between default vs. user-supplied
  34         if ($l2m && grep { $opt->{$_} //= \1 } (qw(mail-sync import-remote
  35                                                         import-before))) {
  36                 $self->_lei_store(1)->write_prepare($self);
  37                 if ($opt->{'mail-sync'}) {
  38                         my $lms = $l2m->{-lms_rw} = $self->lms(1);
  39                         $lms->lms_write_prepare->lms_pause; # just create
  40                 }
  41         }
  42         $l2m and $l2m->{-wq_nr_workers} //= $mj // do {
  43                 # keep some CPU for git, and don't overload IMAP destinations
  44                 my $n = int($nproc * 0.75 + 0.5);
  45                 $self->{net} && $n > 4 ? 4 : $n;
  46         };
  47
  48         # descending docid order is cheapest, MUA controls sorting order
  49         $self->{mset_opt}->{relevance} //= -2 if $l2m || $opt->{threads};
  50
  51         my $tot = $self->{mset_opt}->{total} //= $self->{opt}->{limit} // 10000;
  52         $self->{mset_opt}->{limit} = $tot > 10000 ? 10000 : $tot;
  53         $self->{mset_opt}->{offset} //= 0;
  54         $self->{mset_opt}->{threads} //= $opt->{threads};
  55
  56         if ($self->{net}) {
  57                 require PublicInbox::LeiAuth;
  58                 $self->{auth} = PublicInbox::LeiAuth->new
  59         }
  60         $lxs->do_query($self);
  61 }
  62
  63 sub qstr_add { # PublicInbox::InputPipe::consume callback for --stdin
  64         my ($lei) = @_; # $_[1] = $rbuf
  65         $_[1] // $lei->fail("error reading stdin: $!");
  66         return $lei->{mset_opt}->{qstr} .= $_[1] if $_[1] ne '';
  67         eval {
  68                 $lei->fchdir;
  69                 $lei->{mset_opt}->{q_raw} = $lei->{mset_opt}->{qstr};
  70                 $lei->{lse}->query_approxidate($lei->{lse}->git,
  71                                                 $lei->{mset_opt}->{qstr});
  72                 _start_query($lei);
  73         };
  74         $lei->fail($@) if $@;
  75 }
  76
  77 sub lxs_prepare {
  78         my ($self) = @_;
  79         require PublicInbox::LeiXSearch;
  80         # prepare any number of LeiXSearch || LeiSearch || Inbox || URL
  81         my $lxs = $self->{lxs} = PublicInbox::LeiXSearch->new;
  82         my $opt = $self->{opt};
  83         my @only = @{$opt->{only} // []};
  84         # --local is enabled by default unless --only is used
  85         # we'll allow "--only $LOCATION --local"
  86         my $sto = $self->_lei_store(1);
  87         $self->{lse} = $sto->search;
  88         if ($opt->{'local'} //= scalar(@only) ? 0 : 1) {
  89                 $lxs->prepare_external($self->{lse});
  90         }
  91         if (@only) {
  92                 for my $loc (@only) {
  93                         my @loc = $self->get_externals($loc) or return;
  94                         $lxs->prepare_external($_) for @loc;
  95                 }
  96         } else {
  97                 my (@ilocals, @iremotes);
  98                 for my $loc (@{$opt->{include} // []}) {
  99                         my @loc = $self->get_externals($loc) or return;
 100                         $lxs->prepare_external($_) for @loc;
 101                         @ilocals = @{$lxs->{locals} // []};
 102                         @iremotes = @{$lxs->{remotes} // []};
 103                 }
 104                 # --external is enabled by default, but allow --no-external
 105                 if ($opt->{external} //= 1) {
 106                         my $ex = $self->canonicalize_excludes($opt->{exclude});
 107                         $self->externals_each(\&prep_ext, $lxs, $ex);
 108                         $opt->{remote} //= !($lxs->locals - $opt->{'local'});
 109                         $lxs->{locals} = \@ilocals if !$opt->{'local'};
 110                         $lxs->{remotes} = \@iremotes if !$opt->{remote};
 111                 }
 112         }
 113         ($lxs->locals || $lxs->remotes) ? ($self->{lxs} = $lxs) :
 114                 die("no local or remote inboxes to search\n");
 115 }
 116
 117 # the main "lei q SEARCH_TERMS" method
 118 sub lei_q {
 119         my ($self, @argv) = @_;
 120         PublicInbox::Config->json; # preload before forking
 121         my $lxs = lxs_prepare($self) or return;
 122         $self->ale->refresh_externals($lxs, $self);
 123         my $opt = $self->{opt};
 124         my %mset_opt;
 125         $mset_opt{asc} = $opt->{'reverse'} ? 1 : 0;
 126         if (defined(my $sort = $opt->{'sort'})) {
 127                 if ($sort eq 'relevance') {
 128                         $mset_opt{relevance} = 1;
 129                 } elsif ($sort eq 'docid') {
 130                         $mset_opt{relevance} = $mset_opt{asc} ? -1 : -2;
 131                 } elsif ($sort =~ /\Areceived(?:-?[aA]t)?\z/) {
 132                         # the default
 133                 } else {
 134                         die "unrecognized --sort=$sort\n";
 135                 }
 136                 $opt->{save} and return
 137                         $self->fail('--save and --sort are incompatible');
 138         }
 139         $self->{mset_opt} = \%mset_opt;
 140
 141         if ($opt->{stdin}) {
 142                 return $self->fail(<<'') if @argv;
 143 no query allowed on command-line with --stdin
 144
 145                 require PublicInbox::InputPipe;
 146                 PublicInbox::InputPipe::consume($self->{0}, \&qstr_add, $self);
 147                 return;
 148         }
 149         chomp(@argv) and $self->qerr("# trailing `\\n' removed");
 150         $mset_opt{q_raw} = [ @argv ]; # copy
 151         $mset_opt{qstr} =
 152                 $self->{lse}->query_argv_to_string($self->{lse}->git, \@argv);
 153         _start_query($self);
 154 }
 155
 156 # shell completion helper called by lei__complete
 157 sub _complete_q {
 158         my ($self, @argv) = @_;
 159         my @cur;
 160         my $cb = $self->lazy_cb(qw(forget-external _complete_));
 161         while (@argv) {
 162                 if ($argv[-1] =~ /\A(?:-I|(?:--(?:include|exclude|only)))\z/) {
 163                         my @c = $cb->($self, @cur);
 164                         # try basename match:
 165                         if (scalar(@cur) == 1 && index($cur[0], '/') < 0) {
 166                                 my $all = $self->externals_each;
 167                                 my %bn;
 168                                 for my $loc (keys %$all) {
 169                                         my $bn = (split(m!/!, $loc))[-1];
 170                                         ++$bn{$bn};
 171                                 }
 172                                 push @c, grep {
 173                                         $bn{$_} == 1 && /\A\Q$cur[0]/
 174                                 } keys %bn;
 175                         }
 176                         return @c if @c;
 177                 }
 178                 unshift(@cur, pop @argv);
 179         }
 180         ();
 181 }
 182
 183 # Stuff we may pass through to curl (as of 7.64.0), see curl manpage for
 184 # details, so most options which make sense for HTTP/HTTPS (including proxy
 185 # support for Tor and other methods of getting past weird networks).
 186 # Most of these are untested by us, some may not make sense for our use case
 187 # and typos below are likely.
 188 # n.b. some short options (-$NUMBER) are not supported since they conflict
 189 # with other "lei q" switches.
 190 # FIXME: Getopt::Long doesn't easily let us support support options with
 191 # '.' in them (e.g. --http1.1)
 192 # TODO: should we depend on "-c http.*" options for things which have
 193 # analogues in git(1)? that would reduce likelihood of conflicts with
 194 # our other CLI options
 195 # Note: some names are renamed to avoid potential conflicts,
 196 # see %lei2curl in lib/PublicInbox/LeiCurl.pm
 197 sub curl_opt { qw(
 198         curl-config=s@
 199         abstract-unix-socket=s anyauth basic cacert=s capath=s
 200         cert-status cert-type cert=s ciphers=s
 201         connect-timeout=s connect-to=s cookie-jar=s cookie=s crlfile=s
 202         digest disable dns-interface=s dns-ipv4-addr=s dns-ipv6-addr=s
 203         dns-servers=s doh-url=s egd-file=s engine=s false-start
 204         happy-eyeballs-timeout-ms=s haproxy-protocol header=s@
 205         http2-prior-knowledge http2 insecure
 206         interface=s ipv4 ipv6 junk-session-cookies
 207         key-type=s key=s limit-rate=s local-port=s location-trusted location
 208         max-redirs=i max-time=s negotiate netrc-file=s netrc-optional netrc
 209         no-alpn no-buffer no-npn no-sessionid noproxy=s ntlm-wb ntlm
 210         pass=s pinnedpubkey=s post301 post302 post303 preproxy=s
 211         proxy-anyauth proxy-basic proxy-cacert=s proxy-capath=s
 212         proxy-cert-type=s proxy-cert=s proxy-ciphers=s proxy-crlfile=s
 213         proxy-digest proxy-header=s@ proxy-insecure
 214         proxy-key-type=s proxy-key proxy-negotiate proxy-ntlm proxy-pass=s
 215         proxy-pinnedpubkey=s proxy-service-name=s proxy-ssl-allow-beast
 216         proxy-tls13-ciphers=s proxy-tlsauthtype=s proxy-tlspassword=s
 217         proxy-tlsuser=s proxy-tlsv1 proxy-user=s proxy=s
 218         proxytunnel=s pubkey=s random-file=s referer=s resolve=s
 219         retry-connrefused retry-delay=s retry-max-time=s retry=i
 220         sasl-ir service-name=s socks4=s socks4a=s socks5-basic
 221         socks5-gssapi-service-name=s socks5-gssapi socks5-hostname=s socks5=s
 222         speed-limit speed-type ssl-allow-beast sslv2 sslv3
 223         suppress-connect-headers tcp-fastopen tls-max=s
 224         tls13-ciphers=s tlsauthtype=s tlspassword=s tlsuser=s
 225         tlsv1 trace-ascii=s trace-time trace=s
 226         unix-socket=s user-agent=s user=s
 227 )
 228 }
 229
 230 1;