lib/PublicInbox/LeiQuery.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # handles lei <q|ls-query|rm-query|mv-query> commands
   5 package PublicInbox::LeiQuery;
   6 use strict;
   7 use v5.10.1;
   8 use POSIX ();
   9
  10 sub prep_ext { # externals_each callback
  11         my ($lxs, $exclude, $loc) = @_;
  12         $lxs->prepare_external($loc) unless $exclude->{$loc};
  13 }
  14
  15 sub _start_query { # used by "lei q" and "lei up"
  16         my ($self) = @_;
  17         PublicInbox::LeiOverview->new($self) or return;
  18         my $opt = $self->{opt};
  19         my ($xj, $mj) = split(/,/, $opt->{jobs} // '');
  20         if (defined($xj) && $xj ne '' && $xj !~ /\A[1-9][0-9]*\z/) {
  21                 return $self->fail("`$xj' search jobs must be >= 1");
  22         }
  23         my $lxs = $self->{lxs};
  24         $xj ||= $lxs->concurrency($opt); # allow: "--jobs ,$WRITER_ONLY"
  25         my $nproc = $lxs->detect_nproc // 1; # don't memoize, schedtool(1) exists
  26         $xj = $nproc if $xj > $nproc;
  27         $lxs->{-wq_nr_workers} = $xj;
  28         if (defined($mj) && $mj !~ /\A[1-9][0-9]*\z/) {
  29                 return $self->fail("`$mj' writer jobs must be >= 1");
  30         }
  31         my $l2m = $self->{l2m};
  32         if ($l2m && ($opt->{'import-remote'} //= 1) |
  33                                 # we use \1 (a ref) to distinguish between
  34                                 # user-supplied and default value
  35                                 (($opt->{'import-before'} //= \1) ? 1 : 0)) {
  36                 $self->_lei_store(1)->write_prepare($self);
  37         }
  38         $l2m and $l2m->{-wq_nr_workers} = $mj // do {
  39                 $mj = POSIX::lround($nproc * 3 / 4); # keep some CPU for git
  40                 $mj <= 0 ? 1 : $mj;
  41         };
  42
  43         # descending docid order is cheapest, MUA controls sorting order
  44         $self->{mset_opt}->{relevance} //= -2 if $l2m || $opt->{threads};
  45         if ($self->{net}) {
  46                 require PublicInbox::LeiAuth;
  47                 $self->{auth} = PublicInbox::LeiAuth->new
  48         }
  49         $lxs->do_query($self);
  50 }
  51
  52 sub qstr_add { # PublicInbox::InputPipe::consume callback for --stdin
  53         my ($self) = @_; # $_[1] = $rbuf
  54         if (defined($_[1])) {
  55                 $_[1] eq '' and return eval {
  56                         $self->{mset_opt}->{q_raw} = $self->{mset_opt}->{qstr};
  57                         $self->{lse}->query_approxidate($self->{lse}->git,
  58                                                 $self->{mset_opt}->{qstr});
  59                         _start_query($self);
  60                 };
  61                 $self->{mset_opt}->{qstr} .= $_[1];
  62         } else {
  63                 $self->fail("error reading stdin: $!");
  64         }
  65 }
  66
  67 sub lxs_prepare {
  68         my ($self) = @_;
  69         require PublicInbox::LeiXSearch;
  70         # prepare any number of LeiXSearch || LeiSearch || Inbox || URL
  71         my $lxs = $self->{lxs} = PublicInbox::LeiXSearch->new;
  72         my $opt = $self->{opt};
  73         my @only = @{$opt->{only} // []};
  74         # --local is enabled by default unless --only is used
  75         # we'll allow "--only $LOCATION --local"
  76         my $sto = $self->_lei_store(1); # FIXME: should not create
  77         $self->{lse} = $sto->search;
  78         if ($opt->{'local'} //= scalar(@only) ? 0 : 1) {
  79                 $lxs->prepare_external($self->{lse});
  80         }
  81         if (@only) {
  82                 for my $loc (@only) {
  83                         my @loc = $self->get_externals($loc) or return;
  84                         $lxs->prepare_external($_) for @loc;
  85                 }
  86         } else {
  87                 my (@ilocals, @iremotes);
  88                 for my $loc (@{$opt->{include} // []}) {
  89                         my @loc = $self->get_externals($loc) or return;
  90                         $lxs->prepare_external($_) for @loc;
  91                         @ilocals = @{$lxs->{locals} // []};
  92                         @iremotes = @{$lxs->{remotes} // []};
  93                 }
  94                 # --external is enabled by default, but allow --no-external
  95                 if ($opt->{external} //= 1) {
  96                         my %x;
  97                         for my $loc (@{$opt->{exclude} // []}) {
  98                                 my @l = $self->get_externals($loc, 1) or return;
  99                                 $x{$_} = 1 for @l;
 100                         }
 101                         my $ne = $self->externals_each(\&prep_ext, $lxs, \%x);
 102                         $opt->{remote} //= !($lxs->locals - $opt->{'local'});
 103                         if ($opt->{'local'}) {
 104                                 $lxs->{remotes} = \@iremotes if !$opt->{remote};
 105                         } else {
 106                                 $lxs->{locals} = \@ilocals;
 107                         }
 108                 }
 109         }
 110         ($lxs->locals || $lxs->remotes) ? ($self->{lxs} = $lxs) :
 111                 $self->fail('no local or remote inboxes to search');
 112 }
 113
 114 # the main "lei q SEARCH_TERMS" method
 115 sub lei_q {
 116         my ($self, @argv) = @_;
 117         require PublicInbox::LeiOverview;
 118         PublicInbox::Config->json; # preload before forking
 119         my $lxs = lxs_prepare($self) or return;
 120         $self->ale->refresh_externals($lxs);
 121         my $opt = $self->{opt};
 122         my %mset_opt = map { $_ => $opt->{$_} } qw(threads limit offset);
 123         $mset_opt{asc} = $opt->{'reverse'} ? 1 : 0;
 124         $mset_opt{limit} //= 10000;
 125         if (defined(my $sort = $opt->{'sort'})) {
 126                 if ($sort eq 'relevance') {
 127                         $mset_opt{relevance} = 1;
 128                 } elsif ($sort eq 'docid') {
 129                         $mset_opt{relevance} = $mset_opt{asc} ? -1 : -2;
 130                 } elsif ($sort =~ /\Areceived(?:-?[aA]t)?\z/) {
 131                         # the default
 132                 } else {
 133                         die "unrecognized --sort=$sort\n";
 134                 }
 135         }
 136         $self->{mset_opt} = \%mset_opt;
 137
 138         if ($opt->{stdin}) {
 139                 return $self->fail(<<'') if @argv;
 140 no query allowed on command-line with --stdin
 141
 142                 require PublicInbox::InputPipe;
 143                 PublicInbox::InputPipe::consume($self->{0}, \&qstr_add, $self);
 144                 return;
 145         }
 146         $mset_opt{q_raw} = \@argv;
 147         $mset_opt{qstr} =
 148                 $self->{lse}->query_argv_to_string($self->{lse}->git, \@argv);
 149         _start_query($self);
 150 }
 151
 152 # shell completion helper called by lei__complete
 153 sub _complete_q {
 154         my ($self, @argv) = @_;
 155         my $ext = qr/\A(?:-I|(?:--(?:include|exclude|only)))\z/;
 156         my @cur;
 157         while (@argv) {
 158                 if ($argv[-1] =~ $ext) {
 159                         my @c = $self->_complete_forget_external(@cur);
 160                         # try basename match:
 161                         if (scalar(@cur) == 1 && index($cur[0], '/') < 0) {
 162                                 my $all = $self->externals_each;
 163                                 my %bn;
 164                                 for my $loc (keys %$all) {
 165                                         my $bn = (split(m!/!, $loc))[-1];
 166                                         ++$bn{$bn};
 167                                 }
 168                                 push @c, grep {
 169                                         $bn{$_} == 1 && /\A\Q$cur[0]/
 170                                 } keys %bn;
 171                         }
 172                         return @c if @c;
 173                 }
 174                 unshift(@cur, pop @argv);
 175         }
 176         ();
 177 }
 178
 179 # Stuff we may pass through to curl (as of 7.64.0), see curl manpage for
 180 # details, so most options which make sense for HTTP/HTTPS (including proxy
 181 # support for Tor and other methods of getting past weird networks).
 182 # Most of these are untested by us, some may not make sense for our use case
 183 # and typos below are likely.
 184 # n.b. some short options (-$NUMBER) are not supported since they conflict
 185 # with other "lei q" switches.
 186 # FIXME: Getopt::Long doesn't easily let us support support options with
 187 # '.' in them (e.g. --http1.1)
 188 # TODO: should we depend on "-c http.*" options for things which have
 189 # analogues in git(1)? that would reduce likelyhood of conflicts with
 190 # our other CLI options
 191 # Note: some names are renamed to avoid potential conflicts,
 192 # see %lei2mail in lib/PublicInbox/LeiCurl.pm
 193 sub curl_opt { qw(
 194         curl-config=s@
 195         abstract-unix-socket=s anyauth basic cacert=s capath=s
 196         cert-status cert-type cert=s ciphers=s
 197         connect-timeout=s connect-to=s cookie-jar=s cookie=s crlfile=s
 198         digest disable dns-interface=s dns-ipv4-addr=s dns-ipv6-addr=s
 199         dns-servers=s doh-url=s egd-file=s engine=s false-start
 200         happy-eyeballs-timeout-ms=s haproxy-protocol header=s@
 201         http2-prior-knowledge http2 insecure
 202         interface=s ipv4 ipv6 junk-session-cookies
 203         key-type=s key=s limit-rate=s local-port=s location-trusted location
 204         max-redirs=i max-time=s negotiate netrc-file=s netrc-optional netrc
 205         no-alpn no-buffer no-npn no-sessionid noproxy=s ntlm-wb ntlm
 206         pass=s pinnedpubkey=s post301 post302 post303 preproxy=s
 207         proxy-anyauth proxy-basic proxy-cacert=s proxy-capath=s
 208         proxy-cert-type=s proxy-cert=s proxy-ciphers=s proxy-crlfile=s
 209         proxy-digest proxy-header=s@ proxy-insecure
 210         proxy-key-type=s proxy-key proxy-negotiate proxy-ntlm proxy-pass=s
 211         proxy-pinnedpubkey=s proxy-service-name=s proxy-ssl-allow-beast
 212         proxy-tls13-ciphers=s proxy-tlsauthtype=s proxy-tlspassword=s
 213         proxy-tlsuser=s proxy-tlsv1 proxy-user=s proxy=s
 214         proxytunnel=s pubkey=s random-file=s referer=s resolve=s
 215         retry-connrefused retry-delay=s retry-max-time=s retry=i
 216         sasl-ir service-name=s socks4=s socks4a=s socks5-basic
 217         socks5-gssapi-service-name=s socks5-gssapi socks5-hostname=s socks5=s
 218         speed-limit speed-type ssl-allow-beast sslv2 sslv3
 219         suppress-connect-headers tcp-fastopen tls-max=s
 220         tls13-ciphers=s tlsauthtype=s tlspassword=s tlsuser=s
 221         tlsv1 trace-ascii=s trace-time trace=s
 222         unix-socket=s user-agent=s user=s
 223 )
 224 }
 225
 226 1;