lib/PublicInbox/LeiQuery.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # handles "lei q" command and provides internals for
   5 # several other sub-commands (up, lcat, ...)
   6 package PublicInbox::LeiQuery;
   7 use strict;
   8 use v5.10.1;
   9
  10 sub prep_ext { # externals_each callback
  11         my ($lxs, $exclude, $loc) = @_;
  12         $lxs->prepare_external($loc) unless $exclude->{$loc};
  13 }
  14
  15 sub _start_query { # used by "lei q" and "lei up"
  16         my ($self) = @_;
  17         require PublicInbox::LeiOverview;
  18         PublicInbox::LeiOverview->new($self) or return;
  19         my $opt = $self->{opt};
  20         my ($xj, $mj) = split(/,/, $opt->{jobs} // '');
  21         (defined($xj) && $xj ne '' && $xj !~ /\A[1-9][0-9]*\z/) and
  22                 die "`$xj' search jobs must be >= 1\n";
  23         my $lxs = $self->{lxs};
  24         $xj ||= $lxs->concurrency($opt); # allow: "--jobs ,$WRITER_ONLY"
  25         my $nproc = $lxs->detect_nproc || 1; # don't memoize, schedtool(1) exists
  26         $xj = $nproc if $xj > $nproc;
  27         $lxs->{-wq_nr_workers} = $xj;
  28         (defined($mj) && $mj !~ /\A[1-9][0-9]*\z/) and
  29                 die "`$mj' writer jobs must be >= 1\n";
  30         my $l2m = $self->{l2m};
  31         # we use \1 (a ref) to distinguish between default vs. user-supplied
  32         if ($l2m && grep { $opt->{$_} //= \1 } (qw(mail-sync import-remote
  33                                                         import-before))) {
  34                 $self->_lei_store(1)->write_prepare($self);
  35         }
  36         $l2m and $l2m->{-wq_nr_workers} = $mj // do {
  37                 $mj = int($nproc * 0.75 + 0.5); # keep some CPU for git
  38         };
  39
  40         # descending docid order is cheapest, MUA controls sorting order
  41         $self->{mset_opt}->{relevance} //= -2 if $l2m || $opt->{threads};
  42
  43         my $tot = $self->{mset_opt}->{total} //= $self->{opt}->{limit} // 10000;
  44         $self->{mset_opt}->{limit} = $tot > 10000 ? 10000 : $tot;
  45         $self->{mset_opt}->{offset} //= 0;
  46         $self->{mset_opt}->{threads} //= $opt->{threads};
  47
  48         if ($self->{net}) {
  49                 require PublicInbox::LeiAuth;
  50                 $self->{auth} = PublicInbox::LeiAuth->new
  51         }
  52         $lxs->do_query($self);
  53 }
  54
  55 sub qstr_add { # PublicInbox::InputPipe::consume callback for --stdin
  56         my ($lei) = @_; # $_[1] = $rbuf
  57         $_[1] // $lei->fail("error reading stdin: $!");
  58         return $lei->{mset_opt}->{qstr} .= $_[1] if $_[1] ne '';
  59         eval {
  60                 $lei->fchdir;
  61                 $lei->{mset_opt}->{q_raw} = $lei->{mset_opt}->{qstr};
  62                 $lei->{lse}->query_approxidate($lei->{lse}->git,
  63                                                 $lei->{mset_opt}->{qstr});
  64                 _start_query($lei);
  65         };
  66         $lei->fail($@) if $@;
  67 }
  68
  69 sub lxs_prepare {
  70         my ($self) = @_;
  71         require PublicInbox::LeiXSearch;
  72         # prepare any number of LeiXSearch || LeiSearch || Inbox || URL
  73         my $lxs = $self->{lxs} = PublicInbox::LeiXSearch->new;
  74         my $opt = $self->{opt};
  75         my @only = @{$opt->{only} // []};
  76         # --local is enabled by default unless --only is used
  77         # we'll allow "--only $LOCATION --local"
  78         my $sto = $self->_lei_store(1);
  79         $self->{lse} = $sto->search;
  80         if ($opt->{'local'} //= scalar(@only) ? 0 : 1) {
  81                 $lxs->prepare_external($self->{lse});
  82         }
  83         if (@only) {
  84                 for my $loc (@only) {
  85                         my @loc = $self->get_externals($loc) or return;
  86                         $lxs->prepare_external($_) for @loc;
  87                 }
  88         } else {
  89                 my (@ilocals, @iremotes);
  90                 for my $loc (@{$opt->{include} // []}) {
  91                         my @loc = $self->get_externals($loc) or return;
  92                         $lxs->prepare_external($_) for @loc;
  93                         @ilocals = @{$lxs->{locals} // []};
  94                         @iremotes = @{$lxs->{remotes} // []};
  95                 }
  96                 # --external is enabled by default, but allow --no-external
  97                 if ($opt->{external} //= 1) {
  98                         my $ex = $self->canonicalize_excludes($opt->{exclude});
  99                         $self->externals_each(\&prep_ext, $lxs, $ex);
 100                         $opt->{remote} //= !($lxs->locals - $opt->{'local'});
 101                         $lxs->{locals} = \@ilocals if !$opt->{'local'};
 102                         $lxs->{remotes} = \@iremotes if !$opt->{remote};
 103                 }
 104         }
 105         ($lxs->locals || $lxs->remotes) ? ($self->{lxs} = $lxs) :
 106                 die("no local or remote inboxes to search\n");
 107 }
 108
 109 # the main "lei q SEARCH_TERMS" method
 110 sub lei_q {
 111         my ($self, @argv) = @_;
 112         PublicInbox::Config->json; # preload before forking
 113         my $lxs = lxs_prepare($self) or return;
 114         $self->ale->refresh_externals($lxs, $self);
 115         my $opt = $self->{opt};
 116         my %mset_opt;
 117         $mset_opt{asc} = $opt->{'reverse'} ? 1 : 0;
 118         if (defined(my $sort = $opt->{'sort'})) {
 119                 if ($sort eq 'relevance') {
 120                         $mset_opt{relevance} = 1;
 121                 } elsif ($sort eq 'docid') {
 122                         $mset_opt{relevance} = $mset_opt{asc} ? -1 : -2;
 123                 } elsif ($sort =~ /\Areceived(?:-?[aA]t)?\z/) {
 124                         # the default
 125                 } else {
 126                         die "unrecognized --sort=$sort\n";
 127                 }
 128                 $opt->{save} and return
 129                         $self->fail('--save and --sort are incompatible');
 130         }
 131         $self->{mset_opt} = \%mset_opt;
 132
 133         if ($opt->{stdin}) {
 134                 return $self->fail(<<'') if @argv;
 135 no query allowed on command-line with --stdin
 136
 137                 require PublicInbox::InputPipe;
 138                 PublicInbox::InputPipe::consume($self->{0}, \&qstr_add, $self);
 139                 return;
 140         }
 141         $mset_opt{q_raw} = [ @argv ]; # copy
 142         $mset_opt{qstr} =
 143                 $self->{lse}->query_argv_to_string($self->{lse}->git, \@argv);
 144         _start_query($self);
 145 }
 146
 147 # shell completion helper called by lei__complete
 148 sub _complete_q {
 149         my ($self, @argv) = @_;
 150         my @cur;
 151         my $cb = $self->lazy_cb(qw(forget-external _complete_));
 152         while (@argv) {
 153                 if ($argv[-1] =~ /\A(?:-I|(?:--(?:include|exclude|only)))\z/) {
 154                         my @c = $cb->($self, @cur);
 155                         # try basename match:
 156                         if (scalar(@cur) == 1 && index($cur[0], '/') < 0) {
 157                                 my $all = $self->externals_each;
 158                                 my %bn;
 159                                 for my $loc (keys %$all) {
 160                                         my $bn = (split(m!/!, $loc))[-1];
 161                                         ++$bn{$bn};
 162                                 }
 163                                 push @c, grep {
 164                                         $bn{$_} == 1 && /\A\Q$cur[0]/
 165                                 } keys %bn;
 166                         }
 167                         return @c if @c;
 168                 }
 169                 unshift(@cur, pop @argv);
 170         }
 171         ();
 172 }
 173
 174 # Stuff we may pass through to curl (as of 7.64.0), see curl manpage for
 175 # details, so most options which make sense for HTTP/HTTPS (including proxy
 176 # support for Tor and other methods of getting past weird networks).
 177 # Most of these are untested by us, some may not make sense for our use case
 178 # and typos below are likely.
 179 # n.b. some short options (-$NUMBER) are not supported since they conflict
 180 # with other "lei q" switches.
 181 # FIXME: Getopt::Long doesn't easily let us support support options with
 182 # '.' in them (e.g. --http1.1)
 183 # TODO: should we depend on "-c http.*" options for things which have
 184 # analogues in git(1)? that would reduce likelyhood of conflicts with
 185 # our other CLI options
 186 # Note: some names are renamed to avoid potential conflicts,
 187 # see %lei2curl in lib/PublicInbox/LeiCurl.pm
 188 sub curl_opt { qw(
 189         curl-config=s@
 190         abstract-unix-socket=s anyauth basic cacert=s capath=s
 191         cert-status cert-type cert=s ciphers=s
 192         connect-timeout=s connect-to=s cookie-jar=s cookie=s crlfile=s
 193         digest disable dns-interface=s dns-ipv4-addr=s dns-ipv6-addr=s
 194         dns-servers=s doh-url=s egd-file=s engine=s false-start
 195         happy-eyeballs-timeout-ms=s haproxy-protocol header=s@
 196         http2-prior-knowledge http2 insecure
 197         interface=s ipv4 ipv6 junk-session-cookies
 198         key-type=s key=s limit-rate=s local-port=s location-trusted location
 199         max-redirs=i max-time=s negotiate netrc-file=s netrc-optional netrc
 200         no-alpn no-buffer no-npn no-sessionid noproxy=s ntlm-wb ntlm
 201         pass=s pinnedpubkey=s post301 post302 post303 preproxy=s
 202         proxy-anyauth proxy-basic proxy-cacert=s proxy-capath=s
 203         proxy-cert-type=s proxy-cert=s proxy-ciphers=s proxy-crlfile=s
 204         proxy-digest proxy-header=s@ proxy-insecure
 205         proxy-key-type=s proxy-key proxy-negotiate proxy-ntlm proxy-pass=s
 206         proxy-pinnedpubkey=s proxy-service-name=s proxy-ssl-allow-beast
 207         proxy-tls13-ciphers=s proxy-tlsauthtype=s proxy-tlspassword=s
 208         proxy-tlsuser=s proxy-tlsv1 proxy-user=s proxy=s
 209         proxytunnel=s pubkey=s random-file=s referer=s resolve=s
 210         retry-connrefused retry-delay=s retry-max-time=s retry=i
 211         sasl-ir service-name=s socks4=s socks4a=s socks5-basic
 212         socks5-gssapi-service-name=s socks5-gssapi socks5-hostname=s socks5=s
 213         speed-limit speed-type ssl-allow-beast sslv2 sslv3
 214         suppress-connect-headers tcp-fastopen tls-max=s
 215         tls13-ciphers=s tlsauthtype=s tlspassword=s tlsuser=s
 216         tlsv1 trace-ascii=s trace-time trace=s
 217         unix-socket=s user-agent=s user=s
 218 )
 219 }
 220
 221 1;