lib/PublicInbox/LeiQuery.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # handles "lei q" command and provides internals for
   5 # several other sub-commands (up, lcat, ...)
   6 package PublicInbox::LeiQuery;
   7 use strict;
   8 use v5.10.1;
   9
  10 sub prep_ext { # externals_each callback
  11         my ($lxs, $exclude, $loc) = @_;
  12         $lxs->prepare_external($loc) unless $exclude->{$loc};
  13 }
  14
  15 sub _start_query { # used by "lei q" and "lei up"
  16         my ($self) = @_;
  17         require PublicInbox::LeiOverview;
  18         PublicInbox::LeiOverview->new($self) or return;
  19         my $opt = $self->{opt};
  20         my ($xj, $mj) = split(/,/, $opt->{jobs} // '');
  21         (defined($xj) && $xj ne '' && $xj !~ /\A[1-9][0-9]*\z/) and
  22                 die "`$xj' search jobs must be >= 1\n";
  23         my $lxs = $self->{lxs};
  24         $xj ||= $lxs->concurrency($opt); # allow: "--jobs ,$WRITER_ONLY"
  25         my $nproc = $lxs->detect_nproc || 1; # don't memoize, schedtool(1) exists
  26         $xj = $nproc if $xj > $nproc;
  27         $lxs->{-wq_nr_workers} = $xj;
  28         (defined($mj) && $mj !~ /\A[1-9][0-9]*\z/) and
  29                 die "`$mj' writer jobs must be >= 1\n";
  30         my $l2m = $self->{l2m};
  31         # we use \1 (a ref) to distinguish between default vs. user-supplied
  32         if ($l2m && grep { $opt->{$_} //= \1 } (qw(mail-sync import-remote
  33                                                         import-before))) {
  34                 $self->_lei_store(1)->write_prepare($self);
  35                 if ($opt->{'mail-sync'}) {
  36                         my $lms = $l2m->{-lms_rw} = $self->lms(1);
  37                         $lms->lms_write_prepare->lms_pause; # just create
  38                 }
  39         }
  40         $l2m and $l2m->{-wq_nr_workers} //= $mj //
  41                 int($nproc * 0.75 + 0.5); # keep some CPU for git
  42
  43         # descending docid order is cheapest, MUA controls sorting order
  44         $self->{mset_opt}->{relevance} //= -2 if $l2m || $opt->{threads};
  45
  46         my $tot = $self->{mset_opt}->{total} //= $self->{opt}->{limit} // 10000;
  47         $self->{mset_opt}->{limit} = $tot > 10000 ? 10000 : $tot;
  48         $self->{mset_opt}->{offset} //= 0;
  49         $self->{mset_opt}->{threads} //= $opt->{threads};
  50
  51         if ($self->{net}) {
  52                 require PublicInbox::LeiAuth;
  53                 $self->{auth} = PublicInbox::LeiAuth->new
  54         }
  55         $lxs->do_query($self);
  56 }
  57
  58 sub qstr_add { # PublicInbox::InputPipe::consume callback for --stdin
  59         my ($lei) = @_; # $_[1] = $rbuf
  60         $_[1] // $lei->fail("error reading stdin: $!");
  61         return $lei->{mset_opt}->{qstr} .= $_[1] if $_[1] ne '';
  62         eval {
  63                 $lei->fchdir;
  64                 $lei->{mset_opt}->{q_raw} = $lei->{mset_opt}->{qstr};
  65                 $lei->{lse}->query_approxidate($lei->{lse}->git,
  66                                                 $lei->{mset_opt}->{qstr});
  67                 _start_query($lei);
  68         };
  69         $lei->fail($@) if $@;
  70 }
  71
  72 sub lxs_prepare {
  73         my ($self) = @_;
  74         require PublicInbox::LeiXSearch;
  75         # prepare any number of LeiXSearch || LeiSearch || Inbox || URL
  76         my $lxs = $self->{lxs} = PublicInbox::LeiXSearch->new;
  77         my $opt = $self->{opt};
  78         my @only = @{$opt->{only} // []};
  79         # --local is enabled by default unless --only is used
  80         # we'll allow "--only $LOCATION --local"
  81         my $sto = $self->_lei_store(1);
  82         $self->{lse} = $sto->search;
  83         if ($opt->{'local'} //= scalar(@only) ? 0 : 1) {
  84                 $lxs->prepare_external($self->{lse});
  85         }
  86         if (@only) {
  87                 for my $loc (@only) {
  88                         my @loc = $self->get_externals($loc) or return;
  89                         $lxs->prepare_external($_) for @loc;
  90                 }
  91         } else {
  92                 my (@ilocals, @iremotes);
  93                 for my $loc (@{$opt->{include} // []}) {
  94                         my @loc = $self->get_externals($loc) or return;
  95                         $lxs->prepare_external($_) for @loc;
  96                         @ilocals = @{$lxs->{locals} // []};
  97                         @iremotes = @{$lxs->{remotes} // []};
  98                 }
  99                 # --external is enabled by default, but allow --no-external
 100                 if ($opt->{external} //= 1) {
 101                         my $ex = $self->canonicalize_excludes($opt->{exclude});
 102                         $self->externals_each(\&prep_ext, $lxs, $ex);
 103                         $opt->{remote} //= !($lxs->locals - $opt->{'local'});
 104                         $lxs->{locals} = \@ilocals if !$opt->{'local'};
 105                         $lxs->{remotes} = \@iremotes if !$opt->{remote};
 106                 }
 107         }
 108         ($lxs->locals || $lxs->remotes) ? ($self->{lxs} = $lxs) :
 109                 die("no local or remote inboxes to search\n");
 110 }
 111
 112 # the main "lei q SEARCH_TERMS" method
 113 sub lei_q {
 114         my ($self, @argv) = @_;
 115         PublicInbox::Config->json; # preload before forking
 116         my $lxs = lxs_prepare($self) or return;
 117         $self->ale->refresh_externals($lxs, $self);
 118         my $opt = $self->{opt};
 119         my %mset_opt;
 120         $mset_opt{asc} = $opt->{'reverse'} ? 1 : 0;
 121         if (defined(my $sort = $opt->{'sort'})) {
 122                 if ($sort eq 'relevance') {
 123                         $mset_opt{relevance} = 1;
 124                 } elsif ($sort eq 'docid') {
 125                         $mset_opt{relevance} = $mset_opt{asc} ? -1 : -2;
 126                 } elsif ($sort =~ /\Areceived(?:-?[aA]t)?\z/) {
 127                         # the default
 128                 } else {
 129                         die "unrecognized --sort=$sort\n";
 130                 }
 131                 $opt->{save} and return
 132                         $self->fail('--save and --sort are incompatible');
 133         }
 134         $self->{mset_opt} = \%mset_opt;
 135
 136         if ($opt->{stdin}) {
 137                 return $self->fail(<<'') if @argv;
 138 no query allowed on command-line with --stdin
 139
 140                 require PublicInbox::InputPipe;
 141                 PublicInbox::InputPipe::consume($self->{0}, \&qstr_add, $self);
 142                 return;
 143         }
 144         chomp(@argv) and $self->qerr("# trailing `\\n' removed");
 145         $mset_opt{q_raw} = [ @argv ]; # copy
 146         $mset_opt{qstr} =
 147                 $self->{lse}->query_argv_to_string($self->{lse}->git, \@argv);
 148         _start_query($self);
 149 }
 150
 151 # shell completion helper called by lei__complete
 152 sub _complete_q {
 153         my ($self, @argv) = @_;
 154         my @cur;
 155         my $cb = $self->lazy_cb(qw(forget-external _complete_));
 156         while (@argv) {
 157                 if ($argv[-1] =~ /\A(?:-I|(?:--(?:include|exclude|only)))\z/) {
 158                         my @c = $cb->($self, @cur);
 159                         # try basename match:
 160                         if (scalar(@cur) == 1 && index($cur[0], '/') < 0) {
 161                                 my $all = $self->externals_each;
 162                                 my %bn;
 163                                 for my $loc (keys %$all) {
 164                                         my $bn = (split(m!/!, $loc))[-1];
 165                                         ++$bn{$bn};
 166                                 }
 167                                 push @c, grep {
 168                                         $bn{$_} == 1 && /\A\Q$cur[0]/
 169                                 } keys %bn;
 170                         }
 171                         return @c if @c;
 172                 }
 173                 unshift(@cur, pop @argv);
 174         }
 175         ();
 176 }
 177
 178 # Stuff we may pass through to curl (as of 7.64.0), see curl manpage for
 179 # details, so most options which make sense for HTTP/HTTPS (including proxy
 180 # support for Tor and other methods of getting past weird networks).
 181 # Most of these are untested by us, some may not make sense for our use case
 182 # and typos below are likely.
 183 # n.b. some short options (-$NUMBER) are not supported since they conflict
 184 # with other "lei q" switches.
 185 # FIXME: Getopt::Long doesn't easily let us support support options with
 186 # '.' in them (e.g. --http1.1)
 187 # TODO: should we depend on "-c http.*" options for things which have
 188 # analogues in git(1)? that would reduce likelihood of conflicts with
 189 # our other CLI options
 190 # Note: some names are renamed to avoid potential conflicts,
 191 # see %lei2curl in lib/PublicInbox/LeiCurl.pm
 192 sub curl_opt { qw(
 193         curl-config=s@
 194         abstract-unix-socket=s anyauth basic cacert=s capath=s
 195         cert-status cert-type cert=s ciphers=s
 196         connect-timeout=s connect-to=s cookie-jar=s cookie=s crlfile=s
 197         digest disable dns-interface=s dns-ipv4-addr=s dns-ipv6-addr=s
 198         dns-servers=s doh-url=s egd-file=s engine=s false-start
 199         happy-eyeballs-timeout-ms=s haproxy-protocol header=s@
 200         http2-prior-knowledge http2 insecure
 201         interface=s ipv4 ipv6 junk-session-cookies
 202         key-type=s key=s limit-rate=s local-port=s location-trusted location
 203         max-redirs=i max-time=s negotiate netrc-file=s netrc-optional netrc
 204         no-alpn no-buffer no-npn no-sessionid noproxy=s ntlm-wb ntlm
 205         pass=s pinnedpubkey=s post301 post302 post303 preproxy=s
 206         proxy-anyauth proxy-basic proxy-cacert=s proxy-capath=s
 207         proxy-cert-type=s proxy-cert=s proxy-ciphers=s proxy-crlfile=s
 208         proxy-digest proxy-header=s@ proxy-insecure
 209         proxy-key-type=s proxy-key proxy-negotiate proxy-ntlm proxy-pass=s
 210         proxy-pinnedpubkey=s proxy-service-name=s proxy-ssl-allow-beast
 211         proxy-tls13-ciphers=s proxy-tlsauthtype=s proxy-tlspassword=s
 212         proxy-tlsuser=s proxy-tlsv1 proxy-user=s proxy=s
 213         proxytunnel=s pubkey=s random-file=s referer=s resolve=s
 214         retry-connrefused retry-delay=s retry-max-time=s retry=i
 215         sasl-ir service-name=s socks4=s socks4a=s socks5-basic
 216         socks5-gssapi-service-name=s socks5-gssapi socks5-hostname=s socks5=s
 217         speed-limit speed-type ssl-allow-beast sslv2 sslv3
 218         suppress-connect-headers tcp-fastopen tls-max=s
 219         tls13-ciphers=s tlsauthtype=s tlspassword=s tlsuser=s
 220         tlsv1 trace-ascii=s trace-time trace=s
 221         unix-socket=s user-agent=s user=s
 222 )
 223 }
 224
 225 1;