lib/PublicInbox/LeiQuery.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # handles lei <q|ls-query|rm-query|mv-query> commands
   5 package PublicInbox::LeiQuery;
   6 use strict;
   7 use v5.10.1;
   8
   9 sub prep_ext { # externals_each callback
  10         my ($lxs, $exclude, $loc) = @_;
  11         $lxs->prepare_external($loc) unless $exclude->{$loc};
  12 }
  13
  14 sub _start_query { # used by "lei q" and "lei up"
  15         my ($self) = @_;
  16         require PublicInbox::LeiOverview;
  17         PublicInbox::LeiOverview->new($self) or return;
  18         my $opt = $self->{opt};
  19         my ($xj, $mj) = split(/,/, $opt->{jobs} // '');
  20         if (defined($xj) && $xj ne '' && $xj !~ /\A[1-9][0-9]*\z/) {
  21                 return $self->fail("`$xj' search jobs must be >= 1");
  22         }
  23         my $lxs = $self->{lxs};
  24         $xj ||= $lxs->concurrency($opt); # allow: "--jobs ,$WRITER_ONLY"
  25         my $nproc = $lxs->detect_nproc || 1; # don't memoize, schedtool(1) exists
  26         $xj = $nproc if $xj > $nproc;
  27         $lxs->{-wq_nr_workers} = $xj;
  28         if (defined($mj) && $mj !~ /\A[1-9][0-9]*\z/) {
  29                 return $self->fail("`$mj' writer jobs must be >= 1");
  30         }
  31         my $l2m = $self->{l2m};
  32         if ($l2m && ($opt->{'import-remote'} //= 1) |
  33                                 # we use \1 (a ref) to distinguish between
  34                                 # user-supplied and default value
  35                                 (($opt->{'import-before'} //= \1) ? 1 : 0)) {
  36                 $self->_lei_store(1)->write_prepare($self);
  37         }
  38         $l2m and $l2m->{-wq_nr_workers} = $mj // do {
  39                 $mj = int($nproc * 0.75 + 0.5); # keep some CPU for git
  40         };
  41
  42         # descending docid order is cheapest, MUA controls sorting order
  43         $self->{mset_opt}->{relevance} //= -2 if $l2m || $opt->{threads};
  44         if ($self->{net}) {
  45                 require PublicInbox::LeiAuth;
  46                 $self->{auth} = PublicInbox::LeiAuth->new
  47         }
  48         $lxs->do_query($self);
  49 }
  50
  51 sub qstr_add { # PublicInbox::InputPipe::consume callback for --stdin
  52         my ($self) = @_; # $_[1] = $rbuf
  53         if (defined($_[1])) {
  54                 $_[1] eq '' and return eval {
  55                         if (my $dfd = $self->{3}) {
  56                                 chdir($dfd) or return $self->fail("fchdir: $!");
  57                         }
  58                         $self->{mset_opt}->{q_raw} = $self->{mset_opt}->{qstr};
  59                         $self->{lse}->query_approxidate($self->{lse}->git,
  60                                                 $self->{mset_opt}->{qstr});
  61                         _start_query($self);
  62                 };
  63                 $self->{mset_opt}->{qstr} .= $_[1];
  64         } else {
  65                 $self->fail("error reading stdin: $!");
  66         }
  67 }
  68
  69 sub lxs_prepare {
  70         my ($self) = @_;
  71         require PublicInbox::LeiXSearch;
  72         # prepare any number of LeiXSearch || LeiSearch || Inbox || URL
  73         my $lxs = $self->{lxs} = PublicInbox::LeiXSearch->new;
  74         my $opt = $self->{opt};
  75         my @only = @{$opt->{only} // []};
  76         # --local is enabled by default unless --only is used
  77         # we'll allow "--only $LOCATION --local"
  78         my $sto = $self->_lei_store(1); # FIXME: should not create
  79         $self->{lse} = $sto->search;
  80         if ($opt->{'local'} //= scalar(@only) ? 0 : 1) {
  81                 $lxs->prepare_external($self->{lse});
  82         }
  83         if (@only) {
  84                 for my $loc (@only) {
  85                         my @loc = $self->get_externals($loc) or return;
  86                         $lxs->prepare_external($_) for @loc;
  87                 }
  88         } else {
  89                 my (@ilocals, @iremotes);
  90                 for my $loc (@{$opt->{include} // []}) {
  91                         my @loc = $self->get_externals($loc) or return;
  92                         $lxs->prepare_external($_) for @loc;
  93                         @ilocals = @{$lxs->{locals} // []};
  94                         @iremotes = @{$lxs->{remotes} // []};
  95                 }
  96                 # --external is enabled by default, but allow --no-external
  97                 if ($opt->{external} //= 1) {
  98                         my %x;
  99                         for my $loc (@{$opt->{exclude} // []}) {
 100                                 my @l = $self->get_externals($loc, 1) or return;
 101                                 $x{$_} = 1 for @l;
 102                         }
 103                         my $ne = $self->externals_each(\&prep_ext, $lxs, \%x);
 104                         $opt->{remote} //= !($lxs->locals - $opt->{'local'});
 105                         if ($opt->{'local'}) {
 106                                 $lxs->{remotes} = \@iremotes if !$opt->{remote};
 107                         } else {
 108                                 $lxs->{locals} = \@ilocals;
 109                         }
 110                 }
 111         }
 112         ($lxs->locals || $lxs->remotes) ? ($self->{lxs} = $lxs) :
 113                 $self->fail('no local or remote inboxes to search');
 114 }
 115
 116 # the main "lei q SEARCH_TERMS" method
 117 sub lei_q {
 118         my ($self, @argv) = @_;
 119         PublicInbox::Config->json; # preload before forking
 120         my $lxs = lxs_prepare($self) or return;
 121         $self->ale->refresh_externals($lxs);
 122         my $opt = $self->{opt};
 123         my %mset_opt = map { $_ => $opt->{$_} } qw(threads limit offset);
 124         $mset_opt{asc} = $opt->{'reverse'} ? 1 : 0;
 125         $mset_opt{limit} //= 10000;
 126         if (defined(my $sort = $opt->{'sort'})) {
 127                 if ($sort eq 'relevance') {
 128                         $mset_opt{relevance} = 1;
 129                 } elsif ($sort eq 'docid') {
 130                         $mset_opt{relevance} = $mset_opt{asc} ? -1 : -2;
 131                 } elsif ($sort =~ /\Areceived(?:-?[aA]t)?\z/) {
 132                         # the default
 133                 } else {
 134                         die "unrecognized --sort=$sort\n";
 135                 }
 136         }
 137         $self->{mset_opt} = \%mset_opt;
 138
 139         if ($opt->{stdin}) {
 140                 return $self->fail(<<'') if @argv;
 141 no query allowed on command-line with --stdin
 142
 143                 require PublicInbox::InputPipe;
 144                 PublicInbox::InputPipe::consume($self->{0}, \&qstr_add, $self);
 145                 return;
 146         }
 147         $mset_opt{q_raw} = [ @argv ]; # copy
 148         $mset_opt{qstr} =
 149                 $self->{lse}->query_argv_to_string($self->{lse}->git, \@argv);
 150         _start_query($self);
 151 }
 152
 153 # shell completion helper called by lei__complete
 154 sub _complete_q {
 155         my ($self, @argv) = @_;
 156         my $ext = qr/\A(?:-I|(?:--(?:include|exclude|only)))\z/;
 157         my @cur;
 158         while (@argv) {
 159                 if ($argv[-1] =~ $ext) {
 160                         my @c = $self->_complete_forget_external(@cur);
 161                         # try basename match:
 162                         if (scalar(@cur) == 1 && index($cur[0], '/') < 0) {
 163                                 my $all = $self->externals_each;
 164                                 my %bn;
 165                                 for my $loc (keys %$all) {
 166                                         my $bn = (split(m!/!, $loc))[-1];
 167                                         ++$bn{$bn};
 168                                 }
 169                                 push @c, grep {
 170                                         $bn{$_} == 1 && /\A\Q$cur[0]/
 171                                 } keys %bn;
 172                         }
 173                         return @c if @c;
 174                 }
 175                 unshift(@cur, pop @argv);
 176         }
 177         ();
 178 }
 179
 180 # Stuff we may pass through to curl (as of 7.64.0), see curl manpage for
 181 # details, so most options which make sense for HTTP/HTTPS (including proxy
 182 # support for Tor and other methods of getting past weird networks).
 183 # Most of these are untested by us, some may not make sense for our use case
 184 # and typos below are likely.
 185 # n.b. some short options (-$NUMBER) are not supported since they conflict
 186 # with other "lei q" switches.
 187 # FIXME: Getopt::Long doesn't easily let us support support options with
 188 # '.' in them (e.g. --http1.1)
 189 # TODO: should we depend on "-c http.*" options for things which have
 190 # analogues in git(1)? that would reduce likelyhood of conflicts with
 191 # our other CLI options
 192 # Note: some names are renamed to avoid potential conflicts,
 193 # see %lei2mail in lib/PublicInbox/LeiCurl.pm
 194 sub curl_opt { qw(
 195         curl-config=s@
 196         abstract-unix-socket=s anyauth basic cacert=s capath=s
 197         cert-status cert-type cert=s ciphers=s
 198         connect-timeout=s connect-to=s cookie-jar=s cookie=s crlfile=s
 199         digest disable dns-interface=s dns-ipv4-addr=s dns-ipv6-addr=s
 200         dns-servers=s doh-url=s egd-file=s engine=s false-start
 201         happy-eyeballs-timeout-ms=s haproxy-protocol header=s@
 202         http2-prior-knowledge http2 insecure
 203         interface=s ipv4 ipv6 junk-session-cookies
 204         key-type=s key=s limit-rate=s local-port=s location-trusted location
 205         max-redirs=i max-time=s negotiate netrc-file=s netrc-optional netrc
 206         no-alpn no-buffer no-npn no-sessionid noproxy=s ntlm-wb ntlm
 207         pass=s pinnedpubkey=s post301 post302 post303 preproxy=s
 208         proxy-anyauth proxy-basic proxy-cacert=s proxy-capath=s
 209         proxy-cert-type=s proxy-cert=s proxy-ciphers=s proxy-crlfile=s
 210         proxy-digest proxy-header=s@ proxy-insecure
 211         proxy-key-type=s proxy-key proxy-negotiate proxy-ntlm proxy-pass=s
 212         proxy-pinnedpubkey=s proxy-service-name=s proxy-ssl-allow-beast
 213         proxy-tls13-ciphers=s proxy-tlsauthtype=s proxy-tlspassword=s
 214         proxy-tlsuser=s proxy-tlsv1 proxy-user=s proxy=s
 215         proxytunnel=s pubkey=s random-file=s referer=s resolve=s
 216         retry-connrefused retry-delay=s retry-max-time=s retry=i
 217         sasl-ir service-name=s socks4=s socks4a=s socks5-basic
 218         socks5-gssapi-service-name=s socks5-gssapi socks5-hostname=s socks5=s
 219         speed-limit speed-type ssl-allow-beast sslv2 sslv3
 220         suppress-connect-headers tcp-fastopen tls-max=s
 221         tls13-ciphers=s tlsauthtype=s tlspassword=s tlsuser=s
 222         tlsv1 trace-ascii=s trace-time trace=s
 223         unix-socket=s user-agent=s user=s
 224 )
 225 }
 226
 227 1;