lib/PublicInbox/LeiQuery.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # handles lei <q|ls-query|rm-query|mv-query> commands
   5 package PublicInbox::LeiQuery;
   6 use strict;
   7 use v5.10.1;
   8 use POSIX ();
   9
  10 sub prep_ext { # externals_each callback
  11         my ($lxs, $exclude, $loc) = @_;
  12         $lxs->prepare_external($loc) unless $exclude->{$loc};
  13 }
  14
  15 sub _start_query {
  16         my ($self) = @_;
  17         if ($self->{net}) {
  18                 require PublicInbox::LeiAuth;
  19                 $self->{auth} = PublicInbox::LeiAuth->new
  20         }
  21         $self->{lxs}->do_query($self);
  22 }
  23
  24 sub qstr_add { # PublicInbox::InputPipe::consume callback for --stdin
  25         my ($self) = @_; # $_[1] = $rbuf
  26         if (defined($_[1])) {
  27                 $_[1] eq '' and return eval {
  28                         my $lse = delete $self->{lse};
  29                         $lse->query_approxidate($lse->git,
  30                                                 $self->{mset_opt}->{qstr});
  31                         _start_query($self);
  32                 };
  33                 $self->{mset_opt}->{qstr} .= $_[1];
  34         } else {
  35                 $self->fail("error reading stdin: $!");
  36         }
  37 }
  38
  39 # the main "lei q SEARCH_TERMS" method
  40 sub lei_q {
  41         my ($self, @argv) = @_;
  42         require PublicInbox::LeiXSearch;
  43         require PublicInbox::LeiOverview;
  44         require PublicInbox::V2Writable;
  45         PublicInbox::Config->json; # preload before forking
  46         my $opt = $self->{opt};
  47         # prepare any number of LeiXSearch || LeiSearch || Inbox || URL
  48         my $lxs = $self->{lxs} = PublicInbox::LeiXSearch->new;
  49         my @only = @{$opt->{only} // []};
  50         # --local is enabled by default unless --only is used
  51         # we'll allow "--only $LOCATION --local"
  52         my $sto = $self->_lei_store(1);
  53         my $lse = $sto->search;
  54         if ($opt->{'local'} //= scalar(@only) ? 0 : 1) {
  55                 $lxs->prepare_external($lse);
  56         }
  57         if (@only) {
  58                 for my $loc (@only) {
  59                         my @loc = $self->get_externals($loc) or return;
  60                         $lxs->prepare_external($_) for @loc;
  61                 }
  62         } else {
  63                 for my $loc (@{$opt->{include} // []}) {
  64                         my @loc = $self->get_externals($loc) or return;
  65                         $lxs->prepare_external($_) for @loc;
  66                 }
  67                 # --external is enabled by default, but allow --no-external
  68                 if ($opt->{external} //= 1) {
  69                         my %x;
  70                         for my $loc (@{$opt->{exclude} // []}) {
  71                                 my @l = $self->get_externals($loc, 1) or return;
  72                                 $x{$_} = 1 for @l;
  73                         }
  74                         my $ne = $self->externals_each(\&prep_ext, $lxs, \%x);
  75                         $opt->{remote} //= !($lxs->locals - $opt->{'local'});
  76                         if ($opt->{'local'}) {
  77                                 delete($lxs->{remotes}) if !$opt->{remote};
  78                         } else {
  79                                 delete($lxs->{locals});
  80                         }
  81                 }
  82         }
  83         unless ($lxs->locals || $lxs->remotes) {
  84                 return $self->fail('no local or remote inboxes to search');
  85         }
  86         my ($xj, $mj) = split(/,/, $opt->{jobs} // '');
  87         if (defined($xj) && $xj ne '' && $xj !~ /\A[1-9][0-9]*\z/) {
  88                 return $self->fail("`$xj' search jobs must be >= 1");
  89         }
  90         $xj ||= $lxs->concurrency($opt); # allow: "--jobs ,$WRITER_ONLY"
  91         my $nproc = $lxs->detect_nproc // 1; # don't memoize, schedtool(1) exists
  92         $xj = $nproc if $xj > $nproc;
  93         $lxs->{-wq_nr_workers} = $xj;
  94         if (defined($mj) && $mj !~ /\A[1-9][0-9]*\z/) {
  95                 return $self->fail("`$mj' writer jobs must be >= 1");
  96         }
  97         PublicInbox::LeiOverview->new($self) or return;
  98         $self->{l2m} and $self->{l2m}->{-wq_nr_workers} = $mj // do {
  99                 $mj = POSIX::lround($nproc * 3 / 4); # keep some CPU for git
 100                 $mj <= 0 ? 1 : $mj;
 101         };
 102
 103         my %mset_opt = map { $_ => $opt->{$_} } qw(threads limit offset);
 104         $mset_opt{asc} = $opt->{'reverse'} ? 1 : 0;
 105         $mset_opt{limit} //= 10000;
 106         if (defined(my $sort = $opt->{'sort'})) {
 107                 if ($sort eq 'relevance') {
 108                         $mset_opt{relevance} = 1;
 109                 } elsif ($sort eq 'docid') {
 110                         $mset_opt{relevance} = $mset_opt{asc} ? -1 : -2;
 111                 } elsif ($sort =~ /\Areceived(?:-?[aA]t)?\z/) {
 112                         # the default
 113                 } else {
 114                         die "unrecognized --sort=$sort\n";
 115                 }
 116         }
 117         # descending docid order
 118         $mset_opt{relevance} //= -2 if $opt->{threads};
 119         $self->{mset_opt} = \%mset_opt;
 120
 121         if ($opt->{stdin}) {
 122                 return $self->fail(<<'') if @argv;
 123 no query allowed on command-line with --stdin
 124
 125                 require PublicInbox::InputPipe;
 126                 $self->{lse} = $lse; # for query_approxidate
 127                 PublicInbox::InputPipe::consume($self->{0}, \&qstr_add, $self);
 128                 return;
 129         }
 130         $mset_opt{qstr} = $lse->query_argv_to_string($lse->git, \@argv);
 131         _start_query($self);
 132 }
 133
 134 # shell completion helper called by lei__complete
 135 sub _complete_q {
 136         my ($self, @argv) = @_;
 137         my $ext = qr/\A(?:-I|(?:--(?:include|exclude|only)))\z/;
 138         my @cur;
 139         while (@argv) {
 140                 if ($argv[-1] =~ $ext) {
 141                         my @c = $self->_complete_forget_external(@cur);
 142                         # try basename match:
 143                         if (scalar(@cur) == 1 && index($cur[0], '/') < 0) {
 144                                 my $all = $self->externals_each;
 145                                 my %bn;
 146                                 for my $loc (keys %$all) {
 147                                         my $bn = (split(m!/!, $loc))[-1];
 148                                         ++$bn{$bn};
 149                                 }
 150                                 push @c, grep {
 151                                         $bn{$_} == 1 && /\A\Q$cur[0]/
 152                                 } keys %bn;
 153                         }
 154                         return @c if @c;
 155                 }
 156                 unshift(@cur, pop @argv);
 157         }
 158         ();
 159 }
 160
 161 # Stuff we may pass through to curl (as of 7.64.0), see curl manpage for
 162 # details, so most options which make sense for HTTP/HTTPS (including proxy
 163 # support for Tor and other methods of getting past weird networks).
 164 # Most of these are untested by us, some may not make sense for our use case
 165 # and typos below are likely.
 166 # n.b. some short options (-$NUMBER) are not supported since they conflict
 167 # with other "lei q" switches.
 168 # FIXME: Getopt::Long doesn't easily let us support support options with
 169 # '.' in them (e.g. --http1.1)
 170 # TODO: should we depend on "-c http.*" options for things which have
 171 # analogues in git(1)? that would reduce likelyhood of conflicts with
 172 # our other CLI options
 173 # Note: some names are renamed to avoid potential conflicts,
 174 # see %lei2mail in lib/PublicInbox/LeiCurl.pm
 175 sub curl_opt { qw(
 176         curl-config=s@
 177         abstract-unix-socket=s anyauth basic cacert=s capath=s
 178         cert-status cert-type cert=s ciphers=s
 179         connect-timeout=s connect-to=s cookie-jar=s cookie=s crlfile=s
 180         digest disable dns-interface=s dns-ipv4-addr=s dns-ipv6-addr=s
 181         dns-servers=s doh-url=s egd-file=s engine=s false-start
 182         happy-eyeballs-timeout-ms=s haproxy-protocol header=s@
 183         http2-prior-knowledge http2 insecure
 184         interface=s ipv4 ipv6 junk-session-cookies
 185         key-type=s key=s limit-rate=s local-port=s location-trusted location
 186         max-redirs=i max-time=s negotiate netrc-file=s netrc-optional netrc
 187         no-alpn no-buffer no-npn no-sessionid noproxy=s ntlm-wb ntlm
 188         pass=s pinnedpubkey=s post301 post302 post303 preproxy=s
 189         proxy-anyauth proxy-basic proxy-cacert=s proxy-capath=s
 190         proxy-cert-type=s proxy-cert=s proxy-ciphers=s proxy-crlfile=s
 191         proxy-digest proxy-header=s@ proxy-insecure
 192         proxy-key-type=s proxy-key proxy-negotiate proxy-ntlm proxy-pass=s
 193         proxy-pinnedpubkey=s proxy-service-name=s proxy-ssl-allow-beast
 194         proxy-tls13-ciphers=s proxy-tlsauthtype=s proxy-tlspassword=s
 195         proxy-tlsuser=s proxy-tlsv1 proxy-user=s proxy=s
 196         proxytunnel=s pubkey=s random-file=s referer=s resolve=s
 197         retry-connrefused retry-delay=s retry-max-time=s retry=i
 198         sasl-ir service-name=s socks4=s socks4a=s socks5-basic
 199         socks5-gssapi-service-name=s socks5-gssapi socks5-hostname=s socks5=s
 200         speed-limit speed-type ssl-allow-beast sslv2 sslv3
 201         suppress-connect-headers tcp-fastopen tls-max=s
 202         tls13-ciphers=s tlsauthtype=s tlspassword=s tlsuser=s
 203         tlsv1 trace-ascii=s trace-time trace=s
 204         unix-socket=s user-agent=s user=s
 205 )
 206 }
 207
 208 1;