lib/PublicInbox/LeiSavedSearch.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # pretends to be like LeiDedupe and also PublicInbox::Inbox
   5 package PublicInbox::LeiSavedSearch;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::Lock);
   9 use PublicInbox::Git;
  10 use PublicInbox::OverIdx;
  11 use PublicInbox::LeiSearch;
  12 use PublicInbox::Config;
  13 use PublicInbox::Spawn qw(run_die);
  14 use PublicInbox::ContentHash qw(git_sha);
  15 use PublicInbox::MID qw(mids_for_index);
  16 use Digest::SHA qw(sha256_hex);
  17 our $LOCAL_PFX = qr!\A(?:maildir|mh|mbox.+|mmdf|v2):!i; # TODO: put in LeiToMail?
  18
  19 # move this to PublicInbox::Config if other things use it:
  20 my %cquote = ("\n" => '\\n', "\t" => '\\t', "\b" => '\\b');
  21 sub cquote_val ($) { # cf. git-config(1)
  22         my ($val) = @_;
  23         $val =~ s/([\n\t\b])/$cquote{$1}/g;
  24         $val;
  25 }
  26
  27 sub ARRAY_FIELDS () { qw(only include exclude) }
  28 sub BOOL_FIELDS () {
  29         qw(external local remote import-remote import-before threads)
  30 }
  31
  32 sub cfg_dump ($$) {
  33         my ($lei, $f) = @_;
  34         my $ret = eval { PublicInbox::Config->git_config_dump($f, $lei->{2}) };
  35         return $ret if !$@;
  36         $lei->err($@);
  37         undef;
  38 }
  39
  40 sub lss_dir_for ($$;$) {
  41         my ($lei, $dstref, $on_fs) = @_;
  42         my @n;
  43         if ($$dstref =~ m,\Aimaps?://,i) { # already canonicalized
  44                 require PublicInbox::URIimap;
  45                 my $uri = PublicInbox::URIimap->new($$dstref)->canonical;
  46                 $$dstref = $$uri;
  47                 @n = ($uri->mailbox);
  48         } else {
  49                 # can't use Cwd::abs_path since dirname($$dstref) may not exist
  50                 $$dstref = $lei->rel2abs($$dstref);
  51                 $$dstref =~ tr!/!/!s;
  52                 @n = ($$dstref =~ m{([^/]+)/*\z}); # basename
  53         }
  54         push @n, sha256_hex($$dstref);
  55         my $lss_dir = $lei->share_path . '/saved-searches/';
  56         my $d = $lss_dir . join('-', @n);
  57
  58         # fall-back to looking up by st_ino + st_dev in case we're in
  59         # a symlinked or bind-mounted path
  60         if ($on_fs && !-d $d && -e $$dstref) {
  61                 my @cur = stat(_);
  62                 my $want = pack('dd', @cur[1,0]); # st_ino + st_dev
  63                 my ($c, $o, @st);
  64                 for my $g ("$n[0]-*", '*') {
  65                         my @maybe = glob("$lss_dir$g/lei.saved-search");
  66                         for my $f (@maybe) {
  67                                 $c = cfg_dump($lei, $f) // next;
  68                                 $o = $c->{'lei.q.output'} // next;
  69                                 $o =~ s!$LOCAL_PFX!! or next;
  70                                 @st = stat($o) or next;
  71                                 next if pack('dd', @st[1,0]) ne $want;
  72                                 $f =~ m!\A(.+?)/[^/]+\z! and return $1;
  73                         }
  74                 }
  75         }
  76         $d;
  77 }
  78
  79 sub list {
  80         my ($lei, $pfx) = @_;
  81         my $lss_dir = $lei->share_path.'/saved-searches';
  82         return () unless -d $lss_dir;
  83         # TODO: persist the cache?  Use another format?
  84         my $f = $lei->cache_dir."/saved-tmp.$$.".time.'.config';
  85         open my $fh, '>', $f or die "open $f: $!";
  86         print $fh "[include]\n";
  87         for my $p (glob("$lss_dir/*/lei.saved-search")) {
  88                 print $fh "\tpath = ", cquote_val($p), "\n";
  89         }
  90         close $fh or die "close $f: $!";
  91         my $cfg = cfg_dump($lei, $f);
  92         unlink($f);
  93         my $out = $cfg ? $cfg->get_all('lei.q.output') : [];
  94         map {;
  95                 s!$LOCAL_PFX!!;
  96                 $_;
  97         } @$out
  98 }
  99
 100 sub translate_dedupe ($$$) {
 101         my ($self, $lei, $dd) = @_;
 102         $dd //= 'content';
 103         return 1 if $dd eq 'content'; # the default
 104         return $self->{"-dedupe_$dd"} = 1 if ($dd eq 'oid' || $dd eq 'mid');
 105         $lei->fail("--dedupe=$dd unsupported with --save");
 106 }
 107
 108 sub up { # updating existing saved search via "lei up"
 109         my ($cls, $lei, $dst) = @_;
 110         my $f;
 111         my $self = bless { ale => $lei->ale }, $cls;
 112         my $dir = $dst;
 113         output2lssdir($self, $lei, \$dir, \$f) or
 114                 return $lei->fail("--save was not used with $dst cwd=".
 115                                         $lei->rel2abs('.'));
 116         $self->{-cfg} = cfg_dump($lei, $f) // return $lei->fail;
 117         $self->{-ovf} = "$dir/over.sqlite3";
 118         $self->{'-f'} = $f;
 119         $self->{lock_path} = "$self->{-f}.flock";
 120         $self;
 121 }
 122
 123 sub new { # new saved search "lei q --save"
 124         my ($cls, $lei) = @_;
 125         my $self = bless { ale => $lei->ale }, $cls;
 126         require File::Path;
 127         my $dst = $lei->{ovv}->{dst};
 128
 129         # canonicalize away relative paths into the config
 130         if ($lei->{ovv}->{fmt} eq 'maildir' &&
 131                         $dst =~ m!(?:/*|\A)\.\.(?:/*|\z)! && !-d $dst) {
 132                 File::Path::make_path($dst);
 133                 $lei->{ovv}->{dst} = $dst = $lei->abs_path($dst);
 134         }
 135         my $dir = lss_dir_for($lei, \$dst);
 136         File::Path::make_path($dir); # raises on error
 137         $self->{-cfg} = {};
 138         my $f = $self->{'-f'} = "$dir/lei.saved-search";
 139         my $dd = $lei->{opt}->{dedupe};
 140         translate_dedupe($self, $lei, $dd) or return;
 141         open my $fh, '>', $f or return $lei->fail("open $f: $!");
 142         my $sq_dst = PublicInbox::Config::squote_maybe($dst);
 143         my $q = $lei->{mset_opt}->{q_raw} // die 'BUG: {q_raw} missing';
 144         if (ref $q) {
 145                 $q = join("\n", map { "\tq = ".cquote_val($_) } @$q);
 146         } else {
 147                 $q = "\tq = ".cquote_val($q);
 148         }
 149         $dst = "$lei->{ovv}->{fmt}:$dst" if $dst !~ m!\Aimaps?://!i;
 150         print $fh <<EOM;
 151 ; to refresh with new results, run: lei up $sq_dst
 152 [lei]
 153 $q
 154 [lei "q"]
 155         output = $dst
 156 EOM
 157         print $fh "\tdedupe = $dd\n" if $dd;
 158         for my $k (ARRAY_FIELDS) {
 159                 my $ary = $lei->{opt}->{$k} // next;
 160                 for my $x (@$ary) {
 161                         print $fh "\t$k = ".cquote_val($x)."\n";
 162                 }
 163         }
 164         for my $k (BOOL_FIELDS) {
 165                 my $val = $lei->{opt}->{$k} // next;
 166                 print $fh "\t$k = ".($val ? 1 : 0)."\n";
 167         }
 168         close($fh) or return $lei->fail("close $f: $!");
 169         $self->{lock_path} = "$self->{-f}.flock";
 170         $self->{-ovf} = "$dir/over.sqlite3";
 171         $self;
 172 }
 173
 174 sub description { $_[0]->{qstr} } # for WWW
 175
 176 sub cfg_set { # called by LeiXSearch
 177         my ($self, @args) = @_;
 178         my $lk = $self->lock_for_scope; # git-config doesn't wait
 179         run_die([qw(git config -f), $self->{'-f'}, @args]);
 180 }
 181
 182 # drop-in for LeiDedupe API
 183 sub is_dup {
 184         my ($self, $eml, $smsg) = @_;
 185         my $oidx = $self->{oidx} // die 'BUG: no {oidx}';
 186         my $lk;
 187         if ($self->{-dedupe_mid}) {
 188                 $lk //= $self->lock_for_scope_fast;
 189                 for my $mid (@{mids_for_index($eml)}) {
 190                         my ($id, $prv);
 191                         return 1 if $oidx->next_by_mid($mid, \$id, \$prv);
 192                 }
 193         }
 194         my $blob = $smsg ? $smsg->{blob} : git_sha(1, $eml)->hexdigest;
 195         $lk //= $self->lock_for_scope_fast;
 196         return 1 if $oidx->blob_exists($blob);
 197         if (my $xoids = PublicInbox::LeiSearch::xoids_for($self, $eml, 1)) {
 198                 for my $docid (values %$xoids) {
 199                         $oidx->add_xref3($docid, -1, $blob, '.');
 200                 }
 201                 $oidx->commit_lazy;
 202                 if ($self->{-dedupe_oid}) {
 203                         exists $xoids->{$blob} ? 1 : undef;
 204                 } else {
 205                         1;
 206                 }
 207         } else {
 208                 # n.b. above xoids_for fills out eml->{-lei_fake_mid} if needed
 209                 unless ($smsg) {
 210                         $smsg = bless {}, 'PublicInbox::Smsg';
 211                         $smsg->{bytes} = 0;
 212                         $smsg->populate($eml);
 213                 }
 214                 $smsg->{blob} //= $blob;
 215                 $oidx->begin_lazy;
 216                 $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 217                 $oidx->add_overview($eml, $smsg);
 218                 $oidx->add_xref3($smsg->{num}, -1, $blob, '.');
 219                 $oidx->commit_lazy;
 220                 undef;
 221         }
 222 }
 223
 224 sub prepare_dedupe {
 225         my ($self) = @_;
 226         $self->{oidx} //= do {
 227                 my $creat = !-f $self->{-ovf};
 228                 my $lk = $self->lock_for_scope; # git-config doesn't wait
 229                 my $oidx = PublicInbox::OverIdx->new($self->{-ovf});
 230                 $oidx->{-no_fsync} = 1;
 231                 $oidx->dbh;
 232                 if ($creat) {
 233                         $oidx->{dbh}->do('PRAGMA journal_mode = WAL');
 234                         $oidx->eidx_prep; # for xref3
 235                 }
 236                 $oidx
 237         };
 238 }
 239
 240 sub over { $_[0]->{oidx} } # for xoids_for
 241
 242 # don't use ale->git directly since is_dup is called inside
 243 # ale->git->cat_async callbacks
 244 sub git { $_[0]->{git} //= PublicInbox::Git->new($_[0]->{ale}->git->{git_dir}) }
 245
 246 sub pause_dedupe {
 247         my ($self) = @_;
 248         git($self)->cleanup;
 249         my $lockfh = delete $self->{lockfh}; # from lock_for_scope_fast;
 250         my $oidx = delete($self->{oidx}) // return;
 251         $oidx->commit_lazy;
 252 }
 253
 254 sub reset_dedupe {
 255         my ($self) = @_;
 256         prepare_dedupe($self);
 257         my $lk = $self->lock_for_scope_fast;
 258         for my $t (qw(xref3 over id2num)) {
 259                 $self->{oidx}->{dbh}->do("DELETE FROM $t");
 260         }
 261         pause_dedupe($self);
 262 }
 263
 264 sub mm { undef }
 265
 266 sub altid_map { {} }
 267
 268 sub cloneurl { [] }
 269
 270 # find existing directory containing a `lei.saved-search' file based on
 271 # $dir_ref which is an output
 272 sub output2lssdir {
 273         my ($self, $lei, $dir_ref, $fn_ref) = @_;
 274         my $dst = $$dir_ref; # imap://$MAILBOX, /path/to/maildir, /path/to/mbox
 275         my $dir = lss_dir_for($lei, \$dst, 1);
 276         my $f = "$dir/lei.saved-search";
 277         if (-f $f && -r _) {
 278                 $self->{-cfg} = cfg_dump($lei, $f) // return;
 279                 $$dir_ref = $dir;
 280                 $$fn_ref = $f;
 281                 return 1;
 282         }
 283         undef;
 284 }
 285
 286 # cf. LeiDedupe->has_entries
 287 sub has_entries {
 288         my $oidx = $_[0]->{oidx} // die 'BUG: no {oidx}';
 289         my @n = $oidx->{dbh}->selectrow_array('SELECT num FROM over LIMIT 1');
 290         scalar(@n) ? 1 : undef;
 291 }
 292
 293 no warnings 'once';
 294 *nntp_url = \&cloneurl;
 295 *base_url = \&PublicInbox::Inbox::base_url;
 296 *smsg_eml = \&PublicInbox::Inbox::smsg_eml;
 297 *smsg_by_mid = \&PublicInbox::Inbox::smsg_by_mid;
 298 *msg_by_mid = \&PublicInbox::Inbox::msg_by_mid;
 299 *modified = \&PublicInbox::Inbox::modified;
 300 *recent = \&PublicInbox::Inbox::recent;
 301 *max_git_epoch = *nntp_usable = *msg_by_path = \&mm; # undef
 302 *isrch = *search = \&mm; # TODO
 303 *DESTROY = \&pause_dedupe;
 304
 305 1;