lib/PublicInbox/LeiQuery.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # handles lei <q|ls-query|rm-query|mv-query> commands
   5 package PublicInbox::LeiQuery;
   6 use strict;
   7 use v5.10.1;
   8 use POSIX ();
   9
  10 sub prep_ext { # externals_each callback
  11         my ($lxs, $exclude, $loc) = @_;
  12         $lxs->prepare_external($loc) unless $exclude->{$loc};
  13 }
  14
  15 sub _start_query {
  16         my ($self) = @_;
  17         if ($self->{net}) {
  18                 require PublicInbox::LeiAuth;
  19                 $self->{auth} = PublicInbox::LeiAuth->new
  20         }
  21         $self->{lxs}->do_query($self);
  22 }
  23
  24 sub qstr_add { # PublicInbox::InputPipe::consume callback for --stdin
  25         my ($self) = @_; # $_[1] = $rbuf
  26         if (defined($_[1])) {
  27                 $_[1] eq '' and return eval {
  28                         my $lse = delete $self->{lse};
  29                         $lse->query_approxidate($lse->git,
  30                                                 $self->{mset_opt}->{qstr});
  31                         _start_query($self);
  32                 };
  33                 $self->{mset_opt}->{qstr} .= $_[1];
  34         } else {
  35                 $self->fail("error reading stdin: $!");
  36         }
  37 }
  38
  39 # the main "lei q SEARCH_TERMS" method
  40 sub lei_q {
  41         my ($self, @argv) = @_;
  42         require PublicInbox::LeiXSearch;
  43         require PublicInbox::LeiOverview;
  44         require PublicInbox::V2Writable;
  45         PublicInbox::Config->json; # preload before forking
  46         my $opt = $self->{opt};
  47         # prepare any number of LeiXSearch || LeiSearch || Inbox || URL
  48         my $lxs = $self->{lxs} = PublicInbox::LeiXSearch->new;
  49         my @only = @{$opt->{only} // []};
  50         # --local is enabled by default unless --only is used
  51         # we'll allow "--only $LOCATION --local"
  52         my $sto = $self->_lei_store(1);
  53         my $lse = $sto->search;
  54         if (($opt->{'import-remote'} //= 1) |
  55                         ($opt->{'import-augment'} //= 1)) {
  56                 $sto->write_prepare($self);
  57         }
  58         if ($opt->{'local'} //= scalar(@only) ? 0 : 1) {
  59                 $lxs->prepare_external($lse);
  60         }
  61         if (@only) {
  62                 for my $loc (@only) {
  63                         my @loc = $self->get_externals($loc) or return;
  64                         $lxs->prepare_external($_) for @loc;
  65                 }
  66         } else {
  67                 for my $loc (@{$opt->{include} // []}) {
  68                         my @loc = $self->get_externals($loc) or return;
  69                         $lxs->prepare_external($_) for @loc;
  70                 }
  71                 # --external is enabled by default, but allow --no-external
  72                 if ($opt->{external} //= 1) {
  73                         my %x;
  74                         for my $loc (@{$opt->{exclude} // []}) {
  75                                 my @l = $self->get_externals($loc, 1) or return;
  76                                 $x{$_} = 1 for @l;
  77                         }
  78                         my $ne = $self->externals_each(\&prep_ext, $lxs, \%x);
  79                         $opt->{remote} //= !($lxs->locals - $opt->{'local'});
  80                         if ($opt->{'local'}) {
  81                                 delete($lxs->{remotes}) if !$opt->{remote};
  82                         } else {
  83                                 delete($lxs->{locals});
  84                         }
  85                 }
  86         }
  87         unless ($lxs->locals || $lxs->remotes) {
  88                 return $self->fail('no local or remote inboxes to search');
  89         }
  90         my ($xj, $mj) = split(/,/, $opt->{jobs} // '');
  91         if (defined($xj) && $xj ne '' && $xj !~ /\A[1-9][0-9]*\z/) {
  92                 return $self->fail("`$xj' search jobs must be >= 1");
  93         }
  94         $xj ||= $lxs->concurrency($opt); # allow: "--jobs ,$WRITER_ONLY"
  95         my $nproc = $lxs->detect_nproc // 1; # don't memoize, schedtool(1) exists
  96         $xj = $nproc if $xj > $nproc;
  97         $lxs->{-wq_nr_workers} = $xj;
  98         if (defined($mj) && $mj !~ /\A[1-9][0-9]*\z/) {
  99                 return $self->fail("`$mj' writer jobs must be >= 1");
 100         }
 101         PublicInbox::LeiOverview->new($self) or return;
 102         $self->{l2m} and $self->{l2m}->{-wq_nr_workers} = $mj // do {
 103                 $mj = POSIX::lround($nproc * 3 / 4); # keep some CPU for git
 104                 $mj <= 0 ? 1 : $mj;
 105         };
 106
 107         my %mset_opt = map { $_ => $opt->{$_} } qw(threads limit offset);
 108         $mset_opt{asc} = $opt->{'reverse'} ? 1 : 0;
 109         $mset_opt{limit} //= 10000;
 110         if (defined(my $sort = $opt->{'sort'})) {
 111                 if ($sort eq 'relevance') {
 112                         $mset_opt{relevance} = 1;
 113                 } elsif ($sort eq 'docid') {
 114                         $mset_opt{relevance} = $mset_opt{asc} ? -1 : -2;
 115                 } elsif ($sort =~ /\Areceived(?:-?[aA]t)?\z/) {
 116                         # the default
 117                 } else {
 118                         die "unrecognized --sort=$sort\n";
 119                 }
 120         }
 121         # descending docid order
 122         $mset_opt{relevance} //= -2 if $opt->{threads};
 123         $self->{mset_opt} = \%mset_opt;
 124
 125         if ($opt->{stdin}) {
 126                 return $self->fail(<<'') if @argv;
 127 no query allowed on command-line with --stdin
 128
 129                 require PublicInbox::InputPipe;
 130                 $self->{lse} = $lse; # for query_approxidate
 131                 PublicInbox::InputPipe::consume($self->{0}, \&qstr_add, $self);
 132                 return;
 133         }
 134         $mset_opt{qstr} = $lse->query_argv_to_string($lse->git, \@argv);
 135         _start_query($self);
 136 }
 137
 138 # shell completion helper called by lei__complete
 139 sub _complete_q {
 140         my ($self, @argv) = @_;
 141         my $ext = qr/\A(?:-I|(?:--(?:include|exclude|only)))\z/;
 142         my @cur;
 143         while (@argv) {
 144                 if ($argv[-1] =~ $ext) {
 145                         my @c = $self->_complete_forget_external(@cur);
 146                         # try basename match:
 147                         if (scalar(@cur) == 1 && index($cur[0], '/') < 0) {
 148                                 my $all = $self->externals_each;
 149                                 my %bn;
 150                                 for my $loc (keys %$all) {
 151                                         my $bn = (split(m!/!, $loc))[-1];
 152                                         ++$bn{$bn};
 153                                 }
 154                                 push @c, grep {
 155                                         $bn{$_} == 1 && /\A\Q$cur[0]/
 156                                 } keys %bn;
 157                         }
 158                         return @c if @c;
 159                 }
 160                 unshift(@cur, pop @argv);
 161         }
 162         ();
 163 }
 164
 165 # Stuff we may pass through to curl (as of 7.64.0), see curl manpage for
 166 # details, so most options which make sense for HTTP/HTTPS (including proxy
 167 # support for Tor and other methods of getting past weird networks).
 168 # Most of these are untested by us, some may not make sense for our use case
 169 # and typos below are likely.
 170 # n.b. some short options (-$NUMBER) are not supported since they conflict
 171 # with other "lei q" switches.
 172 # FIXME: Getopt::Long doesn't easily let us support support options with
 173 # '.' in them (e.g. --http1.1)
 174 # TODO: should we depend on "-c http.*" options for things which have
 175 # analogues in git(1)? that would reduce likelyhood of conflicts with
 176 # our other CLI options
 177 # Note: some names are renamed to avoid potential conflicts,
 178 # see %lei2mail in lib/PublicInbox/LeiCurl.pm
 179 sub curl_opt { qw(
 180         curl-config=s@
 181         abstract-unix-socket=s anyauth basic cacert=s capath=s
 182         cert-status cert-type cert=s ciphers=s
 183         connect-timeout=s connect-to=s cookie-jar=s cookie=s crlfile=s
 184         digest disable dns-interface=s dns-ipv4-addr=s dns-ipv6-addr=s
 185         dns-servers=s doh-url=s egd-file=s engine=s false-start
 186         happy-eyeballs-timeout-ms=s haproxy-protocol header=s@
 187         http2-prior-knowledge http2 insecure
 188         interface=s ipv4 ipv6 junk-session-cookies
 189         key-type=s key=s limit-rate=s local-port=s location-trusted location
 190         max-redirs=i max-time=s negotiate netrc-file=s netrc-optional netrc
 191         no-alpn no-buffer no-npn no-sessionid noproxy=s ntlm-wb ntlm
 192         pass=s pinnedpubkey=s post301 post302 post303 preproxy=s
 193         proxy-anyauth proxy-basic proxy-cacert=s proxy-capath=s
 194         proxy-cert-type=s proxy-cert=s proxy-ciphers=s proxy-crlfile=s
 195         proxy-digest proxy-header=s@ proxy-insecure
 196         proxy-key-type=s proxy-key proxy-negotiate proxy-ntlm proxy-pass=s
 197         proxy-pinnedpubkey=s proxy-service-name=s proxy-ssl-allow-beast
 198         proxy-tls13-ciphers=s proxy-tlsauthtype=s proxy-tlspassword=s
 199         proxy-tlsuser=s proxy-tlsv1 proxy-user=s proxy=s
 200         proxytunnel=s pubkey=s random-file=s referer=s resolve=s
 201         retry-connrefused retry-delay=s retry-max-time=s retry=i
 202         sasl-ir service-name=s socks4=s socks4a=s socks5-basic
 203         socks5-gssapi-service-name=s socks5-gssapi socks5-hostname=s socks5=s
 204         speed-limit speed-type ssl-allow-beast sslv2 sslv3
 205         suppress-connect-headers tcp-fastopen tls-max=s
 206         tls13-ciphers=s tlsauthtype=s tlspassword=s tlsuser=s
 207         tlsv1 trace-ascii=s trace-time trace=s
 208         unix-socket=s user-agent=s user=s
 209 )
 210 }
 211
 212 1;