lib/PublicInbox/LeiQuery.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # handles lei <q|ls-query|rm-query|mv-query> commands
   5 package PublicInbox::LeiQuery;
   6 use strict;
   7 use v5.10.1;
   8
   9 sub prep_ext { # externals_each callback
  10         my ($lxs, $exclude, $loc) = @_;
  11         $lxs->prepare_external($loc) unless $exclude->{$loc};
  12 }
  13
  14 sub qstr_add { # for --stdin
  15         my ($self) = @_; # $_[1] = $rbuf
  16         if (defined($_[1])) {
  17                 $_[1] eq '' and return eval {
  18                         my $lse = delete $self->{lse};
  19                         $lse->query_approxidate($lse->git,
  20                                                 $self->{mset_opt}->{qstr});
  21                         $self->{lxs}->do_query($self);
  22                 };
  23                 $self->{mset_opt}->{qstr} .= $_[1];
  24         } else {
  25                 $self->fail("error reading stdin: $!");
  26         }
  27 }
  28
  29 # the main "lei q SEARCH_TERMS" method
  30 sub lei_q {
  31         my ($self, @argv) = @_;
  32         require PublicInbox::LeiXSearch;
  33         require PublicInbox::LeiOverview;
  34         require PublicInbox::V2Writable;
  35         PublicInbox::Config->json; # preload before forking
  36         my $opt = $self->{opt};
  37         # prepare any number of LeiXSearch || LeiSearch || Inbox || URL
  38         my $lxs = $self->{lxs} = PublicInbox::LeiXSearch->new;
  39         my @only = @{$opt->{only} // []};
  40         # --local is enabled by default unless --only is used
  41         # we'll allow "--only $LOCATION --local"
  42         my $sto = $self->_lei_store(1);
  43         my $lse = $sto->search;
  44         if ($opt->{'local'} //= scalar(@only) ? 0 : 1) {
  45                 $lxs->prepare_external($lse);
  46         }
  47         if (@only) {
  48                 for my $loc (@only) {
  49                         my @loc = $self->get_externals($loc) or return;
  50                         $lxs->prepare_external($_) for @loc;
  51                 }
  52         } else {
  53                 for my $loc (@{$opt->{include} // []}) {
  54                         my @loc = $self->get_externals($loc) or return;
  55                         $lxs->prepare_external($_) for @loc;
  56                 }
  57                 # --external is enabled by default, but allow --no-external
  58                 if ($opt->{external} //= 1) {
  59                         my %x;
  60                         for my $loc (@{$opt->{exclude} // []}) {
  61                                 my @l = $self->get_externals($loc, 1) or return;
  62                                 $x{$_} = 1 for @l;
  63                         }
  64                         my $ne = $self->externals_each(\&prep_ext, $lxs, \%x);
  65                         $opt->{remote} //= !($lxs->locals - $opt->{'local'});
  66                         if ($opt->{'local'}) {
  67                                 delete($lxs->{remotes}) if !$opt->{remote};
  68                         } else {
  69                                 delete($lxs->{locals});
  70                         }
  71                 }
  72         }
  73         unless ($lxs->locals || $lxs->remotes) {
  74                 return $self->fail('no local or remote inboxes to search');
  75         }
  76         my ($xj, $mj) = split(/,/, $opt->{jobs} // '');
  77         if (defined($xj) && $xj ne '' && $xj !~ /\A[1-9][0-9]*\z/) {
  78                 return $self->fail("`$xj' search jobs must be >= 1");
  79         }
  80         $xj ||= $lxs->concurrency($opt); # allow: "--jobs ,$WRITER_ONLY"
  81         my $nproc = $lxs->detect_nproc; # don't memoize, schedtool(1) exists
  82         $xj = $nproc if $xj > $nproc;
  83         $lxs->{jobs} = $xj;
  84         if (defined($mj) && $mj !~ /\A[1-9][0-9]*\z/) {
  85                 return $self->fail("`$mj' writer jobs must be >= 1");
  86         }
  87         $self->{l2m}->{jobs} = ($mj // $nproc) if $self->{l2m};
  88         PublicInbox::LeiOverview->new($self) or return;
  89
  90         my %mset_opt = map { $_ => $opt->{$_} } qw(threads limit offset);
  91         $mset_opt{asc} = $opt->{'reverse'} ? 1 : 0;
  92         $mset_opt{limit} //= 10000;
  93         if (defined(my $sort = $opt->{'sort'})) {
  94                 if ($sort eq 'relevance') {
  95                         $mset_opt{relevance} = 1;
  96                 } elsif ($sort eq 'docid') {
  97                         $mset_opt{relevance} = $mset_opt{asc} ? -1 : -2;
  98                 } elsif ($sort =~ /\Areceived(?:-?[aA]t)?\z/) {
  99                         # the default
 100                 } else {
 101                         die "unrecognized --sort=$sort\n";
 102                 }
 103         }
 104         # descending docid order
 105         $mset_opt{relevance} //= -2 if $opt->{threads};
 106         $self->{mset_opt} = \%mset_opt;
 107
 108         if ($opt->{stdin}) {
 109                 return $self->fail(<<'') if @argv;
 110 no query allowed on command-line with --stdin
 111
 112                 require PublicInbox::InputPipe;
 113                 $self->{lse} = $lse; # for query_approxidate
 114                 PublicInbox::InputPipe::consume($self->{0}, \&qstr_add, $self);
 115                 return;
 116         }
 117         $mset_opt{qstr} = $lse->query_argv_to_string($lse->git, \@argv);
 118         $lxs->do_query($self);
 119 }
 120
 121 # shell completion helper called by lei__complete
 122 sub _complete_q {
 123         my ($self, @argv) = @_;
 124         my $ext = qr/\A(?:-I|(?:--(?:include|exclude|only)))\z/;
 125         my @cur;
 126         while (@argv) {
 127                 if ($argv[-1] =~ $ext) {
 128                         my @c = $self->_complete_forget_external(@cur);
 129                         # try basename match:
 130                         if (scalar(@cur) == 1 && index($cur[0], '/') < 0) {
 131                                 my $all = $self->externals_each;
 132                                 my %bn;
 133                                 for my $loc (keys %$all) {
 134                                         my $bn = (split(m!/!, $loc))[-1];
 135                                         ++$bn{$bn};
 136                                 }
 137                                 push @c, grep {
 138                                         $bn{$_} == 1 && /\A\Q$cur[0]/
 139                                 } keys %bn;
 140                         }
 141                         return @c if @c;
 142                 }
 143                 unshift(@cur, pop @argv);
 144         }
 145         ();
 146 }
 147
 148 # Stuff we may pass through to curl (as of 7.64.0), see curl manpage for
 149 # details, so most options which make sense for HTTP/HTTPS (including proxy
 150 # support for Tor and other methods of getting past weird networks).
 151 # Most of these are untested by us, some may not make sense for our use case
 152 # and typos below are likely.
 153 # n.b. some short options (-$NUMBER) are not supported since they conflict
 154 # with other "lei q" switches.
 155 # FIXME: Getopt::Long doesn't easily let us support support options with
 156 # '.' in them (e.g. --http1.1)
 157 # TODO: should we depend on "-c http.*" options for things which have
 158 # analogues in git(1)? that would reduce likelyhood of conflicts with
 159 # our other CLI options
 160 # Note: some names are renamed to avoid potential conflicts,
 161 # see %lei2mail in lib/PublicInbox/LeiCurl.pm
 162 sub curl_opt { qw(
 163         curl-config=s@
 164         abstract-unix-socket=s anyauth basic cacert=s capath=s
 165         cert-status cert-type cert=s ciphers=s
 166         connect-timeout=s connect-to=s cookie-jar=s cookie=s crlfile=s
 167         digest disable dns-interface=s dns-ipv4-addr=s dns-ipv6-addr=s
 168         dns-servers=s doh-url=s egd-file=s engine=s false-start
 169         happy-eyeballs-timeout-ms=s haproxy-protocol header=s@
 170         http2-prior-knowledge http2 insecure
 171         interface=s ipv4 ipv6 junk-session-cookies
 172         key-type=s key=s limit-rate=s local-port=s location-trusted location
 173         max-redirs=i max-time=s negotiate netrc-file=s netrc-optional netrc
 174         no-alpn no-buffer no-npn no-sessionid noproxy=s ntlm-wb ntlm
 175         pass=s pinnedpubkey=s post301 post302 post303 preproxy=s
 176         proxy-anyauth proxy-basic proxy-cacert=s proxy-capath=s
 177         proxy-cert-type=s proxy-cert=s proxy-ciphers=s proxy-crlfile=s
 178         proxy-digest proxy-header=s@ proxy-insecure
 179         proxy-key-type=s proxy-key proxy-negotiate proxy-ntlm proxy-pass=s
 180         proxy-pinnedpubkey=s proxy-service-name=s proxy-ssl-allow-beast
 181         proxy-tls13-ciphers=s proxy-tlsauthtype=s proxy-tlspassword=s
 182         proxy-tlsuser=s proxy-tlsv1 proxy-user=s proxy=s
 183         proxytunnel=s pubkey=s random-file=s referer=s resolve=s
 184         retry-connrefused retry-delay=s retry-max-time=s retry=i
 185         sasl-ir service-name=s socks4=s socks4a=s socks5-basic
 186         socks5-gssapi-service-name=s socks5-gssapi socks5-hostname=s socks5=s
 187         speed-limit speed-type ssl-allow-beast sslv2 sslv3
 188         suppress-connect-headers tcp-fastopen tls-max=s
 189         tls13-ciphers=s tlsauthtype=s tlspassword=s tlsuser=s
 190         tlsv1 trace-ascii=s trace-time trace=s
 191         unix-socket=s user-agent=s user=s
 192 )
 193 }
 194
 195 1;